configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.92cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl system type
  16 case "$host_cpu" in
  17 alpha | alphaev56 )
  18         ARCH_DIR="alpha"
  19         STATIC_CLASSPATH="1"
  20         CFLAGS="-mieee -D__ALPHA__"
  21         ;;
  22
  23 arm )
  24         ARCH_DIR="arm"
  25         STATIC_CLASSPATH="1"
  26         CFLAGS="-D__ARM__"
  27         ;;
  28
  29 i386 | i486 | i586 | i686 )
  30         ARCH_DIR="i386"
  31         CFLAGS="-D__I386__ $CFLAGS"
  32         ;;
  33
  34 mips )
  35         ARCH_DIR="mips"
  36         STATIC_CLASSPATH="1"
  37
  38 dnl for MIPSPro Compiler
  39 dnl     CFLAGS="-64 -OPT:Olimit=0 -woff 1110,1164,1515 -D__MIPS__ -D__MIPSEB__"
  40         CFLAGS="-64 -OPT:Olimit=0 -D__MIPS__ -D__MIPSEB__"
  41
  42 dnl for GCC
  43 dnl     CFLAGS="-mabi=64 -D__MIPS__ -D__MIPSEB__"
  44 dnl     LDFLAGS="-mabi=64"
  45         ;;
  46
  47 powerpc )
  48         ARCH_DIR="powerpc"
  49         CFLAGS="-D__POWERPC__"
  50         ;;
  51
  52 x86_64 )
  53         ARCH_DIR="x86_64"
  54         CFLAGS="-D__X86_64__"
  55         ;;
  56
  57 xdspcore )
  58         ARCH_DIR="xdspcore"
  59         STATIC_CLASSPATH="1"
  60         CFLAGS="-D__XDSPCORE__"
  61         USE_SCHEDULER="1"
  62         ;;
  63 * )
  64         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  65         ;;
  66 esac
  67
  68
  69 dnl set optimization and debugging for all architectures and systems
  70 CFLAGS="-O0 -g3 $CFLAGS"
  71
  72
  73 case "$host_os" in
  74 *linux* | *Linux* )
  75         OS_DIR="linux"
  76         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__LINUX__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  77         ;;
  78 *darwin* )
  79         OS_DIR="darwin"
  80         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__DARWIN__"
  81         ;;
  82 *freebsd* )
  83         OS_DIR="freebsd"
  84         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__FREEBSD__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  85         ;;
  86 *irix* )
  87         OS_DIR="irix"
  88         CFLAGS="$CFLAGS -D__IRIX__"
  89         ;;
  90 * )
  91         ;;
  92 esac
  93
  94
  95 dnl define and substitute some architecture specific variables
  96 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [Architecture directory])
  97 AC_SUBST(ARCH_DIR)
  98 AC_SUBST(OS_DIR)
  99 AC_SUBST(USE_SCHEDULER)
 100
 101
 102 dnl define install prefix
 103 if test "x$prefix" = xNONE; then
 104         CACAO_INSTALL_PREFIX=$ac_default_prefix
 105 else
 106         CACAO_INSTALL_PREFIX=$prefix
 107 fi
 108 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [Installation prefix])
 109 AC_SUBST(CACAO_INSTALL_PREFIX)
 110
 111
 112 dnl Checks for programs.
 113 AC_PROG_CC
 114 AM_PROG_AS
 115 AC_PROG_RANLIB
 116 AC_DISABLE_SHARED
 117 AC_PROG_LN_S
 118 AC_PROG_MAKE_SET
 119
 120 dnl libtool stuff
 121 AC_LIBTOOL_DLOPEN
 122 AC_LIBLTDL_CONVENIENCE
 123 AC_PROG_LIBTOOL
 124 AC_SUBST(LIBLTDL)
 125
 126 dnl Checks for header files.
 127 AC_HEADER_DIRENT
 128 AC_HEADER_STDC
 129 AC_CHECK_HEADERS([fcntl.h])
 130 AC_CHECK_HEADERS([sys/time.h])
 131 AC_CHECK_HEADERS([unistd.h])
 132 AC_CHECK_HEADERS([sys/ioctl.h])
 133
 134 dnl Checks for typedefs, structures, and compiler characteristics.
 135 AC_C_CONST
 136 AC_C_INLINE
 137 AC_TYPE_OFF_T
 138 AC_TYPE_SIZE_T
 139 AC_HEADER_TIME
 140 AC_STRUCT_TM
 141
 142 dnl Checks for library functions.
 143 AC_PROG_GCC_TRADITIONAL
 144 AC_FUNC_MEMCMP
 145 AC_FUNC_MMAP
 146 AC_TYPE_SIGNAL
 147 AC_CHECK_FUNCS(getcwd gettimeofday mkdir mktime select socket)
 148
 149 dnl Checks for libraries.
 150 AC_CHECK_LIB(m, fmod)
 151
 152 dnl Checking sizeof void *
 153 AC_COMPILE_CHECK_SIZEOF(void *)
 154 AC_C_BIGENDIAN
 155
 156 dnl Check for mmap header anomalies (missing MAP_FAILED, etc.)
 157 if test $ac_cv_func_mmap_fixed_mapped = yes; then
 158         AC_CACHE_CHECK(whether MAP_FAILED is defined,
 159                        ac_cv_map_failed,
 160                        AC_EGREP_CPP(yes,
 161                                     [#include <sys/mman.h>
 162                                      #ifdef MAP_FAILED
 163                                         yes
 164                                      #endif],
 165                                     ac_cv_map_failed=yes,
 166                                     ac_cv_map_failed=no))
 167
 168         AC_CACHE_CHECK(whether MAP_ANONYMOUS is defined,
 169                        ac_cv_map_anonymous,
 170                        AC_EGREP_CPP(yes,
 171                                     [#include <sys/mman.h>
 172                                      #ifdef MAP_ANONYMOUS
 173                                         yes
 174                                      #endif],
 175                                     ac_cv_map_anonymous=yes,
 176                                     ac_cv_map_anonymous=no))
 177
 178         AC_CACHE_CHECK(whether MAP_ANON is defined,
 179                        ac_cv_map_anon,
 180                        AC_EGREP_CPP(yes,
 181                                     [#include <sys/mman.h>
 182                                      #ifdef MAP_ANON
 183                                         yes
 184                                      #endif],
 185                                     ac_cv_map_anon=yes,
 186                                     ac_cv_map_anon=no))
 187
 188         if test $ac_cv_map_failed = yes; then
 189                 AC_DEFINE([HAVE_MAP_FAILED], 1, [Define if <sys/mman.h> defines MAP_FAILED])
 190         fi
 191
 192         if test $ac_cv_map_anonymous = yes; then
 193                 AC_DEFINE([HAVE_MAP_ANONYMOUS], 1, [Define if <sys/mman.h> defines MAP_ANONYMOUS])
 194         fi
 195
 196         if test $ac_cv_map_anon = yes; then
 197                 AC_DEFINE([HAVE_MAP_ANON], 1, [Define if <sys/mman.h> defines MAP_ANON])
 198         fi
 199 fi
 200
 201
 202 dnl Features
 203
 204 dnl check arguments
 205
 206 dnl check for garbage collector
 207 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-gc,disable garbage collector [[default=yes]])])
 208
 209 AC_MSG_CHECKING(whether GC should be disabled)
 210 if test x"$enable_gc" = "xno"; then
 211         AC_MSG_RESULT(yes)
 212         AM_CONDITIONAL([DISABLE_GC], [true])
 213 else
 214         AC_MSG_RESULT(no)
 215         AM_CONDITIONAL([DISABLE_GC], [false])
 216 fi
 217
 218 dnl check for statistics
 219 AC_ARG_ENABLE([statistics], [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])])
 220
 221 AC_MSG_CHECKING(whether statistics generation should be enabled)
 222 if test x"$enable_statistics" = "xno"; then
 223         AC_MSG_RESULT(no)
 224         AM_CONDITIONAL([STATISTICS], [false])
 225 else
 226         AC_MSG_RESULT(yes)
 227         AC_DEFINE([STATISTICS], 1, [use statistics])
 228         AM_CONDITIONAL([STATISTICS], [true])
 229 fi
 230
 231
 232 dnl threads
 233 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 234 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 235
 236 AC_MSG_CHECKING(whether to include threads support)
 237 enable_threads=${enable_threads:-native}
 238 case "$enable_threads" in
 239 no | none | single)
 240         AC_MSG_RESULT(no)
 241         dnl no threads for boehm
 242         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 243         AM_CONDITIONAL([USE_THREADS], [false])
 244         AM_CONDITIONAL([NATIVE_THREADS], [false])
 245         ;;
 246
 247 green | native | posix | pthreads)
 248         AC_DEFINE([USE_THREADS], 1, [use threads])
 249         AC_DEFINE([EXTERNAL_OVERFLOW], 1, [external overflow])
 250         AC_DEFINE([DONT_FREE_FIRST], 1, [don't free first])
 251
 252         AM_CONDITIONAL([USE_THREADS], [true])
 253
 254         if test x"$enable_threads" != "xgreen"; then
 255                 AC_MSG_RESULT(yes, native)
 256                 AC_CHECK_LIB(pthread, main)
 257                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 258
 259                 CFLAGS="$CFLAGS -D_REENTRANT"
 260
 261                 dnl tell boehm to support threads as well
 262                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-boehm-threads=posix"
 263                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 264
 265         else
 266                 AC_MSG_RESULT(yes, green)
 267
 268                 dnl no threads for boehm
 269                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-boehm-threads"
 270                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 271         fi
 272     ;;
 273 *)
 274     AC_MSG_ERROR($enable_threads is an unknown thread package)
 275     ;;
 276 esac
 277
 278
 279 dnl Check whether the compiler supports the __thread keyword.
 280 if test "x$use__thread" != xno; then
 281   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 282   [cat > conftest.c <<\EOF
 283 __thread int a = 42;
 284 EOF
 285   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 286     ac_cv_gcc___thread=yes
 287   else
 288     ac_cv_gcc___thread=no
 289   fi
 290   rm -f conftest*])
 291   if test "$ac_cv_gcc___thread" = yes; then
 292     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 293   fi
 294 else
 295   ac_cv_gcc___thread=no
 296 fi
 297
 298
 299 dnl check if linear scan register allocator(lsra) should be used
 300 AC_ARG_ENABLE([lsra], [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])])
 301
 302 AC_MSG_CHECKING(whether lsra should be supported)
 303 if test x"$enable_lsra" = "xno"; then
 304         AC_MSG_RESULT(no)
 305 else
 306         AC_MSG_RESULT(yes)
 307         AC_DEFINE([LSRA], 1, [use lsra])
 308 fi
 309
 310
 311 dnl check for inlining
 312 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 313
 314 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 315 dnl if test x"$enable_inlining" = "xno"; then
 316 dnl     AC_MSG_RESULT(yes)
 317 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 318 dnl else
 319 dnl     AC_MSG_RESULT(no)
 320         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 321         AM_CONDITIONAL([USE_INLINING], [true])
 322 dnl fi
 323
 324
 325 dnl check for instruction scheduler
 326 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 327
 328 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 329 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 330         case "${ARCH_DIR}" in
 331                 xdspcore )
 332                         ;;
 333                 * )
 334                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 335                         ;;
 336         esac
 337
 338         AC_MSG_RESULT(yes)
 339         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 340         AM_CONDITIONAL([USE_SCHEDULER], [true])
 341 else
 342         AC_MSG_RESULT(no)
 343         AM_CONDITIONAL([USE_SCHEDULER], [false])
 344 fi
 345
 346
 347 dnl check if zlib should be used
 348 AC_ARG_ENABLE([zlib], [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])])
 349
 350 AC_MSG_CHECKING(whether zip archives should be supported)
 351 if test x"$enable_zlib" = "xno"; then
 352         AC_MSG_RESULT(no)
 353         AM_CONDITIONAL([USE_ZLIB], [false])
 354 else
 355         AC_MSG_RESULT(yes)
 356         AC_DEFINE([USE_ZLIB], 1, [use zlib])
 357         AC_CHECK_HEADERS([zlib.h])
 358         AC_CHECK_LIB(z, main)
 359         AM_CONDITIONAL([USE_ZLIB], [true])
 360 fi
 361
 362
 363 dnl check if classpath should be linked statically with CACAO
 364 AC_ARG_ENABLE([dynamicclasspath], [AS_HELP_STRING(--disable-dynamicclasspath, link classpath native code static even on platforms supporting dynamic loading)], [use_dynamicclasspath=$enableval], [use_dynamicclasspath=yes])
 365
 366 AC_MSG_CHECKING(whether to link GNU classpath statically)
 367 if test x"$use_dynamicclasspath" = "xno"; then
 368         STATIC_CLASSPATH="1"
 369 fi
 370
 371 if test x"${STATIC_CLASSPATH}" = "x1"; then
 372         AC_MSG_RESULT(yes)
 373         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 374 else
 375         AC_MSG_RESULT(no)
 376         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 377 fi
 378 AC_SUBST(STATIC_CLASSPATH)
 379
 380
 381 dnl enable gtk peer
 382 AC_ARG_ENABLE([gtk-peer], [AS_HELP_STRING(--enable-gtk-peer,compile GTK native peers [[default=no]])])
 383
 384 AC_MSG_CHECKING(whether to use GTK awt peers)
 385 if test x"$enable_gtk_peer" = "xyes"; then
 386         AC_MSG_RESULT(yes)
 387         AC_DEFINE([USE_GTK], 1, [use gtk])
 388         AM_CONDITIONAL([USE_GTK_PEER], [true])
 389         USE_GTK_PEER=yes
 390 else
 391         AC_MSG_RESULT(no)
 392         AM_CONDITIONAL([USE_GTK_PEER], [false])
 393         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-gtk-peer"
 394         USE_GTK_PEER=no
 395 fi
 396 AC_SUBST(USE_GTK_PEER)
 397
 398
 399 dnl pass configure options to classpath
 400 if test x"${STATIC_CLASSPATH}" = "x1"; then
 401         AC_DEFINE([STATIC_CLASSPATH], 1, [use classpath statically linked])
 402         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 403         CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-static --disable-shared"
 404
 405         dnl check for some classpath related stuff when we link statically
 406         AM_ICONV_LINK
 407
 408         dnl taken from GNU classpath configure.ac
 409         if test x"${USE_GTK_PEER}" = "xyes"; then
 410                 AC_ERROR(XXX this is not supported yet)
 411                 AC_PATH_XTRA
 412                 if test "$no_x" = yes; then
 413                         AC_MSG_ERROR([GTK+ peers requested but no X library available])
 414                 fi
 415                 dnl We explicitly want the XTest Extension for Robot support.
 416                 AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
 417                              [AC_MSG_ERROR([libXtst NOT found, required for GdkRobot])],
 418                              [${X_LIBS}])
 419                 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4 gthread-2.0 >= 2.2 libart-2.0 gdk-pixbuf-2.0)
 420                 AC_SUBST(GTK_CFLAGS)
 421                 AC_SUBST(GTK_LIBS)
 422
 423                 AC_SUBST(CAIRO_LIBS)
 424                 AC_SUBST(CAIRO_CFLAGS)
 425                 PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 426                 AC_SUBST(PANGOFT2_LIBS)
 427                 AC_SUBST(PANGOFT2_CFLAGS)
 428         fi
 429 else
 430         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 431         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-static --enable-shared"
 432 fi
 433
 434
 435 dnl should we use an external classpath installation
 436 AC_ARG_WITH([external-classpath], [AS_HELP_STRING(--with-external-classpath=<dir>,installation directory of external GNU classpath [[default=no]])])
 437
 438 AC_MSG_CHECKING(whether to use an external GNU classpath)
 439 if test x"$with_external_classpath" != "x"; then
 440         if test x"$with_external_classpath" = "xyes"; then
 441                 AC_MSG_ERROR(please specify the installation prefix)
 442         fi
 443         AC_MSG_RESULT($with_external_classpath)
 444         AC_DEFINE([WITH_EXTERNAL_CLASSPATH], 1, [external classpath])
 445         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [true])
 446         EXTERNAL_CLASSPATH_PREFIX="$with_external_classpath"
 447         AC_DEFINE_UNQUOTED([EXTERNAL_CLASSPATH_PREFIX], "${EXTERNAL_CLASSPATH_PREFIX}", [external classpath directory])
 448         AC_SUBST(EXTERNAL_CLASSPATH_PREFIX)
 449 else
 450         AC_MSG_RESULT(no)
 451         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [false])
 452 fi
 453
 454
 455 dnl set some essential classpath options, even if their classpath default is
 456 dnl suitable for us
 457 ac_configure_args="$ac_configure_args --libdir=${CACAO_INSTALL_PREFIX}/jre/lib/${ARCH_DIR} --enable-jni --disable-cni --disable-regen-headers ${CONFIGURE_ARGS}"
 458
 459
 460 dnl now configure boehm gc and gnu classpath
 461 dnl the export is not my favorite (is there another way?)
 462 export CFLAGS
 463 AC_CONFIG_SUBDIRS(src/boehm-gc src/classpath src/libltdl)
 464
 465
 466 AC_CONFIG_FILES([Makefile]
 467                 [doc/Makefile]
 468                 [doc/handbook/Makefile]
 469                 [man/Makefile]
 470                 [src/Makefile]
 471                 [src/cacao/Makefile]
 472                 [src/cacaoh/Makefile]
 473                 [src/lib/Makefile]
 474                 [src/mm/Makefile]
 475                 [src/native/Makefile]
 476                 [src/native/include/Makefile]
 477                 [src/native/tools/Makefile]
 478                 [src/native/vm/Makefile]
 479                 [src/scripts/Makefile]
 480                 [src/scripts/cacao]
 481                 [src/scripts/java]
 482                 [src/scripts/kjc]
 483                 [src/scripts/rmic]
 484                 [src/scripts/rmiregistry]
 485                 [src/threads/Makefile]
 486                 [src/threads/green/Makefile]
 487                 [src/threads/native/Makefile]
 488                 [src/toolbox/Makefile]
 489                 [src/vm/Makefile]
 490                 [src/vm/jit/Makefile]
 491                 [src/vm/jit/alpha/Makefile]
 492                 [src/vm/jit/arm/Makefile]
 493                 [src/vm/jit/i386/Makefile]
 494                 [src/vm/jit/i386/linux/Makefile]
 495                 [src/vm/jit/i386/freebsd/Makefile]
 496                 [src/vm/jit/inline/Makefile]
 497                 [src/vm/jit/loop/Makefile]
 498                 [src/vm/jit/mips/Makefile]
 499                 [src/vm/jit/powerpc/Makefile]
 500                 [src/vm/jit/powerpc/darwin/Makefile]
 501                 [src/vm/jit/powerpc/linux/Makefile]
 502                 [src/vm/jit/schedule/Makefile]
 503                 [src/vm/jit/tools/Makefile]
 504                 [src/vm/jit/verify/Makefile]
 505                 [src/vm/jit/x86_64/Makefile]
 506                 [tests/Makefile]
 507                 [tests/codepatching/Makefile]
 508                 [tests/kaffe/Makefile]
 509                 [tests/native/Makefile])
 510
 511 AC_OUTPUT
 512
 513
 514 ## Local variables:
 515 ## mode: m4
 516 ## indent-tabs-mode: t
 517 ## c-basic-offset: 4
 518 ## tab-width: 8
 519 ## compile-command: "automake --add-missing"
 520 ## End: