configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.92cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl system type
  16 case "$host_cpu" in
  17 alpha | alphaev56 )
  18         ARCH_DIR="alpha"
  19         STATIC_CLASSPATH="1"
  20         CFLAGS="-mieee -D__ALPHA__"
  21         ;;
  22
  23 arm )
  24         ARCH_DIR="arm"
  25         STATIC_CLASSPATH="1"
  26         CFLAGS="-D__ARM__"
  27         ;;
  28
  29 i386 | i486 | i586 | i686 )
  30         ARCH_DIR="i386"
  31         STATIC_CLASSPATH="0"
  32         CFLAGS="-D__I386__ $CFLAGS"
  33         ;;
  34
  35 mips )
  36         ARCH_DIR="mips"
  37         STATIC_CLASSPATH="1"
  38
  39 dnl for MIPSPro Compiler
  40 dnl     CFLAGS="-64 -OPT:Olimit=0 -woff 1110,1164,1515 -D__MIPS__ -D__MIPSEB__"
  41         CFLAGS="-64 -OPT:Olimit=0 -D__MIPS__ -D__MIPSEB__"
  42
  43 dnl for GCC
  44 dnl     CFLAGS="-mabi=64 -D__MIPS__ -D__MIPSEB__"
  45 dnl     LDFLAGS="-mabi=64"
  46         ;;
  47
  48 powerpc )
  49         ARCH_DIR="powerpc"
  50         STATIC_CLASSPATH="1"
  51         CFLAGS="-D__POWERPC__"
  52         ;;
  53
  54 x86_64 )
  55         ARCH_DIR="x86_64"
  56         STATIC_CLASSPATH="0"
  57         CFLAGS="-D__X86_64__"
  58         ;;
  59
  60 xdspcore )
  61         ARCH_DIR="xdspcore"
  62         STATIC_CLASSPATH="1"
  63         CFLAGS="-D__XDSPCORE__"
  64         USE_SCHEDULER="1"
  65         ;;
  66 * )
  67         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  68         ;;
  69 esac
  70
  71
  72 dnl set optimization and debugging for all architectures and systems
  73 CFLAGS="-O0 -g3 $CFLAGS"
  74
  75
  76 case "$host_os" in
  77 *linux* | *Linux* )
  78         OS_DIR="linux"
  79         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__LINUX__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  80         ;;
  81 *darwin* )
  82         OS_DIR="darwin"
  83         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__DARWIN__"
  84         ;;
  85 *freebsd* )
  86         OS_DIR="freebsd"
  87         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__FREEBSD__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  88         ;;
  89 *irix* )
  90         OS_DIR="irix"
  91         CFLAGS="$CFLAGS -D__IRIX__"
  92         ;;
  93 * )
  94         ;;
  95 esac
  96
  97
  98 dnl define and substitute some architecture specific variables
  99 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [Architecture directory])
 100 AC_SUBST(ARCH_DIR)
 101 AC_SUBST(OS_DIR)
 102 AC_SUBST(USE_SCHEDULER)
 103
 104
 105 dnl define install prefix
 106 if test "x$prefix" = xNONE; then
 107         CACAO_INSTALL_PREFIX=$ac_default_prefix
 108 else
 109         CACAO_INSTALL_PREFIX=$prefix
 110 fi
 111 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [Installation prefix])
 112 AC_SUBST(CACAO_INSTALL_PREFIX)
 113
 114
 115 dnl Checks for programs.
 116 AC_PROG_CC
 117 AM_PROG_AS
 118 AC_PROG_RANLIB
 119 AC_DISABLE_SHARED
 120 AC_PROG_LN_S
 121 AC_PROG_MAKE_SET
 122
 123 dnl libtool stuff
 124 AC_LIBTOOL_DLOPEN
 125 AC_LIBLTDL_CONVENIENCE
 126 AC_PROG_LIBTOOL
 127 AC_SUBST(LIBLTDL)
 128
 129 dnl Checks for header files.
 130 AC_HEADER_DIRENT
 131 AC_HEADER_STDC
 132 AC_CHECK_HEADERS([fcntl.h])
 133 AC_CHECK_HEADERS([sys/time.h])
 134 AC_CHECK_HEADERS([unistd.h])
 135 AC_CHECK_HEADERS([sys/ioctl.h])
 136
 137 dnl Checks for typedefs, structures, and compiler characteristics.
 138 AC_C_CONST
 139 AC_C_INLINE
 140 AC_TYPE_OFF_T
 141 AC_TYPE_SIZE_T
 142 AC_HEADER_TIME
 143 AC_STRUCT_TM
 144
 145 dnl Checks for library functions.
 146 AC_PROG_GCC_TRADITIONAL
 147 AC_FUNC_MEMCMP
 148 AC_FUNC_MMAP
 149 AC_TYPE_SIGNAL
 150 AC_CHECK_FUNCS(getcwd gettimeofday mkdir mktime select socket)
 151
 152 dnl Checks for libraries.
 153 AC_CHECK_LIB(m, fmod)
 154
 155 dnl Checking sizeof void *
 156 AC_COMPILE_CHECK_SIZEOF(void *)
 157 AC_C_BIGENDIAN
 158
 159 dnl Check for mmap header anomalies (missing MAP_FAILED, etc.)
 160 if test $ac_cv_func_mmap_fixed_mapped = yes; then
 161         AC_CACHE_CHECK(whether MAP_FAILED is defined,
 162                        ac_cv_map_failed,
 163                        AC_EGREP_CPP(yes,
 164                                     [#include <sys/mman.h>
 165                                      #ifdef MAP_FAILED
 166                                         yes
 167                                      #endif],
 168                                     ac_cv_map_failed=yes,
 169                                     ac_cv_map_failed=no))
 170
 171         AC_CACHE_CHECK(whether MAP_ANONYMOUS is defined,
 172                        ac_cv_map_anonymous,
 173                        AC_EGREP_CPP(yes,
 174                                     [#include <sys/mman.h>
 175                                      #ifdef MAP_ANONYMOUS
 176                                         yes
 177                                      #endif],
 178                                     ac_cv_map_anonymous=yes,
 179                                     ac_cv_map_anonymous=no))
 180
 181         AC_CACHE_CHECK(whether MAP_ANON is defined,
 182                        ac_cv_map_anon,
 183                        AC_EGREP_CPP(yes,
 184                                     [#include <sys/mman.h>
 185                                      #ifdef MAP_ANON
 186                                         yes
 187                                      #endif],
 188                                     ac_cv_map_anon=yes,
 189                                     ac_cv_map_anon=no))
 190
 191         if test $ac_cv_map_failed = yes; then
 192                 AC_DEFINE([HAVE_MAP_FAILED], 1, [Define if <sys/mman.h> defines MAP_FAILED])
 193         fi
 194
 195         if test $ac_cv_map_anonymous = yes; then
 196                 AC_DEFINE([HAVE_MAP_ANONYMOUS], 1, [Define if <sys/mman.h> defines MAP_ANONYMOUS])
 197         fi
 198
 199         if test $ac_cv_map_anon = yes; then
 200                 AC_DEFINE([HAVE_MAP_ANON], 1, [Define if <sys/mman.h> defines MAP_ANON])
 201         fi
 202 fi
 203
 204
 205 dnl Features
 206
 207 dnl check arguments
 208
 209 dnl check for garbage collector
 210 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-gc,disable garbage collector [[default=yes]])])
 211
 212 AC_MSG_CHECKING(whether GC should be disabled)
 213 if test x"$enable_gc" = "xno"; then
 214         AC_MSG_RESULT(yes)
 215         AM_CONDITIONAL([DISABLE_GC], [true])
 216 else
 217         AC_MSG_RESULT(no)
 218         AM_CONDITIONAL([DISABLE_GC], [false])
 219 fi
 220
 221 dnl check for statistics
 222 AC_ARG_ENABLE([statistics], [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])])
 223
 224 AC_MSG_CHECKING(whether statistics generation should be enabled)
 225 if test x"$enable_statistics" = "xno"; then
 226         AC_MSG_RESULT(no)
 227         AM_CONDITIONAL([STATISTICS], [false])
 228 else
 229         AC_MSG_RESULT(yes)
 230         AC_DEFINE([STATISTICS], 1, [use statistics])
 231         AM_CONDITIONAL([STATISTICS], [true])
 232 fi
 233
 234
 235 dnl threads
 236 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 237 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 238
 239 AC_MSG_CHECKING(whether to include threads support)
 240 enable_threads=${enable_threads:-native}
 241 case "$enable_threads" in
 242 no | none | single)
 243         AC_MSG_RESULT(no)
 244         dnl no threads for boehm
 245         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 246         AM_CONDITIONAL([USE_THREADS], [false])
 247         AM_CONDITIONAL([NATIVE_THREADS], [false])
 248         ;;
 249
 250 green | native | posix | pthreads)
 251         AC_DEFINE([USE_THREADS], 1, [use threads])
 252         AC_DEFINE([EXTERNAL_OVERFLOW], 1, [external overflow])
 253         AC_DEFINE([DONT_FREE_FIRST], 1, [don't free first])
 254
 255         AM_CONDITIONAL([USE_THREADS], [true])
 256
 257         if test x"$enable_threads" != "xgreen"; then
 258                 AC_MSG_RESULT(yes, native)
 259                 AC_CHECK_LIB(pthread, main)
 260                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 261
 262                 CFLAGS="$CFLAGS -D_REENTRANT"
 263
 264                 dnl tell boehm to support threads as well
 265                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-boehm-threads=posix"
 266                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 267
 268         else
 269                 AC_MSG_RESULT(yes, green)
 270
 271                 dnl no threads for boehm
 272                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-boehm-threads"
 273                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 274         fi
 275     ;;
 276 *)
 277     AC_MSG_ERROR($enable_threads is an unknown thread package)
 278     ;;
 279 esac
 280
 281
 282 dnl Check whether the compiler supports the __thread keyword.
 283 if test "x$use__thread" != xno; then
 284   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 285   [cat > conftest.c <<\EOF
 286 __thread int a = 42;
 287 EOF
 288   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 289     ac_cv_gcc___thread=yes
 290   else
 291     ac_cv_gcc___thread=no
 292   fi
 293   rm -f conftest*])
 294   if test "$ac_cv_gcc___thread" = yes; then
 295     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 296   fi
 297 else
 298   ac_cv_gcc___thread=no
 299 fi
 300
 301
 302 dnl check if linear scan register allocator(lsra) should be used
 303 AC_ARG_ENABLE([lsra], [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])])
 304
 305 AC_MSG_CHECKING(whether lsra should be supported)
 306 if test x"$enable_lsra" = "xno"; then
 307         AC_MSG_RESULT(no)
 308 else
 309         AC_MSG_RESULT(yes)
 310         AC_DEFINE([LSRA], 1, [use lsra])
 311 fi
 312
 313
 314 dnl check for inlining
 315 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 316
 317 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 318 dnl if test x"$enable_inlining" = "xno"; then
 319 dnl     AC_MSG_RESULT(yes)
 320 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 321 dnl else
 322 dnl     AC_MSG_RESULT(no)
 323         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 324         AM_CONDITIONAL([USE_INLINING], [true])
 325 dnl fi
 326
 327
 328 dnl check for instruction scheduler
 329 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 330
 331 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 332 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 333         case "${ARCH_DIR}" in
 334                 xdspcore )
 335                         ;;
 336                 * )
 337                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 338                         ;;
 339         esac
 340
 341         AC_MSG_RESULT(yes)
 342         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 343         AM_CONDITIONAL([USE_SCHEDULER], [true])
 344 else
 345         AC_MSG_RESULT(no)
 346         AM_CONDITIONAL([USE_SCHEDULER], [false])
 347 fi
 348
 349
 350 dnl check if zlib should be used
 351 AC_ARG_ENABLE([zlib], [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])])
 352
 353 AC_MSG_CHECKING(whether zip archives should be supported)
 354 if test x"$enable_zlib" = "xno"; then
 355         AC_MSG_RESULT(no)
 356         AM_CONDITIONAL([USE_ZLIB], [false])
 357 else
 358         AC_MSG_RESULT(yes)
 359         AC_DEFINE([USE_ZLIB], 1, [use zlib])
 360         AC_CHECK_HEADERS([zlib.h])
 361         AC_CHECK_LIB(z, main)
 362         AM_CONDITIONAL([USE_ZLIB], [true])
 363 fi
 364
 365
 366 dnl check if classpath should be linked statically with CACAO
 367 AC_ARG_ENABLE([dynamicclasspath], [AS_HELP_STRING(--disable-dynamicclasspath, link classpath native code static even on platforms supporting dynamic loading)], [use_dynamicclasspath=$enableval], [use_dynamicclasspath=yes])
 368
 369 AC_MSG_CHECKING(whether to link GNU classpath statically)
 370 if test x"$use_dynamicclasspath" = "xno"; then
 371         STATIC_CLASSPATH="1"
 372 fi
 373
 374 if test x"${STATIC_CLASSPATH}" = "x1"; then
 375         AC_MSG_RESULT(yes)
 376         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 377 else
 378         AC_MSG_RESULT(no)
 379         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 380 fi
 381 AC_SUBST(STATIC_CLASSPATH)
 382
 383
 384 dnl enable gtk peer
 385 AC_ARG_ENABLE([gtk-peer], [AS_HELP_STRING(--enable-gtk-peer,compile GTK native peers [[default=no]])])
 386
 387 AC_MSG_CHECKING(whether to use GTK awt peers)
 388 if test x"$enable_gtk_peer" = "xyes"; then
 389         AC_MSG_RESULT(yes)
 390         AC_DEFINE([USE_GTK], 1, [use gtk])
 391         AM_CONDITIONAL([USE_GTK_PEER], [true])
 392         USE_GTK_PEER=yes
 393 else
 394         AC_MSG_RESULT(no)
 395         AM_CONDITIONAL([USE_GTK_PEER], [false])
 396         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-gtk-peer"
 397         USE_GTK_PEER=no
 398 fi
 399 AC_SUBST(USE_GTK_PEER)
 400
 401
 402 dnl pass configure options to classpath
 403 if test x"${STATIC_CLASSPATH}" = "x1"; then
 404         AC_DEFINE([STATIC_CLASSPATH], 1, [use classpath statically linked])
 405         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 406         CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-static --disable-shared"
 407
 408         dnl check for some classpath related stuff when we link statically
 409         AM_ICONV_LINK
 410
 411         dnl taken from GNU classpath configure.ac
 412         if test x"${USE_GTK_PEER}" = "xyes"; then
 413                 AC_ERROR(XXX this is not supported yet)
 414                 AC_PATH_XTRA
 415                 if test "$no_x" = yes; then
 416                         AC_MSG_ERROR([GTK+ peers requested but no X library available])
 417                 fi
 418                 dnl We explicitly want the XTest Extension for Robot support.
 419                 AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
 420                              [AC_MSG_ERROR([libXtst NOT found, required for GdkRobot])],
 421                              [${X_LIBS}])
 422                 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4 gthread-2.0 >= 2.2 libart-2.0 gdk-pixbuf-2.0)
 423                 AC_SUBST(GTK_CFLAGS)
 424                 AC_SUBST(GTK_LIBS)
 425
 426                 AC_SUBST(CAIRO_LIBS)
 427                 AC_SUBST(CAIRO_CFLAGS)
 428                 PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 429                 AC_SUBST(PANGOFT2_LIBS)
 430                 AC_SUBST(PANGOFT2_CFLAGS)
 431         fi
 432 else
 433         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 434         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-static --enable-shared"
 435 fi
 436
 437
 438 dnl should we use an external classpath installation
 439 AC_ARG_WITH([external-classpath], [AS_HELP_STRING(--with-external-classpath=<dir>,installation directory of external GNU classpath [[default=no]])])
 440
 441 AC_MSG_CHECKING(whether to use an external GNU classpath)
 442 if test x"$with_external_classpath" != "x"; then
 443         if test x"$with_external_classpath" = "xyes"; then
 444                 AC_MSG_ERROR(please specify the installation prefix)
 445         fi
 446         AC_MSG_RESULT($with_external_classpath)
 447         AC_DEFINE([WITH_EXTERNAL_CLASSPATH], 1, [external classpath])
 448         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [true])
 449         EXTERNAL_CLASSPATH_PREFIX="$with_external_classpath"
 450         AC_DEFINE_UNQUOTED([EXTERNAL_CLASSPATH_PREFIX], "${EXTERNAL_CLASSPATH_PREFIX}", [external classpath directory])
 451         AC_SUBST(EXTERNAL_CLASSPATH_PREFIX)
 452 else
 453         AC_MSG_RESULT(no)
 454         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [false])
 455 fi
 456
 457
 458 dnl set some essential classpath options, even if their classpath default is
 459 dnl suitable for us
 460 ac_configure_args="$ac_configure_args --libdir=${CACAO_INSTALL_PREFIX}/jre/lib/${ARCH_DIR} --enable-jni --disable-cni --disable-regen-headers ${CONFIGURE_ARGS}"
 461
 462
 463 dnl now configure boehm gc and gnu classpath
 464 dnl the export is not my favorite (is there another way?)
 465 export CFLAGS
 466 AC_CONFIG_SUBDIRS(src/boehm-gc src/classpath src/libltdl)
 467
 468
 469 AC_CONFIG_FILES([Makefile]
 470                 [doc/Makefile]
 471                 [doc/handbook/Makefile]
 472                 [man/Makefile]
 473                 [src/Makefile]
 474                 [src/cacao/Makefile]
 475                 [src/cacaoh/Makefile]
 476                 [src/lib/Makefile]
 477                 [src/mm/Makefile]
 478                 [src/native/Makefile]
 479                 [src/native/include/Makefile]
 480                 [src/native/tools/Makefile]
 481                 [src/native/vm/Makefile]
 482                 [src/scripts/Makefile]
 483                 [src/scripts/cacao]
 484                 [src/scripts/java]
 485                 [src/scripts/kjc]
 486                 [src/scripts/rmic]
 487                 [src/scripts/rmiregistry]
 488                 [src/threads/Makefile]
 489                 [src/threads/green/Makefile]
 490                 [src/threads/native/Makefile]
 491                 [src/toolbox/Makefile]
 492                 [src/vm/Makefile]
 493                 [src/vm/jit/Makefile]
 494                 [src/vm/jit/alpha/Makefile]
 495                 [src/vm/jit/arm/Makefile]
 496                 [src/vm/jit/i386/Makefile]
 497                 [src/vm/jit/i386/linux/Makefile]
 498                 [src/vm/jit/i386/freebsd/Makefile]
 499                 [src/vm/jit/inline/Makefile]
 500                 [src/vm/jit/loop/Makefile]
 501                 [src/vm/jit/mips/Makefile]
 502                 [src/vm/jit/powerpc/Makefile]
 503                 [src/vm/jit/powerpc/darwin/Makefile]
 504                 [src/vm/jit/powerpc/linux/Makefile]
 505                 [src/vm/jit/schedule/Makefile]
 506                 [src/vm/jit/tools/Makefile]
 507                 [src/vm/jit/verify/Makefile]
 508                 [src/vm/jit/x86_64/Makefile]
 509                 [tests/Makefile]
 510                 [tests/codepatching/Makefile]
 511                 [tests/kaffe/Makefile]
 512                 [tests/native/Makefile])
 513
 514 AC_OUTPUT
 515
 516
 517 ## Local variables:
 518 ## mode: m4
 519 ## indent-tabs-mode: t
 520 ## c-basic-offset: 4
 521 ## tab-width: 8
 522 ## compile-command: "automake --add-missing"
 523 ## End: