configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,2.1)
  10 AM_MAINTAINER_MODE
  11
  12 API_VER=1.0
  13 AC_SUBST(API_VER)
  14
  15 AC_PROG_LN_S
  16
  17 # In case of cygwin, override LN_S, irrespective of what it determines.
  18 # The build uses cygwin, but the actual runtime doesn't.
  19 case $host_os in
  20 *cygwin* ) LN_S='cp -p';;
  21 esac
  22
  23
  24 dnl
  25 dnl libgc checks
  26 dnl
  27
  28 gc_headers=no
  29 gc=included
  30 use_included_gc=no
  31 libgc_configure_args=
  32
  33 if test -d $srcdir/libgc ; then
  34   gc_default=included
  35 else
  36   gc_default=boehm
  37 fi
  38
  39 # These variables are the CPPFLAGS/CFLAGS passed to libgc's configure
  40 # libgc should inherit the original CFLAGS/CPPFLAGS passed to configure, i.e. -O0
  41 CPPFLAGS_FOR_LIBGC=$CPPFLAGS
  42 CFLAGS_FOR_LIBGC=$CFLAGS
  43
  44 #
  45 # These are the flags that need to be stored in the mono.pc file for
  46 # compiling code that will embed Mono
  47 #
  48 libmono_cflags=""
  49 libmono_ldflags=""
  50 AC_SUBST(libmono_cflags)
  51 AC_SUBST(libmono_ldflags)
  52
  53 # Variable to have relocatable .pc files (lib, or lib64)
  54 reloc_libdir=`basename ${libdir}`
  55 AC_SUBST(reloc_libdir)
  56
  57 dnl if linker handles the version script
  58 no_version_script=no
  59
  60 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  61 need_link_unlink=no
  62
  63 # Thread configuration inspired by sleepycat's db
  64 AC_MSG_CHECKING([host platform characteristics])
  65 libgc_threads=no
  66 has_dtrace=no
  67 case "$host" in
  68         *-*-mingw*|*-*-cygwin*)
  69                 platform_win32=yes
  70                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  71                 if test "x$cross_compiling" = "xno"; then
  72                         CC="gcc -mno-cygwin -g"
  73                         # So libgc configure gets -mno-cygwin
  74                         export CC
  75                 fi
  76                 HOST_CC="gcc"
  77                 # Windows 2000 is required that includes Internet Explorer 5.01
  78                 CPPFLAGS="$CPPFLAGS -DWINVER=0x0500 -D_WIN32_WINNT=0x0500 -D_WIN32_IE=0x0501 -D_UNICODE -DUNICODE -DWIN32_THREADS -DFD_SETSIZE=1024"
  79                 libmono_cflags="-mno-cygwin -mms-bitfields -mwindows"
  80                 libmono_ldflags="-mno-cygwin -mms-bitfields -mwindows"
  81                 libdl=
  82                 libgc_threads=win32
  83                 gc_default=included
  84                 with_sigaltstack=no
  85                 LN_S=cp
  86                 # This forces libgc to use the DllMain based thread registration code on win32
  87                 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
  88                 ;;
  89         *-*-*netbsd*)
  90                 platform_win32=no
  91                 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
  92                 libmono_cflags="-D_REENTRANT"
  93                 LDFLAGS="$LDFLAGS -pthread"
  94                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
  95                 libmono_ldflags="-pthread"
  96                 need_link_unlink=yes
  97                 libdl="-ldl"
  98                 libgc_threads=pthreads
  99                 with_sigaltstack=no
 100                 ;;
 101         *-*-*freebsd*)
 102                 platform_win32=no
 103                 if test "x$PTHREAD_CFLAGS" = "x"; then
 104                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 105                         libmono_cflags=
 106                 else
 107                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 108                         libmono_cflags="$PTHREAD_CFLAGS"
 109                 fi
 110                 if test "x$PTHREAD_LIBS" = "x"; then
 111                         LDFLAGS="$LDFLAGS -pthread"
 112                         libmono_ldflags="-pthread"
 113                 else
 114                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 115                         libmono_ldflags="$PTHREAD_LIBS"
 116                 fi
 117                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
 118                 need_link_unlink=yes
 119                 AC_DEFINE(PTHREAD_POINTER_ID, 1, [pthread is a pointer])
 120                 libdl=
 121                 libgc_threads=pthreads
 122                 with_sigaltstack=yes
 123 # TLS is only partially implemented on -CURRENT (compiler support
 124 # but NOT library support)
 125 #
 126                 with_tls=pthread
 127                 ;;
 128         *-*-*openbsd*)
 129                 platform_win32=no
 130                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 131                 libmono_cflags="-D_THREAD_SAFE"
 132                 LDFLAGS="$LDFLAGS -pthread"
 133                 libmono_ldflags="-pthread"
 134                 need_link_unlink=yes
 135                 AC_DEFINE(PTHREAD_POINTER_ID)
 136                 libdl=
 137                 libgc_threads=pthreads
 138                 ;;
 139         *-*-linux*)
 140                 platform_win32=no
 141                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP -DUSE_MUNMAP"
 142                 libmono_cflags="-D_REENTRANT"
 143                 libmono_ldflags="-lpthread"
 144                 libdl="-ldl"
 145                 libgc_threads=pthreads
 146                 ;;
 147         *-*-hpux*)
 148         platform_win32=no
 149                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 150                 # +ESdbgasm only valid on bundled cc on RISC
 151                 # silently ignored for ia64
 152                 if test $GCC != "yes"; then
 153                         CFLAGS="$CFLAGS +ESdbgasm"
 154                         # Arrange for run-time dereferencing of null
 155                         # pointers to produce a SIGSEGV signal.
 156                         LDFLAGS="$LDFLAGS -z"
 157                 fi
 158                 CFLAGS="$CFLAGS +ESdbgasm"
 159                 LDFLAGS="$LDFLAGS -z"
 160                 libmono_cflags="-D_REENTRANT"
 161                 libmono_ldflags="-lpthread"
 162                 libgc_threads=pthreads
 163                 need_link_unlink=yes
 164                 ;;
 165         *-*-solaris*)
 166                 platform_win32=no
 167                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP -DPLATFORM_SOLARIS"
 168                 need_link_unlink=yes
 169                 libmono_cflags="-D_REENTRANT"
 170                 libgc_threads=pthreads
 171                 # This doesn't seem to work on solaris/x86, but the configure test runs
 172                 with_tls=pthread
 173                 has_dtrace=yes
 174                 ;;
 175         *-*-darwin*)
 176                 platform_win32=no
 177                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
 178                 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
 179                 libmono_cflags="-D_THREAD_SAFE"
 180                 LDFLAGS="$LDFLAGS -pthread"
 181                 libmono_ldflags="-pthread"
 182                 need_link_unlink=yes
 183                 AC_DEFINE(PTHREAD_POINTER_ID)
 184                 AC_DEFINE(USE_MACH_SEMA, 1, [...])
 185                 no_version_script=yes
 186                 libdl=
 187                 libgc_threads=pthreads
 188                 has_dtrace=yes
 189                 if test "x$cross_compiling" = "xyes"; then
 190                         has_broken_apple_cpp=yes
 191                 fi
 192                 ;;
 193         *)
 194                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 195                 platform_win32=no
 196                 libdl="-ldl"
 197                 ;;
 198 esac
 199 AC_MSG_RESULT(ok)
 200
 201 if test x$need_link_unlink = xyes; then
 202    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 203 fi
 204
 205 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 206 AM_CONDITIONAL(PLATFORM_LINUX, echo x$target_os | grep -q linux)
 207
 208 AC_CHECK_TOOL(CC, gcc, gcc)
 209 AC_PROG_CC
 210 AM_PROG_AS
 211 AM_PROG_CC_STDC
 212 AC_PROG_INSTALL
 213 AC_PROG_AWK
 214 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 215 : ${CCAS='$(CC)'}
 216 # Set ASFLAGS if not already set.
 217 : ${CCASFLAGS='$(CFLAGS)'}
 218 AC_SUBST(CCAS)
 219 AC_SUBST(CCASFLAGS)
 220
 221 AC_CHECK_PROG(BISON, bison,yes,no)
 222 if test "x$BISON" = "xno";
 223 then
 224         AC_MSG_ERROR([You need to install bison])
 225 fi
 226
 227 dnl may require a specific autoconf version
 228 dnl AC_PROG_CC_FOR_BUILD
 229 dnl CC_FOR_BUILD not automatically detected
 230 CC_FOR_BUILD=$CC
 231 CFLAGS_FOR_BUILD=$CFLAGS
 232 BUILD_EXEEXT=
 233 if test "x$cross_compiling" = "xyes"; then
 234         CC_FOR_BUILD=cc
 235         CFLAGS_FOR_BUILD=
 236         BUILD_EXEEXT=""
 237 fi
 238 AC_SUBST(CC_FOR_BUILD)
 239 AC_SUBST(CFLAGS_FOR_BUILD)
 240 AC_SUBST(HOST_CC)
 241 AC_SUBST(BUILD_EXEEXT)
 242
 243 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
 244 AM_CONDITIONAL(USE_BATCH_FILES, [test x$platform_win32 = xyes -a x$cross_compiling = xyes])
 245
 246 # Set STDC_HEADERS
 247 AC_HEADER_STDC
 248 AC_LIBTOOL_WIN32_DLL
 249 # This causes monodis to not link correctly
 250 #AC_DISABLE_FAST_INSTALL
 251 AM_PROG_LIBTOOL
 252 # Use dolt (http://dolt.freedesktop.org/) instead of libtool for building.
 253 DOLT
 254
 255 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
 256 AC_SUBST(export_ldflags)
 257
 258 # Test whenever ld supports -version-script
 259 AC_PROG_LD
 260 AC_PROG_LD_GNU
 261 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 262    no_version_script=yes
 263 fi
 264
 265 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 266
 267 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h sys/utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h sys/mkdev.h)
 268
 269 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 270 if test x$have_zlib = xyes; then
 271    AC_TRY_COMPILE([#include <zlib.h>], [
 272    void main () {
 273    #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
 274    }
 275    #else
 276    #error No good zlib found
 277    #endif
 278    ],[
 279         AC_MSG_RESULT(Using system zlib)
 280         zlib_msg="system zlib"
 281    ],[
 282         AC_MSG_RESULT(Using embedded zlib)
 283         have_zlib=no
 284         zlib_msg="bundled zlib"
 285    ])
 286 fi
 287
 288 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 289 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
 290
 291 # for mono/metadata/debug-symfile.c
 292 AC_CHECK_HEADERS(elf.h)
 293
 294 # for support
 295 AC_CHECK_HEADERS(poll.h)
 296 AC_CHECK_HEADERS(sys/poll.h)
 297 AC_CHECK_HEADERS(sys/wait.h)
 298 AC_CHECK_HEADERS(grp.h)
 299 AC_CHECK_HEADERS(syslog.h)
 300
 301 # for mono/dis
 302 AC_CHECK_HEADERS(wchar.h)
 303 AC_CHECK_HEADERS(ieeefp.h)
 304 AC_MSG_CHECKING(for isinf)
 305 AC_TRY_LINK([#include <math.h>], [
 306         int f = isinf (1);
 307 ], [
 308         AC_MSG_RESULT(yes)
 309         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 310 ], [
 311         # We'll have to use signals
 312         AC_MSG_RESULT(no)
 313 ])
 314
 315
 316 # not 64 bit clean in cross-compile
 317 AC_CHECK_SIZEOF(void *, 4)
 318
 319 WARN=''
 320 if test x"$GCC" = xyes; then
 321         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 322                 # The runtime code does not respect ANSI C strict aliasing rules
 323                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 324
 325                 ORIG_CFLAGS=$CFLAGS
 326                 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 327                 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
 328                 AC_TRY_COMPILE([], [
 329                                                    void main () { }
 330                 ], [
 331                    AC_MSG_RESULT(yes)
 332                 ], [
 333                    AC_MSG_RESULT(no)
 334                    CFLAGS=$ORIG_CFLAGS
 335                 ])
 336 else
 337         # The Sun Forte compiler complains about inline functions that access static variables
 338         # so disable all inlining.
 339         case "$host" in
 340         *-*-solaris*)
 341                 CFLAGS="$CFLAGS -Dinline="
 342                 ;;
 343         esac
 344 fi
 345 CFLAGS="$CFLAGS -g $WARN"
 346 CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -g"
 347
 348 # Where's the 'mcs' source tree?
 349 if test -d $srcdir/mcs; then
 350   mcsdir=mcs
 351 else
 352   mcsdir=../mcs
 353 fi
 354
 355 #
 356 # A sanity check to catch cases where the package was unpacked
 357 # with an ancient tar program (Solaris)
 358 #
 359 AC_MSG_CHECKING(integrity of package)
 360 if test -f $srcdir/$mcsdir/class/System.Runtime.Serialization.Formatters.Soap/System.Runtime.Serialization.Formatters.Soap/SoapTypeMapper.cs
 361 then
 362    AC_MSG_RESULT(ok)
 363 else
 364    errorm="Your mono distribution is incomplete;  if unpacking from a tar file, make sure you use GNU tar;  see http://www.mono-project.com/IncompletePackage for more details"
 365    AC_MSG_ERROR([$errorm])
 366 fi
 367
 368 mcs_topdir='$(top_srcdir)/'$mcsdir
 369 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 370
 371 ## Maybe should also disable if mcsdir is invalid.  Let's punt the issue for now.
 372 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
 373
 374 AC_SUBST([mcs_topdir])
 375 AC_SUBST([mcs_topdir_from_srcdir])
 376
 377 # Where's the 'olive' source tree?
 378 if test -d $srcdir/olive; then
 379   olivedir=olive
 380 else
 381   olivedir=../olive
 382 fi
 383
 384 if test -d $srcdir/$olivedir; then
 385 olive_topdir='$(top_srcdir)/'$olivedir
 386 fi
 387
 388 # gettext: prepare the translation directories.
 389 # we do not configure the full gettext, as we consume it dynamically from C#
 390 AM_PO_SUBDIRS
 391
 392 AC_ARG_WITH([libgdiplus],
 393         [  --with-libgdiplus=installed|sibling|<path>   Override the libgdiplus used for System.Drawing tests (defaults to NO)],
 394         [], [with_libgdiplus=installed])
 395
 396 case $with_libgdiplus in
 397 no|installed) libgdiplus_loc= ;;
 398 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
 399 /*) libgdiplus_loc=$with_libgdiplus ;;
 400 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
 401 esac
 402 AC_SUBST([libgdiplus_loc])
 403
 404 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 405 if test "x$PKG_CONFIG" = "xno"; then
 406         AC_MSG_ERROR([You need to install pkg-config])
 407 fi
 408
 409 pkg_config_path=
 410 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 411         if test x$with_crosspkgdir = "x"; then
 412                 if test -s $PKG_CONFIG_PATH; then
 413                         pkg_config_path=$PKG_CONFIG_PATH
 414                 fi
 415         else
 416                 pkg_config_path=$with_crosspkgdir
 417                 PKG_CONFIG_PATH=$pkg_config_path
 418                 export PKG_CONFIG_PATH
 419         fi
 420 )
 421
 422 AC_ARG_WITH([glib],
 423         [  --with-glib=embedded|system       Choose glib API: system or embedded (default to system)],
 424         [], [with_glib=system])
 425
 426 eglib_dir=
 427
 428 case $with_glib in
 429 embedded)
 430   GLIB_CFLAGS='-I$(top_srcdir)/eglib/src -I$(top_builddir)/eglib/src'
 431   GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
 432   BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
 433   BUILD_GLIB_LIBS="$GLIB_LIBS"
 434   GMODULE_CFLAGS="$GLIB_CFLAGS"
 435   GMODULE_LIBS="$GLIB_LIBS"
 436   eglib_dir=eglib
 437   AC_CONFIG_SUBDIRS(eglib)
 438   ;;
 439 system)
 440   if test "x$cross_compiling" = "xyes"; then
 441     pkg_config_path="$PKG_CONFIG_PATH"
 442     unset PKG_CONFIG_PATH
 443   fi
 444   BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 445   BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 446   if test "x$cross_compiling" = "xyes"; then
 447     PKG_CONFIG_PATH=$pkg_config_path
 448     export PKG_CONFIG_PATH
 449   fi
 450
 451   ## Versions of dependencies
 452   GLIB_REQUIRED_VERSION=1.3.11
 453
 454   PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 455
 456   GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 457   GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 458   GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 459   GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 460   ;;
 461 *)
 462   AC_MSG_ERROR([Invalid argument to --with-glib.])
 463 esac
 464 AM_CONDITIONAL(EGLIB_BUILD, test x$with_glib = xembedded)
 465
 466 AC_SUBST(GLIB_CFLAGS)
 467 AC_SUBST(GLIB_LIBS)
 468 AC_SUBST(GMODULE_CFLAGS)
 469 AC_SUBST(GMODULE_LIBS)
 470 AC_SUBST(BUILD_GLIB_CFLAGS)
 471 AC_SUBST(BUILD_GLIB_LIBS)
 472 AC_SUBST(eglib_dir)
 473
 474 if test x$cross_compiling$platform_win32 = xnoyes; then
 475    AC_MSG_CHECKING(for cygwin glib2-dev package)
 476    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 477       AC_MSG_RESULT(found)
 478           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 479    else
 480       AC_MSG_RESULT(not found, ok)
 481    fi
 482
 483    AC_MSG_CHECKING(for broken gwin32.h)
 484    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 485    if test -f $glib_include/glib/gwin32.h; then
 486           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 487                  AC_MSG_RESULT(failed)
 488                  hashmark='#'
 489                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 490           fi
 491    fi
 492    AC_MSG_RESULT(ok)
 493 fi
 494
 495 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 496
 497 # Enable support for fast thread-local storage
 498 # Some systems have broken support, so we allow to disable it.
 499 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 500
 501 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 502 # This does not work on some platforms (bug #55253)
 503 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 504
 505 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 506
 507 if test "x$enable_static" = "xno"; then
 508    with_static_mono=no
 509 fi
 510
 511 if test "x$platform_win32" = "xyes"; then
 512    # Boehm GC requires the runtime to be in its own dll
 513    with_static_mono=no
 514 fi
 515
 516 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 517 AC_ARG_ENABLE(mcs-build, [  --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
 518
 519 AC_ARG_WITH(xen_opt,   [  --with-xen_opt=yes,no      Enable Xen-specific behaviour],[],[with_xen_opt=yes])
 520 if test "x$with_xen_opt" = "xyes"; then
 521         AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
 522         ORIG_CFLAGS=$CFLAGS
 523         CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
 524         AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
 525         AC_TRY_COMPILE([], [
 526                                            void main () { }
 527         ], [
 528            AC_MSG_RESULT(yes)
 529            # Pass it to libgc as well
 530            CFLAGS_FOR_LIBGC="$CFLAGS_FOR_LIBGC -mno-tls-direct-seg-refs"
 531         ], [
 532            AC_MSG_RESULT(no)
 533            CFLAGS=$ORIG_CFLAGS
 534         ])
 535 fi
 536
 537 AC_ARG_ENABLE(quiet-build, [  --enable-quiet-build  Enable quiet runtime build], enable_quiet_build=$enableval, enable_quiet_build=yes)
 538
 539 DISABLED_FEATURES=none
 540
 541 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 542   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
 543   reflection_emit, reflection_emit_save, large_code, logging, com, ssa, generics, attach, jit, simd.],
 544 [
 545         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 546                 eval "mono_feature_disable_$feature='yes'"
 547                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 548         done
 549         DISABLED_FEATURES=$enable_minimal
 550         disabled="Disabled:    $enable_minimal"
 551 ],[])
 552
 553 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
 554
 555 if test "x$mono_feature_disable_aot" = "xyes"; then
 556         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 557 fi
 558
 559 if test "x$mono_feature_disable_profiler" = "xyes"; then
 560         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 561 fi
 562 AM_CONDITIONAL(DISABLE_PROFILER, test x$mono_feature_disable_profiler = xyes)
 563
 564 if test "x$mono_feature_disable_decimal" = "xyes"; then
 565         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 566 fi
 567
 568 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 569         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 570 fi
 571
 572 if test "x$mono_feature_disable_debug" = "xyes"; then
 573         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 574 fi
 575
 576 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 577         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 578 fi
 579
 580 if test "x$mono_feature_disable_reflection_emit_save" = "xyes"; then
 581         AC_DEFINE(DISABLE_REFLECTION_EMIT_SAVE, 1, [Disable assembly saving support in reflection emit])
 582 fi
 583
 584 if test "x$mono_feature_disable_large_code" = "xyes"; then
 585         AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
 586 fi
 587
 588 if test "x$mono_feature_disable_logging" = "xyes"; then
 589         AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
 590 fi
 591
 592 if test "x$mono_feature_disable_com" = "xyes"; then
 593         AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
 594 fi
 595
 596 if test "x$mono_feature_disable_ssa" = "xyes"; then
 597         AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
 598 fi
 599
 600 if test "x$mono_feature_disable_generics" = "xyes"; then
 601         AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
 602 fi
 603
 604 if test "x$mono_feature_disable_attach" = "xyes"; then
 605         AC_DEFINE(DISABLE_ATTACH, 1, [Disable agent attach support])
 606 fi
 607
 608 if test "x$mono_feature_disable_jit" = "xyes"; then
 609         AC_DEFINE(DISABLE_JIT, 1, [Disable the JIT, only full-aot mode will be supported by the runtime.])
 610 fi
 611
 612 AM_CONDITIONAL(DISABLE_JIT, test x$mono_feature_disable_jit = xyes)
 613
 614 if test "x$mono_feature_disable_simd" = "xyes"; then
 615         AC_DEFINE(DISABLE_SIMD, 1, [Disable SIMD intrinsics related optimizations.])
 616 fi
 617
 618 AC_MSG_CHECKING(for visibility __attribute__)
 619 AC_TRY_COMPILE([], [
 620    void __attribute__ ((visibility ("hidden"))) doit (void) {}
 621    void main () { doit (); }
 622 ], [
 623    have_visibility_hidden=yes
 624    AC_MSG_RESULT(yes)
 625 ], [
 626    have_visibility_hidden=no
 627    AC_MSG_RESULT(no)
 628 ])
 629
 630 AC_ARG_ENABLE(parallel-mark, [  --enable-parallel-mark     Enables GC Parallel Marking])
 631 if test x$enable_parallel_mark = xyes; then
 632         libgc_configure_args="$libgc_configure_args --enable-parallel-mark"
 633 fi
 634
 635 LIBGC_CFLAGS=
 636 LIBGC_LIBS=
 637 LIBGC_STATIC_LIBS=
 638 libgc_dir=
 639 case "x$gc" in
 640         xboehm|xbohem|xyes)
 641                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 642                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 643
 644                 if test "x$found_boehm" != "xyes"; then
 645                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 646                 fi
 647                 if test "x$gc_headers" != "xyes"; then
 648                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 649                 fi
 650
 651                 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
 652                 AC_SUBST(HAVE_BOEHM_GC)
 653                 LIBGC_LIBS="-lgc $libdl"
 654                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 655
 656                 # AC_CHECK_FUNCS does not work for some reason...
 657                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 658                 if test "x$found_gcj_malloc" = "xyes"; then
 659                         AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
 660                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
 661                 else
 662                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
 663                 fi
 664                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 665                 if test "x$found_gc_enable" = "xyes"; then
 666                         AC_DEFINE(HAVE_GC_ENABLE, 1, [Have 'GC_enable'])
 667                 fi
 668                 ;;
 669
 670         xincluded)
 671                 found_boehm=yes
 672                 gc_headers=yes
 673                 use_included_gc=yes
 674                 libgc_dir=libgc
 675
 676                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 677                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 678                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 679
 680                 AC_DEFINE(HAVE_BOEHM_GC, 1, [Have Boehm GC])
 681                 AC_SUBST(HAVE_BOEHM_GC)
 682
 683                 AC_DEFINE(HAVE_GC_H, 1, [Have gc.h])
 684                 AC_DEFINE(USE_INCLUDED_LIBGC, 1, [Use included libgc])
 685
 686                 # The included libgc contains GCJ support
 687                 AC_DEFINE(HAVE_GC_GCJ_MALLOC, 1, [Have GC_gcj_malloc])
 688                 AC_DEFINE(HAVE_GC_ENABLE, 1, [Have GC_enable])
 689                 if test x$enable_parallel_mark = xyes; then
 690                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC and Parallel Mark)", [GC description])
 691                 else
 692                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
 693                 fi
 694                 ;;
 695
 696         xsgen)
 697                 found_boehm=no
 698                 gc_headers=no
 699                 use_included_gc=no
 700                 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
 701                 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
 702                 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
 703                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
 704                 ;;
 705
 706         xnone)
 707                 AC_MSG_WARN("Compiling mono without GC.")
 708                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
 709                 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
 710                 ;;
 711         *)
 712                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 713                 ;;
 714 esac
 715
 716 AC_ARG_WITH(large-heap, [  --with-large-heap=yes,no    Enable support for GC heaps larger than 3GB], [large_heap=$withval], [large_heap=no])
 717 if test "x$large_heap" = "xyes"; then
 718    echo "FOO"
 719    CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
 720 fi
 721
 722 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 723 AC_SUBST(LIBGC_CFLAGS)
 724 AC_SUBST(LIBGC_LIBS)
 725 AC_SUBST(LIBGC_STATIC_LIBS)
 726 AC_SUBST(libgc_dir)
 727
 728 dnl
 729 dnl End of libgc checks
 730 dnl
 731
 732 if test x$platform_win32 = xno; then
 733
 734         dnl hires monotonic clock support
 735         AC_SEARCH_LIBS(clock_gettime, rt)
 736
 737         dnl dynamic loader support
 738         AC_CHECK_FUNC(dlopen, DL_LIB="",
 739                 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
 740         )
 741         if test x$dl_support = xno; then
 742                 AC_MSG_WARN([No dynamic loading support available])
 743         else
 744                 LIBS="$LIBS $DL_LIB"
 745                 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
 746                 dnl from glib's configure.in
 747                 AC_CACHE_CHECK([for preceeding underscore in symbols],
 748                         mono_cv_uscore,[
 749                         AC_TRY_RUN([#include <dlfcn.h>
 750                         int mono_underscore_test (void) { return 42; }
 751                         int main() {
 752                           void *f1 = (void*)0, *f2 = (void*)0, *handle;
 753                           handle = dlopen ((void*)0, 0);
 754                           if (handle) {
 755                             f1 = dlsym (handle, "mono_underscore_test");
 756                             f2 = dlsym (handle, "_mono_underscore_test");
 757                           } return (!f2 || f1);
 758                         }],
 759                                 [mono_cv_uscore=yes],
 760                                 [mono_cv_uscore=no],
 761                         [])
 762                 ])
 763                 if test "x$mono_cv_uscore" = "xyes"; then
 764                         MONO_DL_NEED_USCORE=1
 765                 else
 766                         MONO_DL_NEED_USCORE=0
 767                 fi
 768                 AC_SUBST(MONO_DL_NEED_USCORE)
 769                 AC_CHECK_FUNC(dlerror)
 770         fi
 771
 772         dnl ******************************************************************
 773         dnl *** Checks for the IKVM JNI interface library                  ***
 774         dnl ******************************************************************
 775         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 776
 777         ikvm_native_dir=
 778         if test x$with_ikvm_native = xyes; then
 779                 ikvm_native_dir=ikvm-native
 780                 jdk_headers_found="IKVM Native"
 781         fi
 782
 783         AC_SUBST(ikvm_native_dir)
 784
 785         AC_CHECK_HEADERS(execinfo.h)
 786
 787         AC_CHECK_FUNCS(getgrgid_r)
 788         AC_CHECK_FUNCS(getgrnam_r)
 789         AC_CHECK_FUNCS(getpwnam_r)
 790         AC_CHECK_FUNCS(getpwuid_r)
 791         AC_CHECK_FUNCS(getresuid)
 792         AC_CHECK_FUNCS(setresuid)
 793         AC_CHECK_FUNCS(kqueue)
 794         AC_CHECK_FUNCS(backtrace_symbols)
 795         AC_CHECK_FUNCS(mkstemp)
 796         AC_CHECK_FUNCS(mmap)
 797         AC_CHECK_FUNCS(madvise)
 798         AC_CHECK_FUNCS(getrusage)
 799         AC_CHECK_FUNCS(getpriority)
 800         AC_CHECK_FUNCS(setpriority)
 801
 802         AC_CHECK_FUNCS(sched_setaffinity)
 803
 804         dnl ******************************************************************
 805         dnl *** Check for large file support                               ***
 806         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 807         dnl ******************************************************************
 808
 809         # Check that off_t can represent 2**63 - 1 correctly, working around
 810         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 811         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 812         large_offt=no
 813         AC_DEFUN([LARGE_FILES], [
 814                 large_CPPFLAGS=$CPPFLAGS
 815                 CPPFLAGS="$CPPFLAGS $1"
 816                 AC_TRY_RUN([
 817                         #include <sys/types.h>
 818
 819                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 820
 821                         int main(void) {
 822                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 823                                                (BIG_OFF_T%2147483647==1));
 824                                 if(big_off_t) {
 825                                         exit(0);
 826                                 } else {
 827                                         exit(1);
 828                                 }
 829                         }
 830                 ], [
 831                         AC_MSG_RESULT(ok)
 832                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT, 1, [Have large file support])
 833                         large_CPPFLAGS="$large_CPPFLAGS $1"
 834                         large_offt=yes
 835                 ], [
 836                         AC_MSG_RESULT(no)
 837                 ], "")
 838                 CPPFLAGS=$large_CPPFLAGS
 839         ])
 840
 841         AC_MSG_CHECKING(if off_t is 64 bits wide)
 842         LARGE_FILES("")
 843         if test $large_offt = no; then
 844                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 845                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 846         fi
 847         if test $large_offt = no; then
 848                 AC_MSG_WARN([No 64 bit file size support available])
 849         fi
 850
 851         dnl *****************************
 852         dnl *** Checks for libsocket  ***
 853         dnl *****************************
 854         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 855
 856         dnl *******************************
 857         dnl *** Checks for MSG_NOSIGNAL ***
 858         dnl *******************************
 859         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 860         AC_TRY_COMPILE([#include <sys/socket.h>], [
 861                 int f = MSG_NOSIGNAL;
 862         ], [
 863                 # Yes, we have it...
 864                 AC_MSG_RESULT(yes)
 865                 AC_DEFINE(HAVE_MSG_NOSIGNAL, 1, [Have MSG_NOSIGNAL])
 866         ], [
 867                 # We'll have to use signals
 868                 AC_MSG_RESULT(no)
 869         ])
 870
 871         dnl *****************************
 872         dnl *** Checks for SOL_IP     ***
 873         dnl *****************************
 874         AC_MSG_CHECKING(for SOL_IP)
 875         AC_TRY_COMPILE([#include <netdb.h>], [
 876                 int level = SOL_IP;
 877         ], [
 878                 # Yes, we have it...
 879                 AC_MSG_RESULT(yes)
 880                 AC_DEFINE(HAVE_SOL_IP, 1, [Have SOL_IP])
 881         ], [
 882                 # We'll have to use getprotobyname
 883                 AC_MSG_RESULT(no)
 884         ])
 885
 886         dnl *****************************
 887         dnl *** Checks for SOL_IPV6     ***
 888         dnl *****************************
 889         AC_MSG_CHECKING(for SOL_IPV6)
 890         AC_TRY_COMPILE([#include <netdb.h>], [
 891                 int level = SOL_IPV6;
 892         ], [
 893                 # Yes, we have it...
 894                 AC_MSG_RESULT(yes)
 895                 AC_DEFINE(HAVE_SOL_IPV6, 1, [Have SOL_IPV6])
 896         ], [
 897                 # We'll have to use getprotobyname
 898                 AC_MSG_RESULT(no)
 899         ])
 900
 901         dnl *****************************
 902         dnl *** Checks for SOL_TCP    ***
 903         dnl *****************************
 904         AC_MSG_CHECKING(for SOL_TCP)
 905         AC_TRY_COMPILE([#include <netdb.h>], [
 906                 int level = SOL_TCP;
 907         ], [
 908                 # Yes, we have it...
 909                 AC_MSG_RESULT(yes)
 910                 AC_DEFINE(HAVE_SOL_TCP, 1, [Have SOL_TCP])
 911         ], [
 912                 # We'll have to use getprotobyname
 913                 AC_MSG_RESULT(no)
 914         ])
 915
 916         dnl *****************************
 917         dnl *** Checks for IP_PKTINFO ***
 918         dnl *****************************
 919         AC_MSG_CHECKING(for IP_PKTINFO)
 920         AC_TRY_COMPILE([#include <netdb.h>], [
 921                 int level = IP_PKTINFO;
 922         ], [
 923                 # Yes, we have it...
 924                 AC_MSG_RESULT(yes)
 925                 AC_DEFINE(HAVE_IP_PKTINFO, 1, [Have IP_PKTINFO])
 926         ], [
 927                 AC_MSG_RESULT(no)
 928         ])
 929
 930         dnl *****************************
 931         dnl *** Checks for IPV6_PKTINFO ***
 932         dnl *****************************
 933         AC_MSG_CHECKING(for IPV6_PKTINFO)
 934         AC_TRY_COMPILE([#include <netdb.h>], [
 935                 int level = IPV6_PKTINFO;
 936         ], [
 937                 # Yes, we have it...
 938                 AC_MSG_RESULT(yes)
 939                 AC_DEFINE(HAVE_IPV6_PKTINFO, 1, [Have IPV6_PKTINFO])
 940         ], [
 941                 AC_MSG_RESULT(no)
 942         ])
 943
 944         dnl **********************************
 945         dnl *** Checks for IP_DONTFRAGMENT ***
 946         dnl **********************************
 947         AC_MSG_CHECKING(for IP_DONTFRAGMENT)
 948         AC_TRY_COMPILE([#include <netdb.h>], [
 949                 int level = IP_DONTFRAGMENT;
 950         ], [
 951                 # Yes, we have it...
 952                 AC_MSG_RESULT(yes)
 953                 AC_DEFINE(HAVE_IP_DONTFRAGMENT, 1, [Have IP_DONTFRAGMENT])
 954         ], [
 955                 AC_MSG_RESULT(no)
 956         ])
 957
 958         dnl **********************************
 959         dnl *** Checks for IP_MTU_DISCOVER ***
 960         dnl **********************************
 961         AC_MSG_CHECKING(for IP_MTU_DISCOVER)
 962         AC_TRY_COMPILE([#include <netdb.h>], [
 963                 int level = IP_MTU_DISCOVER;
 964         ], [
 965                 # Yes, we have it...
 966                 AC_MSG_RESULT(yes)
 967                 AC_DEFINE(HAVE_IP_MTU_DISCOVER, 1, [Have IP_MTU_DISCOVER])
 968         ], [
 969                 AC_MSG_RESULT(no)
 970         ])
 971
 972         dnl *********************************
 973         dnl *** Check for struct ip_mreqn ***
 974         dnl *********************************
 975         AC_MSG_CHECKING(for struct ip_mreqn)
 976         AC_TRY_COMPILE([#include <netinet/in.h>], [
 977                 struct ip_mreqn mreq;
 978                 mreq.imr_address.s_addr = 0;
 979         ], [
 980                 # Yes, we have it...
 981                 AC_MSG_RESULT(yes)
 982                 AC_DEFINE(HAVE_STRUCT_IP_MREQN, 1, [Have struct ip_mreqn])
 983         ], [
 984                 # We'll just have to try and use struct ip_mreq
 985                 AC_MSG_RESULT(no)
 986                 AC_MSG_CHECKING(for struct ip_mreq)
 987                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 988                         struct ip_mreq mreq;
 989                         mreq.imr_interface.s_addr = 0;
 990                 ], [
 991                         # Yes, we have it...
 992                         AC_MSG_RESULT(yes)
 993                         AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1, [Have struct ip_mreq])
 994                 ], [
 995                         # No multicast support
 996                         AC_MSG_RESULT(no)
 997                 ])
 998         ])
 999
1000         dnl **********************************
1001         dnl *** Check for gethostbyname2_r ***
1002         dnl **********************************
1003         AC_MSG_CHECKING(for gethostbyname2_r)
1004                 AC_TRY_LINK([#include <netdb.h>], [
1005                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
1006         ], [
1007                 # Yes, we have it...
1008                 AC_MSG_RESULT(yes)
1009                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R, 1, [Have gethostbyname2_r])
1010         ], [
1011                 AC_MSG_RESULT(no)
1012         ])
1013
1014         dnl *****************************
1015         dnl *** Checks for libnsl     ***
1016         dnl *****************************
1017         AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1018
1019         AC_CHECK_FUNCS(inet_pton inet_aton)
1020
1021         dnl ***********************************************
1022         dnl *** Checks for size of sockaddr_un.sun_path ***
1023         dnl ***********************************************
1024         # AC_CHECK_SIZEOF can't cope with struct members :-(
1025         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1026         AC_CACHE_VAL(mono_cv_sizeof_sunpath,
1027                 [AC_TRY_RUN([
1028                         #include <sys/types.h>
1029                         #include <stdio.h>
1030                         #include <sys/un.h>
1031
1032                         int main(void) {
1033                                 struct sockaddr_un sock_un;
1034                                 FILE *f=fopen("conftestval", "w");
1035                                 if(!f) exit(1);
1036                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1037                                 exit(0);
1038                         }
1039                 ], mono_cv_sizeof_sunpath=`cat conftestval`,
1040                    mono_cv_sizeof_sunpath=0,
1041                    mono_cv_sizeof_sunpath=0)])dnl
1042         AC_MSG_RESULT($mono_cv_sizeof_sunpath)
1043         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $mono_cv_sizeof_sunpath, [Sizeof sock_un.sun_path])
1044
1045         dnl *************************************
1046         dnl *** Checks for zero length arrays ***
1047         dnl *************************************
1048         AC_MSG_CHECKING(whether $CC supports zero length arrays)
1049         AC_TRY_COMPILE([
1050                 struct s {
1051                         int  length;
1052                         char data [0];
1053                 };
1054         ], [], [
1055                 AC_MSG_RESULT(yes)
1056                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0, [Length of zero length arrays])
1057         ], [
1058                 AC_MSG_RESULT(no)
1059                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1, [Length of zero length arrays])
1060         ])
1061
1062         dnl *****************************
1063         dnl *** Checks for libxnet    ***
1064         dnl *****************************
1065         case "${host}" in
1066                 *solaris* )
1067                         AC_MSG_CHECKING(for Solaris XPG4 support)
1068                         if test -f /usr/lib/libxnet.so; then
1069                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1070                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1071                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1072                                 LIBS="$LIBS -lxnet"
1073                                 AC_MSG_RESULT(yes)
1074                         else
1075                                 AC_MSG_RESULT(no)
1076                         fi
1077
1078                         if test "$GCC" = "yes"; then
1079                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
1080                         fi
1081                 ;;
1082         esac
1083
1084         dnl *****************************
1085         dnl *** Checks for libpthread ***
1086         dnl *****************************
1087 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1088 # and libpthread does not exist
1089 #
1090         case "${host}" in
1091                 *-*-*freebsd*)
1092                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1093                 ;;
1094                 *)
1095                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1096                 ;;
1097         esac
1098         AC_CHECK_HEADERS(pthread.h)
1099         AC_CHECK_FUNCS(pthread_mutex_timedlock)
1100         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1101         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1102         AC_TRY_COMPILE([ #include <pthread.h>], [
1103                 pthread_mutexattr_t attr;
1104                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1105         ], [
1106                 AC_MSG_RESULT(ok)
1107         ], [
1108                 AC_MSG_RESULT(no)
1109                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1110                 AC_DEFINE(USE_MONO_MUTEX, 1, [Use mono_mutex_t])
1111         ])
1112         AC_CHECK_FUNCS(pthread_attr_setstacksize)
1113         AC_CHECK_FUNCS(pthread_attr_getstack)
1114         AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1115
1116         dnl ***********************************
1117         dnl *** Checks for working __thread ***
1118         dnl ***********************************
1119         AC_MSG_CHECKING(for working __thread)
1120         if test "x$with_tls" != "x__thread"; then
1121                 AC_MSG_RESULT(disabled)
1122         else
1123                 AC_TRY_RUN([
1124                         #include <pthread.h>
1125                         __thread int i;
1126                         static int res1, res2;
1127
1128                         void thread_main (void *arg)
1129                         {
1130                                 i = arg;
1131                                 sleep (1);
1132                                 if (arg == 1)
1133                                         res1 = (i == arg);
1134                                 else
1135                                         res2 = (i == arg);
1136                         }
1137
1138                         int main () {
1139                                 pthread_t t1, t2;
1140
1141                                 i = 5;
1142
1143                                 pthread_create (&t1, NULL, thread_main, 1);
1144                                 pthread_create (&t2, NULL, thread_main, 2);
1145
1146                                 pthread_join (t1, NULL);
1147                                 pthread_join (t2, NULL);
1148
1149                                 return !(res1 + res2 == 2);
1150                         }
1151                 ], [
1152                                 AC_MSG_RESULT(yes)
1153                 ], [
1154                                 AC_MSG_RESULT(no)
1155                                 with_tls=pthread
1156                 ])
1157         fi
1158
1159         dnl **************************************
1160         dnl *** Checks for working sigaltstack ***
1161         dnl **************************************
1162         AC_MSG_CHECKING(for working sigaltstack)
1163         if test "x$with_sigaltstack" != "xyes"; then
1164                 AC_MSG_RESULT(disabled)
1165         else
1166                 AC_TRY_RUN([
1167                         #include <stdio.h>
1168                         #include <stdlib.h>
1169                         #include <unistd.h>
1170                         #include <signal.h>
1171                         #include <pthread.h>
1172                         #include <sys/wait.h>
1173                         #if defined(__FreeBSD__) || defined(__NetBSD__)
1174                         #define SA_STACK SA_ONSTACK
1175                         #endif
1176                         static void
1177                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1178                         {
1179                                 exit (0);
1180                         }
1181
1182                         static void *
1183                         loop (void *ignored)
1184                         {
1185                                 char *ptr = NULL;
1186
1187                                 *ptr = 0;
1188                                 return NULL;
1189                         }
1190
1191                         static void
1192                         child ()
1193                         {
1194                                 struct sigaction sa;
1195                                 struct sigaltstack sas;
1196                                 pthread_t id;
1197                                 pthread_attr_t attr;
1198
1199                                 sa.sa_sigaction = sigsegv_signal_handler;
1200                                 sigemptyset (&sa.sa_mask);
1201                                 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1202                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1203                                         perror ("sigaction");
1204                                         return;
1205                                 }
1206
1207                                 sas.ss_sp = malloc (SIGSTKSZ);
1208                                 sas.ss_size = SIGSTKSZ;
1209                                 sas.ss_flags = 0;
1210                                 if (sigaltstack (&sas, NULL) == -1) {
1211                                         perror ("sigaltstack");
1212                                         return;
1213                                 }
1214
1215                                 pthread_attr_init (&attr);
1216                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1217                                         printf ("pthread_create\n");
1218                                         return;
1219                                 }
1220
1221                                 sleep (100);
1222                         }
1223
1224                         int
1225                         main ()
1226                         {
1227                                 pid_t son;
1228                                 int status;
1229                                 int i;
1230
1231                                 son = fork ();
1232                                 if (son == -1) {
1233                                         return 1;
1234                                 }
1235
1236                                 if (son == 0) {
1237                                         child ();
1238                                         return 0;
1239                                 }
1240
1241                                 for (i = 0; i < 3; ++i) {
1242                                         sleep (1);
1243                                         waitpid (son, &status, WNOHANG);
1244                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1245                                                 return 0;
1246                                 }
1247
1248                                 kill (son, SIGKILL);
1249                                 return 1;
1250                         }
1251
1252                 ], [
1253                                 AC_MSG_RESULT(yes)
1254                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK, 1, [Have a working sigaltstack])
1255                 ], [
1256                                 with_sigaltstack=no
1257                                 AC_MSG_RESULT(no)
1258                 ])
1259         fi
1260
1261         dnl ********************************
1262         dnl *** Checks for semaphore lib ***
1263         dnl ********************************
1264         # 'Real Time' functions on Solaris
1265         # posix4 on Solaris 2.6
1266         # pthread (first!) on Linux
1267         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1268
1269         dnl ********************************
1270         dnl *** Checks for timezone stuff **
1271         dnl ********************************
1272         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1273                 AC_TRY_COMPILE([
1274                         #include <time.h>
1275                         ], [
1276                         struct tm tm;
1277                         tm.tm_gmtoff = 1;
1278                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1279         if test $ac_cv_struct_tm_gmtoff = yes; then
1280                 AC_DEFINE(HAVE_TM_GMTOFF, 1, [Have tm_gmtoff])
1281         else
1282                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1283                         AC_TRY_COMPILE([
1284                                 #include <time.h>
1285                         ], [
1286                                 timezone = 1;
1287                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1288                 if test $ac_cv_var_timezone = yes; then
1289                         AC_DEFINE(HAVE_TIMEZONE, 1, [Have timezone variable])
1290                 else
1291                         AC_ERROR(unable to find a way to determine timezone)
1292                 fi
1293         fi
1294
1295         dnl *********************************
1296         dnl *** Checks for math functions ***
1297         dnl *********************************
1298         LIBS="$LIBS -lm";
1299         if test "x$has_broken_apple_cpp" != "xyes"; then
1300                 AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1301                         AC_TRY_LINK([#include <math.h>],
1302                         [ finite(0.0); ],
1303                         AC_DEFINE(HAVE_FINITE, 1, [Have finite]) AC_MSG_RESULT(yes),
1304                         AC_MSG_RESULT(no)))
1305         fi
1306         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1307                 AC_TRY_LINK([#include <math.h>],
1308                 [ isfinite(0.0); ],
1309                 AC_DEFINE(HAVE_ISFINITE, 1, [Have isfinite]) AC_MSG_RESULT(yes),
1310                 AC_MSG_RESULT(no)))
1311
1312         dnl ****************************************************************
1313         dnl *** Checks for working poll() (macosx defines it but doesn't ***
1314         dnl *** have it in the library (duh))                            ***
1315         dnl ****************************************************************
1316         AC_CHECK_FUNCS(poll)
1317
1318         dnl *************************
1319         dnl *** Check for signbit ***
1320         dnl *************************
1321         AC_MSG_CHECKING(for signbit)
1322         AC_TRY_LINK([#include <math.h>], [
1323                 int s = signbit(1.0);
1324         ], [
1325                 AC_MSG_RESULT(yes)
1326                 AC_DEFINE(HAVE_SIGNBIT, 1, [Have signbit])
1327         ], [
1328                 AC_MSG_RESULT(no)
1329         ])
1330
1331         dnl **********************************
1332         dnl *** epoll                      ***
1333         dnl **********************************
1334         AC_CHECK_HEADERS(sys/epoll.h)
1335         haveepoll=no
1336         AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1337         if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1338                 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1339         fi
1340
1341         dnl ******************************
1342         dnl *** Checks for SIOCGIFCONF ***
1343         dnl ******************************
1344         AC_CHECK_HEADERS(sys/ioctl.h)
1345         AC_CHECK_HEADERS(net/if.h)
1346         AC_MSG_CHECKING(for ifreq)
1347         AC_TRY_COMPILE([
1348                 #include <sys/ioctl.h>
1349                 #include <net/if.h>
1350                 ], [
1351                 struct ifconf ifc;
1352                 struct ifreq *ifr;
1353                 void *x;
1354                 ifc.ifc_len = 0;
1355                 ifc.ifc_buf = NULL;
1356                 x = (void *) &ifr->ifr_addr;
1357                 ],[
1358                         AC_MSG_RESULT(yes)
1359                         AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1360                 ], [
1361                         AC_MSG_RESULT(no)
1362                 ])
1363         dnl **********************************
1364         dnl ***     Checks for sin_len     ***
1365         dnl **********************************
1366         AC_MSG_CHECKING(for sockaddr_in.sin_len)
1367         AC_TRY_COMPILE([
1368                 #include <netinet/in.h>
1369                 ], [
1370                 struct sockaddr_in saddr;
1371                 saddr.sin_len = sizeof (saddr);
1372                 ],[
1373                         AC_MSG_RESULT(yes)
1374                         AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1375                 ], [
1376                         AC_MSG_RESULT(no)
1377                 ])
1378         dnl **********************************
1379         dnl ***    Checks for sin6_len     ***
1380         dnl **********************************
1381         AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1382         AC_TRY_COMPILE([
1383                 #include <netinet/in.h>
1384                 ], [
1385                 struct sockaddr_in6 saddr6;
1386                 saddr6.sin6_len = sizeof (saddr6);
1387                 ],[
1388                         AC_MSG_RESULT(yes)
1389                         AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1390                 ], [
1391                         AC_MSG_RESULT(no)
1392                 ])
1393         dnl **********************************
1394         dnl *** Checks for MonoPosixHelper ***
1395         dnl **********************************
1396         AC_CHECK_HEADERS(checklist.h)
1397         AC_CHECK_HEADERS(fstab.h)
1398         AC_CHECK_HEADERS(attr/xattr.h)
1399         AC_CHECK_HEADERS(sys/extattr.h)
1400         AC_CHECK_HEADERS(sys/sendfile.h)
1401         AC_CHECK_HEADERS(sys/statvfs.h)
1402         AC_CHECK_HEADERS(sys/vfstab.h)
1403         AC_CHECK_HEADERS(sys/xattr.h)
1404         AC_CHECK_HEADERS(sys/mman.h)
1405         AC_CHECK_FUNCS(getdomainname)
1406         AC_CHECK_FUNCS(setdomainname)
1407         AC_CHECK_FUNCS(fgetgrent)
1408         AC_CHECK_FUNCS(fgetpwent)
1409         AC_CHECK_FUNCS(fgetpwent)
1410         AC_CHECK_FUNCS(getfsstat)
1411         AC_CHECK_FUNCS(lutimes)
1412         AC_CHECK_FUNCS(mremap)
1413         AC_CHECK_FUNCS(remap_file_pages)
1414         AC_CHECK_FUNCS(posix_fadvise)
1415         AC_CHECK_FUNCS(posix_fallocate)
1416         AC_CHECK_FUNCS(posix_madvise)
1417         AC_CHECK_FUNCS(vsnprintf)
1418         AC_CHECK_FUNCS(sendfile)
1419         AC_CHECK_FUNCS(sethostid)
1420         AC_CHECK_FUNCS(statfs)
1421         AC_CHECK_FUNCS(fstatfs)
1422         AC_CHECK_FUNCS(statvfs)
1423         AC_CHECK_FUNCS(fstatvfs)
1424         AC_CHECK_FUNCS(stime)
1425         AC_CHECK_FUNCS(strerror_r)
1426         AC_CHECK_FUNCS(ttyname_r)
1427         AC_CHECK_SIZEOF(size_t)
1428         AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1429                 [#include <sys/types.h>
1430                  #include <sys/stat.h>
1431                  #include <unistd.h>])
1432         AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1433                 [#include <sys/types.h>
1434                  #include <sys/stat.h>
1435                  #include <unistd.h>])
1436         AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1437                 [#include <sys/time.h>])
1438         AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1439                 [#include <sys/poll.h>])
1440         AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1441                 [#include <sys/types.h>
1442                  #include <sys/stat.h>
1443                  #include <unistd.h>])
1444         AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1445                 [#include <sys/time.h>
1446                  #include <sys/types.h>
1447                  #include <utime.h>])
1448         AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1449                 [#include <sys/time.h>])
1450         AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1451                 [#include <sys/types.h>
1452                  #include <utime.h>])
1453         AC_CHECK_MEMBERS(
1454                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1455                 [#include <sys/types.h>
1456                  #include <dirent.h>])
1457
1458         dnl Favour xattr through glibc, but use libattr if we have to
1459         AC_CHECK_FUNC(lsetxattr, ,
1460                 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1461         )
1462         AC_SUBST(XATTR_LIB)
1463
1464         dnl *********************************
1465         dnl *** Checks for Windows compilation ***
1466         dnl *********************************
1467         AC_CHECK_HEADERS(sys/time.h)
1468         AC_CHECK_HEADERS(sys/param.h)
1469
1470         dnl *********************************
1471         dnl *** Check for Console 2.0 I/O ***
1472         dnl *********************************
1473         AC_CHECK_HEADERS([curses.h])
1474         AC_CHECK_HEADERS([term.h], [], [],
1475         [#if HAVE_CURSES_H
1476          #include <curses.h>
1477          #endif
1478         ])
1479         AC_CHECK_HEADERS([termios.h])
1480
1481         dnl * This is provided in io-layer, but on windows it's only available
1482         dnl * on xp+
1483         AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1484 else
1485         jdk_headers_found=no
1486         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1487         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1488         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1489         AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1490         AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1491         AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1492         AC_CHECK_LIB(version, main, LIBS="$LIBS -lversion", AC_ERROR(bad mingw install?))
1493
1494         dnl *********************************
1495         dnl *** Check for struct ip_mreqn ***
1496         dnl *********************************
1497         AC_MSG_CHECKING(for struct ip_mreqn)
1498         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1499                 struct ip_mreqn mreq;
1500                 mreq.imr_address.s_addr = 0;
1501         ], [
1502                 # Yes, we have it...
1503                 AC_MSG_RESULT(yes)
1504                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1505         ], [
1506                 # We'll just have to try and use struct ip_mreq
1507                 AC_MSG_RESULT(no)
1508                 AC_MSG_CHECKING(for struct ip_mreq)
1509                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1510                         struct ip_mreq mreq;
1511                         mreq.imr_interface.s_addr = 0;
1512                 ], [
1513                         # Yes, we have it...
1514                         AC_MSG_RESULT(yes)
1515                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1516                 ], [
1517                         # No multicast support
1518                         AC_MSG_RESULT(no)
1519                 ])
1520         ])
1521         AC_CHECK_FUNCS(GetProcessId)
1522 fi
1523
1524 dnl socklen_t check
1525 AC_MSG_CHECKING(for socklen_t)
1526 AC_TRY_COMPILE([
1527 #include <sys/types.h>
1528 #include <sys/socket.h>
1529 ],[
1530   socklen_t foo;
1531 ],[
1532 ac_cv_c_socklen_t=yes
1533         AC_DEFINE(HAVE_SOCKLEN_T, 1, [Have socklen_t])
1534         AC_MSG_RESULT(yes)
1535 ],[
1536         AC_MSG_RESULT(no)
1537 ])
1538
1539 AC_MSG_CHECKING(for array element initalizer support)
1540 AC_TRY_COMPILE([#include <sys/socket.h>], [
1541         const int array[] = {[1] = 2,};
1542 ], [
1543         # Yes, we have it...
1544         AC_MSG_RESULT(yes)
1545         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1546 ], [
1547         # We'll have to use signals
1548         AC_MSG_RESULT(no)
1549 ])
1550
1551 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1552         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1553         AC_TRY_LINK([#include <math.h>],
1554         [ static void *p = &trunc; ],
1555         [
1556                 AC_DEFINE(HAVE_TRUNC)
1557                 AC_MSG_RESULT(yes)
1558                 ac_cv_trunc=yes
1559         ],
1560         AC_MSG_RESULT(no)))
1561
1562 if test "x$ac_cv_truncl" != "xyes"; then
1563    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL, 1, [Has the 'aintl' function]) LIBS="$LIBS -lsunmath"])
1564 fi
1565
1566 dnl ****************************
1567 dnl *** Look for /dev/random ***
1568 dnl ****************************
1569
1570 AC_MSG_CHECKING([if usage of random device is requested])
1571 AC_ARG_ENABLE(dev-random,
1572 [  --disable-dev-random    disable the use of the random device],
1573 try_dev_random=$enableval, try_dev_random=yes)
1574 AC_MSG_RESULT($try_dev_random)
1575
1576 case "{$target}" in
1577     *-openbsd*)
1578     NAME_DEV_RANDOM="/dev/srandom"
1579     ;;
1580
1581 dnl Win32 does not have /dev/random, they have their own method...
1582
1583     *-*-mingw*|*-*-cygwin*)
1584     ac_cv_have_dev_random=no
1585     ;;
1586
1587 dnl Everywhere else, it's /dev/random
1588
1589     *)
1590     NAME_DEV_RANDOM="/dev/random"
1591     ;;
1592 esac
1593
1594 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM", [Name of /dev/random])
1595
1596 dnl Now check if the device actually exists
1597
1598 if test "x$try_dev_random" = "xyes"; then
1599     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1600     [if test -r "$NAME_DEV_RANDOM" ; then
1601         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1602     if test "x$ac_cv_have_dev_random" = "xyes"; then
1603         AC_DEFINE(HAVE_CRYPT_RNG, 1, [Have /dev/random])
1604     fi
1605 else
1606     AC_MSG_CHECKING(for random device)
1607     ac_cv_have_dev_random=no
1608     AC_MSG_RESULT(has been disabled)
1609 fi
1610
1611 if test "x$platform_win32" = "xyes"; then
1612     AC_DEFINE(HAVE_CRYPT_RNG)
1613 fi
1614
1615 if test "x$ac_cv_have_dev_random" = "xno" \
1616     && test "x$platform_win32" = "xno"; then
1617     AC_MSG_WARN([[
1618 ***
1619 *** A system-provided entropy source was not found on this system.
1620 *** Because of this, the System.Security.Cryptography random number generator
1621 *** will throw a NotImplemented exception.
1622 ***
1623 *** If you are seeing this message, and you know your system DOES have an
1624 *** entropy collection in place, please contact <crichton@gimp.org> and
1625 *** provide information about the system and how to access the random device.
1626 ***
1627 *** Otherwise you can install either egd or prngd and set the environment
1628 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1629 ***]])
1630 fi
1631
1632 AC_MSG_CHECKING([if inter-process shared handles are requested])
1633 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1634 AC_MSG_RESULT($try_shared_handles)
1635 if test "x$try_shared_handles" != "xyes"; then
1636         AC_DEFINE(DISABLE_SHARED_HANDLES, 1, [Disable inter-process shared handles])
1637         AC_SUBST(DISABLE_SHARED_HANDLES)
1638 fi
1639
1640 if test x$gc = xsgen; then
1641    if test x$with_tls != x__thread; then
1642           AC_MSG_ERROR([The SGEN garbage collector depends on a working __thread implementation, and either --with-thread=pthread was passed to configure, or the configure test for __thread failed.])
1643    fi
1644 fi
1645
1646 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1647 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1648
1649 AC_MSG_CHECKING([if big-arrays are to be enabled])
1650 AC_ARG_ENABLE(big-arrays,  [ --enable-big-arrays        Enable the allocation and indexing of arrays greater than Int32.MaxValue], enable_big_arrays=$enableval, enable_big_arrays=no)
1651 if test "x$enable_big_arrays" = "xyes" ; then
1652     if  test "x$ac_cv_sizeof_void_p" = "x8"; then
1653         AC_DEFINE(MONO_BIG_ARRAYS,1,[Enable the allocation and indexing of arrays greater than Int32.MaxValue])
1654     else
1655         AC_MSG_ERROR([The allocation and indexing of arrays greater than Int32.MaxValue is not supported on this platform.])
1656     fi
1657 fi
1658 AC_MSG_RESULT($enable_big_arrays)
1659
1660 dnl **************
1661 dnl *** DTRACE ***
1662 dnl **************
1663
1664 AC_ARG_ENABLE(dtrace,[  --enable-dtrace Enable DTrace probes], enable_dtrace=$enableval, enable_dtrace=$has_dtrace)
1665
1666 if test "x$enable_dtrace" = "xyes"; then
1667    if test "x$has_dtrace" = "xno"; then
1668           AC_MSG_ERROR([DTrace probes are not supported on this platform.])
1669    fi
1670    AC_PATH_PROG(DTRACE, [dtrace], [no], [$PATH:/usr/sbin])
1671    if test "x$DTRACE" = "xno"; then
1672           AC_MSG_RESULT([dtrace utility not found, dtrace support disabled.])
1673           enable_dtrace=no
1674    fi
1675 fi
1676
1677 dtrace_g=no
1678 if test "x$enable_dtrace" = "xyes"; then
1679         AC_DEFINE(ENABLE_DTRACE, 1, [Enable DTrace probes])
1680         DTRACEFLAGS=
1681         if test "x$ac_cv_sizeof_void_p" = "x8"; then
1682                 case "$host" in
1683                         powerpc-*-darwin*)
1684                         DTRACEFLAGS="-arch ppc64"
1685                         ;;
1686                         i*86-*-darwin*)
1687                         DTRACEFLAGS="-arch x86_64"
1688                         ;;
1689                         *)
1690                         DTRACEFLAGS=-64
1691                         ;;
1692                 esac
1693         else
1694                 case "$host" in
1695                         powerpc-*-darwin*)
1696                         DTRACEFLAGS="-arch ppc"
1697                         ;;
1698                         i*86-*-darwin*)
1699                         DTRACEFLAGS="-arch i386"
1700                         ;;
1701                         *)
1702                         DTRACEFLAGS=-32
1703                         ;;
1704                 esac
1705         fi
1706         AC_SUBST(DTRACEFLAGS)
1707         case "$host" in
1708                 *-*-solaris*)
1709                 dtrace_g=yes
1710                 ;;
1711         esac
1712         AC_CHECK_HEADERS([sys/sdt.h])
1713 fi
1714 AM_CONDITIONAL(ENABLE_DTRACE, [test x$enable_dtrace = xyes])
1715 AM_CONDITIONAL(DTRACE_G_REQUIRED, [test x$dtrace_g = xyes])
1716
1717 TARGET="unknown"
1718 ACCESS_UNALIGNED="yes"
1719
1720 JIT_SUPPORTED=no
1721 INTERP_SUPPORTED=no
1722 LIBC="libc.so.6"
1723 INTL="libc.so.6"
1724 SQLITE="libsqlite.so.0"
1725 SQLITE3="libsqlite3.so.0"
1726 X11="libX11.so"
1727
1728 jit_wanted=false
1729 interp_wanted=false
1730 case "$host" in
1731 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1732 #               TARGET=MIPS;
1733 #               ACCESS_UNALIGNED="no"
1734 #               ;;
1735         mips*)
1736                 TARGET=MIPS;
1737                 arch_target=mips;
1738                 ACCESS_UNALIGNED="no"
1739                 JIT_SUPPORTED=yes
1740                 jit_wanted=true
1741                 ;;
1742         i*86-*-*)
1743                 TARGET=X86;
1744                 arch_target=x86;
1745                 JIT_SUPPORTED=yes
1746                 jit_wanted=true
1747                 case $host_os in
1748                   solaris*)
1749                         LIBC="libc.so"
1750                         INTL="libintl.so"
1751                         if test "x$ac_cv_sizeof_void_p" = "x8"; then
1752                                 TARGET=AMD64
1753                                 arch_target=amd64
1754                         fi
1755
1756                         # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
1757                         # int astruct __attribute__ ((visibility ("hidden")));
1758                         # void foo ()
1759                         # {
1760                         #       void *p = &astruct;
1761                         # }
1762                         # gcc -fPIC --shared -o libfoo.so foo.c
1763                         # yields:
1764                         # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
1765                         # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
1766                         have_visibility_hidden=no
1767
1768                 esac
1769                 ;;
1770         x86_64-*-* | amd64-*-*)
1771                 TARGET=AMD64;
1772                 arch_target=amd64;
1773                 JIT_SUPPORTED=yes
1774                 jit_wanted=true
1775                 ;;
1776         ia64-*-*)
1777                 TARGET=IA64
1778                 arch_target=ia64
1779                 ACCESS_UNALIGNED="no"
1780                 JIT_SUPPORTED=yes
1781                 jit_wanted=true
1782                 LIBC="libc.so.6.1"
1783                 INTL="libc.so.6.1"
1784                 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
1785                 libmono_ldflags="-lunwind"
1786                 ;;
1787         sparc*-*-*)
1788                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1789                    TARGET=SPARC64
1790                 else
1791                         TARGET=SPARC
1792                 fi
1793                 arch_target=sparc;
1794                 JIT_SUPPORTED=yes
1795                 ACCESS_UNALIGNED="no"
1796                 case $host_os in
1797                   linux*) ;;
1798                   *)
1799                         LIBC="libc.so"
1800                         INTL="libintl.so"
1801                 esac
1802                 jit_wanted=true
1803                 if test x"$GCC" = xyes; then
1804                         # We don't support v8 cpus
1805                         CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
1806                 fi
1807                 if test x"$AR" = xfalse; then
1808                         AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
1809                 fi
1810                 ;;
1811        alpha*-*-linux* | alpha*-*-osf*)
1812                 TARGET=ALPHA;
1813                 ACCESS_UNALIGNED="no"
1814                 JIT_SUPPORTED=yes
1815                 jit_wanted=true
1816                 arch_target=alpha;
1817                 CFLAGS="$CFLAGS -mieee -O0"
1818                 case $host_os in
1819                   linux*)
1820                         LIBC="libc.so.6.1"
1821                         INTL="libc.so.6.1"
1822                 esac
1823                ;;
1824         *-*-mingw*|*-*-cygwin*)
1825                 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
1826                 have_visibility_hidden=no
1827                 INTL="intl"
1828                 ;;
1829         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1830                 TARGET=HPPA;
1831                 arch_target=hppa;
1832                 LIBC="libc.sl"
1833                 ACCESS_UNALIGNED="no"
1834                 INTERP_SUPPORTED=yes
1835                 interp_wanted=true
1836                 ;;
1837         hppa*linux*)
1838                 TARGET=HPPA;
1839                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1840                 arch_target=hppa;
1841                 ACCESS_UNALIGNED="no"
1842                 JIT_SUPPORTED=yes
1843                 jit_wanted=true
1844                 ;;
1845         macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
1846         powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* )
1847                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1848                         TARGET=POWERPC64;
1849                 else
1850                         TARGET=POWERPC;
1851                 fi
1852                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1853                 arch_target=ppc;
1854                 JIT_SUPPORTED=yes
1855                 jit_wanted=true
1856                 ;;
1857         arm*-darwin*)
1858                 TARGET=ARM;
1859                 arch_target=arm;
1860                 ACCESS_UNALIGNED="no"
1861                 JIT_SUPPORTED=yes
1862                 CPPFLAGS="$CPPFLAGS -DARM_FPU_NONE=1"
1863                 jit_wanted=true
1864                 ;;
1865         arm*-linux*)
1866                 TARGET=ARM;
1867                 arch_target=arm;
1868                 ACCESS_UNALIGNED="no"
1869                 JIT_SUPPORTED=yes
1870                 jit_wanted=true
1871                 ;;
1872         s390-*-linux*)
1873                 TARGET=S390;
1874                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1875                 arch_target=s390;
1876                 ACCESS_UNALIGNED="no"
1877                 JIT_SUPPORTED=yes
1878                 jit_wanted=true
1879                 # Required CFLAGS for s390[x].  USE_STRING_INLINES is automatic with gcc 4.1
1880                 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
1881                 ;;
1882         s390x-*-linux*)
1883                 TARGET=S390x;
1884                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1885                 arch_target=s390x;
1886                 ACCESS_UNALIGNED="no"
1887                 JIT_SUPPORTED=yes
1888                 jit_wanted=true
1889                 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
1890                 ;;
1891 esac
1892
1893 if test "x$have_visibility_hidden" = "xyes"; then
1894    AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
1895 fi
1896
1897 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1898         if test x$withval = xyes; then
1899            jit_wanted=true
1900         else
1901            jit_wanted=false
1902         fi
1903 ])
1904
1905 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1906         if test x$withval = xyes; then
1907            interp_wanted=true
1908         else
1909            interp_wanted=false
1910         fi
1911 ])
1912
1913 USEJIT=false
1914 if test x$JIT_SUPPORTED = xyes; then
1915    if $jit_wanted; then
1916       USEJIT=true
1917       jit_status="Building and using the JIT"
1918    else
1919       if $interp_wanted; then
1920          jit_status="Building the JIT, defaulting to the interpreter"
1921       else
1922          AC_ERROR(No JIT or interpreter support available or selected.)
1923       fi
1924    fi
1925 else
1926    if test x$interp_wanted = xtrue; then
1927       jit_status="interpreter"
1928    else
1929       AC_ERROR(No JIT or interpreter support available or selected.)
1930    fi
1931 fi
1932
1933 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1934
1935 libsuffix=".so"
1936
1937 case "$host" in
1938      *-*-darwin*)
1939         libsuffix=".dylib"
1940         LIBC="libc.dylib"
1941         INTL="libintl.dylib"
1942         SQLITE="libsqlite.0.dylib"
1943         SQLITE3="libsqlite3.0.dylib"
1944         X11="libX11.dylib"
1945         ;;
1946      *-*-*netbsd*)
1947         LIBC="libc.so.12"
1948         INTL="libintl.so.0"
1949         ;;
1950     *-*-*freebsd*)
1951         LIBC="libc.so"
1952         INTL="libintl.so"
1953         ;;
1954     *-*-*openbsd*)
1955         LIBC="libc.so"
1956         INTL="libintl.so"
1957         ;;
1958     *-*-*linux*)
1959         AC_PATH_X
1960         AC_MSG_CHECKING(for the soname of libX11.so)
1961         for i in $x_libraries /usr/lib /usr/lib64; do
1962                 for r in 4 5 6; do
1963                         if test -f $i/libX11.so.$r; then
1964                                 X11=libX11.so.$r
1965                                 AC_MSG_RESULT($X11)
1966                         fi
1967                 done
1968         done
1969
1970         if test "x$X11" = "xlibX11.so"; then
1971                 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
1972         fi
1973         ;;
1974 esac
1975
1976
1977 AC_SUBST(libsuffix)
1978
1979 AC_CHECK_HEADERS(valgrind/memcheck.h)
1980
1981 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1982         if test "x$with_tls" = "x__thread"; then
1983                 #
1984                 # On some linux distributions, TLS works in executables, but linking
1985                 # against a shared library containing TLS fails with:
1986                 # undefined reference to `__tls_get_addr'
1987                 #
1988                 rm -f conftest.c conftest.so conftest
1989                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1990                 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1991                 $CC -o conftest conftest.so > /dev/null 2>&1
1992                 if test ! -f conftest; then
1993                    AC_MSG_WARN([Disabling usage of __thread.]);
1994                    with_tls=pthread
1995                 fi
1996                 rm -f conftest.c conftest.so conftest
1997         fi
1998 fi
1999
2000 mono_debugger_supported=no
2001 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
2002         if test x$use_included_gc = xyes; then
2003                 case "$host" in
2004                 *-*-*linux*)
2005                         mono_debugger_supported=yes
2006                         ;;
2007                 esac
2008         fi
2009 fi
2010
2011 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
2012 if test "x$mono_debugger_supported" = "xyes"; then
2013         AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
2014 fi
2015 AC_MSG_RESULT($mono_debugger_supported)
2016 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
2017
2018 if test "x$with_tls" = "x__thread"; then
2019         AC_DEFINE(HAVE_KW_THREAD, 1, [Have __thread keyword])
2020         # Pass the information to libgc
2021         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
2022         AC_MSG_CHECKING(if the tls_model attribute is supported)
2023         AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
2024                 ], [
2025                         AC_MSG_RESULT(yes)
2026                         AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
2027                 ], [
2028                         AC_MSG_RESULT(no)
2029         ])
2030 fi
2031
2032 if test ${TARGET} = ARM && test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2033         dnl ******************************************
2034         dnl *** Check to see what FPU is available ***
2035         dnl ******************************************
2036         AC_MSG_CHECKING(which FPU to use)
2037
2038         AC_TRY_COMPILE([], [
2039                 __asm__ ("ldfd f0, [r0]");
2040                 ], fpu=FPA, fpu=NONE)
2041
2042         AC_MSG_RESULT($fpu)
2043         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
2044         unset fpu
2045 fi
2046
2047 if test ${TARGET} = unknown; then
2048         CPPFLAGS="$CPPFLAGS -DNO_PORT"
2049         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
2050 fi
2051
2052 if test ${ACCESS_UNALIGNED} = no; then
2053         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
2054 fi
2055
2056 case "x$gc" in
2057         xincluded)
2058                 # Pass CPPFLAGS to libgc configure
2059                 # We should use a separate variable for this to avoid passing useless and
2060                 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
2061                 # This should be executed late so we pick up the final version of CPPFLAGS
2062                 # The problem with this approach, is that during a reconfigure, the main
2063                 # configure scripts gets invoked with these arguments, so we use separate
2064                 # variables understood by libgc's configure to pass CPPFLAGS and CFLAGS.
2065                 LIBGC_CPPFLAGS=$CPPFLAGS
2066                 if test x$TARGET = xSPARC -o x$TARGET = xSPARC64; then
2067                         LIBGC_CPPFLAGS=`echo $LIBGC_CPPFLAGS | sed -e 's/-D_FILE_OFFSET_BITS=64//g'`
2068                 fi
2069                 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args \"CPPFLAGS_FOR_LIBGC=$LIBGC_CPPFLAGS\" \"CFLAGS_FOR_LIBGC=$CFLAGS_FOR_LIBGC\""
2070                 AC_CONFIG_SUBDIRS(libgc)
2071                 ;;
2072 esac
2073
2074 PREVIEW=yes
2075 AC_ARG_WITH(preview,  [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
2076         if test x$with_preview = xno; then
2077               PREVIEW=no
2078         fi
2079 ])
2080
2081 MOONLIGHT=yes
2082 AC_ARG_WITH(moonlight,[ --with-moonlight=yes,no   If you want to build the Moonlight 2.1 assemblies],[
2083         if test x$with_moonlight = xno; then
2084               MOONLIGHT=no
2085         fi
2086 ])
2087
2088 OPROFILE=no
2089 AC_ARG_WITH(oprofile,[ --with-oprofile=no,<path>   Enable oprofile support (defaults to NO)],[
2090         if test x$with_oprofile != xno; then
2091               OPROFILE=yes
2092               OPROFILE_CFLAGS="-I$with_oprofile/include"
2093               OPROFILE_LIBS=
2094               AC_DEFINE(HAVE_OPROFILE,1,[Have oprofile support])
2095         fi
2096 ])
2097
2098 MALLOC_MEMPOOLS=no
2099 AC_ARG_WITH(malloc_mempools,[ --with-malloc-mempools=yes,no  Use malloc for each single mempool allocation (only for runtime debugging, defaults to NO)],[
2100         if test x$with_malloc_mempools = xyes; then
2101                 MALLOC_MEMPOOLS=yes
2102                 AC_DEFINE(USE_MALLOC_FOR_MEMPOOLS,1,[Use malloc for each single mempool allocation])
2103         fi
2104 ])
2105
2106 AM_CONDITIONAL(HAVE_OPROFILE, test x$OPROFILE = xyes)
2107 AC_SUBST(OPROFILE_CFLAGS)
2108 AC_SUBST(OPROFILE_LIBS)
2109
2110 libmono_ldflags="$libmono_ldflags $LIBS"
2111
2112 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
2113 AM_CONDITIONAL(INSTALL_2_1, test x$MOONLIGHT = xyes)
2114
2115 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
2116 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
2117 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
2118 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
2119 AM_CONDITIONAL(X86, test x$TARGET = xX86)
2120 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
2121 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
2122 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
2123 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
2124 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
2125 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
2126 AM_CONDITIONAL(POWERPC64, test x$TARGET = xPOWERPC64)
2127 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
2128 AM_CONDITIONAL(S390, test x$TARGET = xS390)
2129 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2130 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2131
2132 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2133 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2134 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2135
2136 AC_SUBST(LIBC)
2137 AC_SUBST(INTL)
2138 AC_SUBST(SQLITE)
2139 AC_SUBST(SQLITE3)
2140 AC_SUBST(X11)
2141 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2142 AC_SUBST(arch_target)
2143 AC_SUBST(CFLAGS)
2144 AC_SUBST(CPPFLAGS)
2145 AC_SUBST(LDFLAGS)
2146
2147 mono_build_root=`pwd`
2148 AC_SUBST(mono_build_root)
2149
2150 if test x$USEJIT = xtrue; then
2151   mono_runtime=mono/mini/mono
2152 else
2153   mono_runtime=mono/interpreter/mint
2154 fi
2155 AC_SUBST(mono_runtime)
2156
2157 mono_cfg_root=$mono_build_root/runtime
2158 if test x$platform_win32 = xyes; then
2159   if test "x$cross_compiling" = "xno"; then
2160     mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2161   else
2162     mono_cfg_dir=`echo $mono_cfg_root | tr '/' '\\\'`\\etc
2163   fi
2164 else
2165   mono_cfg_dir=$mono_cfg_root/etc
2166 fi
2167 AC_SUBST(mono_cfg_dir)
2168
2169 AC_CONFIG_FILES([po/mcs/Makefile.in])
2170
2171 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2172 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2173
2174 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2175 [   depth=../../../..
2176     case $srcdir in
2177     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2178     .) reldir=$depth ;;
2179     *) reldir=$depth/$srcdir ;;
2180     esac
2181     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2182     cd runtime/etc/mono/1.0
2183     rm -f machine.config
2184     $LN_S $reldir/data/net_1_1/machine.config machine.config
2185     cd $depth
2186 ],[LN_S='$LN_S'])
2187
2188 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2189 [   depth=../../../..
2190     case $srcdir in
2191     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2192     .) reldir=$depth ;;
2193     *) reldir=$depth/$srcdir ;;
2194     esac
2195     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2196     cd runtime/etc/mono/2.0
2197     rm -f machine.config
2198     $LN_S $reldir/data/net_2_0/machine.config machine.config
2199     cd $depth
2200 ],[LN_S='$LN_S'])
2201
2202 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2203 [   depth=../../../..
2204     case $srcdir in
2205     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2206     .) reldir=$depth ;;
2207     *) reldir=$depth/$srcdir ;;
2208     esac
2209     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2210     cd runtime/etc/mono/2.0
2211     rm -f web.config
2212     $LN_S $reldir/data/net_2_0/web.config web.config
2213     cd $depth
2214 ],[LN_S='$LN_S'])
2215
2216 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2217 [   depth=../../..
2218     case $srcdir in
2219     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2220     .) reldir=$depth ;;
2221     *) reldir=$depth/$srcdir ;;
2222     esac
2223     $ac_aux_dir/install-sh -d runtime/etc/mono/
2224     cd runtime/etc/mono/
2225     rm -f browscap.ini
2226     $LN_S $reldir/data/browscap.ini browscap.ini
2227     cd $depth
2228 ],[LN_S='$LN_S'])
2229
2230 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/Browsers/Compat.browser],
2231 [   depth=../../../../..
2232     case $srcdir in
2233     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2234     .) reldir=$depth ;;
2235     *) reldir=$depth/$srcdir ;;
2236     esac
2237     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0/Browsers/
2238     cd runtime/etc/mono/2.0/Browsers
2239     rm -f Compat.browser
2240     $LN_S $reldir/data/net_2_0/Browsers/Compat.browser Compat.browser
2241     cd $depth
2242 ],[LN_S='$LN_S'])
2243
2244 if test x$enable_quiet_build = xyes; then
2245    AC_CONFIG_COMMANDS([quiet], [find mono libgc support -name Makefile -exec $shell $srcdir/scripts/patch-quiet.sh {} \;], [shell=$SHELL])
2246    AC_CONFIG_COMMANDS([quiet-libtool], [sed -e 's/$echo "copying selected/$show "copying selected/g' < libtool > libtool.tmp && mv libtool.tmp libtool && chmod a+x libtool])
2247 fi
2248
2249 AC_OUTPUT([
2250 Makefile
2251 mono-uninstalled.pc
2252 scripts/mono-find-provides
2253 scripts/mono-find-requires
2254 mono/Makefile
2255 mono/utils/Makefile
2256 mono/metadata/Makefile
2257 mono/dis/Makefile
2258 mono/cil/Makefile
2259 mono/arch/Makefile
2260 mono/os/Makefile
2261 mono/arch/x86/Makefile
2262 mono/arch/amd64/Makefile
2263 mono/arch/hppa/Makefile
2264 mono/arch/ppc/Makefile
2265 mono/arch/sparc/Makefile
2266 mono/arch/s390/Makefile
2267 mono/arch/s390x/Makefile
2268 mono/arch/arm/Makefile
2269 mono/arch/alpha/Makefile
2270 mono/arch/ia64/Makefile
2271 mono/arch/mips/Makefile
2272 mono/interpreter/Makefile
2273 mono/tests/Makefile
2274 mono/tests/tests-config
2275 mono/tests/assemblyresolve/Makefile
2276 mono/tests/cas/Makefile
2277 mono/tests/cas/assembly/Makefile
2278 mono/tests/cas/demand/Makefile
2279 mono/tests/cas/inheritance/Makefile
2280 mono/tests/cas/linkdemand/Makefile
2281 mono/tests/cas/threads/Makefile
2282 mono/benchmark/Makefile
2283 mono/monoburg/Makefile
2284 mono/monograph/Makefile
2285 mono/io-layer/Makefile
2286 mono/mini/Makefile
2287 mono/profiler/Makefile
2288 ikvm-native/Makefile
2289 scripts/Makefile
2290 man/Makefile
2291 web/Makefile
2292 docs/Makefile
2293 data/Makefile
2294 data/net_1_1/Makefile
2295 data/net_2_0/Makefile
2296 data/net_2_0/Browsers/Makefile
2297 data/mint.pc
2298 data/mono.pc
2299 data/mono-cairo.pc
2300 data/mono-nunit.pc
2301 data/dotnet.pc
2302 data/dotnet35.pc
2303 data/wcf.pc
2304 data/cecil.pc
2305 data/smcs.pc
2306 samples/Makefile
2307 support/Makefile
2308 data/config
2309 tools/Makefile
2310 tools/locale-builder/Makefile
2311 runtime/Makefile
2312 msvc/Makefile
2313 po/Makefile
2314 ])
2315
2316 if test x$platform_win32 = xyes; then
2317    # Get rid of 'cyg' prefixes in library names
2318    sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2319    # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2320    # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2321    # executable doesn't work...
2322    sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2323 fi
2324
2325 (
2326   case $prefix in
2327   NONE) prefix=$ac_default_prefix ;;
2328   esac
2329   case $exec_prefix in
2330   NONE) exec_prefix='${prefix}' ;;
2331   esac
2332
2333   test -w $srcdir/$mcsdir/build || chmod +w $srcdir/$mcsdir/build
2334
2335   #
2336   # If we are cross compiling, we don't build in the mcs/ tree.  Let us not clobber
2337   # any existing config.make.  This allows people to share the same source tree
2338   # with different build directories, one native and one cross
2339   #
2340   if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2341     echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
2342     echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
2343     echo "sysconfdir=$sysconfdir" >> $srcdir/$mcsdir/build/config.make
2344     echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$mcsdir/build/config.make
2345     echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
2346     echo 'IL_FLAGS = /debug' >> $srcdir/$mcsdir/build/config.make
2347     echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$mcsdir/build/config.make
2348     echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $srcdir/$mcsdir/build/config.make
2349     case $INSTALL in
2350     [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2351     *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2352     esac
2353
2354     echo "INSTALL = $mcs_INSTALL" >> $srcdir/$mcsdir/build/config.make
2355
2356     export VERSION
2357     [myver=$($AWK 'BEGIN {
2358       split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2359       if(length(vsplit [1]) > 4) {
2360         split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2361       }
2362       print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2363     }')]
2364
2365     echo "MONO_VERSION = $myver" >> $srcdir/$mcsdir/build/config.make
2366   fi
2367
2368   # if we have an olive folder, override the default settings
2369   if test -d $olivedir; then
2370
2371     test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2372
2373     if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2374       echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2375       echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2376       echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2377       echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2378       echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2379       echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2380           if test x$with_moonlight = xyes; then
2381         echo "WITH_MOONLIGHT = yes" >> $srcdir/$olivedir/build/config.make
2382       fi
2383     fi
2384   fi
2385 )
2386
2387 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2388
2389 echo "
2390         mcs source:    $mcs_topdir
2391         olive source:  $olive_topdir
2392
2393         GC:          $gc
2394         TLS:         $with_tls
2395         SIGALTSTACK: $with_sigaltstack
2396         Engine:      $jit_status
2397         2.0 Beta:    $PREVIEW
2398         2.1 Alpha:   $MOONLIGHT
2399         JNI support: $jdk_headers_found
2400         libgdiplus:  $libgdiplus_msg
2401         zlib:        $zlib_msg
2402         oprofile:    $OPROFILE
2403         BigArrays:   $enable_big_arrays
2404         DTrace:      $enable_dtrace
2405         $disabled
2406
2407 "
2408 if test x$with_static_mono = xno -a "x$platform_win32" != "xyes"; then
2409    AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexepcted bugs)
2410 fi
2411
2412 if test x$gc = xsgen; then
2413         echo IMPORTANT:
2414         echo IMPORTANT: You have selected an experimental, work-in-progress
2415         echo IMPORTANT: GC engine.  This GC engine is currently not supported
2416         echo IMPORTANT: and is not yet ready for use.
2417         echo IMPORTANT:
2418         echo IMPORTANT: There are known problems with it, use at your own risk.
2419 fi