configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.92)
   5 AM_MAINTAINER_MODE
   6
   7 dnl
   8 dnl libgc checks
   9 dnl
  10
  11 gc_headers=no
  12 gc=included
  13 use_included_gc=no
  14
  15 if test -d $srcdir/libgc ; then
  16   gc_default=included
  17 else
  18   gc_default=boehm
  19 fi
  20
  21 #
  22 # These are the flags that need to be stored in the mono.pc file for
  23 # compiling code that will embed Mono
  24 #
  25 libmono_cflags=""
  26 libmono_ldflags=""
  27 AC_SUBST(libmono_cflags)
  28 AC_SUBST(libmono_ldflags)
  29
  30 dnl if linker handles the version script
  31 no_version_script=no
  32
  33 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  34 need_link_unlink=no
  35
  36 # Thread configuration inspired by sleepycat's db
  37 AC_MSG_CHECKING([host platform characteristics])
  38 libgc_threads=no
  39 case "$host" in
  40         *-*-mingw*|*-*-cygwin*)
  41                 platform_win32=yes
  42                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  43                 CC="gcc -mno-cygwin"
  44                 HOST_CC="gcc"
  45 # latest libgc already defines GC_WIN32_THREADS
  46 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  47                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  48                 libdl=
  49                 libgc_threads=win32
  50                 gc_default=boehm
  51                 ;;
  52         *-*-*netbsd*)
  53                 platform_win32=no
  54                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  55                 libmono_cflags="-D_REENTRANT"
  56                 LDFLAGS="$LDFLAGS -pthread"
  57                 libmono_ldflags="-pthread"
  58                 need_link_unlink=yes
  59                 libdl=
  60                 libgc_threads=no
  61                 ;;
  62         *-*-*freebsd*|*-*-*openbsd*)
  63                 platform_win32=no
  64                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  65                 libmono_cflags="-D_THREAD_SAFE"
  66                 LDFLAGS="$LDFLAGS -pthread"
  67                 libmono_ldflags="-pthread"
  68                 need_link_unlink=yes
  69                 AC_DEFINE(PTHREAD_POINTER_ID)
  70                 libdl=
  71                 libgc_threads=pthreads
  72                 ;;
  73         *-*-linux*)
  74                 platform_win32=no
  75                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
  76                 libmono_cflags="-D_REENTRANT"
  77                 libmono_ldflags="-lpthread"
  78                 libdl="-ldl"
  79                 libgc_threads=pthreads
  80                 ;;
  81         *-*-hpux*)
  82                 platform_win32=no
  83                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
  84                 CFLAGS="$CFLAGS +ESdbgasm"
  85                 LDFLAGS="$LDFLAGS -z"
  86                 libmono_cflags="-D_REENTRANT"
  87                 libmono_ldflags="-lpthread"
  88                 libgc_threads=pthreads
  89                 need_link_unlink=yes
  90                 ;;
  91         *-*-solaris*)
  92                 platform_win32=no
  93                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
  94                 need_link_unlink=yes
  95                 libmono_cflags="-D_REENTRANT"
  96                 libgc_threads=pthreads
  97                 ;;
  98         *-*-darwin*)
  99                 platform_win32=no
 100                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
 101                 libmono_cflags="-D_THREAD_SAFE"
 102                 LDFLAGS="$LDFLAGS -pthread"
 103                 libmono_ldflags="-pthread"
 104                 need_link_unlink=yes
 105                 AC_DEFINE(PTHREAD_POINTER_ID)
 106                 AC_DEFINE(USE_MACH_SEMA)
 107                 no_version_script=yes
 108                 libdl=
 109                 libgc_threads=pthreads
 110                 ;;
 111         *)
 112                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 113                 platform_win32=no
 114                 libdl="-ldl"
 115                 ;;
 116 esac
 117 AC_MSG_RESULT(ok)
 118
 119 if test x$need_link_unlink = xyes; then
 120    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 121 fi
 122
 123 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 124
 125 AC_CHECK_TOOL(CC, gcc, gcc)
 126 AC_PROG_CC
 127 AM_PROG_CC_STDC
 128 AC_PROG_INSTALL
 129 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 130 : ${CCAS='$(CC)'}
 131 # Set ASFLAGS if not already set.
 132 : ${CCASFLAGS='$(CFLAGS)'}
 133 AC_SUBST(CCAS)
 134 AC_SUBST(CCASFLAGS)
 135
 136 AC_CHECK_PROG(BISON, bison,yes,no)
 137 if test "x$BISON" = "xno";
 138 then
 139         AC_MSG_ERROR([You need to install bison])
 140 fi
 141
 142 dnl may require a specific autoconf version
 143 dnl AC_PROG_CC_FOR_BUILD
 144 dnl CC_FOR_BUILD not automatically detected
 145 CC_FOR_BUILD=$CC
 146 BUILD_EXEEXT=
 147 if test "x$cross_compiling" = "xyes"; then
 148         CC_FOR_BUILD=cc
 149         BUILD_EXEEXT=""
 150 fi
 151 AC_SUBST(CC_FOR_BUILD)
 152 AC_SUBST(HOST_CC)
 153 AC_SUBST(BUILD_EXEEXT)
 154
 155 # Set STDC_HEADERS
 156 AC_HEADER_STDC
 157 AC_LIBTOOL_WIN32_DLL
 158 AM_PROG_LIBTOOL
 159
 160 # Test whenever ld supports -version-script
 161 AC_PROG_LD
 162 AC_PROG_LD_GNU
 163 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 164    no_version_script=yes
 165 fi
 166
 167 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 168
 169 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
 170
 171 # for mono/mini/tramp-x86.c
 172 AC_CHECK_HEADERS(valgrind/memcheck.h)
 173
 174 # for mono/metadata/debug-symfile.c
 175 AC_CHECK_HEADERS(elf.h)
 176
 177 # for mono/dis
 178 AC_CHECK_HEADERS(wchar.h)
 179
 180 # not 64 bit clean in cross-compile
 181 AC_CHECK_SIZEOF(void *, 4)
 182
 183 WARN=''
 184 if test x"$GCC" = xyes; then
 185         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 186                 # The runtime code does not respect ANSI C strict aliasing rules
 187                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 188 else
 189         # The Sun Forte compiler complains about inline functions that access static variables
 190         # so disable all inlining.
 191         case "$host" in
 192         *-*-solaris*)
 193                 CFLAGS="$CFLAGS -Dinline="
 194                 ;;
 195         esac
 196 fi
 197 CFLAGS="$CFLAGS -g $WARN"
 198
 199 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 200 if test "x$PKG_CONFIG" = "xno"; then
 201         AC_MSG_ERROR([You need to install pkg-config])
 202 fi
 203
 204 dnl for use on the build system
 205 dnl pkg-config is stupid
 206 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 207 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 208 AC_SUBST(BUILD_GLIB_CFLAGS)
 209 AC_SUBST(BUILD_GLIB_LIBS)
 210
 211 PKG_PATH=
 212 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 213         if test x$with_crosspkgdir = "x"; then
 214                 if test -s $PKG_CONFIG_PATH; then
 215                         PKG_PATH=$PKG_CONFIG_PATH
 216                 fi
 217         else
 218                 PKG_PATH=$with_crosspkgdir
 219                 PKG_CONFIG_PATH=$PKG_PATH
 220                 export PKG_CONFIG_PATH
 221         fi
 222 )
 223
 224 ## Versions of dependencies
 225 GLIB_REQUIRED_VERSION=1.3.11
 226
 227 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 228
 229 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 230 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 231 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 232 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 233
 234 AC_SUBST(GLIB_CFLAGS)
 235 AC_SUBST(GLIB_LIBS)
 236 AC_SUBST(GMODULE_CFLAGS)
 237 AC_SUBST(GMODULE_LIBS)
 238
 239 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 240
 241 # Enable support for NPTL only features like fast thread-local storage
 242 # We can't reliably detect nptl at compile & run time
 243 # so this option will stay until nptl becomes more widespread
 244 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      enable/disable support for NPTL],[],[with_nptl=yes])
 245
 246 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 247 # This does not work on some platforms (bug #55253)
 248 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 249
 250 # assembly bundle support, see metadata/make-bundle.pl for more info
 251 AC_ARG_WITH(bundle, [  --with-bundle=bundle_template],[
 252         BUNDLE_FILE=$with_bundle
 253         AC_SUBST(BUNDLE_FILE)
 254         AC_DEFINE(WITH_BUNDLE)
 255 ],[with_bundle=no])
 256 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
 257
 258 LIBGC_CFLAGS=
 259 LIBGC_LIBS=
 260 libgc_dir=
 261 case "x$gc" in
 262         xboehm|xbohem|xyes)
 263                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 264                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 265
 266                 if test "x$found_boehm" != "xyes"; then
 267                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 268                 fi
 269                 if test "x$gc_headers" != "xyes"; then
 270                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 271                 fi
 272
 273                 AC_DEFINE(HAVE_BOEHM_GC)
 274                 AC_SUBST(HAVE_BOEHM_GC)
 275                 LIBGC_LIBS="-lgc $libdl"
 276
 277                 # AC_CHECK_FUNCS does not work for some reason...
 278                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 279                 if test "x$found_gcj_malloc" = "xyes"; then
 280                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 281                 fi
 282                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 283                 if test "x$found_gc_enable" = "xyes"; then
 284                         AC_DEFINE(HAVE_GC_ENABLE)
 285                 fi
 286                 ;;
 287
 288         xincluded)
 289                 AC_CONFIG_SUBDIRS(libgc)
 290
 291                 found_boehm=yes
 292                 gc_headers=yes
 293                 use_included_gc=yes
 294                 libgc_dir=libgc
 295
 296                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 297                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 298
 299                 AC_DEFINE(HAVE_BOEHM_GC)
 300                 AC_SUBST(HAVE_BOEHM_GC)
 301
 302                 AC_DEFINE(HAVE_GC_H)
 303                 AC_DEFINE(USE_INCLUDED_LIBGC)
 304
 305                 # The included libgc contains GCJ support
 306                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 307                 AC_DEFINE(HAVE_GC_ENABLE)
 308                 ;;
 309
 310         xnone)
 311                 AC_MSG_WARN("Compiling mono without GC.")
 312                 ;;
 313         *)
 314                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 315                 ;;
 316 esac
 317
 318
 319 # tell libgc/configure about what we want
 320 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
 321
 322 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 323 AC_SUBST(LIBGC_CFLAGS)
 324 AC_SUBST(LIBGC_LIBS)
 325 AC_SUBST(libgc_dir)
 326
 327 dnl
 328 dnl End of libgc checks
 329 dnl
 330
 331 if test x$platform_win32 = xno; then
 332
 333         dnl ******************************************************************
 334         dnl *** Checks for the IKVM JNI interface library                  ***
 335         dnl ******************************************************************
 336         AC_ARG_WITH(ikvm-jni, [  --with-ikvm-jni=yes,no  build the IKVM JNI interface library],[with_ikvm_jni=$withval],[with_ikvm_jni=yes])
 337         AC_ARG_WITH(jdk, [  --with-jdk=DIRECTORY    Use JDK from DIRECTORY],[with_jdk_dir=$withval],[with_jdk_dir=])
 338
 339         ikvm_jni_dir=
 340         if test x$with_ikvm_jni = xyes; then
 341                 AC_MSG_CHECKING([JDK headers])
 342
 343                 if test x$with_jdk_dir = x; then
 344                         # Try JAVA_HOME variable
 345                         if test x$JAVA_HOME != x; then
 346                                 with_jdk_dir=$JAVA_HOME
 347                         fi
 348                 fi
 349
 350                 jdk_platform=
 351                 if test -d $with_jdk_dir/include; then
 352                         jdk_headers_found=yes
 353
 354                         if test -d $with_jdk_dir/include/linux; then
 355                                 jdk_platform=linux
 356                         else
 357                         if test -d $with_jdk_dir/include/solaris; then
 358                                 jdk_platform=solaris
 359                         else
 360                         if test -f $with_jdk_dir/include/jni_md.h; then
 361                                 # GNU Classpath sources
 362                                 jdk_platform=
 363                         else
 364                                 jdk_headers_found=no
 365                         fi
 366                         fi
 367                         fi
 368                 else
 369                         jdk_headers_found=no
 370                 fi
 371
 372                 if test x$jdk_headers_found = xyes; then
 373                         AC_MSG_RESULT($with_jdk_dir/include $with_jdk_dir/include/$jdk_platform)
 374                 else
 375                         AC_MSG_RESULT(not found)
 376                 fi
 377
 378                 if test x$jdk_headers_found = xyes; then
 379                         ikvm_jni_dir=ikvm-jni
 380                         IKVM_JNI_CFLAGS="-I$with_jdk_dir/include -I$with_jdk_dir/include/$jdk_platform"
 381                 fi
 382         fi
 383
 384         AC_SUBST(ikvm_jni_dir)
 385         AC_SUBST(IKVM_JNI_CFLAGS)
 386
 387         AC_CHECK_FUNCS(getgrgid_r)
 388         AC_CHECK_FUNCS(getgrnam_r)
 389         AC_CHECK_FUNCS(getpwnam_r)
 390         AC_CHECK_FUNCS(getpwuid_r)
 391         AC_CHECK_FUNCS(getresuid)
 392         AC_CHECK_FUNCS(setresuid)
 393
 394         dnl ******************************************************************
 395         dnl *** Check for large file support                               ***
 396         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 397         dnl ******************************************************************
 398
 399         # Check that off_t can represent 2**63 - 1 correctly, working around
 400         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 401         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 402         large_offt=no
 403         AC_DEFUN(LARGE_FILES, [
 404                 large_CPPFLAGS=$CPPFLAGS
 405                 CPPFLAGS="$CPPFLAGS $1"
 406                 AC_TRY_RUN([
 407                         #include <sys/types.h>
 408
 409                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 410
 411                         int main(void) {
 412                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 413                                                (BIG_OFF_T%2147483647==1));
 414                                 if(big_off_t) {
 415                                         exit(0);
 416                                 } else {
 417                                         exit(1);
 418                                 }
 419                         }
 420                 ], [
 421                         AC_MSG_RESULT(ok)
 422                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 423                         large_CPPFLAGS="$large_CPPFLAGS $1"
 424                         large_offt=yes
 425                 ], [
 426                         AC_MSG_RESULT(no)
 427                 ], "")
 428                 CPPFLAGS=$large_CPPFLAGS
 429         ])
 430
 431         AC_MSG_CHECKING(if off_t is 64 bits wide)
 432         LARGE_FILES("")
 433         if test $large_offt = no; then
 434                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 435                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 436         fi
 437         if test $large_offt = no; then
 438                 AC_MSG_WARN([No 64 bit file size support available])
 439         fi
 440
 441         dnl *****************************
 442         dnl *** Checks for libsocket  ***
 443         dnl *****************************
 444         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 445
 446         dnl *******************************
 447         dnl *** Checks for MSG_NOSIGNAL ***
 448         dnl *******************************
 449         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 450         AC_TRY_COMPILE([#include <sys/socket.h>], [
 451                 int f = MSG_NOSIGNAL;
 452         ], [
 453                 # Yes, we have it...
 454                 AC_MSG_RESULT(yes)
 455                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 456         ], [
 457                 # We'll have to use signals
 458                 AC_MSG_RESULT(no)
 459         ])
 460
 461         dnl *****************************
 462         dnl *** Checks for SOL_IP     ***
 463         dnl *****************************
 464         AC_MSG_CHECKING(for SOL_IP)
 465         AC_TRY_COMPILE([#include <netdb.h>], [
 466                 int level = SOL_IP;
 467         ], [
 468                 # Yes, we have it...
 469                 AC_MSG_RESULT(yes)
 470                 AC_DEFINE(HAVE_SOL_IP)
 471         ], [
 472                 # We'll have to use getprotobyname
 473                 AC_MSG_RESULT(no)
 474         ])
 475
 476         dnl *****************************
 477         dnl *** Checks for SOL_IPV6     ***
 478         dnl *****************************
 479         AC_MSG_CHECKING(for SOL_IPV6)
 480         AC_TRY_COMPILE([#include <netdb.h>], [
 481                 int level = SOL_IPV6;
 482         ], [
 483                 # Yes, we have it...
 484                 AC_MSG_RESULT(yes)
 485                 AC_DEFINE(HAVE_SOL_IPV6)
 486         ], [
 487                 # We'll have to use getprotobyname
 488                 AC_MSG_RESULT(no)
 489         ])
 490
 491         dnl *****************************
 492         dnl *** Checks for SOL_TCP    ***
 493         dnl *****************************
 494         AC_MSG_CHECKING(for SOL_TCP)
 495         AC_TRY_COMPILE([#include <netdb.h>], [
 496                 int level = SOL_TCP;
 497         ], [
 498                 # Yes, we have it...
 499                 AC_MSG_RESULT(yes)
 500                 AC_DEFINE(HAVE_SOL_TCP)
 501         ], [
 502                 # We'll have to use getprotobyname
 503                 AC_MSG_RESULT(no)
 504         ])
 505
 506         dnl *****************************
 507         dnl *** Checks for IP_PKTINFO ***
 508         dnl *****************************
 509         AC_MSG_CHECKING(for IP_PKTINFO)
 510         AC_TRY_COMPILE([#include <netdb.h>], [
 511                 int level = IP_PKTINFO;
 512         ], [
 513                 # Yes, we have it...
 514                 AC_MSG_RESULT(yes)
 515                 AC_DEFINE(HAVE_IP_PKTINFO)
 516         ], [
 517                 AC_MSG_RESULT(no)
 518         ])
 519
 520         dnl *********************************
 521         dnl *** Check for struct ip_mreqn ***
 522         dnl *********************************
 523         AC_MSG_CHECKING(for struct ip_mreqn)
 524         AC_TRY_COMPILE([#include <netinet/in.h>], [
 525                 struct ip_mreqn mreq;
 526                 mreq.imr_address.s_addr = 0;
 527         ], [
 528                 # Yes, we have it...
 529                 AC_MSG_RESULT(yes)
 530                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 531         ], [
 532                 # We'll just have to try and use struct ip_mreq
 533                 AC_MSG_RESULT(no)
 534                 AC_MSG_CHECKING(for struct ip_mreq)
 535                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 536                         struct ip_mreq mreq;
 537                         mreq.imr_interface.s_addr = 0;
 538                 ], [
 539                         # Yes, we have it...
 540                         AC_MSG_RESULT(yes)
 541                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 542                 ], [
 543                         # No multicast support
 544                         AC_MSG_RESULT(no)
 545                 ])
 546         ])
 547
 548         dnl **********************************
 549         dnl *** Check for gethostbyname2_r ***
 550         dnl **********************************
 551         AC_MSG_CHECKING(for gethostbyname2_r)
 552                 AC_TRY_LINK([#include <netdb.h>], [
 553                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 554         ], [
 555                 # Yes, we have it...
 556                 AC_MSG_RESULT(yes)
 557                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 558         ], [
 559                 AC_MSG_RESULT(no)
 560         ])
 561
 562         dnl *****************************
 563         dnl *** Checks for libnsl     ***
 564         dnl *****************************
 565         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 566
 567         AC_CHECK_FUNCS(inet_pton inet_aton)
 568
 569         dnl ***********************************************
 570         dnl *** Checks for size of sockaddr_un.sun_path ***
 571         dnl ***********************************************
 572         # AC_CHECK_SIZEOF can't cope with struct members :-(
 573         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 574         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 575                 [AC_TRY_RUN([
 576                         #include <sys/types.h>
 577                         #include <stdio.h>
 578                         #include <sys/un.h>
 579
 580                         int main(void) {
 581                                 struct sockaddr_un sock_un;
 582                                 FILE *f=fopen("conftestval", "w");
 583                                 if(!f) exit(1);
 584                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 585                                 exit(0);
 586                         }
 587                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 588                    cv_mono_sizeof_sunpath=0,
 589                    cv_mono_sizeof_sunpath=0)])dnl
 590         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 591         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 592
 593         dnl *************************************
 594         dnl *** Checks for zero length arrays ***
 595         dnl *************************************
 596         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 597         AC_TRY_COMPILE([
 598                 struct s {
 599                         int  length;
 600                         char data [0];
 601                 };
 602         ], [], [
 603                 AC_MSG_RESULT(yes)
 604                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 605         ], [
 606                 AC_MSG_RESULT(no)
 607                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 608         ])
 609
 610         dnl *****************************
 611         dnl *** Checks for libxnet    ***
 612         dnl *****************************
 613         case "${host}" in
 614                 *solaris* )
 615                         AC_MSG_CHECKING(for Solaris XPG4 support)
 616                         if test -f /usr/lib/libxnet.so; then
 617                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 618                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 619                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 620                                 LIBS="$LIBS -lxnet"
 621                                 AC_MSG_RESULT(yes)
 622                         else
 623                                 AC_MSG_RESULT(no)
 624                         fi
 625
 626                         if test "$GCC" = "yes"; then
 627                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 628                         fi
 629                 ;;
 630         esac
 631
 632         dnl *****************************
 633         dnl *** Checks for libpthread ***
 634         dnl *****************************
 635         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 636         AC_CHECK_HEADERS(pthread.h)
 637         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 638         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 639         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 640         AC_TRY_COMPILE([ #include <pthread.h>], [
 641                 pthread_mutexattr_t attr;
 642                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 643         ], [
 644                 AC_MSG_RESULT(ok)
 645         ], [
 646                 AC_MSG_RESULT(no)
 647                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 648                 AC_DEFINE(USE_MONO_MUTEX)
 649         ])
 650         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 651
 652         dnl ***********************************
 653         dnl *** Checks for working __thread ***
 654         dnl ***********************************
 655         AC_MSG_CHECKING(for working __thread)
 656         if test "x$with_nptl" != "xyes"; then
 657                 AC_MSG_RESULT(disabled)
 658         else
 659                 AC_TRY_RUN([
 660                         #include <pthread.h>
 661
 662                         __thread int i;
 663                         static int res1, res2;
 664
 665                         void thread_main (void *arg)
 666                         {
 667                                 i = arg;
 668                                 sleep (1);
 669                                 if (arg == 1)
 670                                         res1 = (i == arg);
 671                                 else
 672                                         res2 = (i == arg);
 673                         }
 674
 675                         int main () {
 676                                 pthread_t t1, t2;
 677
 678                                 i = 5;
 679
 680                                 pthread_create (&t1, NULL, thread_main, 1);
 681                                 pthread_create (&t2, NULL, thread_main, 2);
 682
 683                                 pthread_join (t1, NULL);
 684                                 pthread_join (t2, NULL);
 685
 686                                 return !(res1 + res2 == 2);
 687                         }
 688                 ], [
 689                                 AC_MSG_RESULT(yes)
 690                                 AC_DEFINE(HAVE_KW_THREAD)
 691                 ], [
 692                                 AC_MSG_RESULT(no)
 693                 ])
 694         fi
 695
 696         dnl **************************************
 697         dnl *** Checks for working sigaltstack ***
 698         dnl **************************************
 699         AC_MSG_CHECKING(for working sigaltstack)
 700         if test "x$with_sigaltstack" != "xyes"; then
 701                 AC_MSG_RESULT(disabled)
 702         else
 703                 AC_TRY_RUN([
 704                         #include <stdio.h>
 705                         #include <stdlib.h>
 706                         #include <unistd.h>
 707                         #include <signal.h>
 708                         #include <pthread.h>
 709                         #include <sys/wait.h>
 710
 711                         static void
 712                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 713                         {
 714                                 exit (0);
 715                         }
 716
 717                         static void *
 718                         loop (void *ignored)
 719                         {
 720                                 char *ptr = NULL;
 721
 722                                 *ptr = 0;
 723                                 return NULL;
 724                         }
 725
 726                         static void
 727                         child ()
 728                         {
 729                                 struct sigaction sa;
 730                                 struct sigaltstack sas;
 731                                 pthread_t id;
 732                                 pthread_attr_t attr;
 733
 734                                 sa.sa_sigaction = sigsegv_signal_handler;
 735                                 sigemptyset (&sa.sa_mask);
 736                                 sa.sa_flags = SA_SIGINFO | SA_STACK;
 737                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 738                                         perror ("lala");
 739                                         return;
 740                                 }
 741
 742                                 sas.ss_sp = malloc (SIGSTKSZ);
 743                                 sas.ss_size = SIGSTKSZ;
 744                                 sas.ss_flags = SS_ONSTACK;
 745                                 if (sigaltstack (&sas, NULL) == -1) {
 746                                         perror ("lala");
 747                                         return;
 748                                 }
 749
 750                                 pthread_attr_init (&attr);
 751                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 752                                         printf ("failed\n");
 753                                         return;
 754                                 }
 755
 756                                 sleep (100);
 757                         }
 758
 759                         int
 760                         main ()
 761                         {
 762                                 pid_t son;
 763                                 int status;
 764                                 int i;
 765
 766                                 son = fork ();
 767                                 if (son == -1) {
 768                                         return 1;
 769                                 }
 770
 771                                 if (son == 0) {
 772                                         child ();
 773                                         return 0;
 774                                 }
 775
 776                                 for (i = 0; i < 3; ++i) {
 777                                         sleep (1);
 778                                         waitpid (son, &status, WNOHANG);
 779                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 780                                                 return 0;
 781                                 }
 782
 783                                 kill (son, SIGKILL);
 784                                 return 1;
 785                         }
 786
 787                 ], [
 788                                 AC_MSG_RESULT(yes)
 789                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 790                 ], [
 791                                 with_sigaltstack=no
 792                                 AC_MSG_RESULT(no)
 793                 ])
 794         fi
 795
 796         dnl ********************************
 797         dnl *** Checks for semaphore lib ***
 798         dnl ********************************
 799         # 'Real Time' functions on Solaris
 800         # posix4 on Solaris 2.6
 801         # pthread (first!) on Linux
 802         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 803
 804         dnl ********************************
 805         dnl *** Checks for timezone stuff **
 806         dnl ********************************
 807         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 808                 AC_TRY_COMPILE([
 809                         #include <time.h>
 810                         ], [
 811                         struct tm tm;
 812                         tm.tm_gmtoff = 1;
 813                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 814         if test $ac_cv_struct_tm_gmtoff = yes; then
 815                 AC_DEFINE(HAVE_TM_GMTOFF)
 816         else
 817                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 818                         AC_TRY_COMPILE([
 819                                 #include <time.h>
 820                         ], [
 821                                 timezone = 1;
 822                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 823                 if test $ac_cv_var_timezone = yes; then
 824                         AC_DEFINE(HAVE_TIMEZONE)
 825                 else
 826                         AC_ERROR(unable to find a way to determine timezone)
 827                 fi
 828         fi
 829
 830         dnl *********************************
 831         dnl *** Checks for math functions ***
 832         dnl *********************************
 833         LIBS="$LIBS -lm";
 834         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 835                 AC_TRY_LINK([#include <math.h>],
 836                 [ finite(0.0); ],
 837                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 838                 AC_MSG_RESULT(no)))
 839         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 840                 AC_TRY_LINK([#include <math.h>],
 841                 [ isfinite(0.0); ],
 842                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 843                 AC_MSG_RESULT(no)))
 844
 845         dnl ****************************************************************
 846         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 847         dnl *** have it in the library (duh))                            ***
 848         dnl ****************************************************************
 849         AC_CHECK_FUNCS(poll)
 850
 851         dnl *************************
 852         dnl *** Check for signbit ***
 853         dnl *************************
 854         AC_MSG_CHECKING(for signbit)
 855         AC_TRY_LINK([#include <math.h>], [
 856                 int s = signbit(1.0);
 857         ], [
 858                 AC_MSG_RESULT(yes)
 859                 AC_DEFINE(HAVE_SIGNBIT)
 860         ], [
 861                 AC_MSG_RESULT(no)
 862         ])
 863
 864         dnl *********************
 865         dnl *** Check for AIO ***
 866         dnl *********************
 867         AC_MSG_CHECKING([for SIGEV_THREAD definition])
 868         dnl Some systems (FreeBSD at least) may have aio_read
 869         dnl but don't support/define SIGEV_THREAD.
 870         AC_TRY_COMPILE([
 871         #include <sys/signal.h>
 872         ],[
 873         int x = SIGEV_THREAD;
 874         ],[
 875                 ac_cv_c_sigev_thread=yes
 876                 AC_MSG_RESULT(yes)
 877         ],[
 878                 AC_MSG_RESULT(no)
 879         ])
 880
 881         if test "$ac_cv_c_sigev_thread" = "yes" ; then
 882                 AC_CHECK_HEADERS(aio.h sys/aio.h)
 883                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
 884                 SIGVAL_PTR="undefined"
 885                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
 886                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
 887                                         #include <sys/signal.h>
 888                                         ])
 889                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
 890                                         #include <sys/signal.h>
 891                                         ])
 892                         if test "$SIGVAL_PTR" = "undefined" ; then
 893                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
 894                         fi
 895                 fi
 896                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
 897         fi
 898 else
 899         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 900         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 901 fi
 902
 903 dnl socklen_t check
 904 AC_MSG_CHECKING(for socklen_t)
 905 AC_TRY_COMPILE([
 906 #include <sys/types.h>
 907 #include <sys/socket.h>
 908 ],[
 909   socklen_t foo;
 910 ],[
 911 ac_cv_c_socklen_t=yes
 912         AC_DEFINE(HAVE_SOCKLEN_T)
 913         AC_MSG_RESULT(yes)
 914 ],[
 915         AC_MSG_RESULT(no)
 916 ])
 917
 918 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
 919         AC_TRY_LINK([#include <math.h>],
 920         [ trunc(0.0); ],
 921         [
 922                 AC_DEFINE(HAVE_TRUNC)
 923                 AC_MSG_RESULT(yes)
 924                 ac_cv_trunc=yes
 925         ],
 926         AC_MSG_RESULT(no)))
 927
 928 if test "x$ac_cv_truncl" != "xyes"; then
 929    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
 930 fi
 931
 932 dnl ****************************
 933 dnl *** Look for /dev/random ***
 934 dnl ****************************
 935
 936 AC_MSG_CHECKING([if usage of random device is requested])
 937 AC_ARG_ENABLE(dev-random,
 938 [  --disable-dev-random    disable the use of the random device],
 939 try_dev_random=$enableval, try_dev_random=yes)
 940 AC_MSG_RESULT($try_dev_random)
 941
 942 case "{$target}" in
 943     *-openbsd*)
 944     NAME_DEV_RANDOM="/dev/srandom"
 945     ;;
 946
 947 dnl Win32 does not have /dev/random, they have their own method...
 948
 949     *-*-mingw*|*-*-cygwin*)
 950     ac_cv_have_dev_random = no
 951     ;;
 952
 953 dnl Everywhere else, it's /dev/random
 954
 955     *)
 956     NAME_DEV_RANDOM="/dev/random"
 957     ;;
 958 esac
 959
 960 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 961
 962 dnl Now check if the device actually exists
 963
 964 if test "x$try_dev_random" = "xyes"; then
 965     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 966     [if test -r "$NAME_DEV_RANDOM" ; then
 967         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 968     if test "x$ac_cv_have_dev_random" = "xyes"; then
 969         AC_DEFINE(HAVE_CRYPT_RNG)
 970     fi
 971 else
 972     AC_MSG_CHECKING(for random device)
 973     ac_cv_have_dev_random=no
 974     AC_MSG_RESULT(has been disabled)
 975 fi
 976
 977 if test "x$platform_win32" = "xyes"; then
 978     AC_DEFINE(HAVE_CRYPT_RNG)
 979 fi
 980
 981 if test "x$ac_cv_have_dev_random" = "xno" \
 982     && test "x$platform_win32" = "xno"; then
 983     AC_MSG_WARN([[
 984 ***
 985 *** A system-provided entropy source was not found on this system.
 986 *** Because of this, the System.Security.Cryptography random number generator
 987 *** will throw a NotImplemented exception.
 988 ***
 989 *** If you are seeing this message, and you know your system DOES have an
 990 *** entropy collection in place, please contact <crichton@gimp.org> and
 991 *** provide information about the system and how to access the random device.
 992 ***
 993 *** Otherwise you can install either egd or prngd and set the environment
 994 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
 995 ***]])
 996 fi
 997
 998 AC_MSG_CHECKING([if inter-process shared handles are requested])
 999 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1000 AC_MSG_RESULT($try_shared_handles)
1001 if test "x$try_shared_handles" != "xyes"; then
1002         AC_DEFINE(DISABLE_SHARED_HANDLES)
1003         AC_SUBST(DISABLE_SHARED_HANDLES)
1004 fi
1005
1006 #
1007 # ICU
1008 #
1009 ICU_CFLAGS=""
1010 ICU_LIBS=""
1011 enable_icu=no
1012
1013 probe_icu=true
1014 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1015         if test x$with_icu = xno; then
1016            probe_icu=false;
1017            AC_MSG_RESULT(Will not probe for ICU)
1018         fi
1019 )
1020
1021 if $probe_icu; then
1022         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1023         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1024                 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1025                 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1026         else
1027                 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1028                 AC_DEFINE(HAVE_ICU)
1029                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1030                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1031         fi
1032 fi
1033 AC_SUBST(ICU_CFLAGS)
1034 AC_SUBST(ICU_LIBS)
1035
1036 TARGET="unknown"
1037 ACCESS_UNALIGNED="yes"
1038
1039 JIT_SUPPORTED=no
1040 LIBC="libc.so.6"
1041
1042 jit_wanted=false
1043 case "$host" in
1044 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1045 #               TARGET=MIPS;
1046 #               ACCESS_UNALIGNED="no"
1047 #               ;;
1048         i*86-*-*)
1049                 TARGET=X86;
1050                 arch_target=x86;
1051                 JIT_SUPPORTED=yes
1052                 jit_wanted=true
1053                 ;;
1054         x86_64-*-* | amd64-*-*)
1055                 TARGET=AMD64;
1056                 arch_target=amd64;
1057                 JIT_SUPPORTED=no
1058                 ;;
1059         sparc*-*-*)
1060                 TARGET=SPARC;
1061                 arch_target=sparc;
1062                 JIT_SUPPORTED=yes
1063                 ACCESS_UNALIGNED="no"
1064                 LIBC="libc.so"
1065                 jit_wanted=true
1066                 ;;
1067 #       alpha*-*-linux* | alpha*-*-osf*)
1068 #               TARGET=ALPHA;
1069 #               ACCESS_UNALIGNED="no"
1070 #              ;;
1071 #       ia64-*-linux* | ia64-*-hpux*)
1072 #               TARGET=IA64;
1073 #               arch_target=ia64;
1074 #               JIT_SUPPORTED=no;
1075 #               ACCESS_UNALIGNED="no";
1076 #               case "$host_os" in
1077 #                       linux*) LIBC="libc.so.6.1";;
1078 #                       hpux*)  LIBC="libc.so.1";;
1079 #               esac
1080 #               ;;
1081 #       m68k-*-linux*)
1082 #               TARGET=M68K
1083 #               ;;
1084         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1085                 TARGET=HPPA;
1086                 arch_target=hppa;
1087                 LIBC="libc.sl"
1088                 ACCESS_UNALIGNED="no"
1089                 ;;
1090         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1091         powerpc-*-sysv* | powerpc-*-darwin*)
1092                 TARGET=POWERPC;
1093                 arch_target=ppc;
1094                 JIT_SUPPORTED=yes
1095                 jit_wanted=true
1096                 ;;
1097         arm-*-linux-* | armv4l-*-linux-*)
1098                 TARGET=ARM;
1099                 arch_target=arm;
1100                 ACCESS_UNALIGNED="no"
1101                 ;;
1102         s390-*-linux*)
1103                 TARGET=S390;
1104                 arch_target=s390;
1105                 ACCESS_UNALIGNED="no"
1106                 JIT_SUPPORTED=yes
1107                 ;;
1108 esac
1109
1110 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1111         jit_wanted=true
1112 ])
1113
1114 USEJIT=false
1115 if test x$JIT_SUPPORTED = xyes; then
1116    if $jit_wanted; then
1117       USEJIT=true
1118       jit_status="Building and using the JIT"
1119    else
1120       jit_status="Building the JIT, defaulting to the interpreter"
1121    fi
1122 else
1123    jit_status="interpreter"
1124 fi
1125
1126 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1127
1128 libsuffix=".so"
1129
1130 case "$host" in
1131      powerpc-*-darwin*)
1132         libsuffix=".dylib"
1133         LIBC="libc.dylib"
1134         ;;
1135 esac
1136 AC_SUBST(libsuffix)
1137
1138 if test ${TARGET} = ARM; then
1139         dnl ******************************************
1140         dnl *** Check to see what FPU is available ***
1141         dnl ******************************************
1142         AC_MSG_CHECKING(which FPU to use)
1143
1144         AC_TRY_COMPILE([], [
1145                 __asm__ ("ldfd f0, [r0]");
1146                 ], fpu=FPA, [
1147                         AC_TRY_COMPILE([], [
1148                                 __asm__ ("fldd d0, [r0]");
1149                         ], fpu=VFP, fpu=NONE)
1150                 ])
1151
1152         AC_MSG_RESULT($fpu)
1153         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1154         unset fpu
1155 fi
1156
1157 if test ${TARGET} = unknown; then
1158         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1159         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1160 fi
1161
1162 if test ${ACCESS_UNALIGNED} = no; then
1163         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1164 fi
1165
1166 PREVIEW=no
1167 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1168         if test x$with_preview = xyes; then
1169               PREVIEW=yes
1170         fi
1171 ])
1172
1173 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1174
1175 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1176 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1177 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1178 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1179 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1180 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1181 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1182 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1183 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1184 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1185 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1186 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1187
1188 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1189
1190 AC_SUBST(LIBC)
1191
1192 AC_SUBST(arch_target)
1193 AC_SUBST(CFLAGS)
1194 AC_SUBST(CPPFLAGS)
1195 AC_SUBST(LDFLAGS)
1196
1197 AC_OUTPUT([
1198 Makefile
1199 mint.pc
1200 mono.pc
1201 mono/Makefile
1202 mono/utils/Makefile
1203 mono/metadata/Makefile
1204 mono/dis/Makefile
1205 mono/cil/Makefile
1206 mono/arch/Makefile
1207 mono/os/Makefile
1208 mono/os/win32/Makefile
1209 mono/os/unix/Makefile
1210 mono/arch/x86/Makefile
1211 mono/arch/amd64/Makefile
1212 mono/arch/hppa/Makefile
1213 mono/arch/ppc/Makefile
1214 mono/arch/sparc/Makefile
1215 mono/arch/s390/Makefile
1216 mono/arch/arm/Makefile
1217 mono/arch/alpha/Makefile
1218 mono/interpreter/Makefile
1219 mono/tests/Makefile
1220 mono/tests/tests-config
1221 mono/benchmark/Makefile
1222 mono/monoburg/Makefile
1223 mono/monograph/Makefile
1224 mono/io-layer/Makefile
1225 mono/handles/Makefile
1226 mono/mini/Makefile
1227 mono/profiler/Makefile
1228 ikvm-jni/Makefile
1229 runtime/Makefile
1230 runtime/net_1_1/Makefile
1231 runtime/net_2_0/Makefile
1232 scripts/Makefile
1233 man/Makefile
1234 web/Makefile
1235 docs/Makefile
1236 data/Makefile
1237 samples/Makefile
1238 support/Makefile
1239 data/config
1240 mono.spec
1241 tools/Makefile
1242 tools/locale-builder/Makefile
1243 ])
1244
1245 echo "
1246
1247         GC:          $gc
1248         ICU:         $enable_icu
1249         NPTL:        $with_nptl
1250         SIGALTSTACK: $with_sigaltstack
1251         Engine:      $jit_status
1252         2.0 Alpha:   $PREVIEW
1253         JNI support: $jdk_headers_found
1254
1255 "