configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,1.1.6.5)
  10 AM_MAINTAINER_MODE
  11
  12 AC_PROG_LN_S
  13
  14 # In case of cygwin, override LN_S, irrespective of what it determines.
  15 # The build uses cygwin, but the actual runtime doesn't.
  16 case $host_os in
  17 *cygwin* ) LN_S='cp -p';;
  18 esac
  19
  20
  21 dnl
  22 dnl libgc checks
  23 dnl
  24
  25 gc_headers=no
  26 gc=included
  27 use_included_gc=no
  28
  29 if test -d $srcdir/libgc ; then
  30   gc_default=included
  31 else
  32   gc_default=boehm
  33 fi
  34
  35 #
  36 # These are the flags that need to be stored in the mono.pc file for
  37 # compiling code that will embed Mono
  38 #
  39 libmono_cflags=""
  40 libmono_ldflags=""
  41 AC_SUBST(libmono_cflags)
  42 AC_SUBST(libmono_ldflags)
  43
  44 dnl if linker handles the version script
  45 no_version_script=no
  46
  47 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  48 need_link_unlink=no
  49
  50 # Thread configuration inspired by sleepycat's db
  51 AC_MSG_CHECKING([host platform characteristics])
  52 libgc_threads=no
  53 case "$host" in
  54         *-*-mingw*|*-*-cygwin*)
  55                 platform_win32=yes
  56                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  57                 CC="gcc -mno-cygwin -g"
  58                 HOST_CC="gcc"
  59                 # So libgc configure gets -mno-cygwin
  60                 export CC
  61 # latest libgc already defines GC_WIN32_THREADS
  62 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  63                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS -DFD_SETSIZE=1024"
  64                 libdl=
  65                 libgc_threads=win32
  66                 gc_default=included
  67                 with_nptl=default
  68                 with_sigaltstack=no
  69                 LN_S=cp
  70                 ;;
  71         *-*-*netbsd*)
  72                 platform_win32=no
  73                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  74                 libmono_cflags="-D_REENTRANT"
  75                 LDFLAGS="$LDFLAGS -pthread"
  76                 libmono_ldflags="-pthread"
  77                 need_link_unlink=yes
  78                 libdl=
  79                 libgc_threads=no
  80                 ;;
  81 # these flags will work for all versions of -STABLE
  82 #
  83         *-*-*freebsd4*)
  84                 platform_win32=no
  85                 if test "x$PTHREAD_CFLAGS" = "x"; then
  86                         CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  87                         libmono_cflags="-D_THREAD_SAFE"
  88                 else
  89                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
  90                         libmono_cflags="$PTHREAD_CFLAGS"
  91                 fi
  92                 if test "x$PTHREAD_LIBS" = "x"; then
  93                         LDFLAGS="$LDFLAGS -pthread"
  94                         libmono_ldflags="-pthread"
  95                 else
  96                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
  97                         libmono_ldflags="$PTHREAD_LIBS"
  98                 fi
  99                 need_link_unlink=yes
 100                 AC_DEFINE(PTHREAD_POINTER_ID)
 101                 libdl=
 102                 libgc_threads=pthreads
 103 # TLS isn't implemented at all on 4-STABLE
 104                 with_nptl=no
 105                 with_tls=pthread
 106                 ;;
 107         *-*-*freebsd5*)
 108                 platform_win32=no
 109                 if test "x$PTHREAD_CFLAGS" = "x"; then
 110                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 111                         libmono_cflags=
 112                 else
 113                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 114                         libmono_cflags="$PTHREAD_CFLAGS"
 115                 fi
 116                 if test "x$PTHREAD_LIBS" = "x"; then
 117                         LDFLAGS="$LDFLAGS -pthread"
 118                         libmono_ldflags="-pthread"
 119                 else
 120                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 121                         libmono_ldflags="$PTHREAD_LIBS"
 122                 fi
 123                 need_link_unlink=yes
 124                 AC_DEFINE(PTHREAD_POINTER_ID)
 125                 libdl=
 126                 with_sigaltstack=yes
 127                 libgc_threads=pthreads
 128 # TLS is only partially implemented on 5-STABLE (compiler support
 129 # but NOT library support)
 130 #
 131                 with_tls=pthread
 132                 ;;
 133         *-*-*freebsd6*)
 134                 platform_win32=no
 135                 if test "x$PTHREAD_CFLAGS" = "x"; then
 136                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 137                         libmono_cflags=
 138                 else
 139                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 140                         libmono_cflags="$PTHREAD_CFLAGS"
 141                 fi
 142                 if test "x$PTHREAD_LIBS" = "x"; then
 143                         LDFLAGS="$LDFLAGS -pthread"
 144                         libmono_ldflags="-pthread"
 145                 else
 146                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 147                         libmono_ldflags="$PTHREAD_LIBS"
 148                 fi
 149                 need_link_unlink=yes
 150                 AC_DEFINE(PTHREAD_POINTER_ID)
 151                 libdl=
 152                 libgc_threads=pthreads
 153                 with_sigaltstack=yes
 154 # TLS is only partially implemented on -CURRENT (compiler support
 155 # but NOT library support)
 156 #
 157                 with_tls=pthread
 158                 ;;
 159         *-*-*openbsd*)
 160                 platform_win32=no
 161                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 162                 libmono_cflags="-D_THREAD_SAFE"
 163                 LDFLAGS="$LDFLAGS -pthread"
 164                 libmono_ldflags="-pthread"
 165                 need_link_unlink=yes
 166                 AC_DEFINE(PTHREAD_POINTER_ID)
 167                 libdl=
 168                 libgc_threads=pthreads
 169                 ;;
 170         *-*-linux*)
 171                 platform_win32=no
 172                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
 173                 libmono_cflags="-D_REENTRANT"
 174                 libmono_ldflags="-lpthread"
 175                 libdl="-ldl"
 176                 libgc_threads=pthreads
 177                 ;;
 178         *-*-hpux*)
 179                 platform_win32=no
 180                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 181                 CFLAGS="$CFLAGS +ESdbgasm"
 182                 LDFLAGS="$LDFLAGS -z"
 183                 libmono_cflags="-D_REENTRANT"
 184                 libmono_ldflags="-lpthread"
 185                 libgc_threads=pthreads
 186                 need_link_unlink=yes
 187                 ;;
 188         *-*-solaris*)
 189                 platform_win32=no
 190                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS"
 191                 need_link_unlink=yes
 192                 libmono_cflags="-D_REENTRANT"
 193                 libgc_threads=pthreads
 194                 ;;
 195         *-*-darwin*)
 196                 platform_win32=no
 197                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
 198                 libmono_cflags="-D_THREAD_SAFE"
 199                 LDFLAGS="$LDFLAGS -pthread"
 200                 libmono_ldflags="-pthread"
 201                 need_link_unlink=yes
 202                 AC_DEFINE(PTHREAD_POINTER_ID)
 203                 AC_DEFINE(USE_MACH_SEMA)
 204                 no_version_script=yes
 205                 libdl=
 206                 libgc_threads=pthreads
 207                 ;;
 208         *)
 209                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 210                 platform_win32=no
 211                 libdl="-ldl"
 212                 ;;
 213 esac
 214 AC_MSG_RESULT(ok)
 215
 216 if test x$need_link_unlink = xyes; then
 217    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 218 fi
 219
 220 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 221
 222 AC_CHECK_TOOL(CC, gcc, gcc)
 223 AC_PROG_CC
 224 AM_PROG_CC_STDC
 225 AC_PROG_INSTALL
 226 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 227 : ${CCAS='$(CC)'}
 228 # Set ASFLAGS if not already set.
 229 : ${CCASFLAGS='$(CFLAGS)'}
 230 AC_SUBST(CCAS)
 231 AC_SUBST(CCASFLAGS)
 232
 233 AC_CHECK_PROG(BISON, bison,yes,no)
 234 if test "x$BISON" = "xno";
 235 then
 236         AC_MSG_ERROR([You need to install bison])
 237 fi
 238
 239 dnl may require a specific autoconf version
 240 dnl AC_PROG_CC_FOR_BUILD
 241 dnl CC_FOR_BUILD not automatically detected
 242 CC_FOR_BUILD=$CC
 243 BUILD_EXEEXT=
 244 if test "x$cross_compiling" = "xyes"; then
 245         CC_FOR_BUILD=cc
 246         BUILD_EXEEXT=""
 247 fi
 248 AC_SUBST(CC_FOR_BUILD)
 249 AC_SUBST(HOST_CC)
 250 AC_SUBST(BUILD_EXEEXT)
 251
 252 # Set STDC_HEADERS
 253 AC_HEADER_STDC
 254 AC_LIBTOOL_WIN32_DLL
 255 AM_PROG_LIBTOOL
 256
 257 # Test whenever ld supports -version-script
 258 AC_PROG_LD
 259 AC_PROG_LD_GNU
 260 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 261    no_version_script=yes
 262 fi
 263
 264 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 265
 266 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h linux/rtc.h)
 267
 268 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 269
 270 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 271
 272 # for mono/metadata/debug-symfile.c
 273 AC_CHECK_HEADERS(elf.h)
 274
 275 # for support
 276 AC_CHECK_HEADERS(poll.h)
 277 AC_CHECK_HEADERS(sys/poll.h)
 278 AC_CHECK_HEADERS(sys/wait.h)
 279 AC_CHECK_HEADERS(grp.h)
 280 AC_CHECK_HEADERS(syslog.h)
 281
 282 # for mono/dis
 283 AC_CHECK_HEADERS(wchar.h)
 284 case "$host" in
 285         *-*-*freebsd6*)
 286                 AC_CHECK_HEADERS(ieeefp.h)
 287         ;;
 288         *-*-*freebsd*)
 289                 /* Only freebsd6 has a working ieeefp.h */
 290         ;;
 291         *)
 292                 AC_CHECK_HEADERS(ieeefp.h)
 293         ;;
 294 esac
 295 AC_MSG_CHECKING(for isinf)
 296 AC_TRY_LINK([#include <math.h>], [
 297         int f = isinf (1);
 298 ], [
 299         AC_MSG_RESULT(yes)
 300         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 301 ], [
 302         # We'll have to use signals
 303         AC_MSG_RESULT(no)
 304 ])
 305
 306
 307 # not 64 bit clean in cross-compile
 308 AC_CHECK_SIZEOF(void *, 4)
 309
 310 WARN=''
 311 if test x"$GCC" = xyes; then
 312         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 313                 # The runtime code does not respect ANSI C strict aliasing rules
 314                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 315
 316                 ORIG_CFLAGS=$CFLAGS
 317                 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 318                 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
 319                 AC_TRY_COMPILE([], [
 320                                                    void main () { }
 321                 ], [
 322                    AC_MSG_RESULT(yes)
 323                 ], [
 324                    AC_MSG_RESULT(no)
 325                    CFLAGS=$ORIG_CFLAGS
 326                 ])
 327 else
 328         # The Sun Forte compiler complains about inline functions that access static variables
 329         # so disable all inlining.
 330         case "$host" in
 331         *-*-solaris*)
 332                 CFLAGS="$CFLAGS -Dinline="
 333                 ;;
 334         esac
 335 fi
 336 CFLAGS="$CFLAGS -g $WARN"
 337
 338 # Where's the 'mcs' source tree?
 339 if test -d $srcdir/mcs; then
 340   mcsdir=mcs
 341 else
 342   mcsdir=../mcs
 343 fi
 344
 345 mcs_topdir='$(top_srcdir)/'$mcsdir
 346 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 347
 348 AC_SUBST([mcs_topdir])
 349 AC_SUBST([mcs_topdir_from_srcdir])
 350
 351 AC_ARG_WITH([libgdiplus],
 352         [  --with-libgdiplus=installed|sibling|<path>   Override the libgdiplus used for System.Drawing tests (defaults to NO)],
 353         [], [with_libgdiplus=installed])
 354
 355 case $with_libgdiplus in
 356 no|installed) libgdiplus_loc= ;;
 357 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
 358 /*) libgdiplus_loc=$with_libgdiplus ;;
 359 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
 360 esac
 361 AC_SUBST([libgdiplus_loc])
 362
 363 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 364 if test "x$PKG_CONFIG" = "xno"; then
 365         AC_MSG_ERROR([You need to install pkg-config])
 366 fi
 367
 368 dnl for use on the build system
 369 dnl pkg-config is stupid
 370 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 371 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 372 AC_SUBST(BUILD_GLIB_CFLAGS)
 373 AC_SUBST(BUILD_GLIB_LIBS)
 374
 375 pkg_config_path=
 376 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 377         if test x$with_crosspkgdir = "x"; then
 378                 if test -s $PKG_CONFIG_PATH; then
 379                         pkg_config_path=$PKG_CONFIG_PATH
 380                 fi
 381         else
 382                 pkg_config_path=$with_crosspkgdir
 383                 PKG_CONFIG_PATH=$pkg_config_path
 384                 export PKG_CONFIG_PATH
 385         fi
 386 )
 387
 388 ## Versions of dependencies
 389 GLIB_REQUIRED_VERSION=1.3.11
 390
 391 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 392
 393 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 394 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 395 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 396 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 397
 398 AC_SUBST(GLIB_CFLAGS)
 399 AC_SUBST(GLIB_LIBS)
 400 AC_SUBST(GMODULE_CFLAGS)
 401 AC_SUBST(GMODULE_LIBS)
 402
 403 if test x$platform_win32 = xyes; then
 404    AC_MSG_CHECKING(for cygwin glib2-dev package)
 405    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 406       AC_MSG_RESULT(found)
 407           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 408    else
 409       AC_MSG_RESULT(not found, ok)
 410    fi
 411
 412    AC_MSG_CHECKING(for broken gwin32.h)
 413    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 414    if test -f $glib_include/glib/gwin32.h; then
 415           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 416                  AC_MSG_RESULT(failed)
 417                  hashmark='#'
 418                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 419           fi
 420    fi
 421    AC_MSG_RESULT(ok)
 422 fi
 423
 424 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 425
 426 # Enable support for fast thread-local storage
 427 # Some systems have broken support, so we allow to disable it.
 428 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 429
 430 # Kept for compatibility
 431 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      deprecated, use --with-tls instead],[],[with_nptl=default])
 432
 433 if test "x$with_nptl" != "xdefault"; then
 434    if test "x$with_nptl" = "xyes"; then
 435       AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
 436           with_tls=__thread
 437    fi
 438    if test "x$with_nptl" = "xno"; then
 439       AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
 440           with_tls=pthread
 441    fi
 442 fi
 443
 444 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 445 # This does not work on some platforms (bug #55253)
 446 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=no])
 447
 448 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 449
 450 if test "x$enable_static" = "xno"; then
 451    with_static_mono=no
 452 fi
 453
 454 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 455
 456 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 457   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug, reflection_emit.],
 458 [
 459         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 460                 eval "mono_feature_disable_$feature='yes'"
 461                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 462         done
 463         disabled="Disabled:    $enable_minimal"
 464 ],[])
 465
 466 if test "x$mono_feature_disable_aot" = "xyes"; then
 467         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 468 fi
 469
 470 if test "x$mono_feature_disable_profiler" = "xyes"; then
 471         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 472 fi
 473
 474 if test "x$mono_feature_disable_decimal" = "xyes"; then
 475         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 476 fi
 477
 478 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 479         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 480 fi
 481
 482 if test "x$mono_feature_disable_debug" = "xyes"; then
 483         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 484 fi
 485
 486 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 487         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 488 fi
 489
 490 LIBGC_CFLAGS=
 491 LIBGC_LIBS=
 492 LIBGC_STATIC_LIBS=
 493 libgc_dir=
 494 case "x$gc" in
 495         xboehm|xbohem|xyes)
 496                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 497                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 498
 499                 if test "x$found_boehm" != "xyes"; then
 500                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 501                 fi
 502                 if test "x$gc_headers" != "xyes"; then
 503                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 504                 fi
 505
 506                 AC_DEFINE(HAVE_BOEHM_GC)
 507                 AC_SUBST(HAVE_BOEHM_GC)
 508                 LIBGC_LIBS="-lgc $libdl"
 509                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 510
 511                 # AC_CHECK_FUNCS does not work for some reason...
 512                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 513                 if test "x$found_gcj_malloc" = "xyes"; then
 514                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 515                 fi
 516                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 517                 if test "x$found_gc_enable" = "xyes"; then
 518                         AC_DEFINE(HAVE_GC_ENABLE)
 519                 fi
 520                 ;;
 521
 522         xincluded)
 523                 AC_CONFIG_SUBDIRS(libgc)
 524
 525                 found_boehm=yes
 526                 gc_headers=yes
 527                 use_included_gc=yes
 528                 libgc_dir=libgc
 529
 530                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 531                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 532                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 533
 534                 AC_DEFINE(HAVE_BOEHM_GC)
 535                 AC_SUBST(HAVE_BOEHM_GC)
 536
 537                 AC_DEFINE(HAVE_GC_H)
 538                 AC_DEFINE(USE_INCLUDED_LIBGC)
 539
 540                 # The included libgc contains GCJ support
 541                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 542                 AC_DEFINE(HAVE_GC_ENABLE)
 543                 ;;
 544
 545         xnone)
 546                 AC_MSG_WARN("Compiling mono without GC.")
 547                 ;;
 548         *)
 549                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 550                 ;;
 551 esac
 552
 553 AC_ARG_WITH(large-heap, [  --with-large-heap=yes,no    Enable support for GC heaps larger than 3GB], [large_heap=$withval], [large_heap=no])
 554 if test "x$large_heap" = "xyes"; then
 555    echo "FOO"
 556    CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
 557 fi
 558
 559 # tell libgc/configure about what we want
 560 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
 561
 562 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 563 AC_SUBST(LIBGC_CFLAGS)
 564 AC_SUBST(LIBGC_LIBS)
 565 AC_SUBST(LIBGC_STATIC_LIBS)
 566 AC_SUBST(libgc_dir)
 567
 568 dnl
 569 dnl End of libgc checks
 570 dnl
 571
 572 if test x$platform_win32 = xno; then
 573
 574         dnl ******************************************************************
 575         dnl *** Checks for the IKVM JNI interface library                  ***
 576         dnl ******************************************************************
 577         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 578
 579         ikvm_native_dir=
 580         if test x$with_ikvm_native = xyes; then
 581                 ikvm_native_dir=ikvm-native
 582                 jdk_headers_found="IKVM Native"
 583         fi
 584
 585         AC_SUBST(ikvm_native_dir)
 586
 587         AC_CHECK_FUNCS(getgrgid_r)
 588         AC_CHECK_FUNCS(getgrnam_r)
 589         AC_CHECK_FUNCS(getpwnam_r)
 590         AC_CHECK_FUNCS(getpwuid_r)
 591         AC_CHECK_FUNCS(getresuid)
 592         AC_CHECK_FUNCS(setresuid)
 593         AC_CHECK_FUNCS(kqueue)
 594         AC_CHECK_FUNCS(backtrace_symbols)
 595
 596         dnl ******************************************************************
 597         dnl *** Check for large file support                               ***
 598         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 599         dnl ******************************************************************
 600
 601         # Check that off_t can represent 2**63 - 1 correctly, working around
 602         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 603         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 604         large_offt=no
 605         AC_DEFUN(LARGE_FILES, [
 606                 large_CPPFLAGS=$CPPFLAGS
 607                 CPPFLAGS="$CPPFLAGS $1"
 608                 AC_TRY_RUN([
 609                         #include <sys/types.h>
 610
 611                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 612
 613                         int main(void) {
 614                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 615                                                (BIG_OFF_T%2147483647==1));
 616                                 if(big_off_t) {
 617                                         exit(0);
 618                                 } else {
 619                                         exit(1);
 620                                 }
 621                         }
 622                 ], [
 623                         AC_MSG_RESULT(ok)
 624                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 625                         large_CPPFLAGS="$large_CPPFLAGS $1"
 626                         large_offt=yes
 627                 ], [
 628                         AC_MSG_RESULT(no)
 629                 ], "")
 630                 CPPFLAGS=$large_CPPFLAGS
 631         ])
 632
 633         AC_MSG_CHECKING(if off_t is 64 bits wide)
 634         LARGE_FILES("")
 635         if test $large_offt = no; then
 636                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 637                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 638         fi
 639         if test $large_offt = no; then
 640                 AC_MSG_WARN([No 64 bit file size support available])
 641         fi
 642
 643         dnl *****************************
 644         dnl *** Checks for libsocket  ***
 645         dnl *****************************
 646         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 647
 648         dnl *******************************
 649         dnl *** Checks for MSG_NOSIGNAL ***
 650         dnl *******************************
 651         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 652         AC_TRY_COMPILE([#include <sys/socket.h>], [
 653                 int f = MSG_NOSIGNAL;
 654         ], [
 655                 # Yes, we have it...
 656                 AC_MSG_RESULT(yes)
 657                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 658         ], [
 659                 # We'll have to use signals
 660                 AC_MSG_RESULT(no)
 661         ])
 662
 663         dnl *****************************
 664         dnl *** Checks for SOL_IP     ***
 665         dnl *****************************
 666         AC_MSG_CHECKING(for SOL_IP)
 667         AC_TRY_COMPILE([#include <netdb.h>], [
 668                 int level = SOL_IP;
 669         ], [
 670                 # Yes, we have it...
 671                 AC_MSG_RESULT(yes)
 672                 AC_DEFINE(HAVE_SOL_IP)
 673         ], [
 674                 # We'll have to use getprotobyname
 675                 AC_MSG_RESULT(no)
 676         ])
 677
 678         dnl *****************************
 679         dnl *** Checks for SOL_IPV6     ***
 680         dnl *****************************
 681         AC_MSG_CHECKING(for SOL_IPV6)
 682         AC_TRY_COMPILE([#include <netdb.h>], [
 683                 int level = SOL_IPV6;
 684         ], [
 685                 # Yes, we have it...
 686                 AC_MSG_RESULT(yes)
 687                 AC_DEFINE(HAVE_SOL_IPV6)
 688         ], [
 689                 # We'll have to use getprotobyname
 690                 AC_MSG_RESULT(no)
 691         ])
 692
 693         dnl *****************************
 694         dnl *** Checks for SOL_TCP    ***
 695         dnl *****************************
 696         AC_MSG_CHECKING(for SOL_TCP)
 697         AC_TRY_COMPILE([#include <netdb.h>], [
 698                 int level = SOL_TCP;
 699         ], [
 700                 # Yes, we have it...
 701                 AC_MSG_RESULT(yes)
 702                 AC_DEFINE(HAVE_SOL_TCP)
 703         ], [
 704                 # We'll have to use getprotobyname
 705                 AC_MSG_RESULT(no)
 706         ])
 707
 708         dnl *****************************
 709         dnl *** Checks for IP_PKTINFO ***
 710         dnl *****************************
 711         AC_MSG_CHECKING(for IP_PKTINFO)
 712         AC_TRY_COMPILE([#include <netdb.h>], [
 713                 int level = IP_PKTINFO;
 714         ], [
 715                 # Yes, we have it...
 716                 AC_MSG_RESULT(yes)
 717                 AC_DEFINE(HAVE_IP_PKTINFO)
 718         ], [
 719                 AC_MSG_RESULT(no)
 720         ])
 721
 722         dnl *********************************
 723         dnl *** Check for struct ip_mreqn ***
 724         dnl *********************************
 725         AC_MSG_CHECKING(for struct ip_mreqn)
 726         AC_TRY_COMPILE([#include <netinet/in.h>], [
 727                 struct ip_mreqn mreq;
 728                 mreq.imr_address.s_addr = 0;
 729         ], [
 730                 # Yes, we have it...
 731                 AC_MSG_RESULT(yes)
 732                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 733         ], [
 734                 # We'll just have to try and use struct ip_mreq
 735                 AC_MSG_RESULT(no)
 736                 AC_MSG_CHECKING(for struct ip_mreq)
 737                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 738                         struct ip_mreq mreq;
 739                         mreq.imr_interface.s_addr = 0;
 740                 ], [
 741                         # Yes, we have it...
 742                         AC_MSG_RESULT(yes)
 743                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 744                 ], [
 745                         # No multicast support
 746                         AC_MSG_RESULT(no)
 747                 ])
 748         ])
 749
 750         dnl **********************************
 751         dnl *** Check for gethostbyname2_r ***
 752         dnl **********************************
 753         AC_MSG_CHECKING(for gethostbyname2_r)
 754                 AC_TRY_LINK([#include <netdb.h>], [
 755                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 756         ], [
 757                 # Yes, we have it...
 758                 AC_MSG_RESULT(yes)
 759                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 760         ], [
 761                 AC_MSG_RESULT(no)
 762         ])
 763
 764         dnl *****************************
 765         dnl *** Checks for libnsl     ***
 766         dnl *****************************
 767         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 768
 769         AC_CHECK_FUNCS(inet_pton inet_aton)
 770
 771         dnl ***********************************************
 772         dnl *** Checks for size of sockaddr_un.sun_path ***
 773         dnl ***********************************************
 774         # AC_CHECK_SIZEOF can't cope with struct members :-(
 775         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 776         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 777                 [AC_TRY_RUN([
 778                         #include <sys/types.h>
 779                         #include <stdio.h>
 780                         #include <sys/un.h>
 781
 782                         int main(void) {
 783                                 struct sockaddr_un sock_un;
 784                                 FILE *f=fopen("conftestval", "w");
 785                                 if(!f) exit(1);
 786                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 787                                 exit(0);
 788                         }
 789                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 790                    cv_mono_sizeof_sunpath=0,
 791                    cv_mono_sizeof_sunpath=0)])dnl
 792         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 793         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 794
 795         dnl *************************************
 796         dnl *** Checks for zero length arrays ***
 797         dnl *************************************
 798         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 799         AC_TRY_COMPILE([
 800                 struct s {
 801                         int  length;
 802                         char data [0];
 803                 };
 804         ], [], [
 805                 AC_MSG_RESULT(yes)
 806                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 807         ], [
 808                 AC_MSG_RESULT(no)
 809                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 810         ])
 811
 812         dnl *****************************
 813         dnl *** Checks for libxnet    ***
 814         dnl *****************************
 815         case "${host}" in
 816                 *solaris* )
 817                         AC_MSG_CHECKING(for Solaris XPG4 support)
 818                         if test -f /usr/lib/libxnet.so; then
 819                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 820                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 821                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 822                                 LIBS="$LIBS -lxnet"
 823                                 AC_MSG_RESULT(yes)
 824                         else
 825                                 AC_MSG_RESULT(no)
 826                         fi
 827
 828                         if test "$GCC" = "yes"; then
 829                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 830                         fi
 831                 ;;
 832         esac
 833
 834         dnl *****************************
 835         dnl *** Checks for libpthread ***
 836         dnl *****************************
 837 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
 838 # and libpthread does not exist
 839 #
 840         case "${host}" in
 841                 *-*-*freebsd4*)
 842                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 843                 ;;
 844                 *-*-*freebsd5*)
 845                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 846                 ;;
 847                 *-*-*freebsd6*)
 848                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 849                 ;;
 850                 *)
 851                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 852                 ;;
 853         esac
 854         AC_CHECK_HEADERS(pthread.h)
 855         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 856         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 857         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 858         AC_TRY_COMPILE([ #include <pthread.h>], [
 859                 pthread_mutexattr_t attr;
 860                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 861         ], [
 862                 AC_MSG_RESULT(ok)
 863         ], [
 864                 AC_MSG_RESULT(no)
 865                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 866                 AC_DEFINE(USE_MONO_MUTEX)
 867         ])
 868         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 869
 870         dnl ***********************************
 871         dnl *** Checks for working __thread ***
 872         dnl ***********************************
 873         AC_MSG_CHECKING(for working __thread)
 874         if test "x$with_tls" != "x__thread"; then
 875                 AC_MSG_RESULT(disabled)
 876         else
 877                 AC_TRY_RUN([
 878                         #include <pthread.h>
 879                         __thread int i;
 880                         static int res1, res2;
 881
 882                         void thread_main (void *arg)
 883                         {
 884                                 i = arg;
 885                                 sleep (1);
 886                                 if (arg == 1)
 887                                         res1 = (i == arg);
 888                                 else
 889                                         res2 = (i == arg);
 890                         }
 891
 892                         int main () {
 893                                 pthread_t t1, t2;
 894
 895                                 i = 5;
 896
 897                                 pthread_create (&t1, NULL, thread_main, 1);
 898                                 pthread_create (&t2, NULL, thread_main, 2);
 899
 900                                 pthread_join (t1, NULL);
 901                                 pthread_join (t2, NULL);
 902
 903                                 return !(res1 + res2 == 2);
 904                         }
 905                 ], [
 906                                 AC_MSG_RESULT(yes)
 907                 ], [
 908                                 AC_MSG_RESULT(no)
 909                                 with_tls=pthread
 910                 ])
 911         fi
 912
 913         dnl **************************************
 914         dnl *** Checks for working sigaltstack ***
 915         dnl **************************************
 916         AC_MSG_CHECKING(for working sigaltstack)
 917         if test "x$with_sigaltstack" != "xyes"; then
 918                 AC_MSG_RESULT(disabled)
 919         else
 920                 AC_TRY_RUN([
 921                         #include <stdio.h>
 922                         #include <stdlib.h>
 923                         #include <unistd.h>
 924                         #include <signal.h>
 925                         #include <pthread.h>
 926                         #include <sys/wait.h>
 927                         #if defined(__FreeBSD__) || defined(__NetBSD__)
 928                         #define SA_STACK SA_ONSTACK
 929                         #endif
 930                         static void
 931                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 932                         {
 933                                 exit (0);
 934                         }
 935
 936                         static void *
 937                         loop (void *ignored)
 938                         {
 939                                 char *ptr = NULL;
 940
 941                                 *ptr = 0;
 942                                 return NULL;
 943                         }
 944
 945                         static void
 946                         child ()
 947                         {
 948                                 struct sigaction sa;
 949                                 struct sigaltstack sas;
 950                                 pthread_t id;
 951                                 pthread_attr_t attr;
 952
 953                                 sa.sa_sigaction = sigsegv_signal_handler;
 954                                 sigemptyset (&sa.sa_mask);
 955                                 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
 956                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 957                                         perror ("sigaction");
 958                                         return;
 959                                 }
 960
 961                                 sas.ss_sp = malloc (SIGSTKSZ);
 962                                 sas.ss_size = SIGSTKSZ;
 963                                 sas.ss_flags = 0;
 964                                 if (sigaltstack (&sas, NULL) == -1) {
 965                                         perror ("sigaltstack");
 966                                         return;
 967                                 }
 968
 969                                 pthread_attr_init (&attr);
 970                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 971                                         printf ("pthread_create\n");
 972                                         return;
 973                                 }
 974
 975                                 sleep (100);
 976                         }
 977
 978                         int
 979                         main ()
 980                         {
 981                                 pid_t son;
 982                                 int status;
 983                                 int i;
 984
 985                                 son = fork ();
 986                                 if (son == -1) {
 987                                         return 1;
 988                                 }
 989
 990                                 if (son == 0) {
 991                                         child ();
 992                                         return 0;
 993                                 }
 994
 995                                 for (i = 0; i < 3; ++i) {
 996                                         sleep (1);
 997                                         waitpid (son, &status, WNOHANG);
 998                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 999                                                 return 0;
1000                                 }
1001
1002                                 kill (son, SIGKILL);
1003                                 return 1;
1004                         }
1005
1006                 ], [
1007                                 AC_MSG_RESULT(yes)
1008                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
1009                 ], [
1010                                 with_sigaltstack=no
1011                                 AC_MSG_RESULT(no)
1012                 ])
1013         fi
1014
1015         dnl ********************************
1016         dnl *** Checks for semaphore lib ***
1017         dnl ********************************
1018         # 'Real Time' functions on Solaris
1019         # posix4 on Solaris 2.6
1020         # pthread (first!) on Linux
1021         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1022
1023         dnl ********************************
1024         dnl *** Checks for timezone stuff **
1025         dnl ********************************
1026         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1027                 AC_TRY_COMPILE([
1028                         #include <time.h>
1029                         ], [
1030                         struct tm tm;
1031                         tm.tm_gmtoff = 1;
1032                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1033         if test $ac_cv_struct_tm_gmtoff = yes; then
1034                 AC_DEFINE(HAVE_TM_GMTOFF)
1035         else
1036                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1037                         AC_TRY_COMPILE([
1038                                 #include <time.h>
1039                         ], [
1040                                 timezone = 1;
1041                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1042                 if test $ac_cv_var_timezone = yes; then
1043                         AC_DEFINE(HAVE_TIMEZONE)
1044                 else
1045                         AC_ERROR(unable to find a way to determine timezone)
1046                 fi
1047         fi
1048
1049         dnl *********************************
1050         dnl *** Checks for math functions ***
1051         dnl *********************************
1052         LIBS="$LIBS -lm";
1053         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1054                 AC_TRY_LINK([#include <math.h>],
1055                 [ finite(0.0); ],
1056                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
1057                 AC_MSG_RESULT(no)))
1058         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1059                 AC_TRY_LINK([#include <math.h>],
1060                 [ isfinite(0.0); ],
1061                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
1062                 AC_MSG_RESULT(no)))
1063
1064         dnl ****************************************************************
1065         dnl *** Checks for working poll() (macosx defines it but doesn't ***
1066         dnl *** have it in the library (duh))                            ***
1067         dnl ****************************************************************
1068         AC_CHECK_FUNCS(poll)
1069
1070         dnl *************************
1071         dnl *** Check for signbit ***
1072         dnl *************************
1073         AC_MSG_CHECKING(for signbit)
1074         AC_TRY_LINK([#include <math.h>], [
1075                 int s = signbit(1.0);
1076         ], [
1077                 AC_MSG_RESULT(yes)
1078                 AC_DEFINE(HAVE_SIGNBIT)
1079         ], [
1080                 AC_MSG_RESULT(no)
1081         ])
1082
1083         dnl *********************
1084         dnl *** Check for AIO ***
1085         dnl *********************
1086         AC_MSG_CHECKING([for SIGEV_THREAD definition])
1087         dnl Some systems (FreeBSD at least) may have aio_read
1088         dnl but don't support/define SIGEV_THREAD.
1089         AC_TRY_COMPILE([
1090         #include <sys/signal.h>
1091         ],[
1092         int x = SIGEV_THREAD;
1093         ],[
1094                 ac_cv_c_sigev_thread=yes
1095                 AC_MSG_RESULT(yes)
1096         ],[
1097                 AC_MSG_RESULT(no)
1098         ])
1099
1100         if test "$ac_cv_c_sigev_thread" = "yes" ; then
1101                 AC_CHECK_HEADERS(aio.h sys/aio.h)
1102                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
1103                 SIGVAL_PTR="undefined"
1104                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
1105                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
1106                                         #include <sys/signal.h>
1107                                         ])
1108                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
1109                                         #include <sys/signal.h>
1110                                         ])
1111                         if test "$SIGVAL_PTR" = "undefined" ; then
1112                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
1113                         fi
1114                 fi
1115                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
1116         fi
1117
1118         dnl **********************************
1119         dnl *** epoll                      ***
1120         dnl **********************************
1121         AC_CHECK_HEADERS(sys/epoll.h)
1122         haveepoll=no
1123         AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1124         if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1125                 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1126         fi
1127
1128         dnl **********************************
1129         dnl *** Checks for MonoPosixHelper ***
1130         dnl **********************************
1131         AC_CHECK_HEADERS(checklist.h)
1132         AC_CHECK_HEADERS(fstab.h)
1133         AC_CHECK_HEADERS(sys/sendfile.h)
1134         AC_CHECK_HEADERS(sys/statvfs.h)
1135         AC_CHECK_HEADERS(sys/vfstab.h)
1136         AC_CHECK_HEADERS(sys/xattr.h)
1137         AC_CHECK_FUNCS(getdomainname)
1138         AC_CHECK_FUNCS(setdomainname)
1139         AC_CHECK_FUNCS(fgetgrent)
1140         AC_CHECK_FUNCS(fgetpwent)
1141         AC_CHECK_FUNCS(fgetpwent)
1142         AC_CHECK_FUNCS(getfsstat)
1143         AC_CHECK_FUNCS(posix_fadvise)
1144         AC_CHECK_FUNCS(posix_fallocate)
1145         AC_CHECK_FUNCS(posix_madvise)
1146         AC_CHECK_FUNCS(vsnprintf)
1147         AC_CHECK_FUNCS(sendfile)
1148         AC_CHECK_FUNCS(sethostid)
1149         AC_CHECK_FUNCS(statfs)
1150         AC_CHECK_FUNCS(fstatfs)
1151         AC_CHECK_FUNCS(statvfs)
1152         AC_CHECK_FUNCS(fstatvfs)
1153         AC_CHECK_FUNCS(stime)
1154         AC_CHECK_FUNCS(strerror_r)
1155         AC_CHECK_FUNCS(ttyname_r)
1156         AC_CHECK_SIZEOF(size_t)
1157         AC_CHECK_MEMBERS(
1158                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1159                 [#include <sys/types.h>
1160                  #include <dirent.h>])
1161
1162         dnl *********************************
1163         dnl *** Check for Console 2.0 I/O ***
1164         dnl *********************************
1165         AC_CHECK_HEADERS([curses.h])
1166         AC_CHECK_HEADERS([term.h], [], [],
1167         [#if HAVE_CURSES_H
1168          #include <curses.h>
1169          #endif
1170         ])
1171         AC_CHECK_HEADERS([termios.h])
1172 else
1173         jdk_headers_found=no
1174         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1175         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1176         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1177
1178         dnl *********************************
1179         dnl *** Check for struct ip_mreqn ***
1180         dnl *********************************
1181         AC_MSG_CHECKING(for struct ip_mreqn)
1182         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1183                 struct ip_mreqn mreq;
1184                 mreq.imr_address.s_addr = 0;
1185         ], [
1186                 # Yes, we have it...
1187                 AC_MSG_RESULT(yes)
1188                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1189         ], [
1190                 # We'll just have to try and use struct ip_mreq
1191                 AC_MSG_RESULT(no)
1192                 AC_MSG_CHECKING(for struct ip_mreq)
1193                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1194                         struct ip_mreq mreq;
1195                         mreq.imr_interface.s_addr = 0;
1196                 ], [
1197                         # Yes, we have it...
1198                         AC_MSG_RESULT(yes)
1199                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1200                 ], [
1201                         # No multicast support
1202                         AC_MSG_RESULT(no)
1203                 ])
1204         ])
1205 fi
1206
1207 dnl socklen_t check
1208 AC_MSG_CHECKING(for socklen_t)
1209 AC_TRY_COMPILE([
1210 #include <sys/types.h>
1211 #include <sys/socket.h>
1212 ],[
1213   socklen_t foo;
1214 ],[
1215 ac_cv_c_socklen_t=yes
1216         AC_DEFINE(HAVE_SOCKLEN_T)
1217         AC_MSG_RESULT(yes)
1218 ],[
1219         AC_MSG_RESULT(no)
1220 ])
1221
1222 AC_MSG_CHECKING(for array element initalizer support)
1223 AC_TRY_COMPILE([#include <sys/socket.h>], [
1224         const int array[] = {[1] = 2,};
1225 ], [
1226         # Yes, we have it...
1227         AC_MSG_RESULT(yes)
1228         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1229 ], [
1230         # We'll have to use signals
1231         AC_MSG_RESULT(no)
1232 ])
1233
1234 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1235         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1236         AC_TRY_LINK([#include <math.h>],
1237         [ static void *p = &trunc; ],
1238         [
1239                 AC_DEFINE(HAVE_TRUNC)
1240                 AC_MSG_RESULT(yes)
1241                 ac_cv_trunc=yes
1242         ],
1243         AC_MSG_RESULT(no)))
1244
1245 if test "x$ac_cv_truncl" != "xyes"; then
1246    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1247 fi
1248
1249 dnl ****************************
1250 dnl *** Look for /dev/random ***
1251 dnl ****************************
1252
1253 AC_MSG_CHECKING([if usage of random device is requested])
1254 AC_ARG_ENABLE(dev-random,
1255 [  --disable-dev-random    disable the use of the random device],
1256 try_dev_random=$enableval, try_dev_random=yes)
1257 AC_MSG_RESULT($try_dev_random)
1258
1259 case "{$target}" in
1260     *-openbsd*)
1261     NAME_DEV_RANDOM="/dev/srandom"
1262     ;;
1263
1264 dnl Win32 does not have /dev/random, they have their own method...
1265
1266     *-*-mingw*|*-*-cygwin*)
1267     ac_cv_have_dev_random=no
1268     ;;
1269
1270 dnl Everywhere else, it's /dev/random
1271
1272     *)
1273     NAME_DEV_RANDOM="/dev/random"
1274     ;;
1275 esac
1276
1277 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1278
1279 dnl Now check if the device actually exists
1280
1281 if test "x$try_dev_random" = "xyes"; then
1282     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1283     [if test -r "$NAME_DEV_RANDOM" ; then
1284         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1285     if test "x$ac_cv_have_dev_random" = "xyes"; then
1286         AC_DEFINE(HAVE_CRYPT_RNG)
1287     fi
1288 else
1289     AC_MSG_CHECKING(for random device)
1290     ac_cv_have_dev_random=no
1291     AC_MSG_RESULT(has been disabled)
1292 fi
1293
1294 if test "x$platform_win32" = "xyes"; then
1295     AC_DEFINE(HAVE_CRYPT_RNG)
1296 fi
1297
1298 if test "x$ac_cv_have_dev_random" = "xno" \
1299     && test "x$platform_win32" = "xno"; then
1300     AC_MSG_WARN([[
1301 ***
1302 *** A system-provided entropy source was not found on this system.
1303 *** Because of this, the System.Security.Cryptography random number generator
1304 *** will throw a NotImplemented exception.
1305 ***
1306 *** If you are seeing this message, and you know your system DOES have an
1307 *** entropy collection in place, please contact <crichton@gimp.org> and
1308 *** provide information about the system and how to access the random device.
1309 ***
1310 *** Otherwise you can install either egd or prngd and set the environment
1311 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1312 ***]])
1313 fi
1314
1315 AC_MSG_CHECKING([if inter-process shared handles are requested])
1316 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1317 AC_MSG_RESULT($try_shared_handles)
1318 if test "x$try_shared_handles" != "xyes"; then
1319         AC_DEFINE(DISABLE_SHARED_HANDLES)
1320         AC_SUBST(DISABLE_SHARED_HANDLES)
1321 fi
1322
1323 #
1324 # ICU
1325 #
1326 ICU_CFLAGS=""
1327 ICU_LIBS=""
1328 enable_glob="normal;  default"
1329
1330 probe_icu=false
1331 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1332         if test x$with_icu = xno; then
1333            probe_icu=false;
1334            AC_MSG_RESULT(Will not probe for ICU)
1335         fi
1336         if test x$with_icu = xyes; then
1337            probe_icu=true;
1338         fi
1339 )
1340
1341 if $probe_icu; then
1342         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1343         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1344                 enable_glob="ICU not found, using non-ICU globalization code."
1345         else
1346                 enable_glob="ICU, unsupported. Version: `$ICU_CONFIG --version`"
1347                 AC_DEFINE(HAVE_ICU)
1348                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1349                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1350         fi
1351 fi
1352 AC_SUBST(ICU_CFLAGS)
1353 AC_SUBST(ICU_LIBS)
1354
1355 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1356 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1357
1358 TARGET="unknown"
1359 ACCESS_UNALIGNED="yes"
1360
1361 JIT_SUPPORTED=no
1362 INTERP_SUPPORTED=no
1363 LIBC="libc.so.6"
1364 INTL="libc.so.6"
1365
1366 jit_wanted=false
1367 interp_wanted=false
1368 case "$host" in
1369 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1370 #               TARGET=MIPS;
1371 #               ACCESS_UNALIGNED="no"
1372 #               ;;
1373         i*86-*-*)
1374                 TARGET=X86;
1375                 arch_target=x86;
1376                 JIT_SUPPORTED=yes
1377                 jit_wanted=true
1378                 ;;
1379         x86_64-*-* | amd64-*-*)
1380                 TARGET=AMD64;
1381                 arch_target=amd64;
1382                 JIT_SUPPORTED=yes
1383                 jit_wanted=true
1384                 ;;
1385         sparc*-*-*)
1386                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1387                    TARGET=SPARC64
1388                 else
1389                         TARGET=SPARC
1390                 fi
1391                 arch_target=sparc;
1392                 JIT_SUPPORTED=yes
1393                 ACCESS_UNALIGNED="no"
1394                 LIBC="libc.so"
1395                 INTL="libintl.so"
1396                 jit_wanted=true
1397                 if test x"$GCC" = xyes; then
1398                         CFLAGS="$CFLAGS -Wno-cast-align"
1399                 fi
1400                 ;;
1401        alpha*-*-linux* | alpha*-*-osf*)
1402                 TARGET=ALPHA;
1403                 ACCESS_UNALIGNED="no"
1404                 JIT_SUPPORTED=no
1405                 INTERP_SUPPORTED=yes
1406                 interp_wanted=true
1407                 arch_target=alpha;
1408                ;;
1409         *-*-mingw*|*-*-cygwin*)
1410                 INTL="intl"
1411                 ;;
1412 #       ia64-*-linux* | ia64-*-hpux*)
1413 #               TARGET=IA64;
1414 #               arch_target=ia64;
1415 #               JIT_SUPPORTED=no;
1416 #               ACCESS_UNALIGNED="no";
1417 #               case "$host_os" in
1418 #                       linux*) LIBC="libc.so.6.1";;
1419 #                       hpux*)  LIBC="libc.so.1";;
1420 #               esac
1421 #               ;;
1422 #       m68k-*-linux*)
1423 #               TARGET=M68K
1424 #               ;;
1425         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1426                 TARGET=HPPA;
1427                 arch_target=hppa;
1428                 LIBC="libc.sl"
1429                 ACCESS_UNALIGNED="no"
1430                 INTERP_SUPPORTED=yes
1431                 interp_wanted=true
1432                 ;;
1433         hppa*linux*)
1434                 TARGET=HPPA;
1435                 arch_target=hppa;
1436                 ACCESS_UNALIGNED="no"
1437                 INTERP_SUPPORTED=yes
1438                 interp_wanted=true
1439                 ;;
1440         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1441         powerpc-*-sysv* | powerpc-*-darwin*)
1442                 TARGET=POWERPC;
1443                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1444                 arch_target=ppc;
1445                 JIT_SUPPORTED=yes
1446                 jit_wanted=true
1447                 ;;
1448         arm-*-linux-* | armv4l-*-linux-*)
1449                 TARGET=ARM;
1450                 arch_target=arm;
1451                 ACCESS_UNALIGNED="no"
1452                 INTERP_SUPPORTED=yes
1453                 interp_wanted=true
1454                 ;;
1455         s390-*-linux*)
1456                 TARGET=S390;
1457                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1458                 arch_target=s390;
1459                 ACCESS_UNALIGNED="no"
1460                 JIT_SUPPORTED=yes
1461                 ;;
1462         s390x-*-linux*)
1463                 TARGET=S390x;
1464                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1465                 arch_target=s390x;
1466                 ACCESS_UNALIGNED="no"
1467                 JIT_SUPPORTED=yes
1468                 ;;
1469 esac
1470
1471 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1472         if test x$withval = xyes; then
1473            jit_wanted=true
1474         else
1475            jit_wanted=false
1476         fi
1477 ])
1478
1479 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1480         if test x$withval = xyes; then
1481            interp_wanted=true
1482         else
1483            interp_wanted=false
1484         fi
1485 ])
1486
1487 USEJIT=false
1488 if test x$JIT_SUPPORTED = xyes; then
1489    if $jit_wanted; then
1490       USEJIT=true
1491       jit_status="Building and using the JIT"
1492    else
1493       if $interp_wanted; then
1494          jit_status="Building the JIT, defaulting to the interpreter"
1495       else
1496          AC_ERROR(No JIT or interpreter support available or selected.)
1497       fi
1498    fi
1499 else
1500    if $interp_wanted; then
1501       jit_status="interpreter"
1502    else
1503       AC_ERROR(No JIT or interpreter support available or selected.)
1504    fi
1505 fi
1506
1507 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1508
1509 libsuffix=".so"
1510
1511 case "$host" in
1512      powerpc-*-darwin*)
1513         libsuffix=".dylib"
1514         LIBC="libc.dylib"
1515         INTL="libintl.dylib"
1516         ;;
1517      *-*-*netbsd*)
1518         LIBC="libc.so.12"
1519         INTL="libintl.so.0"
1520         ;;
1521     *-*-*freebsd*)
1522         LIBC="libc.so"
1523         INTL="libintl.so"
1524         ;;
1525     *-*-*openbsd*)
1526         LIBC="libc.so"
1527         INTL="libintl.so"
1528         ;;
1529 esac
1530 AC_SUBST(libsuffix)
1531
1532 if test "x$TARGET" != "xAMD64"; then
1533    # valgrind headers don't compile under x86-64
1534    AC_CHECK_HEADERS(valgrind/memcheck.h)
1535 fi
1536
1537 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1538         if test "x$with_tls" = "x__thread"; then
1539                 #
1540                 # On some linux distributions, TLS works in executables, but linking
1541                 # against a shared library containing TLS fails with:
1542                 # undefined reference to `__tls_get_addr'
1543                 #
1544                 rm -f conftest.c conftest.so conftest
1545                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1546                 gcc -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1547                 gcc -o conftest conftest.so > /dev/null 2>&1
1548                 if test ! -f conftest; then
1549                    AC_MSG_WARN([Disabling usage of __thread.]);
1550                    with_tls=pthread
1551                 fi
1552                 rm -f conftest.c conftest.so conftest
1553         fi
1554 fi
1555
1556 if test "x$with_tls" = "x__thread"; then
1557         AC_DEFINE(HAVE_KW_THREAD)
1558    # Pass the information to libgc
1559         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1560         export CPPFLAGS
1561         AC_MSG_CHECKING(if the tls_model attribute is supported)
1562         AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
1563                 ], [
1564                         AC_MSG_RESULT(yes)
1565                         AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
1566                 ], [
1567                         AC_MSG_RESULT(no)
1568         ])
1569 fi
1570
1571 if test ${TARGET} = ARM; then
1572         dnl ******************************************
1573         dnl *** Check to see what FPU is available ***
1574         dnl ******************************************
1575         AC_MSG_CHECKING(which FPU to use)
1576
1577         AC_TRY_COMPILE([], [
1578                 __asm__ ("ldfd f0, [r0]");
1579                 ], fpu=FPA, [
1580                         AC_TRY_COMPILE([], [
1581                                 __asm__ ("fldd d0, [r0]");
1582                         ], fpu=VFP, fpu=NONE)
1583                 ])
1584
1585         AC_MSG_RESULT($fpu)
1586         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1587         unset fpu
1588 fi
1589
1590 if test ${TARGET} = unknown; then
1591         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1592         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1593 fi
1594
1595 if test ${ACCESS_UNALIGNED} = no; then
1596         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1597 fi
1598
1599 PREVIEW=yes
1600 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1601         if test x$with_preview = xno; then
1602               PREVIEW=no
1603         fi
1604 ])
1605
1606 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1607
1608 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1609 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1610 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1611 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1612 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1613 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1614 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1615 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1616 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1617 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1618 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1619 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1620 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1621 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1622
1623 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1624 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
1625 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
1626
1627 AC_SUBST(LIBC)
1628 AC_SUBST(INTL)
1629
1630 AC_SUBST(arch_target)
1631 AC_SUBST(CFLAGS)
1632 AC_SUBST(CPPFLAGS)
1633 AC_SUBST(LDFLAGS)
1634
1635 mono_build_root=`pwd`
1636 AC_SUBST(mono_build_root)
1637
1638 if test x$USEJIT = xtrue; then
1639   mono_runtime=mono/mini/mono
1640 else
1641   mono_runtime=mono/interpreter/mint
1642 fi
1643 AC_SUBST(mono_runtime)
1644
1645 mono_cfg_root=$mono_build_root/runtime
1646 if test x$platform_win32 = xyes; then
1647   mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
1648 else
1649   mono_cfg_dir=$mono_cfg_root/etc
1650 fi
1651 AC_SUBST(mono_cfg_dir)
1652
1653 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
1654
1655 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
1656 [   depth=../../../..
1657     case $srcdir in
1658     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1659     .) reldir=$depth ;;
1660     *) reldir=$depth/$srcdir ;;
1661     esac
1662     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
1663     cd runtime/etc/mono/1.0
1664     rm -f machine.config
1665     $LN_S $reldir/data/net_1_1/machine.config machine.config
1666     cd $depth
1667 ],[LN_S='$LN_S'])
1668
1669 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
1670 [   depth=../../../..
1671     case $srcdir in
1672     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1673     .) reldir=$depth ;;
1674     *) reldir=$depth/$srcdir ;;
1675     esac
1676     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1677     cd runtime/etc/mono/2.0
1678     rm -f machine.config
1679     $LN_S $reldir/data/net_2_0/machine.config machine.config
1680     cd $depth
1681 ],[LN_S='$LN_S'])
1682
1683 AC_OUTPUT([
1684 Makefile
1685 mint.pc
1686 mono.pc
1687 scripts/mono-nunit.pc
1688 mono/Makefile
1689 mono/utils/Makefile
1690 mono/metadata/Makefile
1691 mono/dis/Makefile
1692 mono/cil/Makefile
1693 mono/arch/Makefile
1694 mono/os/Makefile
1695 mono/os/win32/Makefile
1696 mono/os/unix/Makefile
1697 mono/arch/x86/Makefile
1698 mono/arch/amd64/Makefile
1699 mono/arch/hppa/Makefile
1700 mono/arch/ppc/Makefile
1701 mono/arch/sparc/Makefile
1702 mono/arch/s390/Makefile
1703 mono/arch/s390x/Makefile
1704 mono/arch/arm/Makefile
1705 mono/arch/alpha/Makefile
1706 mono/interpreter/Makefile
1707 mono/tests/Makefile
1708 mono/tests/tests-config
1709 mono/benchmark/Makefile
1710 mono/monoburg/Makefile
1711 mono/monograph/Makefile
1712 mono/io-layer/Makefile
1713 mono/mini/Makefile
1714 mono/handles/Makefile
1715 mono/profiler/Makefile
1716 ikvm-native/Makefile
1717 scripts/Makefile
1718 man/Makefile
1719 web/Makefile
1720 docs/Makefile
1721 data/Makefile
1722 data/net_1_1/Makefile
1723 data/net_2_0/Makefile
1724 samples/Makefile
1725 support/Makefile
1726 data/config
1727 mono.spec
1728 tools/Makefile
1729 tools/locale-builder/Makefile
1730 runtime/Makefile
1731 ])
1732
1733 (
1734   case $prefix in
1735   NONE) prefix=/usr/local ;;
1736   esac
1737   case $exec_prefix in
1738   NONE | '${prefix}') exec_prefix=$prefix ;;
1739   esac
1740
1741   echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
1742   echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
1743   echo "mono_libdir=$exec_prefix/lib" >> $srcdir/$mcsdir/build/config.make
1744   echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
1745 )
1746
1747 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
1748
1749 echo "
1750         mcs source:  $mcs_topdir
1751         GC:          $gc
1752         Globalization:     $enable_glob
1753         TLS:         $with_tls
1754         SIGALTSTACK: $with_sigaltstack
1755         Engine:      $jit_status
1756         2.0 Alpha:   $PREVIEW
1757         JNI support: $jdk_headers_found
1758         libgdiplus:  $libgdiplus_msg
1759         $disabled
1760
1761 "