configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.93+cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl set optimization and debugging for all architectures and systems
  16 if test x"$CFLAGS" = "x"; then
  17         CFLAGS="-O0 -g3"
  18 fi
  19
  20 dnl system type
  21 case "$host_cpu" in
  22 alpha | alphaev56 | alphapca56 )
  23         ARCH_DIR="alpha"
  24         CFLAGS="$CFLAGS -mieee -D__ALPHA__"
  25         ;;
  26
  27 arm | armv4tl | armv5b )
  28         ARCH_DIR="arm"
  29         CFLAGS="$CFLAGS -D__ARM__"
  30         ;;
  31
  32 i386 | i486 | i586 | i686 )
  33         ARCH_DIR="i386"
  34         CFLAGS="$CFLAGS -D__I386__"
  35         ;;
  36
  37 mips )
  38         ARCH_DIR="mips"
  39         CFLAGS="$CFLAGS -D__MIPS__"
  40         ;;
  41
  42 powerpc )
  43         ARCH_DIR="powerpc"
  44         CFLAGS="$CFLAGS -D__POWERPC__"
  45         ;;
  46
  47 x86_64 )
  48         ARCH_DIR="x86_64"
  49         CFLAGS="$CFLAGS -D__X86_64__"
  50         ;;
  51
  52 xdspcore )
  53         ARCH_DIR="xdspcore"
  54         ENABLE_STATICVM="yes"
  55         CFLAGS="$CFLAGS -D__XDSPCORE__"
  56         USE_SCHEDULER="1"
  57         ;;
  58 * )
  59         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  60         ;;
  61 esac
  62
  63 dnl host type
  64 case "$host_os" in
  65 *linux* | *Linux* )
  66         OS_DIR="linux"
  67         CFLAGS="$CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  68         ;;
  69 *darwin* )
  70         OS_DIR="darwin"
  71         CFLAGS="$CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
  72         ;;
  73 *freebsd* )
  74         OS_DIR="freebsd"
  75         CFLAGS="$CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
  76         ;;
  77 *irix* )
  78         OS_DIR="irix"
  79         CFLAGS="$CFLAGS -D__IRIX__"
  80         ;;
  81 * )
  82         ;;
  83 esac
  84
  85
  86 dnl define and substitute some architecture specific variables
  87 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
  88 AC_SUBST(ARCH_DIR)
  89 AC_SUBST(OS_DIR)
  90 AC_SUBST(USE_SCHEDULER)
  91
  92
  93 dnl Checks for programs.
  94 AC_PROG_CC
  95 AM_PROG_AS
  96 AC_PROG_LD
  97 AC_PROG_LD_GNU
  98 AC_PROG_RANLIB
  99 AC_DISABLE_SHARED
 100 AC_PROG_LN_S
 101 AC_PROG_MAKE_SET
 102 AM_PROG_MKDIR_P
 103
 104 dnl libtool stuff
 105 AC_LIBTOOL_DLOPEN
 106 AC_PROG_LIBTOOL
 107
 108 dnl Checks for header files.
 109 AC_HEADER_DIRENT
 110 AC_HEADER_STDC
 111 AC_CHECK_HEADERS([fcntl.h])
 112 AC_CHECK_HEADERS([sys/time.h])
 113 AC_CHECK_HEADERS([unistd.h])
 114 AC_CHECK_HEADERS([sys/ioctl.h])
 115
 116 dnl this is for fdlibm
 117 AC_CHECK_HEADERS([stdint.h])
 118 AC_CHECK_HEADERS([inttypes.h])
 119 AC_CHECK_HEADERS([sys/config.h])
 120 AC_CHECK_HEADERS([sys/types.h])
 121 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 122 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 123 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 124 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 125
 126 dnl Checks for typedefs, structures, and compiler characteristics.
 127 AC_C_CONST
 128 AC_C_INLINE
 129 AC_C_ATTRIBUTE
 130 AC_TYPE_OFF_T
 131 AC_TYPE_SIZE_T
 132 AC_HEADER_TIME
 133 AC_STRUCT_TM
 134
 135 dnl Checks for library functions.
 136 AC_PROG_GCC_TRADITIONAL
 137 AC_TYPE_SIGNAL
 138 AC_FUNC_MEMCMP
 139 AC_CHECK_FUNCS([calloc mprotect getpagesize free])
 140 AC_CHECK_FUNCS([getcwd gettimeofday])
 141 AC_CHECK_FUNCS([scandir])
 142 AC_CHECK_FUNCS([mmap])
 143 AC_CHECK_FUNCS([isnan])
 144
 145 dnl Checks for libraries.
 146
 147 dnl Checking sizeof void *
 148 AC_CHECK_SIZEOF(void *)
 149 AC_C_BIGENDIAN
 150
 151
 152 dnl check which ld flags are required to export symbols
 153 if test x"$with_gnu_ld" = "xyes"; then
 154     EXPORT_SYMBOLS_FLAGS="-Wl,--export-dynamic"
 155 else
 156     EXPORT_SYMBOLS_FLAGS=""
 157 fi
 158 AC_SUBST(EXPORT_SYMBOLS_FLAGS)
 159
 160
 161 dnl define install prefix
 162 if test "x$prefix" = "xNONE"; then
 163     CACAO_INSTALL_PREFIX=$ac_default_prefix
 164 else
 165     CACAO_INSTALL_PREFIX=$prefix
 166 fi
 167 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [installation prefix])
 168 AC_SUBST(CACAO_INSTALL_PREFIX)
 169
 170
 171 dnl Features
 172
 173 dnl check arguments
 174
 175 dnl check for JIT compiler
 176 AC_MSG_CHECKING(whether JIT compiler should be compiled)
 177 AC_ARG_ENABLE([jit],
 178               [AS_HELP_STRING(--disable-jit,disable JIT compiler [[default=yes]])],
 179               [case "${enableval}" in
 180                    no) ENABLE_JIT=no;;
 181                    *) ENABLE_JIT=yes;;
 182                esac],
 183               [ENABLE_JIT=yes])
 184 AC_MSG_RESULT(${ENABLE_JIT})
 185 AM_CONDITIONAL([ENABLE_JIT], test x"${ENABLE_JIT}" = "xyes")
 186
 187 if test x"${ENABLE_JIT}" = "xyes"; then
 188     AC_DEFINE([ENABLE_JIT], 1, [enable JIT compiler])
 189 fi
 190
 191
 192 dnl check for interpreter
 193 AC_ARG_ENABLE([intrp], [AS_HELP_STRING(--enable-intrp,enable interpreter [[default=no]])])
 194
 195 AC_MSG_CHECKING(whether interpreter should be compiled)
 196 if test x"$enable_intrp" = "xyes"; then
 197     AC_MSG_RESULT(yes)
 198     AC_DEFINE([ENABLE_INTRP], 1, [enable interpreter])
 199     AM_CONDITIONAL([ENABLE_INTRP], [true])
 200     ENABLE_INTRP=yes
 201
 202     AC_ASM_SKIP16
 203
 204     dnl check for libffi
 205     AC_ARG_WITH([ffi],
 206                 [AS_HELP_STRING(--with-ffi,use libffi to call native functions)],
 207                 [WITH_FFI=yes
 208                  AC_CHECK_HEADERS([ffi.h],, [AC_MSG_ERROR(cannot find ffi.h)])
 209                  AC_CHECK_LIB(ffi, ffi_call,, [AC_MSG_ERROR(cannot find libffi)])
 210                  AC_DEFINE([WITH_FFI], 1, [use libffi])],
 211                 [WITH_FFI=no])
 212
 213     dnl check for libffcall
 214     AC_ARG_WITH([ffcall],
 215                 [AS_HELP_STRING(--with-ffcall,use libffcall to call native functions)],
 216                 [WITH_FFCALL=yes
 217                  AC_CHECK_HEADERS([avcall.h],, [AC_MSG_ERROR(cannot find avcall.h)])
 218                  AC_CHECK_LIB(avcall, __builtin_avcall,, [AC_MSG_ERROR(cannot find libavcall (from libffcall))])
 219                  AC_DEFINE([WITH_FFCALL], 1, [use libffcall])],
 220                 [WITH_FFCALL=no])
 221
 222     dnl check for libffi or libffcall
 223     if test x"${WITH_FFI}" = "xyes" -a x"${WITH_FFCALL}" = "xyes"; then
 224         AC_ERROR(Enable only libffi or libffcall.)
 225     fi
 226     if test x"${WITH_FFI}" = "xno" -a x"${WITH_FFCALL}" = "xno"; then
 227         AC_ERROR(Enable one of libffi or libffcall.)
 228     fi
 229
 230 else
 231     AC_MSG_RESULT(no)
 232     AM_CONDITIONAL([ENABLE_INTRP], [false])
 233     ENABLE_INTRP="no"
 234 fi
 235
 236 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 237     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 238 fi
 239
 240
 241 dnl check for garbage collector usage
 242 AC_MSG_CHECKING(whether GC should be disabled)
 243 AC_ARG_ENABLE([gc],
 244               [AS_HELP_STRING(--disable-gc,disable garbage collector (for debugging only!) [[default=yes]])],
 245               [case "${enableval}" in
 246                    no) DISABLE_GC=yes
 247                        AC_DEFINE([DISABLE_GC], 1, [disable garbage collector])
 248                        ;;
 249                    *) DISABLE_GC=no;;
 250                esac],
 251               [DISABLE_GC=no])
 252 AC_MSG_RESULT(${DISABLE_GC})
 253 AM_CONDITIONAL([DISABLE_GC], test x"${DISABLE_GC}" = "xyes")
 254
 255
 256 dnl check for dump memory usage
 257 AC_MSG_CHECKING(whether dump memory should be disabled)
 258 AC_ARG_ENABLE([dump],
 259               [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])],
 260               [case "${enableval}" in
 261                    no)
 262                        DISABLE_DUMP=yes
 263                        AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 264                        ;;
 265                    *) DISABLE_DUMP=no;;
 266                esac],
 267                [DISABLE_DUMP=no])
 268 AC_MSG_RESULT(${DISABLE_DUMP})
 269
 270
 271 dnl check for debug
 272 AC_MSG_CHECKING(whether debug code generation should be enabled)
 273 AC_ARG_ENABLE([debug],
 274               [AS_HELP_STRING(--disable-debug,disable debug code generation [[default=yes]])],
 275               [case "${enableval}" in
 276                    no) NDEBUG=yes
 277                        AC_DEFINE([NDEBUG], 1, [disable debug code])
 278                        ;;
 279                    *) NDEBUG=no;;
 280                esac],
 281               [NDEBUG=no])
 282
 283 if test x"${NDEBUG}" = "xno"; then
 284     AC_MSG_RESULT(yes)
 285
 286     dnl check for binutils headers and libraries on some architectures for the
 287     dnl disassembler
 288     case "${ARCH_DIR}" in
 289         arm | i386 | powerpc | x86_64 )
 290             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 291             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from bintuils))])
 292             AC_CHECK_LIB(opcodes, init_disassemble_info,, [AC_MSG_ERROR(cannot find libopcodes (from bintuils))])
 293             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 294             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 295             ;;
 296         * )
 297             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 298             ;;
 299     esac
 300
 301 else
 302     AC_MSG_RESULT(no)
 303 fi
 304 AM_CONDITIONAL([NDEBUG], test x"${NDEBUG}" = "xno")
 305
 306
 307 dnl check for statistics
 308 AC_MSG_CHECKING(whether statistics generation should be enabled)
 309 AC_ARG_ENABLE([statistics],
 310               [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])],
 311               [case "${enableval}" in
 312                    no) ENABLE_STATISTICS=no;;
 313                    *) ENABLE_STATISTICS=yes;;
 314                esac],
 315               [ENABLE_STATISTICS=yes])
 316 AC_MSG_RESULT(${ENABLE_STATISTICS})
 317 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 318
 319 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 320     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 321 fi
 322
 323
 324 dnl check for JVMTI
 325 AC_MSG_CHECKING(whether to compile JVMTI support)
 326 AC_ARG_ENABLE([jvmti],
 327               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 328               [case "${enableval}" in
 329                    yes) ENABLE_JVMTI=yes;;
 330                    *) ENABLE_JVMTI=no;;
 331                esac],
 332               [ENABLE_JVMTI=no])
 333 AC_MSG_RESULT(${ENABLE_JVMTI})
 334 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 335
 336 if test x"${ENABLE_JVMTI}" = "xyes"; then
 337     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 338 fi
 339
 340
 341 dnl threads
 342 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 343 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 344
 345 AC_MSG_CHECKING(whether to include threads support)
 346 enable_threads=${enable_threads:-native}
 347 case "$enable_threads" in
 348 no | none | single)
 349         AC_MSG_RESULT(no)
 350         dnl no threads for boehm
 351         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 352         AM_CONDITIONAL([USE_THREADS], [false])
 353         AM_CONDITIONAL([NATIVE_THREADS], [false])
 354         ;;
 355
 356 green | native | posix | pthreads)
 357         AC_DEFINE([USE_THREADS], 1, [use threads])
 358
 359         AM_CONDITIONAL([USE_THREADS], [true])
 360
 361         if test x"$enable_threads" != "xgreen"; then
 362                 AC_MSG_RESULT(yes, native)
 363                 AC_CHECK_LIB(pthread, main)
 364                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 365
 366                 CFLAGS="$CFLAGS -D_REENTRANT"
 367
 368                 dnl tell boehm to support threads as well
 369                 ac_configure_args="$ac_configure_args --enable-boehm-threads=posix"
 370                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 371
 372         else
 373                 AC_MSG_RESULT(yes, green)
 374
 375                 dnl no threads for boehm
 376                 ac_configure_args="$ac_configure_args --disable-boehm-threads"
 377                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 378         fi
 379     ;;
 380 *)
 381     AC_MSG_ERROR($enable_threads is an unknown thread package)
 382     ;;
 383 esac
 384
 385
 386 dnl Check whether the compiler supports the __thread keyword.
 387 if test "x$use__thread" != xno; then
 388   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 389   [cat > conftest.c <<\EOF
 390 __thread int a = 42;
 391 EOF
 392   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 393     ac_cv_gcc___thread=yes
 394   else
 395     ac_cv_gcc___thread=no
 396   fi
 397   rm -f conftest*])
 398   if test "$ac_cv_gcc___thread" = yes; then
 399     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 400   fi
 401 else
 402   ac_cv_gcc___thread=no
 403 fi
 404
 405
 406 dnl check if linear scan register allocator(lsra) should be used
 407 AC_MSG_CHECKING(whether lsra should be supported)
 408 AC_ARG_ENABLE([lsra],
 409               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])],
 410               [case "${enableval}" in
 411                    no) ENABLE_LSRA=no;;
 412                    *) ENABLE_LSRA=yes;;
 413                esac],
 414               [ENABLE_LSRA=yes])
 415 AC_MSG_RESULT(${ENABLE_LSRA})
 416 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 417
 418 if test x"${ENABLE_LSRA}" = "xyes"; then
 419     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 420 fi
 421
 422
 423 dnl check for inlining
 424 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 425
 426 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 427 dnl if test x"$enable_inlining" = "xno"; then
 428 dnl     AC_MSG_RESULT(yes)
 429 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 430 dnl else
 431 dnl     AC_MSG_RESULT(no)
 432         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 433         AM_CONDITIONAL([USE_INLINING], [true])
 434 dnl fi
 435
 436
 437 dnl check for instruction scheduler
 438 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 439
 440 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 441 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 442         case "${ARCH_DIR}" in
 443                 xdspcore )
 444                         ;;
 445                 * )
 446                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 447                         ;;
 448         esac
 449
 450         AC_MSG_RESULT(yes)
 451         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 452         AM_CONDITIONAL([USE_SCHEDULER], [true])
 453 else
 454         AC_MSG_RESULT(no)
 455         AM_CONDITIONAL([USE_SCHEDULER], [false])
 456 fi
 457
 458
 459 dnl check if zlib should be used
 460 AC_MSG_CHECKING(whether zip archives should be supported)
 461 AC_ARG_ENABLE([zlib],
 462               [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])],
 463               [case "${enableval}" in
 464                   no) ENABLE_ZLIB=yes;;
 465                   *) ENABLE_ZLIB=no;;
 466                esac],
 467               [ENABLE_ZLIB=yes])
 468 AC_MSG_RESULT(${ENABLE_ZLIB})
 469
 470 if test x"${ENABLE_ZLIB}" = "xyes"; then
 471     AC_CHECK_HEADERS([zlib.h],, [AC_MSG_ERROR(cannot find zlib.h)])
 472     AC_CHECK_LIB(z, inflate,, [AC_MSG_ERROR(cannot find libz)])
 473     AC_DEFINE([ENABLE_ZLIB], 1, [use zlib])
 474 fi
 475 AM_CONDITIONAL([ENABLE_ZLIB], test x"${ENABLE_ZLIB}" = "xyes")
 476
 477
 478 dnl check if CACAO should be linked statically
 479 AC_MSG_CHECKING(whether to link GNU classpath native libraries statically into CACAO)
 480 AC_ARG_ENABLE([staticvm],
 481               [AS_HELP_STRING(--enable-staticvm, link GNU classpath native libraries statically into CACAO [[default=no]])],
 482               [case "${enableval}" in
 483                   yes) ENABLE_STATICVM=yes;;
 484                   *) ENABLE_STATICVM=no;;
 485                esac],
 486               [ENABLE_STATICVM=no])
 487 AC_MSG_RESULT(${ENABLE_STATICVM})
 488
 489 if test x"${ENABLE_STATICVM}" = "xyes"; then
 490     AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 491
 492     dnl check for some classpath related stuff when we link statically
 493     AM_ICONV_LINK
 494 else
 495     AC_CHECK_HEADERS([ltdl.h],, [AC_MSG_ERROR(cannot find ltdl.h)])
 496     AC_CHECK_LIB(ltdl, lt_dlopen,, [AC_MSG_ERROR(cannot find libltdl)])
 497 fi
 498 AM_CONDITIONAL([ENABLE_STATICVM], test x"${ENABLE_STATICVM}" = "xyes")
 499 AC_SUBST(ENABLE_STATICVM)
 500
 501
 502 dnl is GNU classpath installed somewhere different
 503 AC_MSG_CHECKING(where GNU classpath is installed)
 504 AC_ARG_WITH([classpath-install-dir],
 505             [AS_HELP_STRING(--with-classpath-install-dir=<dir>,installation directory of GNU classpath [[default=/usr/local/classpath]])],
 506             [CLASSPATH_INSTALL_DIR=${withval}],
 507             [CLASSPATH_INSTALL_DIR=/usr/local/classpath])
 508 AC_MSG_RESULT(${CLASSPATH_INSTALL_DIR})
 509 AC_DEFINE_UNQUOTED([CLASSPATH_INSTALL_DIR], "${CLASSPATH_INSTALL_DIR}", [GNU classpath installation directory])
 510 AC_SUBST(CLASSPATH_INSTALL_DIR)
 511
 512
 513 dnl Maybe the user has Classpath installed 'flat'.
 514 AC_ARG_WITH([flat-classpath], [AS_HELP_STRING(--with-flat-classpath, GNU Classpath is not zipped in the install directory)])
 515 if test x"$with_flat_classpath" = "x"; then
 516         GLIBJZ=glibj.zip
 517 else
 518         GLIBJZ=
 519 fi
 520 AC_SUBST(GLIBJZ)
 521 AC_DEFINE_UNQUOTED(GLIBJZ_STRING, "$GLIBJZ", [define to the string base name of the classpath zip file])
 522
 523
 524 dnl check for some programs we need
 525 AC_PROG_JAVAC
 526 AC_PATH_PROG(ZIP, zip)
 527 if test -z "${ZIP}"; then
 528     AC_MSG_ERROR([cannot find zip])
 529 fi
 530
 531
 532 dnl now configure subpackages
 533 dnl the export is not my favorite (is there another way?)
 534 export CFLAGS
 535 AC_CONFIG_SUBDIRS(src/boehm-gc)
 536
 537 AC_CONFIG_FILES([Makefile]
 538                 [contrib/Makefile]
 539                 [contrib/setenvinstalled]
 540                 [contrib/setenvsource]
 541                 [doc/Makefile]
 542                 [doc/handbook/Makefile]
 543                 [man/Makefile]
 544                 [src/Makefile]
 545                 [src/cacao/Makefile]
 546                 [src/cacaoh/Makefile]
 547                 [src/fdlibm/Makefile]
 548                 [src/lib/Makefile]
 549                 [src/mm/Makefile]
 550                 [src/native/Makefile]
 551                 [src/native/include/Makefile]
 552                 [src/native/jvmti/Makefile]
 553                 [src/native/tools/Makefile]
 554                 [src/native/vm/Makefile]
 555                 [src/scripts/Makefile]
 556                 [src/scripts/java]
 557                 [src/scripts/rmiregistry]
 558                 [src/threads/Makefile]
 559                 [src/threads/green/Makefile]
 560                 [src/threads/native/Makefile]
 561                 [src/toolbox/Makefile]
 562                 [src/vm/Makefile]
 563                 [src/vm/jit/Makefile]
 564                 [src/vm/jit/allocator/Makefile]
 565                 [src/vm/jit/alpha/Makefile]
 566                 [src/vm/jit/alpha/freebsd/Makefile]
 567                 [src/vm/jit/alpha/linux/Makefile]
 568                 [src/vm/jit/i386/Makefile]
 569                 [src/vm/jit/i386/freebsd/Makefile]
 570                 [src/vm/jit/i386/linux/Makefile]
 571                 [src/vm/jit/intrp/Makefile]
 572                 [src/vm/jit/inline/Makefile]
 573                 [src/vm/jit/loop/Makefile]
 574                 [src/vm/jit/mips/Makefile]
 575                 [src/vm/jit/mips/irix/Makefile]
 576                 [src/vm/jit/mips/linux/Makefile]
 577                 [src/vm/jit/powerpc/Makefile]
 578                 [src/vm/jit/powerpc/darwin/Makefile]
 579                 [src/vm/jit/powerpc/linux/Makefile]
 580                 [src/vm/jit/schedule/Makefile]
 581                 [src/vm/jit/tools/Makefile]
 582                 [src/vm/jit/verify/Makefile]
 583                 [src/vm/jit/x86_64/Makefile]
 584                 [tests/Makefile]
 585                 [tests/codepatching/Makefile]
 586                 [tests/native/Makefile]
 587                 [tests/regression/Makefile])
 588
 589 AC_OUTPUT
 590
 591
 592 ## Local variables:
 593 ## mode: m4
 594 ## indent-tabs-mode: t
 595 ## c-basic-offset: 4
 596 ## tab-width: 8
 597 ## compile-command: "automake --add-missing"
 598 ## End: