configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.31.99)
   5 AM_MAINTAINER_MODE
   6
   7 dnl
   8 dnl libgc checks
   9 dnl
  10
  11 gc_headers=no
  12 gc=included
  13 use_included_gc=no
  14
  15 if test -d $srcdir/libgc ; then
  16   gc_default=included
  17 else
  18   gc_default=boehm
  19 fi
  20
  21 #
  22 # These are the flags that need to be stored in the mono.pc file for
  23 # compiling code that will embed Mono
  24 #
  25 libmono_cflags=""
  26 libmono_ldflags=""
  27 AC_SUBST(libmono_cflags)
  28 AC_SUBST(libmono_ldflags)
  29
  30 dnl if linker handles the version script
  31 no_version_script=no
  32
  33 # Thread configuration inspired by sleepycat's db
  34 AC_MSG_CHECKING([host platform characteristics])
  35 libgc_threads=no
  36 case "$host" in
  37         *-*-mingw*|*-*-cygwin*)
  38                 platform_win32=yes
  39                 AC_DEFINE(PLATFORM_WIN32)
  40                 CC="gcc -mno-cygwin"
  41                 HOST_CC="gcc"
  42 # latest libgc already defines GC_WIN32_THREADS
  43 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  44                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  45                 libdl=
  46                 libgc_threads=win32
  47                 gc_default=boehm
  48                 ;;
  49         *-*-*netbsd*)
  50                 platform_win32=no
  51                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  52                 libmono_cflags="-D_REENTRANT"
  53                 LDFLAGS="$LDFLAGS -pthread"
  54                 libmono_ldflags="-pthread"
  55                 AC_DEFINE(NEED_LINK_UNLINK)
  56                 libdl=
  57                 libgc_threads=pthreads
  58                 ;;
  59         *-*-*freebsd*|*-*-*openbsd*)
  60                 platform_win32=no
  61                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE"
  62                 libmono_cflags="-D_THREAD_SAFE"
  63                 LDFLAGS="$LDFLAGS -pthread"
  64                 libmono_ldflags="-pthread"
  65                 AC_DEFINE(NEED_LINK_UNLINK)
  66                 AC_DEFINE(PTHREAD_POINTER_ID)
  67                 libdl=
  68                 libgc_threads=pthreads
  69                 ;;
  70         *-*-linux*)
  71                 platform_win32=no
  72                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -DMONO_USE_EXC_TABLES -D_GNU_SOURCE -D_REENTRANT -fexceptions"
  73                 libmono_cflags="-DMONO_USE_EXC_TABLES -fexceptions -D_REENTRANT"
  74                 libmono_ldflags="-lpthread"
  75                 libdl="-ldl"
  76                 libgc_threads=pthreads
  77                 ;;
  78         *-*-hpux*)
  79                 platform_win32=no
  80                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
  81                 CFLAGS="$CFLAGS +ESdbgasm"
  82                 LDFLAGS="$LDFLAGS -z"
  83                 libmono_cflags="-D_REENTRANT"
  84                 libmono_ldflags="-lpthread"
  85                 libgc_threads=pthreads
  86                 AC_DEFINE(NEED_LINK_UNLINK)
  87                 ;;
  88         *-*-solaris*)
  89                 platform_win32=no
  90                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
  91                 AC_DEFINE(NEED_LINK_UNLINK)
  92                 libmono_cflags="-D_REENTRANT"
  93                 libgc_threads=pthreads
  94                 ;;
  95         *-*-darwin*)
  96                 platform_win32=no
  97                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE"
  98                 libmono_cflags="-D_THREAD_SAFE"
  99                 LDFLAGS="$LDFLAGS -pthread"
 100                 libmono_ldflags="-pthread"
 101                 AC_DEFINE(NEED_LINK_UNLINK)
 102                 AC_DEFINE(PTHREAD_POINTER_ID)
 103                 AC_DEFINE(USE_MACH_SEMA)
 104                 no_version_script=yes
 105                 libdl=
 106                 libgc_threads=no
 107                 gc_default=none
 108                 ;;
 109         *)
 110                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 111                 platform_win32=no
 112                 libdl="-ldl"
 113                 ;;
 114 esac
 115 AC_MSG_RESULT(ok)
 116 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 117
 118 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 119
 120 AC_CHECK_TOOL(CC, gcc, gcc)
 121 AC_PROG_CC
 122 AM_PROG_CC_STDC
 123 AC_PROG_INSTALL
 124 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 125 : ${CCAS='$(CC)'}
 126 # Set ASFLAGS if not already set.
 127 : ${CCASFLAGS='$(CFLAGS)'}
 128 AC_SUBST(CCAS)
 129 AC_SUBST(CCASFLAGS)
 130
 131 AC_CHECK_PROG(BISON, bison,yes,no)
 132 if test "x$BISON" = "xno";
 133 then
 134         AC_MSG_ERROR([You need to install bison])
 135 fi
 136
 137 dnl may require a specific autoconf version
 138 dnl AC_PROG_CC_FOR_BUILD
 139 dnl CC_FOR_BUILD not automatically detected
 140 CC_FOR_BUILD=$CC
 141 BUILD_EXEEXT=
 142 if test "x$cross_compiling" = "xyes"; then
 143         CC_FOR_BUILD=cc
 144         BUILD_EXEEXT=""
 145 fi
 146 AC_SUBST(CC_FOR_BUILD)
 147 AC_SUBST(HOST_CC)
 148 AC_SUBST(BUILD_EXEEXT)
 149
 150 # Set STDC_HEADERS
 151 AC_HEADER_STDC
 152 AC_LIBTOOL_WIN32_DLL
 153 AM_PROG_LIBTOOL
 154
 155 # Test whenever ld supports -version-script
 156 AC_PROG_LD
 157 AC_PROG_LD_GNU
 158 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 159    no_version_script=yes
 160 fi
 161
 162 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
 163
 164 # for mono/mini/tramp-x86.c
 165 AC_CHECK_HEADERS(valgrind/memcheck.h)
 166
 167 # for mono/metadata/debug-symfile.c
 168 AC_CHECK_HEADERS(elf.h)
 169
 170 # for mono/dis
 171 AC_CHECK_HEADERS(wchar.h)
 172
 173 # not 64 bit clean in cross-compile
 174 AC_CHECK_SIZEOF(void *, 4)
 175
 176 WARN=''
 177 if test x"$GCC" = xyes; then
 178         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 179                 # The runtime code does not respect ANSI C strict aliasing rules
 180                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 181 else
 182         # The Sun Forte compiler complains about inline functions that access static variables
 183         # so disable all inlining.
 184         case "$host" in
 185         *-*-solaris*)
 186                 CFLAGS="$CFLAGS -Dinline="
 187                 ;;
 188         esac
 189 fi
 190 CFLAGS="$CFLAGS -g $WARN"
 191
 192 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 193 if test "x$PKG_CONFIG" = "xno"; then
 194         AC_MSG_ERROR([You need to install pkg-config])
 195 fi
 196
 197 dnl for use on the build system
 198 dnl pkg-config is stupid
 199 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 200 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 201 AC_SUBST(BUILD_GLIB_CFLAGS)
 202 AC_SUBST(BUILD_GLIB_LIBS)
 203
 204 PKG_PATH=
 205 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 206         if test x$with_crosspkgdir = "x"; then
 207                 if test -s $PKG_CONFIG_PATH; then
 208                         PKG_PATH=$PKG_CONFIG_PATH
 209                 fi
 210         else
 211                 PKG_PATH=$with_crosspkgdir
 212                 PKG_CONFIG_PATH=$PKG_PATH
 213                 export PKG_CONFIG_PATH
 214         fi
 215 )
 216
 217 ## Versions of dependencies
 218 GLIB_REQUIRED_VERSION=1.3.11
 219
 220 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 221
 222 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 223 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 224 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 225 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 226
 227 AC_SUBST(GLIB_CFLAGS)
 228 AC_SUBST(GLIB_LIBS)
 229 AC_SUBST(GMODULE_CFLAGS)
 230 AC_SUBST(GMODULE_LIBS)
 231
 232 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 233
 234 # Enable support for NPTL only features like fast thread-local storage
 235 # We can't reliably detect nptl at compile & run time
 236 # so this option will stay until nptl becomes more widespread
 237 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      enable/disable support for NPTL],[],[with_nptl=yes])
 238
 239 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 240 # This does not work on some platforms (bug #55253)
 241 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 242
 243 # assembly bundle support, see metadata/make-bundle.pl for more info
 244 AC_ARG_WITH(bundle, [  --with-bundle=bundle_template],[
 245         BUNDLE_FILE=$with_bundle
 246         AC_SUBST(BUNDLE_FILE)
 247         AC_DEFINE(WITH_BUNDLE)
 248 ],[with_bundle=no])
 249 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
 250
 251 LIBGC_CFLAGS=
 252 LIBGC_LIBS=
 253 libgc_dir=
 254 case "x$gc" in
 255         xboehm|xbohem|xyes)
 256                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 257                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 258
 259                 if test "x$found_boehm" != "xyes"; then
 260                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 261                 fi
 262                 if test "x$gc_headers" != "xyes"; then
 263                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 264                 fi
 265
 266                 AC_DEFINE(HAVE_BOEHM_GC)
 267                 AC_SUBST(HAVE_BOEHM_GC)
 268                 LIBGC_LIBS="-lgc $libdl"
 269
 270                 # AC_CHECK_FUNCS does not work for some reason...
 271                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 272                 if test "x$found_gcj_malloc" = "xyes"; then
 273                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 274                 fi
 275                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 276                 if test "x$found_gc_enable" = "xyes"; then
 277                         AC_DEFINE(HAVE_GC_ENABLE)
 278                 fi
 279                 ;;
 280
 281         xincluded)
 282                 AC_CONFIG_SUBDIRS(libgc)
 283
 284                 found_boehm=yes
 285                 gc_headers=yes
 286                 use_included_gc=yes
 287                 libgc_dir=libgc
 288
 289                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 290                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 291
 292                 AC_DEFINE(HAVE_BOEHM_GC)
 293                 AC_SUBST(HAVE_BOEHM_GC)
 294
 295                 AC_DEFINE(HAVE_GC_H)
 296                 AC_DEFINE(USE_INCLUDED_LIBGC)
 297
 298                 # The included libgc contains GCJ support
 299                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 300                 AC_DEFINE(HAVE_GC_ENABLE)
 301                 ;;
 302
 303         xnone)
 304                 AC_MSG_WARN("Compiling mono without GC.")
 305                 ;;
 306         *)
 307                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 308                 ;;
 309 esac
 310
 311 we_are_embedded_in_mono=yes
 312 export we_are_embedded_in_mono
 313 export libgc_threads
 314
 315 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 316 AC_SUBST(LIBGC_CFLAGS)
 317 AC_SUBST(LIBGC_LIBS)
 318 AC_SUBST(libgc_dir)
 319
 320 dnl
 321 dnl End of libgc checks
 322 dnl
 323
 324 if test x$platform_win32 = xno; then
 325         dnl ******************************************************************
 326         dnl *** Check for large file support                               ***
 327         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 328         dnl ******************************************************************
 329
 330         # Check that off_t can represent 2**63 - 1 correctly, working around
 331         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 332         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 333         large_offt=no
 334         AC_DEFUN(LARGE_FILES, [
 335                 large_CPPFLAGS=$CPPFLAGS
 336                 CPPFLAGS="$CPPFLAGS $1"
 337                 AC_TRY_RUN([
 338                         #include <sys/types.h>
 339
 340                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 341
 342                         int main(void) {
 343                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 344                                                (BIG_OFF_T%2147483647==1));
 345                                 if(big_off_t) {
 346                                         exit(0);
 347                                 } else {
 348                                         exit(1);
 349                                 }
 350                         }
 351                 ], [
 352                         AC_MSG_RESULT(ok)
 353                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 354                         large_CPPFLAGS="$large_CPPFLAGS $1"
 355                         large_offt=yes
 356                 ], [
 357                         AC_MSG_RESULT(no)
 358                 ], "")
 359                 CPPFLAGS=$large_CPPFLAGS
 360         ])
 361
 362         AC_MSG_CHECKING(if off_t is 64 bits wide)
 363         LARGE_FILES("")
 364         if test $large_offt = no; then
 365                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 366                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 367         fi
 368         if test $large_offt = no; then
 369                 AC_MSG_WARN([No 64 bit file size support available])
 370         fi
 371
 372         dnl *****************************
 373         dnl *** Checks for libsocket  ***
 374         dnl *****************************
 375         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 376
 377         dnl *******************************
 378         dnl *** Checks for MSG_NOSIGNAL ***
 379         dnl *******************************
 380         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 381         AC_TRY_COMPILE([#include <sys/socket.h>], [
 382                 int f = MSG_NOSIGNAL;
 383         ], [
 384                 # Yes, we have it...
 385                 AC_MSG_RESULT(yes)
 386                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 387         ], [
 388                 # We'll have to use signals
 389                 AC_MSG_RESULT(no)
 390         ])
 391
 392         dnl *****************************
 393         dnl *** Checks for SOL_IP     ***
 394         dnl *****************************
 395         AC_MSG_CHECKING(for SOL_IP)
 396         AC_TRY_COMPILE([#include <netdb.h>], [
 397                 int level = SOL_IP;
 398         ], [
 399                 # Yes, we have it...
 400                 AC_MSG_RESULT(yes)
 401                 AC_DEFINE(HAVE_SOL_IP)
 402         ], [
 403                 # We'll have to use getprotobyname
 404                 AC_MSG_RESULT(no)
 405         ])
 406
 407         dnl *****************************
 408         dnl *** Checks for SOL_IPV6     ***
 409         dnl *****************************
 410         AC_MSG_CHECKING(for SOL_IPV6)
 411         AC_TRY_COMPILE([#include <netdb.h>], [
 412                 int level = SOL_IPV6;
 413         ], [
 414                 # Yes, we have it...
 415                 AC_MSG_RESULT(yes)
 416                 AC_DEFINE(HAVE_SOL_IPV6)
 417         ], [
 418                 # We'll have to use getprotobyname
 419                 AC_MSG_RESULT(no)
 420         ])
 421
 422         dnl *****************************
 423         dnl *** Checks for SOL_TCP    ***
 424         dnl *****************************
 425         AC_MSG_CHECKING(for SOL_TCP)
 426         AC_TRY_COMPILE([#include <netdb.h>], [
 427                 int level = SOL_TCP;
 428         ], [
 429                 # Yes, we have it...
 430                 AC_MSG_RESULT(yes)
 431                 AC_DEFINE(HAVE_SOL_TCP)
 432         ], [
 433                 # We'll have to use getprotobyname
 434                 AC_MSG_RESULT(no)
 435         ])
 436
 437         dnl *****************************
 438         dnl *** Checks for IP_PKTINFO ***
 439         dnl *****************************
 440         AC_MSG_CHECKING(for IP_PKTINFO)
 441         AC_TRY_COMPILE([#include <netdb.h>], [
 442                 int level = IP_PKTINFO;
 443         ], [
 444                 # Yes, we have it...
 445                 AC_MSG_RESULT(yes)
 446                 AC_DEFINE(HAVE_IP_PKTINFO)
 447         ], [
 448                 AC_MSG_RESULT(no)
 449         ])
 450
 451         dnl *********************************
 452         dnl *** Check for struct ip_mreqn ***
 453         dnl *********************************
 454         AC_MSG_CHECKING(for struct ip_mreqn)
 455         AC_TRY_COMPILE([#include <netinet/in.h>], [
 456                 struct ip_mreqn mreq;
 457                 mreq.imr_address.s_addr = 0;
 458         ], [
 459                 # Yes, we have it...
 460                 AC_MSG_RESULT(yes)
 461                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 462         ], [
 463                 # We'll just have to try and use struct ip_mreq
 464                 AC_MSG_RESULT(no)
 465                 AC_MSG_CHECKING(for struct ip_mreq)
 466                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 467                         struct ip_mreq mreq;
 468                         mreq.imr_interface.s_addr = 0;
 469                 ], [
 470                         # Yes, we have it...
 471                         AC_MSG_RESULT(yes)
 472                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 473                 ], [
 474                         # No multicast support
 475                         AC_MSG_RESULT(no)
 476                 ])
 477         ])
 478
 479         dnl **********************************
 480         dnl *** Check for gethostbyname2_r ***
 481         dnl **********************************
 482         AC_MSG_CHECKING(for gethostbyname2_r)
 483                 AC_TRY_LINK([#include <netdb.h>], [
 484                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 485         ], [
 486                 # Yes, we have it...
 487                 AC_MSG_RESULT(yes)
 488                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 489         ], [
 490                 AC_MSG_RESULT(no)
 491         ])
 492
 493         dnl *****************************
 494         dnl *** Checks for libnsl     ***
 495         dnl *****************************
 496         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 497
 498         AC_CHECK_FUNCS(inet_pton inet_aton)
 499
 500         dnl ***********************************************
 501         dnl *** Checks for size of sockaddr_un.sun_path ***
 502         dnl ***********************************************
 503         # AC_CHECK_SIZEOF can't cope with struct members :-(
 504         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 505         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 506                 [AC_TRY_RUN([
 507                         #include <sys/types.h>
 508                         #include <stdio.h>
 509                         #include <sys/un.h>
 510
 511                         int main(void) {
 512                                 struct sockaddr_un sock_un;
 513                                 FILE *f=fopen("conftestval", "w");
 514                                 if(!f) exit(1);
 515                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 516                                 exit(0);
 517                         }
 518                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 519                    cv_mono_sizeof_sunpath=0,
 520                    cv_mono_sizeof_sunpath=0)])dnl
 521         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 522         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 523
 524         dnl *************************************
 525         dnl *** Checks for zero length arrays ***
 526         dnl *************************************
 527         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 528         AC_TRY_COMPILE([
 529                 struct s {
 530                         int  length;
 531                         char data [0];
 532                 };
 533         ], [], [
 534                 AC_MSG_RESULT(yes)
 535                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 536         ], [
 537                 AC_MSG_RESULT(no)
 538                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 539         ])
 540
 541         dnl *****************************
 542         dnl *** Checks for libxnet    ***
 543         dnl *****************************
 544         case "${host}" in
 545                 *solaris* )
 546                         AC_MSG_CHECKING(for Solaris XPG4 support)
 547                         if test -f /usr/lib/libxnet.so; then
 548                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 549                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 550                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 551                                 LIBS="$LIBS -lxnet"
 552                                 AC_MSG_RESULT(yes)
 553                         else
 554                                 AC_MSG_RESULT(no)
 555                         fi
 556
 557                         if test "$GCC" = "yes"; then
 558                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 559                         fi
 560                 ;;
 561         esac
 562
 563         dnl *****************************
 564         dnl *** Checks for libpthread ***
 565         dnl *****************************
 566         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 567         AC_CHECK_HEADERS(pthread.h)
 568         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 569         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 570         AC_TRY_COMPILE([ #include <pthread.h>], [
 571                 pthread_mutexattr_t attr;
 572                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 573         ], [
 574                 AC_MSG_RESULT(ok)
 575         ], [
 576                 AC_MSG_RESULT(no)
 577                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 578                 AC_DEFINE(USE_MONO_MUTEX)
 579         ])
 580         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 581
 582         dnl ***********************************
 583         dnl *** Checks for working __thread ***
 584         dnl ***********************************
 585         AC_MSG_CHECKING(for working __thread)
 586         AC_TRY_RUN([
 587                 #include <pthread.h>
 588
 589                 __thread int i;
 590                 static int res1, res2;
 591
 592                 void thread_main (void *arg)
 593                 {
 594                         i = arg;
 595                         sleep (1);
 596                         if (arg == 1)
 597                                 res1 = (i == arg);
 598                         else
 599                                 res2 = (i == arg);
 600                 }
 601
 602                 int main () {
 603                         pthread_t t1, t2;
 604
 605                         i = 5;
 606
 607                         pthread_create (&t1, NULL, thread_main, 1);
 608                         pthread_create (&t2, NULL, thread_main, 2);
 609
 610                         pthread_join (t1, NULL);
 611                         pthread_join (t2, NULL);
 612
 613                         return !(res1 + res2 == 2);
 614                 }
 615         ], [
 616                         if test "x$with_nptl" != "xyes"; then
 617                                 AC_MSG_RESULT(disabled)
 618                         else
 619                                 AC_MSG_RESULT(yes)
 620                                 AC_DEFINE(HAVE_KW_THREAD)
 621                         fi
 622         ], [
 623                         AC_MSG_RESULT(no)
 624         ])
 625
 626         dnl **************************************
 627         dnl *** Checks for working sigaltstack ***
 628         dnl **************************************
 629         AC_MSG_CHECKING(for working sigaltstack)
 630         AC_TRY_RUN([
 631                 #include <stdio.h>
 632                 #include <stdlib.h>
 633                 #include <unistd.h>
 634                 #include <signal.h>
 635                 #include <pthread.h>
 636                 #include <sys/wait.h>
 637
 638                 static void
 639                 sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 640                 {
 641                         exit (0);
 642                 }
 643
 644                 static void *
 645                 loop (void *ignored)
 646                 {
 647                         char *ptr = NULL;
 648
 649                         *ptr = 0;
 650                         return NULL;
 651                 }
 652
 653                 static void
 654                 child ()
 655                 {
 656                         struct sigaction sa;
 657                         struct sigaltstack sas;
 658                         pthread_t id;
 659                         pthread_attr_t attr;
 660
 661                         sa.sa_sigaction = sigsegv_signal_handler;
 662                         sigemptyset (&sa.sa_mask);
 663                         sa.sa_flags = SA_SIGINFO | SA_STACK;
 664                         if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 665                                 perror ("lala");
 666                                 return;
 667                         }
 668
 669                         sas.ss_sp = malloc (SIGSTKSZ);
 670                         sas.ss_size = SIGSTKSZ;
 671                         sas.ss_flags = SS_ONSTACK;
 672                         if (sigaltstack (&sas, NULL) == -1) {
 673                                 perror ("lala");
 674                                 return;
 675                         }
 676
 677                         pthread_attr_init (&attr);
 678                         if (pthread_create(&id, &attr, loop, &attr) != 0) {
 679                                 printf ("failed\n");
 680                                 return;
 681                         }
 682
 683                         sleep (100);
 684                 }
 685
 686                 int
 687                 main ()
 688                 {
 689                         pid_t son;
 690                         int status;
 691                         int i;
 692
 693                         son = fork ();
 694                         if (son == -1) {
 695                                 return 1;
 696                         }
 697
 698                         if (son == 0) {
 699                                 child ();
 700                                 return 0;
 701                         }
 702
 703                         for (i = 0; i < 3; ++i) {
 704                                 sleep (1);
 705                                 waitpid (son, &status, WNOHANG);
 706                                 if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 707                                         return 0;
 708                         }
 709
 710                         kill (son, SIGKILL);
 711                         return 1;
 712                 }
 713
 714         ], [
 715                         if test "x$with_sigaltstack" != "xyes"; then
 716                                 AC_MSG_RESULT(disabled)
 717                         else
 718                                 AC_MSG_RESULT(yes)
 719                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 720                         fi
 721         ], [
 722                         with_sigaltstack=no
 723                         AC_MSG_RESULT(no)
 724         ])
 725
 726         dnl ********************************
 727         dnl *** Checks for semaphore lib ***
 728         dnl ********************************
 729         # 'Real Time' functions on Solaris
 730         # posix4 on Solaris 2.6
 731         # pthread (first!) on Linux
 732         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 733
 734         dnl ********************************
 735         dnl *** Checks for timezone stuff **
 736         dnl ********************************
 737         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 738                 AC_TRY_COMPILE([
 739                         #include <time.h>
 740                         ], [
 741                         struct tm tm;
 742                         tm.tm_gmtoff = 1;
 743                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 744         if test $ac_cv_struct_tm_gmtoff = yes; then
 745                 AC_DEFINE(HAVE_TM_GMTOFF)
 746         else
 747                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 748                         AC_TRY_COMPILE([
 749                                 #include <time.h>
 750                         ], [
 751                                 timezone = 1;
 752                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 753                 if test $ac_cv_var_timezone = yes; then
 754                         AC_DEFINE(HAVE_TIMEZONE)
 755                 else
 756                         AC_ERROR(unable to find a way to determine timezone)
 757                 fi
 758         fi
 759
 760         dnl *********************************
 761         dnl *** Checks for math functions ***
 762         dnl *********************************
 763         LIBS="$LIBS -lm";
 764         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 765                 AC_TRY_LINK([#include <math.h>],
 766                 [ finite(0.0); ],
 767                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 768                 AC_MSG_RESULT(no)))
 769         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 770                 AC_TRY_LINK([#include <math.h>],
 771                 [ isfinite(0.0); ],
 772                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 773                 AC_MSG_RESULT(no)))
 774
 775         dnl ****************************************************************
 776         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 777         dnl *** have it in the library (duh))                            ***
 778         dnl ****************************************************************
 779         AC_CHECK_FUNCS(poll)
 780
 781         dnl *************************
 782         dnl *** Check for signbit ***
 783         dnl *************************
 784         AC_MSG_CHECKING(for signbit)
 785         AC_TRY_LINK([#include <math.h>], [
 786                 int s = signbit(1.0);
 787         ], [
 788                 AC_MSG_RESULT(yes)
 789                 AC_DEFINE(HAVE_SIGNBIT)
 790         ], [
 791                 AC_MSG_RESULT(no)
 792         ])
 793
 794         dnl *********************
 795         dnl *** Check for AIO ***
 796         dnl *********************
 797         AC_CHECK_HEADERS(aio.h)
 798         AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
 799 else
 800         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 801         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 802 fi
 803
 804 dnl socklen_t check
 805 AC_MSG_CHECKING(for socklen_t)
 806 AC_TRY_COMPILE([
 807 #include <sys/types.h>
 808 #include <sys/socket.h>
 809 ],[
 810   socklen_t foo;
 811 ],[
 812 ac_cv_c_socklen_t=yes
 813         AC_DEFINE(HAVE_SOCKLEN_T)
 814         AC_MSG_RESULT(yes)
 815 ],[
 816         AC_MSG_RESULT(no)
 817 ])
 818
 819 AC_CHECK_FUNCS(truncl, , AC_MSG_CHECKING(for truncl in math.h)
 820         AC_TRY_LINK([#include <math.h>],
 821         [ truncl(0.0); ],
 822         [
 823                 AC_DEFINE(HAVE_TRUNCL)
 824                 AC_MSG_RESULT(yes)
 825                 ac_cv_truncl=yes
 826         ],
 827         AC_MSG_RESULT(no)))
 828
 829 if test "x$ac_cv_truncl" != "xyes"; then
 830    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
 831 fi
 832
 833 dnl ****************************
 834 dnl *** Look for /dev/random ***
 835 dnl ****************************
 836
 837 AC_MSG_CHECKING([if usage of random device is requested])
 838 AC_ARG_ENABLE(dev-random,
 839 [  --disable-dev-random    disable the use of the random device],
 840 try_dev_random=$enableval, try_dev_random=yes)
 841 AC_MSG_RESULT($try_dev_random)
 842
 843 case "{$target}" in
 844     *-openbsd*)
 845     NAME_DEV_RANDOM="/dev/srandom"
 846     ;;
 847
 848 dnl Win32 does not have /dev/random, they have their own method...
 849
 850     *-*-mingw*|*-*-cygwin*)
 851     ac_cv_have_dev_random = no
 852     ;;
 853
 854 dnl Everywhere else, it's /dev/random
 855
 856     *)
 857     NAME_DEV_RANDOM="/dev/random"
 858     ;;
 859 esac
 860
 861 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 862
 863 dnl Now check if the device actually exists
 864
 865 if test "x$try_dev_random" = "xyes"; then
 866     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 867     [if test -r "$NAME_DEV_RANDOM" ; then
 868         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 869     if test "x$ac_cv_have_dev_random" = "xyes"; then
 870         AC_DEFINE(HAVE_CRYPT_RNG)
 871     fi
 872 else
 873     AC_MSG_CHECKING(for random device)
 874     ac_cv_have_dev_random=no
 875     AC_MSG_RESULT(has been disabled)
 876 fi
 877
 878 if test "x$platform_win32" = "xyes"; then
 879     AC_DEFINE(HAVE_CRYPT_RNG)
 880 fi
 881
 882 if test "x$ac_cv_have_dev_random" = "xno" \
 883     && test "x$platform_win32" = "xno"; then
 884     AC_MSG_WARN([[
 885 ***
 886 *** A system-provided entropy source was not found on this system.
 887 *** Because of this, the System.Security.Cryptography random number generator
 888 *** will throw a NotImplemented exception.
 889 ***
 890 *** If you are seeing this message, and you know your system DOES have an
 891 *** entropy collection in place, please contact <crichton@gimp.org> and
 892 *** provide information about the system and how to access the random device.
 893 ***
 894 *** For those systems who lack a random device, EGD support is forthcoming.
 895 ***]])
 896 fi
 897
 898 AC_MSG_CHECKING([if inter-process shared handles are requested])
 899 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
 900 AC_MSG_RESULT($try_shared_handles)
 901 if test "x$try_shared_handles" != "xyes"; then
 902         AC_DEFINE(DISABLE_SHARED_HANDLES)
 903         AC_SUBST(DISABLE_SHARED_HANDLES)
 904 fi
 905
 906 ICU_CFLAGS=""
 907 ICU_LIBS=""
 908 enable_icu=no
 909 AC_PATH_PROG(ICU_CONFIG, icu-config, no)
 910 if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
 911         AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
 912         enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
 913 else
 914         enable_icu="yes. Version: `$ICU_CONFIG --version`"
 915         AC_DEFINE(HAVE_ICU)
 916         ICU_CFLAGS=`$ICU_CONFIG --cppflags`
 917         ICU_LIBS=`$ICU_CONFIG --ldflags`
 918 fi
 919 AC_SUBST(ICU_CFLAGS)
 920 AC_SUBST(ICU_LIBS)
 921
 922 TARGET="unknown"
 923 ACCESS_UNALIGNED="yes"
 924
 925 JIT_SUPPORTED=no
 926 LIBC="libc.so.6"
 927
 928 jit_wanted=false
 929 case "$host" in
 930 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
 931 #               TARGET=MIPS;
 932 #               ACCESS_UNALIGNED="no"
 933 #               ;;
 934         i*86-*-*)
 935                 TARGET=X86;
 936                 arch_target=x86;
 937                 JIT_SUPPORTED=yes
 938                 jit_wanted=true
 939                 ;;
 940         x86_64-*-* | amd64-*-*)
 941                 TARGET=AMD64;
 942                 arch_target=amd64;
 943                 JIT_SUPPORTED=no
 944                 ;;
 945         sparc*-*-*)
 946                 TARGET=SPARC;
 947                 arch_target=sparc;
 948                 JIT_SUPPORTED=yes
 949                 ACCESS_UNALIGNED="no"
 950                 jit_wanted=true
 951                 ;;
 952 #       alpha*-*-linux* | alpha*-*-osf*)
 953 #               TARGET=ALPHA;
 954 #               ACCESS_UNALIGNED="no"
 955 #              ;;
 956 #       ia64-*-linux* | ia64-*-hpux*)
 957 #               TARGET=IA64;
 958 #               arch_target=ia64;
 959 #               JIT_SUPPORTED=no;
 960 #               ACCESS_UNALIGNED="no";
 961 #               case "$host_os" in
 962 #                       linux*) LIBC="libc.so.6.1";;
 963 #                       hpux*)  LIBC="libc.so.1";;
 964 #               esac
 965 #               ;;
 966 #       m68k-*-linux*)
 967 #               TARGET=M68K
 968 #               ;;
 969         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
 970                 TARGET=HPPA;
 971                 arch_target=hppa;
 972                 ACCESS_UNALIGNED="no"
 973                 ;;
 974         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
 975         powerpc-*-sysv* | powerpc-*-darwin*)
 976                 TARGET=POWERPC;
 977                 arch_target=ppc;
 978                 JIT_SUPPORTED=yes
 979                 ;;
 980         arm-*-linux-* | armv4l-*-linux-*)
 981                 TARGET=ARM;
 982                 arch_target=arm;
 983                 ACCESS_UNALIGNED="no"
 984                 ;;
 985         s390-*-linux*)
 986                 TARGET=S390;
 987                 arch_target=s390;
 988                 ACCESS_UNALIGNED="no"
 989                 ;;
 990 esac
 991
 992 AC_ARG_WITH(jit, [  --with-jit=yes,no    If you want to build scripts that default to the JIT],[
 993         jit_wanted=true
 994 ])
 995
 996 USEJIT=false
 997 if test x$JIT_SUPPORTED = xyes; then
 998    if $jit_wanted; then
 999       USEJIT=true
1000       jit_status="Building and using the JIT"
1001    else
1002       jit_status="Building the JIT, defaulting to the interpreter"
1003    fi
1004 else
1005    jit_status="interpreter"
1006 fi
1007
1008 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1009
1010 libsuffix=".so"
1011
1012 case "$host" in
1013      powerpc-*-darwin*)
1014         libsuffix=".dylib"
1015         ;;
1016 esac
1017 AC_SUBST(libsuffix)
1018
1019 if test ${TARGET} = ARM; then
1020         dnl ******************************************
1021         dnl *** Check to see what FPU is available ***
1022         dnl ******************************************
1023         AC_MSG_CHECKING(which FPU to use)
1024
1025         AC_TRY_COMPILE([], [
1026                 __asm__ ("ldfd f0, [r0]");
1027                 ], fpu=FPA, [
1028                         AC_TRY_COMPILE([], [
1029                                 __asm__ ("fldd d0, [r0]");
1030                         ], fpu=VFP, fpu=NONE)
1031                 ])
1032
1033         AC_MSG_RESULT($fpu)
1034         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1035         unset fpu
1036 fi
1037
1038 if test ${TARGET} = unknown; then
1039         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1040         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1041 fi
1042
1043 if test ${ACCESS_UNALIGNED} = no; then
1044         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1045 fi
1046
1047 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1048 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1049 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1050 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1051 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1052 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1053 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1054 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1055 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1056 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1057 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1058 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1059
1060 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1061
1062 AC_SUBST(LIBC)
1063
1064 AC_SUBST(arch_target)
1065 AC_SUBST(CFLAGS)
1066 AC_SUBST(CPPFLAGS)
1067 AC_SUBST(LDFLAGS)
1068
1069 AC_OUTPUT([
1070 Makefile
1071 mint.pc
1072 mono.pc
1073 mono/Makefile
1074 mono/utils/Makefile
1075 mono/metadata/Makefile
1076 mono/dis/Makefile
1077 mono/cil/Makefile
1078 mono/arch/Makefile
1079 mono/os/Makefile
1080 mono/os/win32/Makefile
1081 mono/os/unix/Makefile
1082 mono/arch/x86/Makefile
1083 mono/arch/amd64/Makefile
1084 mono/arch/hppa/Makefile
1085 mono/arch/ppc/Makefile
1086 mono/arch/sparc/Makefile
1087 mono/arch/s390/Makefile
1088 mono/arch/arm/Makefile
1089 mono/arch/alpha/Makefile
1090 mono/interpreter/Makefile
1091 mono/tests/Makefile
1092 mono/tests/tests-config
1093 mono/benchmark/Makefile
1094 mono/monoburg/Makefile
1095 mono/monograph/Makefile
1096 mono/io-layer/Makefile
1097 mono/handles/Makefile
1098 mono/mini/Makefile
1099 mono/profiler/Makefile
1100 runtime/Makefile
1101 scripts/Makefile
1102 man/Makefile
1103 web/Makefile
1104 docs/Makefile
1105 data/Makefile
1106 samples/Makefile
1107 support/Makefile
1108 data/config
1109 mono.spec
1110 ])
1111
1112 echo "
1113
1114         GC:          $gc
1115         ICU:         $enable_icu
1116         NPTL:        $with_nptl
1117         SIGALTSTACK: $with_sigaltstack
1118         Engine:      $jit_status
1119
1120 "