configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.92cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl system type
  16 case "$host_cpu" in
  17 alpha | alphaev56 )
  18         ARCH_DIR="alpha"
  19         STATIC_CLASSPATH="1"
  20         CFLAGS="-mieee -D__ALPHA__"
  21         ;;
  22
  23 arm )
  24         ARCH_DIR="arm"
  25         STATIC_CLASSPATH="1"
  26         CFLAGS="-D__ARM__"
  27         ;;
  28
  29 i386 | i486 | i586 | i686 )
  30         ARCH_DIR="i386"
  31         STATIC_CLASSPATH="0"
  32         CFLAGS="-D__I386__ $CFLAGS"
  33         ;;
  34
  35 mips )
  36         ARCH_DIR="mips"
  37         STATIC_CLASSPATH="1"
  38
  39 dnl for MIPSPro Compiler
  40 dnl     CFLAGS="-64 -OPT:Olimit=0 -woff 1110,1164,1515 -D__MIPS__ -D__MIPSEB__"
  41         CFLAGS="-64 -OPT:Olimit=0 -D__MIPS__ -D__MIPSEB__"
  42
  43 dnl for GCC
  44 dnl     CFLAGS="-mabi=64 -D__MIPS__ -D__MIPSEB__"
  45 dnl     LDFLAGS="-mabi=64"
  46         ;;
  47
  48 powerpc )
  49         ARCH_DIR="powerpc"
  50         STATIC_CLASSPATH="1"
  51         CFLAGS="-D__POWERPC__"
  52         ;;
  53
  54 x86_64 )
  55         ARCH_DIR="x86_64"
  56         STATIC_CLASSPATH="0"
  57         CFLAGS="-D__X86_64__"
  58         ;;
  59
  60 xdspcore )
  61         ARCH_DIR="xdspcore"
  62         STATIC_CLASSPATH="1"
  63         CFLAGS="-D__XDSPCORE__"
  64         USE_SCHEDULER="1"
  65         ;;
  66 * )
  67         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  68         ;;
  69 esac
  70
  71
  72 dnl set optimization and debugging for all architectures and systems
  73 CFLAGS="-O0 -g3 $CFLAGS"
  74
  75
  76 case "$host_os" in
  77 *linux* | *Linux* )
  78         OS_DIR="linux"
  79         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__LINUX__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  80         ;;
  81 *darwin* )
  82         OS_DIR="darwin"
  83         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__DARWIN__"
  84         ;;
  85 *irix* )
  86         OS_DIR="irix"
  87         CFLAGS="$CFLAGS -D__IRIX__"
  88         ;;
  89 * )
  90         ;;
  91 esac
  92
  93
  94 dnl define and substitute some architecture specific variables
  95 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [Architecture directory])
  96 AC_SUBST(ARCH_DIR)
  97 AC_SUBST(OS_DIR)
  98 AC_SUBST(USE_SCHEDULER)
  99
 100
 101 dnl define install prefix
 102 if test "x$prefix" = xNONE; then
 103         CACAO_INSTALL_PREFIX=$ac_default_prefix
 104 else
 105         CACAO_INSTALL_PREFIX=$prefix
 106 fi
 107 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [Installation prefix])
 108 AC_SUBST(CACAO_INSTALL_PREFIX)
 109
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AM_PROG_AS
 114 AC_PROG_RANLIB
 115 AC_DISABLE_SHARED
 116 AC_PROG_LIBTOOL
 117 AC_PROG_LN_S
 118 AC_PROG_MAKE_SET
 119
 120 dnl Checks for header files.
 121 AC_HEADER_DIRENT
 122 AC_HEADER_STDC
 123 AC_CHECK_HEADERS([fcntl.h])
 124 AC_CHECK_HEADERS([sys/time.h])
 125 AC_CHECK_HEADERS([unistd.h])
 126 AC_CHECK_HEADERS([sys/ioctl.h])
 127
 128 dnl Checks for typedefs, structures, and compiler characteristics.
 129 AC_C_CONST
 130 AC_C_INLINE
 131 AC_TYPE_OFF_T
 132 AC_TYPE_SIZE_T
 133 AC_HEADER_TIME
 134 AC_STRUCT_TM
 135
 136 dnl Checks for library functions.
 137 AC_PROG_GCC_TRADITIONAL
 138 AC_FUNC_MEMCMP
 139 AC_FUNC_MMAP
 140 AC_TYPE_SIGNAL
 141 AC_CHECK_FUNCS(getcwd gettimeofday mkdir mktime select socket)
 142
 143 dnl Checks for libraries.
 144 AC_CHECK_LIB(m, fmod)
 145
 146 dnl Checking sizeof void *
 147 AC_COMPILE_CHECK_SIZEOF(void *)
 148 AC_C_BIGENDIAN
 149
 150 dnl Check for mmap header anomalies (missing MAP_FAILED, etc.)
 151 if test $ac_cv_func_mmap_fixed_mapped = yes; then
 152         AC_CACHE_CHECK(whether MAP_FAILED is defined,
 153                        ac_cv_map_failed,
 154                        AC_EGREP_CPP(yes,
 155                                     [#include <sys/mman.h>
 156                                      #ifdef MAP_FAILED
 157                                         yes
 158                                      #endif],
 159                                     ac_cv_map_failed=yes,
 160                                     ac_cv_map_failed=no))
 161
 162         AC_CACHE_CHECK(whether MAP_ANONYMOUS is defined,
 163                        ac_cv_map_anonymous,
 164                        AC_EGREP_CPP(yes,
 165                                     [#include <sys/mman.h>
 166                                      #ifdef MAP_ANONYMOUS
 167                                         yes
 168                                      #endif],
 169                                     ac_cv_map_anonymous=yes,
 170                                     ac_cv_map_anonymous=no))
 171
 172         AC_CACHE_CHECK(whether MAP_ANON is defined,
 173                        ac_cv_map_anon,
 174                        AC_EGREP_CPP(yes,
 175                                     [#include <sys/mman.h>
 176                                      #ifdef MAP_ANON
 177                                         yes
 178                                      #endif],
 179                                     ac_cv_map_anon=yes,
 180                                     ac_cv_map_anon=no))
 181
 182         if test $ac_cv_map_failed = yes; then
 183                 AC_DEFINE([HAVE_MAP_FAILED], 1, [Define if <sys/mman.h> defines MAP_FAILED])
 184         fi
 185
 186         if test $ac_cv_map_anonymous = yes; then
 187                 AC_DEFINE([HAVE_MAP_ANONYMOUS], 1, [Define if <sys/mman.h> defines MAP_ANONYMOUS])
 188         fi
 189
 190         if test $ac_cv_map_anon = yes; then
 191                 AC_DEFINE([HAVE_MAP_ANON], 1, [Define if <sys/mman.h> defines MAP_ANON])
 192         fi
 193 fi
 194
 195
 196 dnl Features
 197
 198 dnl check arguments
 199
 200 dnl check for garbage collector
 201 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-gc,disable garbage collector [[default=yes]])])
 202
 203 AC_MSG_CHECKING(whether GC should be disabled)
 204 if test x"$disable_gc" = "xyes"; then
 205         AC_MSG_RESULT(yes)
 206         AM_CONDITIONAL([DISABLE_GC], [true])
 207 else
 208         AC_MSG_RESULT(no)
 209         AM_CONDITIONAL([DISABLE_GC], [false])
 210 fi
 211
 212
 213 dnl check for statistics
 214 AC_ARG_ENABLE([statistics], [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])])
 215
 216 AC_MSG_CHECKING(whether statistics generation should be enabled)
 217 if test x"$enable_statistics" = "xno"; then
 218         AC_MSG_RESULT(no)
 219         AM_CONDITIONAL([STATISTICS], [false])
 220 else
 221         AC_MSG_RESULT(yes)
 222         AC_DEFINE([STATISTICS], 1, [use statistics])
 223         AM_CONDITIONAL([STATISTICS], [true])
 224 fi
 225
 226
 227 dnl threads
 228 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 229 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 230
 231 AC_MSG_CHECKING(whether to include threads support)
 232 enable_threads=${enable_threads:-native}
 233 case "$enable_threads" in
 234 no | none | single)
 235         AC_MSG_RESULT(no)
 236         dnl no threads for boehm
 237         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 238         AM_CONDITIONAL([USE_THREADS], [false])
 239         AM_CONDITIONAL([NATIVE_THREADS], [false])
 240         ;;
 241
 242 green | native | posix | pthreads)
 243         AC_DEFINE([USE_THREADS], 1, [use threads])
 244         AC_DEFINE([EXTERNAL_OVERFLOW], 1, [external overflow])
 245         AC_DEFINE([DONT_FREE_FIRST], 1, [don't free first])
 246
 247         AM_CONDITIONAL([USE_THREADS], [true])
 248
 249         if test x"$enable_threads" != "xgreen"; then
 250                 AC_MSG_RESULT(yes, native)
 251                 AC_CHECK_LIB(pthread, main)
 252                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 253
 254                 CFLAGS="$CFLAGS -D_REENTRANT"
 255
 256                 dnl tell boehm to support threads as well
 257                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-boehm-threads=posix"
 258                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 259
 260         else
 261                 AC_MSG_RESULT(yes, green)
 262
 263                 dnl no threads for boehm
 264                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-boehm-threads"
 265                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 266         fi
 267     ;;
 268 *)
 269     AC_MSG_ERROR($enable_threads is an unknown thread package)
 270     ;;
 271 esac
 272
 273
 274 dnl Check whether the compiler supports the __thread keyword.
 275 if test "x$use__thread" != xno; then
 276   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 277   [cat > conftest.c <<\EOF
 278 __thread int a = 42;
 279 EOF
 280   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 281     ac_cv_gcc___thread=yes
 282   else
 283     ac_cv_gcc___thread=no
 284   fi
 285   rm -f conftest*])
 286   if test "$ac_cv_gcc___thread" = yes; then
 287     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 288   fi
 289 else
 290   ac_cv_gcc___thread=no
 291 fi
 292
 293
 294 dnl check if linear scan register allocator(lsra) should be used
 295 AC_ARG_ENABLE([lsra], [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])])
 296
 297 AC_MSG_CHECKING(whether lsra should be supported)
 298 if test x"$enable_lsra" = "xno"; then
 299         AC_MSG_RESULT(no)
 300 else
 301         AC_MSG_RESULT(yes)
 302         AC_DEFINE([LSRA], 1, [use lsra])
 303 fi
 304
 305
 306 dnl check for inlining
 307 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 308
 309 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 310 dnl if test x"$enable_inlining" = "xno"; then
 311 dnl     AC_MSG_RESULT(yes)
 312 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 313 dnl else
 314 dnl     AC_MSG_RESULT(no)
 315         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 316         AM_CONDITIONAL([USE_INLINING], [true])
 317 dnl fi
 318
 319
 320 dnl check for instruction scheduler
 321 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 322
 323 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 324 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 325         case "${ARCH_DIR}" in
 326                 xdspcore )
 327                         ;;
 328                 * )
 329                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 330                         ;;
 331         esac
 332
 333         AC_MSG_RESULT(yes)
 334         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 335         AM_CONDITIONAL([USE_SCHEDULER], [true])
 336 else
 337         AC_MSG_RESULT(no)
 338         AM_CONDITIONAL([USE_SCHEDULER], [false])
 339 fi
 340
 341
 342 dnl check if zlib should be used
 343 AC_ARG_ENABLE([zlib], [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])])
 344
 345 AC_MSG_CHECKING(whether zip archives should be supported)
 346 if test x"$enable_zlib" = "xno"; then
 347         AC_MSG_RESULT(no)
 348         AM_CONDITIONAL([USE_ZLIB], [false])
 349 else
 350         AC_MSG_RESULT(yes)
 351         AC_DEFINE([USE_ZLIB], 1, [use zlib])
 352         AC_CHECK_HEADERS([zlib.h])
 353         AC_CHECK_LIB(z, main)
 354         AM_CONDITIONAL([USE_ZLIB], [true])
 355 fi
 356
 357
 358 dnl check if classpath should be linked statically with CACAO
 359 AC_ARG_ENABLE([dynamicclasspath], [AS_HELP_STRING(--disable-dynamicclasspath, link classpath native code static even on platforms supporting dynamic loading)], [use_dynamicclasspath=$enableval], [use_dynamicclasspath=yes])
 360
 361 AC_MSG_CHECKING(whether to link GNU classpath statically)
 362 if test x"$use_dynamicclasspath" = "xno"; then
 363         STATIC_CLASSPATH="1"
 364 fi
 365
 366 if test x"${STATIC_CLASSPATH}" = "x1"; then
 367         AC_MSG_RESULT(yes)
 368         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 369 else
 370         AC_MSG_RESULT(no)
 371         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 372 fi
 373 AC_SUBST(STATIC_CLASSPATH)
 374
 375
 376 dnl enable gtk peer
 377 AC_ARG_ENABLE([gtk-peer], [AS_HELP_STRING(--enable-gtk-peer,compile GTK native peers [[default=no]])])
 378
 379 AC_MSG_CHECKING(whether to use GTK awt peers)
 380 if test x"$enable_gtk_peer" = "xyes"; then
 381         AC_MSG_RESULT(yes)
 382         AC_DEFINE([USE_GTK], 1, [use gtk])
 383         AM_CONDITIONAL([USE_GTK_PEER], [true])
 384         USE_GTK_PEER=yes
 385 else
 386         AC_MSG_RESULT(no)
 387         AM_CONDITIONAL([USE_GTK_PEER], [false])
 388         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-gtk-peer"
 389         USE_GTK_PEER=no
 390 fi
 391 AC_SUBST(USE_GTK_PEER)
 392
 393
 394 dnl pass configure options to classpath
 395 if test x"${STATIC_CLASSPATH}" = "x1"; then
 396         AC_DEFINE([STATIC_CLASSPATH], 1, [use classpath statically linked])
 397         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 398         CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-static --disable-shared"
 399
 400         dnl check for some classpath related stuff when we link statically
 401         AM_ICONV_LINK
 402
 403         dnl taken from GNU classpath configure.ac
 404         if test x"${USE_GTK_PEER}" = "xyes"; then
 405                 AC_ERROR(XXX this is not supported yet)
 406                 AC_PATH_XTRA
 407                 if test "$no_x" = yes; then
 408                         AC_MSG_ERROR([GTK+ peers requested but no X library available])
 409                 fi
 410                 dnl We explicitly want the XTest Extension for Robot support.
 411                 AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
 412                              [AC_MSG_ERROR([libXtst NOT found, required for GdkRobot])],
 413                              [${X_LIBS}])
 414                 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4 gthread-2.0 >= 2.2 libart-2.0 gdk-pixbuf-2.0)
 415                 AC_SUBST(GTK_CFLAGS)
 416                 AC_SUBST(GTK_LIBS)
 417
 418                 AC_SUBST(CAIRO_LIBS)
 419                 AC_SUBST(CAIRO_CFLAGS)
 420                 PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 421                 AC_SUBST(PANGOFT2_LIBS)
 422                 AC_SUBST(PANGOFT2_CFLAGS)
 423         fi
 424 else
 425         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 426         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-static --enable-shared"
 427 fi
 428
 429
 430 dnl should we use an external classpath installation
 431 AC_ARG_WITH([external-classpath], [AS_HELP_STRING(--with-external-classpath=<dir>,installation directory of external GNU classpath [[default=no]])])
 432
 433 AC_MSG_CHECKING(whether to use an external GNU classpath)
 434 if test x"$with_external_classpath" != "x"; then
 435         if test x"$with_external_classpath" = "xyes"; then
 436                 AC_MSG_ERROR(please specify the installation prefix)
 437         fi
 438         AC_MSG_RESULT($with_external_classpath)
 439         AC_DEFINE([WITH_EXTERNAL_CLASSPATH], 1, [external classpath])
 440         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [true])
 441         EXTERNAL_CLASSPATH_PREFIX="$with_external_classpath"
 442         AC_DEFINE_UNQUOTED([EXTERNAL_CLASSPATH_PREFIX], "${EXTERNAL_CLASSPATH_PREFIX}", [external classpath directory])
 443         AC_SUBST(EXTERNAL_CLASSPATH_PREFIX)
 444 else
 445         AC_MSG_RESULT(no)
 446         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [false])
 447 fi
 448
 449
 450 dnl set some essential classpath options, even if their classpath default is
 451 dnl suitable for us
 452 ac_configure_args="$ac_configure_args --libdir=${CACAO_INSTALL_PREFIX}/jre/lib/${ARCH_DIR} --enable-jni --disable-cni --disable-regen-headers ${CONFIGURE_ARGS}"
 453
 454
 455 dnl now configure boehm gc and gnu classpath
 456 dnl the export is not my favorite (is there another way?)
 457 export CFLAGS
 458 AC_CONFIG_SUBDIRS(src/boehm-gc src/classpath)
 459
 460
 461 AC_CONFIG_FILES([Makefile]
 462                 [doc/Makefile]
 463                 [doc/handbook/Makefile]
 464                 [man/Makefile]
 465                 [src/Makefile]
 466                 [src/cacao/Makefile]
 467                 [src/cacaoh/Makefile]
 468                 [src/lib/Makefile]
 469                 [src/mm/Makefile]
 470                 [src/native/Makefile]
 471                 [src/native/include/Makefile]
 472                 [src/native/tools/Makefile]
 473                 [src/native/vm/Makefile]
 474                 [src/scripts/Makefile]
 475                 [src/scripts/cacao]
 476                 [src/scripts/java]
 477                 [src/scripts/kjc]
 478                 [src/scripts/rmic]
 479                 [src/scripts/rmiregistry]
 480                 [src/threads/Makefile]
 481                 [src/threads/green/Makefile]
 482                 [src/threads/native/Makefile]
 483                 [src/toolbox/Makefile]
 484                 [src/vm/Makefile]
 485                 [src/vm/jit/Makefile]
 486                 [src/vm/jit/alpha/Makefile]
 487                 [src/vm/jit/i386/Makefile]
 488                 [src/vm/jit/inline/Makefile]
 489                 [src/vm/jit/loop/Makefile]
 490                 [src/vm/jit/mips/Makefile]
 491                 [src/vm/jit/powerpc/Makefile]
 492                 [src/vm/jit/powerpc/darwin/Makefile]
 493                 [src/vm/jit/powerpc/linux/Makefile]
 494                 [src/vm/jit/schedule/Makefile]
 495                 [src/vm/jit/tools/Makefile]
 496                 [src/vm/jit/verify/Makefile]
 497                 [src/vm/jit/x86_64/Makefile]
 498                 [tests/Makefile]
 499                 [tests/codepatching/Makefile]
 500                 [tests/kaffe/Makefile]
 501                 [tests/native/Makefile])
 502
 503 AC_OUTPUT
 504
 505
 506 ## Local variables:
 507 ## mode: m4
 508 ## indent-tabs-mode: t
 509 ## c-basic-offset: 4
 510 ## tab-width: 8
 511 ## compile-command: "automake --add-missing"
 512 ## End: