configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,1.2.6)
  10 AM_MAINTAINER_MODE
  11
  12 API_VER=1.0
  13 AC_SUBST(API_VER)
  14
  15 AC_PROG_LN_S
  16
  17 # In case of cygwin, override LN_S, irrespective of what it determines.
  18 # The build uses cygwin, but the actual runtime doesn't.
  19 case $host_os in
  20 *cygwin* ) LN_S='cp -p';;
  21 esac
  22
  23
  24 dnl
  25 dnl libgc checks
  26 dnl
  27
  28 gc_headers=no
  29 gc=included
  30 use_included_gc=no
  31 libgc_configure_args=
  32
  33 if test -d $srcdir/libgc ; then
  34   gc_default=included
  35 else
  36   gc_default=boehm
  37 fi
  38
  39 #
  40 # These are the flags that need to be stored in the mono.pc file for
  41 # compiling code that will embed Mono
  42 #
  43 libmono_cflags=""
  44 libmono_ldflags=""
  45 AC_SUBST(libmono_cflags)
  46 AC_SUBST(libmono_ldflags)
  47 export_ldflags=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
  48 AC_SUBST(export_ldflags)
  49
  50 # Variable to have relocatable .pc files (lib, or lib64)
  51 reloc_libdir=`basename ${libdir}`
  52 AC_SUBST(reloc_libdir)
  53
  54 dnl if linker handles the version script
  55 no_version_script=no
  56
  57 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  58 need_link_unlink=no
  59
  60 # Thread configuration inspired by sleepycat's db
  61 AC_MSG_CHECKING([host platform characteristics])
  62 libgc_threads=no
  63 case "$host" in
  64         *-*-mingw*|*-*-cygwin*)
  65                 platform_win32=yes
  66                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  67                 if test "x$cross_compiling" = "xno"; then
  68                         CC="gcc -mno-cygwin -g"
  69                         # So libgc configure gets -mno-cygwin
  70                         export CC
  71                 fi
  72                 HOST_CC="gcc"
  73                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS -DFD_SETSIZE=1024 -DUNICODE -D_UNICODE"
  74                 libmono_cflags="-mno-cygwin"
  75                 libmono_ldflags="-mno-cygwin"
  76                 libdl=
  77                 libgc_threads=win32
  78                 gc_default=included
  79                 with_sigaltstack=no
  80                 LN_S=cp
  81                 # This forces libgc to use the DllMain based thread registration code on win32
  82                 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
  83                 ;;
  84         *-*-*netbsd*)
  85                 platform_win32=no
  86                 CPPFLAGS="$CPPFLAGS -D_REENTRANT -DGC_NETBSD_THREADS -D_GNU_SOURCE"
  87                 libmono_cflags="-D_REENTRANT"
  88                 LDFLAGS="$LDFLAGS -pthread"
  89                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
  90                 libmono_ldflags="-pthread"
  91                 need_link_unlink=yes
  92                 libdl="-ldl"
  93                 libgc_threads=pthreads
  94                 with_sigaltstack=no
  95                 ;;
  96 # these flags will work for all versions of -STABLE
  97 #
  98         *-*-*freebsd4*)
  99                 platform_win32=no
 100                 if test "x$PTHREAD_CFLAGS" = "x"; then
 101                         CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 102                         libmono_cflags="-D_THREAD_SAFE"
 103                 else
 104                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 105                         libmono_cflags="$PTHREAD_CFLAGS"
 106                 fi
 107                 if test "x$PTHREAD_LIBS" = "x"; then
 108                         LDFLAGS="$LDFLAGS -pthread"
 109                         libmono_ldflags="-pthread"
 110                 else
 111                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 112                         libmono_ldflags="$PTHREAD_LIBS"
 113                 fi
 114                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD -DPLATFORM_BSD4"
 115                 need_link_unlink=yes
 116                 AC_DEFINE(PTHREAD_POINTER_ID)
 117                 libdl=
 118                 libgc_threads=pthreads
 119 # TLS isn't implemented at all on 4-STABLE
 120                 with_tls=pthread
 121                 ;;
 122         *-*-*freebsd5*)
 123                 platform_win32=no
 124                 if test "x$PTHREAD_CFLAGS" = "x"; then
 125                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 126                         libmono_cflags=
 127                 else
 128                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 129                         libmono_cflags="$PTHREAD_CFLAGS"
 130                 fi
 131                 if test "x$PTHREAD_LIBS" = "x"; then
 132                         LDFLAGS="$LDFLAGS -pthread"
 133                         libmono_ldflags="-pthread"
 134                 else
 135                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 136                         libmono_ldflags="$PTHREAD_LIBS"
 137                 fi
 138                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD -DPLATFORM_BSD5"
 139                 need_link_unlink=yes
 140                 AC_DEFINE(PTHREAD_POINTER_ID)
 141                 libdl=
 142                 with_sigaltstack=yes
 143                 libgc_threads=pthreads
 144 # TLS is only partially implemented on 5-STABLE (compiler support
 145 # but NOT library support)
 146 #
 147                 with_tls=pthread
 148                 ;;
 149         *-*-*freebsd6*)
 150                 platform_win32=no
 151                 if test "x$PTHREAD_CFLAGS" = "x"; then
 152                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 153                         libmono_cflags=
 154                 else
 155                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 156                         libmono_cflags="$PTHREAD_CFLAGS"
 157                 fi
 158                 if test "x$PTHREAD_LIBS" = "x"; then
 159                         LDFLAGS="$LDFLAGS -pthread"
 160                         libmono_ldflags="-pthread"
 161                 else
 162                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 163                         libmono_ldflags="$PTHREAD_LIBS"
 164                 fi
 165                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD -DPLATFORM_BSD6"
 166                 need_link_unlink=yes
 167                 AC_DEFINE(PTHREAD_POINTER_ID)
 168                 libdl=
 169                 libgc_threads=pthreads
 170                 with_sigaltstack=yes
 171 # TLS is only partially implemented on -CURRENT (compiler support
 172 # but NOT library support)
 173 #
 174                 with_tls=pthread
 175                 ;;
 176         *-*-*openbsd*)
 177                 platform_win32=no
 178                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 179                 libmono_cflags="-D_THREAD_SAFE"
 180                 LDFLAGS="$LDFLAGS -pthread"
 181                 libmono_ldflags="-pthread"
 182                 need_link_unlink=yes
 183                 AC_DEFINE(PTHREAD_POINTER_ID)
 184                 libdl=
 185                 libgc_threads=pthreads
 186                 ;;
 187         *-*-linux*)
 188                 platform_win32=no
 189                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP -DUSE_MUNMAP"
 190                 libmono_cflags="-D_REENTRANT"
 191                 libmono_ldflags="-lpthread"
 192                 libdl="-ldl"
 193                 libgc_threads=pthreads
 194                 ;;
 195         *-*-hpux*)
 196         platform_win32=no
 197                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 198                 # +ESdbgasm only valid on bundled cc on RISC
 199                 # silently ignored for ia64
 200                 if test $GCC != "yes"; then
 201                         CFLAGS="$CFLAGS +ESdbgasm"
 202                         # Arrange for run-time dereferencing of null
 203                         # pointers to produce a SIGSEGV signal.
 204                         LDFLAGS="$LDFLAGS -z"
 205                 fi
 206                 CFLAGS="$CFLAGS +ESdbgasm"
 207                 LDFLAGS="$LDFLAGS -z"
 208                 libmono_cflags="-D_REENTRANT"
 209                 libmono_ldflags="-lpthread"
 210                 libgc_threads=pthreads
 211                 need_link_unlink=yes
 212                 ;;
 213         *-*-solaris*)
 214                 platform_win32=no
 215                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP"
 216                 need_link_unlink=yes
 217                 libmono_cflags="-D_REENTRANT"
 218                 libgc_threads=pthreads
 219                 # This doesn't seem to work on solaris/x86, but the configure test runs
 220                 with_tls=pthread
 221                 ;;
 222         *-*-darwin*)
 223                 platform_win32=no
 224                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX -DUSE_MMAP -DUSE_MUNMAP"
 225                 CPPFLAGS="$CPPFLAGS -DGetCurrentProcess=MonoGetCurrentProcess -DGetCurrentThread=MonoGetCurrentThread -DCreateEvent=MonoCreateEvent"
 226                 libmono_cflags="-D_THREAD_SAFE"
 227                 LDFLAGS="$LDFLAGS -pthread"
 228                 libmono_ldflags="-pthread"
 229                 need_link_unlink=yes
 230                 AC_DEFINE(PTHREAD_POINTER_ID)
 231                 AC_DEFINE(USE_MACH_SEMA)
 232                 no_version_script=yes
 233                 libdl=
 234                 libgc_threads=pthreads
 235                 ;;
 236         *)
 237                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 238                 platform_win32=no
 239                 libdl="-ldl"
 240                 ;;
 241 esac
 242 AC_MSG_RESULT(ok)
 243
 244 if test x$need_link_unlink = xyes; then
 245    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 246 fi
 247
 248 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 249
 250 AC_CHECK_TOOL(CC, gcc, gcc)
 251 AC_PROG_CC
 252 AM_PROG_AS
 253 AM_PROG_CC_STDC
 254 AC_PROG_INSTALL
 255 AC_PROG_AWK
 256 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 257 : ${CCAS='$(CC)'}
 258 # Set ASFLAGS if not already set.
 259 : ${CCASFLAGS='$(CFLAGS)'}
 260 AC_SUBST(CCAS)
 261 AC_SUBST(CCASFLAGS)
 262
 263 AC_CHECK_PROG(BISON, bison,yes,no)
 264 if test "x$BISON" = "xno";
 265 then
 266         AC_MSG_ERROR([You need to install bison])
 267 fi
 268
 269 dnl may require a specific autoconf version
 270 dnl AC_PROG_CC_FOR_BUILD
 271 dnl CC_FOR_BUILD not automatically detected
 272 CC_FOR_BUILD=$CC
 273 CFLAGS_FOR_BUILD=$CFLAGS
 274 BUILD_EXEEXT=
 275 if test "x$cross_compiling" = "xyes"; then
 276         CC_FOR_BUILD=cc
 277         CFLAGS_FOR_BUILD=
 278         BUILD_EXEEXT=""
 279 fi
 280 AC_SUBST(CC_FOR_BUILD)
 281 AC_SUBST(CFLAGS_FOR_BUILD)
 282 AC_SUBST(HOST_CC)
 283 AC_SUBST(BUILD_EXEEXT)
 284
 285 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
 286
 287 # Set STDC_HEADERS
 288 AC_HEADER_STDC
 289 AC_LIBTOOL_WIN32_DLL
 290 # This causes monodis to not link correctly
 291 #AC_DISABLE_FAST_INSTALL
 292 AM_PROG_LIBTOOL
 293
 294 # Test whenever ld supports -version-script
 295 AC_PROG_LD
 296 AC_PROG_LD_GNU
 297 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 298    no_version_script=yes
 299 fi
 300
 301 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 302
 303 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h)
 304
 305 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 306 if test x$have_zlib = xyes; then
 307    AC_TRY_COMPILE([#include <zlib.h>], [
 308    void main () {
 309    #if defined(ZLIB_VERNUM) && (ZLIB_VERNUM >= 0x1230)
 310    }
 311    #else
 312    #error No good zlib found
 313    #endif
 314    ],[
 315         AC_MSG_RESULT(Using system zlib)
 316         zlib_msg="system zlib"
 317    ],[
 318         AC_MSG_RESULT(Using embedded zlib)
 319         have_zlib=no
 320         zlib_msg="bundled zlib"
 321    ])
 322 fi
 323
 324 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 325 AC_DEFINE(HAVE_ZLIB,1,[Have system zlib])
 326
 327 # for mono/metadata/debug-symfile.c
 328 AC_CHECK_HEADERS(elf.h)
 329
 330 # for support
 331 AC_CHECK_HEADERS(poll.h)
 332 AC_CHECK_HEADERS(sys/poll.h)
 333 AC_CHECK_HEADERS(sys/wait.h)
 334 AC_CHECK_HEADERS(grp.h)
 335 AC_CHECK_HEADERS(syslog.h)
 336
 337 # for mono/dis
 338 AC_CHECK_HEADERS(wchar.h)
 339 case "$host" in
 340         *-*-*freebsd6*)
 341                 AC_CHECK_HEADERS(ieeefp.h)
 342         ;;
 343         *-*-*freebsd*)
 344                 /* Only freebsd6 has a working ieeefp.h */
 345         ;;
 346         *)
 347                 AC_CHECK_HEADERS(ieeefp.h)
 348         ;;
 349 esac
 350 AC_MSG_CHECKING(for isinf)
 351 AC_TRY_LINK([#include <math.h>], [
 352         int f = isinf (1);
 353 ], [
 354         AC_MSG_RESULT(yes)
 355         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 356 ], [
 357         # We'll have to use signals
 358         AC_MSG_RESULT(no)
 359 ])
 360
 361
 362 # not 64 bit clean in cross-compile
 363 AC_CHECK_SIZEOF(void *, 4)
 364
 365 WARN=''
 366 if test x"$GCC" = xyes; then
 367         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 368                 # The runtime code does not respect ANSI C strict aliasing rules
 369                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 370
 371                 ORIG_CFLAGS=$CFLAGS
 372                 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 373                 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
 374                 AC_TRY_COMPILE([], [
 375                                                    void main () { }
 376                 ], [
 377                    AC_MSG_RESULT(yes)
 378                 ], [
 379                    AC_MSG_RESULT(no)
 380                    CFLAGS=$ORIG_CFLAGS
 381                 ])
 382 else
 383         # The Sun Forte compiler complains about inline functions that access static variables
 384         # so disable all inlining.
 385         case "$host" in
 386         *-*-solaris*)
 387                 CFLAGS="$CFLAGS -Dinline="
 388                 ;;
 389         esac
 390 fi
 391 CFLAGS="$CFLAGS -g $WARN"
 392
 393 # Where's the 'mcs' source tree?
 394 if test -d $srcdir/mcs; then
 395   mcsdir=mcs
 396 else
 397   mcsdir=../mcs
 398 fi
 399
 400 mcs_topdir='$(top_srcdir)/'$mcsdir
 401 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 402
 403 ## Maybe should also disable if mcsdir is invalid.  Let's punt the issue for now.
 404 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno && test x$enable_mcs_build != xno])
 405
 406 AC_SUBST([mcs_topdir])
 407 AC_SUBST([mcs_topdir_from_srcdir])
 408
 409 # Where's the 'olive' source tree?
 410 if test -d $srcdir/olive; then
 411   olivedir=olive
 412 else
 413   olivedir=../olive
 414 fi
 415
 416 if test -d $srcdir/$olivedir; then
 417 olive_topdir='$(top_srcdir)/'$olivedir
 418 fi
 419
 420 AC_ARG_WITH([libgdiplus],
 421         [  --with-libgdiplus=installed|sibling|<path>   Override the libgdiplus used for System.Drawing tests (defaults to NO)],
 422         [], [with_libgdiplus=installed])
 423
 424 case $with_libgdiplus in
 425 no|installed) libgdiplus_loc= ;;
 426 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
 427 /*) libgdiplus_loc=$with_libgdiplus ;;
 428 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
 429 esac
 430 AC_SUBST([libgdiplus_loc])
 431
 432 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 433 if test "x$PKG_CONFIG" = "xno"; then
 434         AC_MSG_ERROR([You need to install pkg-config])
 435 fi
 436
 437 pkg_config_path=
 438 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 439         if test x$with_crosspkgdir = "x"; then
 440                 if test -s $PKG_CONFIG_PATH; then
 441                         pkg_config_path=$PKG_CONFIG_PATH
 442                 fi
 443         else
 444                 pkg_config_path=$with_crosspkgdir
 445                 PKG_CONFIG_PATH=$pkg_config_path
 446                 export PKG_CONFIG_PATH
 447         fi
 448 )
 449
 450 AC_ARG_WITH([glib],
 451         [  --with-glib=embedded|system       Choose glib API: system or embedded (default to system)],
 452         [], [with_glib=system])
 453
 454 case $with_glib in
 455 embedded)
 456   GLIB_CFLAGS='-I$(top_srcdir)/eglib/src'
 457   GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib -lm'
 458   BUILD_GLIB_CFLAGS="$GLIB_CFLAGS"
 459   BUILD_GLIB_LIBS="$GLIB_LIBS"
 460   GMODULE_CFLAGS="$GLIB_CFLAGS"
 461   GMODULE_LIBS="$GLIB_LIBS"
 462   AC_CONFIG_SUBDIRS(eglib)
 463   ;;
 464 system)
 465   BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 466   BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 467
 468   ## Versions of dependencies
 469   GLIB_REQUIRED_VERSION=1.3.11
 470
 471   PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 472
 473   GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 474   GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 475   GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 476   GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 477   ;;
 478 *)
 479   AC_MSG_ERROR([Invalid argument to --with-glib.])
 480 esac
 481 AM_CONDITIONAL(EGLIB_BUILD, test x$with_glib = xembedded)
 482
 483 AC_SUBST(GLIB_CFLAGS)
 484 AC_SUBST(GLIB_LIBS)
 485 AC_SUBST(GMODULE_CFLAGS)
 486 AC_SUBST(GMODULE_LIBS)
 487 AC_SUBST(BUILD_GLIB_CFLAGS)
 488 AC_SUBST(BUILD_GLIB_LIBS)
 489
 490 if test x$cross_compiling$platform_win32 = xnoyes; then
 491    AC_MSG_CHECKING(for cygwin glib2-dev package)
 492    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 493       AC_MSG_RESULT(found)
 494           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 495    else
 496       AC_MSG_RESULT(not found, ok)
 497    fi
 498
 499    AC_MSG_CHECKING(for broken gwin32.h)
 500    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 501    if test -f $glib_include/glib/gwin32.h; then
 502           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 503                  AC_MSG_RESULT(failed)
 504                  hashmark='#'
 505                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 506           fi
 507    fi
 508    AC_MSG_RESULT(ok)
 509 fi
 510
 511 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 512
 513 # Enable support for fast thread-local storage
 514 # Some systems have broken support, so we allow to disable it.
 515 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 516
 517 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 518 # This does not work on some platforms (bug #55253)
 519 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 520
 521 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 522
 523 if test "x$enable_static" = "xno"; then
 524    with_static_mono=no
 525 fi
 526
 527 if test "x$platform_win32" = "xyes"; then
 528    # Boehm GC requires the runtime to be in its own dll
 529    with_static_mono=no
 530 fi
 531
 532 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 533 AC_ARG_ENABLE(mcs-build, [  --disable-mcs-build disable the build of the mcs directory], try_mcs_build=$enableval, enable_mcs_build=yes)
 534
 535 AC_ARG_WITH(xen_opt,   [  --with-xen_opt=yes,no      Enable Xen-specific behaviour],[],[with_xen_opt=yes])
 536 if test "x$with_xen_opt" = "xyes"; then
 537         AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
 538         ORIG_CFLAGS=$CFLAGS
 539         CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
 540         AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
 541         AC_TRY_COMPILE([], [
 542                                            void main () { }
 543         ], [
 544            AC_MSG_RESULT(yes)
 545         ], [
 546            AC_MSG_RESULT(no)
 547            CFLAGS=$ORIG_CFLAGS
 548         ])
 549 fi
 550
 551 DISABLED_FEATURES=none
 552
 553 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 554   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
 555   reflection_emit, large_code, logging, com, ssa, generics.],
 556 [
 557         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 558                 eval "mono_feature_disable_$feature='yes'"
 559                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 560         done
 561         DISABLED_FEATURES=$enable_minimal
 562         disabled="Disabled:    $enable_minimal"
 563 ],[])
 564
 565 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
 566
 567 if test "x$mono_feature_disable_aot" = "xyes"; then
 568         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 569 fi
 570
 571 if test "x$mono_feature_disable_profiler" = "xyes"; then
 572         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 573 fi
 574
 575 if test "x$mono_feature_disable_decimal" = "xyes"; then
 576         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 577 fi
 578
 579 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 580         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 581 fi
 582
 583 if test "x$mono_feature_disable_debug" = "xyes"; then
 584         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 585 fi
 586
 587 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 588         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 589 fi
 590
 591 if test "x$mono_feature_disable_large_code" = "xyes"; then
 592         AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
 593 fi
 594
 595 if test "x$mono_feature_disable_logging" = "xyes"; then
 596         AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
 597 fi
 598
 599 if test "x$mono_feature_disable_com" = "xyes"; then
 600         AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
 601 fi
 602
 603 if test "x$mono_feature_disable_ssa" = "xyes"; then
 604         AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
 605 fi
 606
 607 if test "x$mono_feature_disable_generics" = "xyes"; then
 608         AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
 609 fi
 610
 611 AC_MSG_CHECKING(for visibility __attribute__)
 612 AC_TRY_COMPILE([], [
 613    void __attribute__ ((visibility ("hidden"))) doit (void) {}
 614    void main () { doit (); }
 615 ], [
 616    have_visibility_hidden=yes
 617    AC_MSG_RESULT(yes)
 618 ], [
 619    have_visibility_hidden=no
 620    AC_MSG_RESULT(no)
 621 ])
 622
 623 LIBGC_CFLAGS=
 624 LIBGC_LIBS=
 625 LIBGC_STATIC_LIBS=
 626 libgc_dir=
 627 case "x$gc" in
 628         xboehm|xbohem|xyes)
 629                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 630                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 631
 632                 if test "x$found_boehm" != "xyes"; then
 633                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 634                 fi
 635                 if test "x$gc_headers" != "xyes"; then
 636                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 637                 fi
 638
 639                 AC_DEFINE(HAVE_BOEHM_GC)
 640                 AC_SUBST(HAVE_BOEHM_GC)
 641                 LIBGC_LIBS="-lgc $libdl"
 642                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 643
 644                 # AC_CHECK_FUNCS does not work for some reason...
 645                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 646                 if test "x$found_gcj_malloc" = "xyes"; then
 647                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 648                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
 649                 else
 650                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
 651                 fi
 652                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 653                 if test "x$found_gc_enable" = "xyes"; then
 654                         AC_DEFINE(HAVE_GC_ENABLE)
 655                 fi
 656                 ;;
 657
 658         xincluded)
 659                 AC_CONFIG_SUBDIRS(libgc)
 660
 661                 # Pass CPPFLAGS to libgc configure
 662                 # Maybe we should use a separate variable for this to avoid passing useless and
 663                 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
 664                 export CPPFLAGS
 665
 666                 found_boehm=yes
 667                 gc_headers=yes
 668                 use_included_gc=yes
 669                 libgc_dir=libgc
 670
 671                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 672                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 673                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 674
 675                 AC_DEFINE(HAVE_BOEHM_GC)
 676                 AC_SUBST(HAVE_BOEHM_GC)
 677
 678                 AC_DEFINE(HAVE_GC_H)
 679                 AC_DEFINE(USE_INCLUDED_LIBGC)
 680
 681                 # The included libgc contains GCJ support
 682                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 683                 AC_DEFINE(HAVE_GC_ENABLE)
 684                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
 685                 ;;
 686
 687         xsgen)
 688                 found_boehm=no
 689                 gc_headers=no
 690                 use_included_gc=no
 691                 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
 692                 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
 693                 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
 694                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
 695                 ;;
 696
 697         xnone)
 698                 AC_MSG_WARN("Compiling mono without GC.")
 699                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
 700                 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
 701                 ;;
 702         *)
 703                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 704                 ;;
 705 esac
 706
 707 AC_ARG_WITH(large-heap, [  --with-large-heap=yes,no    Enable support for GC heaps larger than 3GB], [large_heap=$withval], [large_heap=no])
 708 if test "x$large_heap" = "xyes"; then
 709    echo "FOO"
 710    CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
 711 fi
 712
 713 # tell libgc/configure about what we want
 714 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args"
 715
 716 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 717 AC_SUBST(LIBGC_CFLAGS)
 718 AC_SUBST(LIBGC_LIBS)
 719 AC_SUBST(LIBGC_STATIC_LIBS)
 720 AC_SUBST(libgc_dir)
 721
 722 dnl
 723 dnl End of libgc checks
 724 dnl
 725
 726 if test x$platform_win32 = xno; then
 727
 728         dnl dynamic loader support
 729         AC_CHECK_FUNC(dlopen, DL_LIB="",
 730                 AC_CHECK_LIB(dl, dlopen, DL_LIB="-ldl", dl_support=no)
 731         )
 732         if test x$dl_support = xno; then
 733                 AC_MSG_WARN([No dynamic loading support available])
 734         else
 735                 LIBS="$LIBS $DL_LIB"
 736                 AC_DEFINE(HAVE_DL_LOADER,1,[dlopen-based dynamic loader available])
 737                 dnl from glib's configure.in
 738                 AC_CACHE_CHECK([for preceeding underscore in symbols],
 739                         mono_cv_uscore,[
 740                         AC_TRY_RUN([#include <dlfcn.h>
 741                         int mono_underscore_test (void) { return 42; }
 742                         int main() {
 743                           void *f1 = (void*)0, *f2 = (void*)0, *handle;
 744                           handle = dlopen ((void*)0, 0);
 745                           if (handle) {
 746                             f1 = dlsym (handle, "mono_underscore_test");
 747                             f2 = dlsym (handle, "_mono_underscore_test");
 748                           } return (!f2 || f1);
 749                         }],
 750                                 [mono_cv_uscore=yes],
 751                                 [mono_cv_uscore=no],
 752                         [])
 753                 ])
 754                 if test "x$mono_cv_uscore" = "xyes"; then
 755                         MONO_DL_NEED_USCORE=1
 756                 else
 757                         MONO_DL_NEED_USCORE=0
 758                 fi
 759                 AC_SUBST(MONO_DL_NEED_USCORE)
 760                 AC_CHECK_FUNC(dlerror)
 761         fi
 762
 763         dnl ******************************************************************
 764         dnl *** Checks for the IKVM JNI interface library                  ***
 765         dnl ******************************************************************
 766         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 767
 768         ikvm_native_dir=
 769         if test x$with_ikvm_native = xyes; then
 770                 ikvm_native_dir=ikvm-native
 771                 jdk_headers_found="IKVM Native"
 772         fi
 773
 774         AC_SUBST(ikvm_native_dir)
 775
 776         AC_CHECK_HEADERS(execinfo.h)
 777
 778         AC_CHECK_FUNCS(getgrgid_r)
 779         AC_CHECK_FUNCS(getgrnam_r)
 780         AC_CHECK_FUNCS(getpwnam_r)
 781         AC_CHECK_FUNCS(getpwuid_r)
 782         AC_CHECK_FUNCS(getresuid)
 783         AC_CHECK_FUNCS(setresuid)
 784         AC_CHECK_FUNCS(kqueue)
 785         AC_CHECK_FUNCS(backtrace_symbols)
 786         AC_CHECK_FUNCS(mkstemp)
 787         AC_CHECK_FUNCS(mmap)
 788         AC_CHECK_FUNCS(madvise)
 789         AC_CHECK_FUNCS(getrusage)
 790         AC_CHECK_FUNCS(getpriority)
 791         AC_CHECK_FUNCS(setpriority)
 792
 793         AC_CHECK_FUNCS(sched_setaffinity)
 794
 795         dnl ******************************************************************
 796         dnl *** Check for large file support                               ***
 797         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 798         dnl ******************************************************************
 799
 800         # Check that off_t can represent 2**63 - 1 correctly, working around
 801         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 802         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 803         large_offt=no
 804         AC_DEFUN([LARGE_FILES], [
 805                 large_CPPFLAGS=$CPPFLAGS
 806                 CPPFLAGS="$CPPFLAGS $1"
 807                 AC_TRY_RUN([
 808                         #include <sys/types.h>
 809
 810                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 811
 812                         int main(void) {
 813                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 814                                                (BIG_OFF_T%2147483647==1));
 815                                 if(big_off_t) {
 816                                         exit(0);
 817                                 } else {
 818                                         exit(1);
 819                                 }
 820                         }
 821                 ], [
 822                         AC_MSG_RESULT(ok)
 823                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 824                         large_CPPFLAGS="$large_CPPFLAGS $1"
 825                         large_offt=yes
 826                 ], [
 827                         AC_MSG_RESULT(no)
 828                 ], "")
 829                 CPPFLAGS=$large_CPPFLAGS
 830         ])
 831
 832         AC_MSG_CHECKING(if off_t is 64 bits wide)
 833         LARGE_FILES("")
 834         if test $large_offt = no; then
 835                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 836                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 837         fi
 838         if test $large_offt = no; then
 839                 AC_MSG_WARN([No 64 bit file size support available])
 840         fi
 841
 842         dnl *****************************
 843         dnl *** Checks for libsocket  ***
 844         dnl *****************************
 845         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 846
 847         dnl *******************************
 848         dnl *** Checks for MSG_NOSIGNAL ***
 849         dnl *******************************
 850         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 851         AC_TRY_COMPILE([#include <sys/socket.h>], [
 852                 int f = MSG_NOSIGNAL;
 853         ], [
 854                 # Yes, we have it...
 855                 AC_MSG_RESULT(yes)
 856                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 857         ], [
 858                 # We'll have to use signals
 859                 AC_MSG_RESULT(no)
 860         ])
 861
 862         dnl *****************************
 863         dnl *** Checks for SOL_IP     ***
 864         dnl *****************************
 865         AC_MSG_CHECKING(for SOL_IP)
 866         AC_TRY_COMPILE([#include <netdb.h>], [
 867                 int level = SOL_IP;
 868         ], [
 869                 # Yes, we have it...
 870                 AC_MSG_RESULT(yes)
 871                 AC_DEFINE(HAVE_SOL_IP)
 872         ], [
 873                 # We'll have to use getprotobyname
 874                 AC_MSG_RESULT(no)
 875         ])
 876
 877         dnl *****************************
 878         dnl *** Checks for SOL_IPV6     ***
 879         dnl *****************************
 880         AC_MSG_CHECKING(for SOL_IPV6)
 881         AC_TRY_COMPILE([#include <netdb.h>], [
 882                 int level = SOL_IPV6;
 883         ], [
 884                 # Yes, we have it...
 885                 AC_MSG_RESULT(yes)
 886                 AC_DEFINE(HAVE_SOL_IPV6)
 887         ], [
 888                 # We'll have to use getprotobyname
 889                 AC_MSG_RESULT(no)
 890         ])
 891
 892         dnl *****************************
 893         dnl *** Checks for SOL_TCP    ***
 894         dnl *****************************
 895         AC_MSG_CHECKING(for SOL_TCP)
 896         AC_TRY_COMPILE([#include <netdb.h>], [
 897                 int level = SOL_TCP;
 898         ], [
 899                 # Yes, we have it...
 900                 AC_MSG_RESULT(yes)
 901                 AC_DEFINE(HAVE_SOL_TCP)
 902         ], [
 903                 # We'll have to use getprotobyname
 904                 AC_MSG_RESULT(no)
 905         ])
 906
 907         dnl *****************************
 908         dnl *** Checks for IP_PKTINFO ***
 909         dnl *****************************
 910         AC_MSG_CHECKING(for IP_PKTINFO)
 911         AC_TRY_COMPILE([#include <netdb.h>], [
 912                 int level = IP_PKTINFO;
 913         ], [
 914                 # Yes, we have it...
 915                 AC_MSG_RESULT(yes)
 916                 AC_DEFINE(HAVE_IP_PKTINFO)
 917         ], [
 918                 AC_MSG_RESULT(no)
 919         ])
 920
 921         dnl *****************************
 922         dnl *** Checks for IPV6_PKTINFO ***
 923         dnl *****************************
 924         AC_MSG_CHECKING(for IPV6_PKTINFO)
 925         AC_TRY_COMPILE([#include <netdb.h>], [
 926                 int level = IPV6_PKTINFO;
 927         ], [
 928                 # Yes, we have it...
 929                 AC_MSG_RESULT(yes)
 930                 AC_DEFINE(HAVE_IPV6_PKTINFO)
 931         ], [
 932                 AC_MSG_RESULT(no)
 933         ])
 934
 935         dnl **********************************
 936         dnl *** Checks for IP_DONTFRAGMENT ***
 937         dnl **********************************
 938         AC_MSG_CHECKING(for IP_DONTFRAGMENT)
 939         AC_TRY_COMPILE([#include <netdb.h>], [
 940                 int level = IP_DONTFRAGMENT;
 941         ], [
 942                 # Yes, we have it...
 943                 AC_MSG_RESULT(yes)
 944                 AC_DEFINE(HAVE_IP_DONTFRAGMENT)
 945         ], [
 946                 AC_MSG_RESULT(no)
 947         ])
 948
 949         dnl **********************************
 950         dnl *** Checks for IP_MTU_DISCOVER ***
 951         dnl **********************************
 952         AC_MSG_CHECKING(for IP_MTU_DISCOVER)
 953         AC_TRY_COMPILE([#include <netdb.h>], [
 954                 int level = IP_MTU_DISCOVER;
 955         ], [
 956                 # Yes, we have it...
 957                 AC_MSG_RESULT(yes)
 958                 AC_DEFINE(HAVE_IP_MTU_DISCOVER)
 959         ], [
 960                 AC_MSG_RESULT(no)
 961         ])
 962
 963         dnl *********************************
 964         dnl *** Check for struct ip_mreqn ***
 965         dnl *********************************
 966         AC_MSG_CHECKING(for struct ip_mreqn)
 967         AC_TRY_COMPILE([#include <netinet/in.h>], [
 968                 struct ip_mreqn mreq;
 969                 mreq.imr_address.s_addr = 0;
 970         ], [
 971                 # Yes, we have it...
 972                 AC_MSG_RESULT(yes)
 973                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 974         ], [
 975                 # We'll just have to try and use struct ip_mreq
 976                 AC_MSG_RESULT(no)
 977                 AC_MSG_CHECKING(for struct ip_mreq)
 978                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 979                         struct ip_mreq mreq;
 980                         mreq.imr_interface.s_addr = 0;
 981                 ], [
 982                         # Yes, we have it...
 983                         AC_MSG_RESULT(yes)
 984                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 985                 ], [
 986                         # No multicast support
 987                         AC_MSG_RESULT(no)
 988                 ])
 989         ])
 990
 991         dnl **********************************
 992         dnl *** Check for gethostbyname2_r ***
 993         dnl **********************************
 994         AC_MSG_CHECKING(for gethostbyname2_r)
 995                 AC_TRY_LINK([#include <netdb.h>], [
 996                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 997         ], [
 998                 # Yes, we have it...
 999                 AC_MSG_RESULT(yes)
1000                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
1001         ], [
1002                 AC_MSG_RESULT(no)
1003         ])
1004
1005         dnl *****************************
1006         dnl *** Checks for libnsl     ***
1007         dnl *****************************
1008         AC_CHECK_FUNC(gethostbyaddr, , AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl"))
1009
1010         AC_CHECK_FUNCS(inet_pton inet_aton)
1011
1012         dnl ***********************************************
1013         dnl *** Checks for size of sockaddr_un.sun_path ***
1014         dnl ***********************************************
1015         # AC_CHECK_SIZEOF can't cope with struct members :-(
1016         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
1017         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
1018                 [AC_TRY_RUN([
1019                         #include <sys/types.h>
1020                         #include <stdio.h>
1021                         #include <sys/un.h>
1022
1023                         int main(void) {
1024                                 struct sockaddr_un sock_un;
1025                                 FILE *f=fopen("conftestval", "w");
1026                                 if(!f) exit(1);
1027                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
1028                                 exit(0);
1029                         }
1030                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
1031                    cv_mono_sizeof_sunpath=0,
1032                    cv_mono_sizeof_sunpath=0)])dnl
1033         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
1034         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
1035
1036         dnl *************************************
1037         dnl *** Checks for zero length arrays ***
1038         dnl *************************************
1039         AC_MSG_CHECKING(whether $CC supports zero length arrays)
1040         AC_TRY_COMPILE([
1041                 struct s {
1042                         int  length;
1043                         char data [0];
1044                 };
1045         ], [], [
1046                 AC_MSG_RESULT(yes)
1047                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
1048         ], [
1049                 AC_MSG_RESULT(no)
1050                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
1051         ])
1052
1053         dnl *****************************
1054         dnl *** Checks for libxnet    ***
1055         dnl *****************************
1056         case "${host}" in
1057                 *solaris* )
1058                         AC_MSG_CHECKING(for Solaris XPG4 support)
1059                         if test -f /usr/lib/libxnet.so; then
1060                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
1061                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
1062                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
1063                                 LIBS="$LIBS -lxnet"
1064                                 AC_MSG_RESULT(yes)
1065                         else
1066                                 AC_MSG_RESULT(no)
1067                         fi
1068
1069                         if test "$GCC" = "yes"; then
1070                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
1071                         fi
1072                 ;;
1073         esac
1074
1075         dnl *****************************
1076         dnl *** Checks for libpthread ***
1077         dnl *****************************
1078 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
1079 # and libpthread does not exist
1080 #
1081         case "${host}" in
1082                 *-*-*freebsd4*)
1083                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1084                 ;;
1085                 *-*-*freebsd5*)
1086                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1087                 ;;
1088                 *-*-*freebsd6*)
1089                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
1090                 ;;
1091                 *)
1092                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
1093                 ;;
1094         esac
1095         AC_CHECK_HEADERS(pthread.h)
1096         AC_CHECK_FUNCS(pthread_mutex_timedlock)
1097         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
1098         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
1099         AC_TRY_COMPILE([ #include <pthread.h>], [
1100                 pthread_mutexattr_t attr;
1101                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
1102         ], [
1103                 AC_MSG_RESULT(ok)
1104         ], [
1105                 AC_MSG_RESULT(no)
1106                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1107                 AC_DEFINE(USE_MONO_MUTEX)
1108         ])
1109         AC_CHECK_FUNCS(pthread_attr_setstacksize)
1110         AC_CHECK_FUNCS(pthread_attr_getstack)
1111         AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1112
1113         dnl ***********************************
1114         dnl *** Checks for working __thread ***
1115         dnl ***********************************
1116         AC_MSG_CHECKING(for working __thread)
1117         if test "x$with_tls" != "x__thread"; then
1118                 AC_MSG_RESULT(disabled)
1119         else
1120                 AC_TRY_RUN([
1121                         #include <pthread.h>
1122                         __thread int i;
1123                         static int res1, res2;
1124
1125                         void thread_main (void *arg)
1126                         {
1127                                 i = arg;
1128                                 sleep (1);
1129                                 if (arg == 1)
1130                                         res1 = (i == arg);
1131                                 else
1132                                         res2 = (i == arg);
1133                         }
1134
1135                         int main () {
1136                                 pthread_t t1, t2;
1137
1138                                 i = 5;
1139
1140                                 pthread_create (&t1, NULL, thread_main, 1);
1141                                 pthread_create (&t2, NULL, thread_main, 2);
1142
1143                                 pthread_join (t1, NULL);
1144                                 pthread_join (t2, NULL);
1145
1146                                 return !(res1 + res2 == 2);
1147                         }
1148                 ], [
1149                                 AC_MSG_RESULT(yes)
1150                 ], [
1151                                 AC_MSG_RESULT(no)
1152                                 with_tls=pthread
1153                 ])
1154         fi
1155
1156         dnl **************************************
1157         dnl *** Checks for working sigaltstack ***
1158         dnl **************************************
1159         AC_MSG_CHECKING(for working sigaltstack)
1160         if test "x$with_sigaltstack" != "xyes"; then
1161                 AC_MSG_RESULT(disabled)
1162         else
1163                 AC_TRY_RUN([
1164                         #include <stdio.h>
1165                         #include <stdlib.h>
1166                         #include <unistd.h>
1167                         #include <signal.h>
1168                         #include <pthread.h>
1169                         #include <sys/wait.h>
1170                         #if defined(__FreeBSD__) || defined(__NetBSD__)
1171                         #define SA_STACK SA_ONSTACK
1172                         #endif
1173                         static void
1174                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1175                         {
1176                                 exit (0);
1177                         }
1178
1179                         static void *
1180                         loop (void *ignored)
1181                         {
1182                                 char *ptr = NULL;
1183
1184                                 *ptr = 0;
1185                                 return NULL;
1186                         }
1187
1188                         static void
1189                         child ()
1190                         {
1191                                 struct sigaction sa;
1192                                 struct sigaltstack sas;
1193                                 pthread_t id;
1194                                 pthread_attr_t attr;
1195
1196                                 sa.sa_sigaction = sigsegv_signal_handler;
1197                                 sigemptyset (&sa.sa_mask);
1198                                 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1199                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1200                                         perror ("sigaction");
1201                                         return;
1202                                 }
1203
1204                                 sas.ss_sp = malloc (SIGSTKSZ);
1205                                 sas.ss_size = SIGSTKSZ;
1206                                 sas.ss_flags = 0;
1207                                 if (sigaltstack (&sas, NULL) == -1) {
1208                                         perror ("sigaltstack");
1209                                         return;
1210                                 }
1211
1212                                 pthread_attr_init (&attr);
1213                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1214                                         printf ("pthread_create\n");
1215                                         return;
1216                                 }
1217
1218                                 sleep (100);
1219                         }
1220
1221                         int
1222                         main ()
1223                         {
1224                                 pid_t son;
1225                                 int status;
1226                                 int i;
1227
1228                                 son = fork ();
1229                                 if (son == -1) {
1230                                         return 1;
1231                                 }
1232
1233                                 if (son == 0) {
1234                                         child ();
1235                                         return 0;
1236                                 }
1237
1238                                 for (i = 0; i < 3; ++i) {
1239                                         sleep (1);
1240                                         waitpid (son, &status, WNOHANG);
1241                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1242                                                 return 0;
1243                                 }
1244
1245                                 kill (son, SIGKILL);
1246                                 return 1;
1247                         }
1248
1249                 ], [
1250                                 AC_MSG_RESULT(yes)
1251                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
1252                 ], [
1253                                 with_sigaltstack=no
1254                                 AC_MSG_RESULT(no)
1255                 ])
1256         fi
1257
1258         dnl ********************************
1259         dnl *** Checks for semaphore lib ***
1260         dnl ********************************
1261         # 'Real Time' functions on Solaris
1262         # posix4 on Solaris 2.6
1263         # pthread (first!) on Linux
1264         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1265
1266         dnl ********************************
1267         dnl *** Checks for timezone stuff **
1268         dnl ********************************
1269         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1270                 AC_TRY_COMPILE([
1271                         #include <time.h>
1272                         ], [
1273                         struct tm tm;
1274                         tm.tm_gmtoff = 1;
1275                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1276         if test $ac_cv_struct_tm_gmtoff = yes; then
1277                 AC_DEFINE(HAVE_TM_GMTOFF)
1278         else
1279                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1280                         AC_TRY_COMPILE([
1281                                 #include <time.h>
1282                         ], [
1283                                 timezone = 1;
1284                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1285                 if test $ac_cv_var_timezone = yes; then
1286                         AC_DEFINE(HAVE_TIMEZONE)
1287                 else
1288                         AC_ERROR(unable to find a way to determine timezone)
1289                 fi
1290         fi
1291
1292         dnl *********************************
1293         dnl *** Checks for math functions ***
1294         dnl *********************************
1295         LIBS="$LIBS -lm";
1296         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1297                 AC_TRY_LINK([#include <math.h>],
1298                 [ finite(0.0); ],
1299                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
1300                 AC_MSG_RESULT(no)))
1301         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1302                 AC_TRY_LINK([#include <math.h>],
1303                 [ isfinite(0.0); ],
1304                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
1305                 AC_MSG_RESULT(no)))
1306
1307         dnl ****************************************************************
1308         dnl *** Checks for working poll() (macosx defines it but doesn't ***
1309         dnl *** have it in the library (duh))                            ***
1310         dnl ****************************************************************
1311         AC_CHECK_FUNCS(poll)
1312
1313         dnl *************************
1314         dnl *** Check for signbit ***
1315         dnl *************************
1316         AC_MSG_CHECKING(for signbit)
1317         AC_TRY_LINK([#include <math.h>], [
1318                 int s = signbit(1.0);
1319         ], [
1320                 AC_MSG_RESULT(yes)
1321                 AC_DEFINE(HAVE_SIGNBIT)
1322         ], [
1323                 AC_MSG_RESULT(no)
1324         ])
1325
1326         dnl **********************************
1327         dnl *** epoll                      ***
1328         dnl **********************************
1329         AC_CHECK_HEADERS(sys/epoll.h)
1330         haveepoll=no
1331         AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1332         if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1333                 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1334         fi
1335
1336         dnl ******************************
1337         dnl *** Checks for SIOCGIFCONF ***
1338         dnl ******************************
1339         AC_CHECK_HEADERS(sys/ioctl.h)
1340         AC_CHECK_HEADERS(net/if.h)
1341         AC_MSG_CHECKING(for ifreq)
1342         AC_TRY_COMPILE([
1343                 #include <sys/ioctl.h>
1344                 #include <net/if.h>
1345                 ], [
1346                 struct ifconf ifc;
1347                 struct ifreq *ifr;
1348                 void *x;
1349                 ifc.ifc_len = 0;
1350                 ifc.ifc_buf = NULL;
1351                 x = (void *) &ifr->ifr_addr;
1352                 ],[
1353                         AC_MSG_RESULT(yes)
1354                         AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1355                 ], [
1356                         AC_MSG_RESULT(no)
1357                 ])
1358         dnl **********************************
1359         dnl ***     Checks for sin_len     ***
1360         dnl **********************************
1361         AC_MSG_CHECKING(for sockaddr_in.sin_len)
1362         AC_TRY_COMPILE([
1363                 #include <netinet/in.h>
1364                 ], [
1365                 struct sockaddr_in saddr;
1366                 saddr.sin_len = sizeof (saddr);
1367                 ],[
1368                         AC_MSG_RESULT(yes)
1369                         AC_DEFINE(HAVE_SOCKADDR_IN_SIN_LEN, 1, [sockaddr_in has sin_len])
1370                 ], [
1371                         AC_MSG_RESULT(no)
1372                 ])
1373         dnl **********************************
1374         dnl ***    Checks for sin6_len     ***
1375         dnl **********************************
1376         AC_MSG_CHECKING(for sockaddr_in6.sin6_len)
1377         AC_TRY_COMPILE([
1378                 #include <netinet/in.h>
1379                 ], [
1380                 struct sockaddr_in6 saddr6;
1381                 saddr6.sin6_len = sizeof (saddr6);
1382                 ],[
1383                         AC_MSG_RESULT(yes)
1384                         AC_DEFINE(HAVE_SOCKADDR_IN6_SIN_LEN, 1, [sockaddr_in6 has sin6_len])
1385                 ], [
1386                         AC_MSG_RESULT(no)
1387                 ])
1388         dnl **********************************
1389         dnl *** Checks for MonoPosixHelper ***
1390         dnl **********************************
1391         AC_CHECK_HEADERS(checklist.h)
1392         AC_CHECK_HEADERS(fstab.h)
1393         AC_CHECK_HEADERS(attr/xattr.h)
1394         AC_CHECK_HEADERS(sys/extattr.h)
1395         AC_CHECK_HEADERS(sys/sendfile.h)
1396         AC_CHECK_HEADERS(sys/statvfs.h)
1397         AC_CHECK_HEADERS(sys/vfstab.h)
1398         AC_CHECK_HEADERS(sys/xattr.h)
1399         AC_CHECK_HEADERS(sys/mman.h)
1400         AC_CHECK_FUNCS(getdomainname)
1401         AC_CHECK_FUNCS(setdomainname)
1402         AC_CHECK_FUNCS(fgetgrent)
1403         AC_CHECK_FUNCS(fgetpwent)
1404         AC_CHECK_FUNCS(fgetpwent)
1405         AC_CHECK_FUNCS(getfsstat)
1406         AC_CHECK_FUNCS(lutimes)
1407         AC_CHECK_FUNCS(mremap)
1408         AC_CHECK_FUNCS(remap_file_pages)
1409         AC_CHECK_FUNCS(posix_fadvise)
1410         AC_CHECK_FUNCS(posix_fallocate)
1411         AC_CHECK_FUNCS(posix_madvise)
1412         AC_CHECK_FUNCS(vsnprintf)
1413         AC_CHECK_FUNCS(sendfile)
1414         AC_CHECK_FUNCS(sethostid)
1415         AC_CHECK_FUNCS(statfs)
1416         AC_CHECK_FUNCS(fstatfs)
1417         AC_CHECK_FUNCS(statvfs)
1418         AC_CHECK_FUNCS(fstatvfs)
1419         AC_CHECK_FUNCS(stime)
1420         AC_CHECK_FUNCS(strerror_r)
1421         AC_CHECK_FUNCS(ttyname_r)
1422         AC_CHECK_SIZEOF(size_t)
1423         AC_CHECK_TYPES([blksize_t], [AC_DEFINE(HAVE_BLKSIZE_T)], ,
1424                 [#include <sys/types.h>
1425                  #include <sys/stat.h>
1426                  #include <unistd.h>])
1427         AC_CHECK_TYPES([blkcnt_t], [AC_DEFINE(HAVE_BLKCNT_T)], ,
1428                 [#include <sys/types.h>
1429                  #include <sys/stat.h>
1430                  #include <unistd.h>])
1431         AC_CHECK_TYPES([suseconds_t], [AC_DEFINE(HAVE_SUSECONDS_T)], ,
1432                 [#include <sys/time.h>])
1433         AC_CHECK_TYPES([struct pollfd], [AC_DEFINE(HAVE_STRUCT_POLLFD)], ,
1434                 [#include <sys/poll.h>])
1435         AC_CHECK_TYPES([struct stat], [AC_DEFINE(HAVE_STRUCT_STAT)], ,
1436                 [#include <sys/types.h>
1437                  #include <sys/stat.h>
1438                  #include <unistd.h>])
1439         AC_CHECK_TYPES([struct timeval], [AC_DEFINE(HAVE_STRUCT_TIMEVAL)], ,
1440                 [#include <sys/time.h>
1441                  #include <sys/types.h>
1442                  #include <utime.h>])
1443         AC_CHECK_TYPES([struct timezone], [AC_DEFINE(HAVE_STRUCT_TIMEZONE)], ,
1444                 [#include <sys/time.h>])
1445         AC_CHECK_TYPES([struct utimbuf], [AC_DEFINE(HAVE_STRUCT_UTIMBUF)], ,
1446                 [#include <sys/types.h>
1447                  #include <utime.h>])
1448         AC_CHECK_MEMBERS(
1449                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1450                 [#include <sys/types.h>
1451                  #include <dirent.h>])
1452
1453         dnl Favour xattr through glibc, but use libattr if we have to
1454         AC_CHECK_FUNC(lsetxattr, ,
1455                 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1456         )
1457         AC_SUBST(XATTR_LIB)
1458
1459         dnl *********************************
1460         dnl *** Checks for Windows compilation ***
1461         dnl *********************************
1462         AC_CHECK_HEADERS(sys/time.h)
1463         AC_CHECK_HEADERS(sys/param.h)
1464
1465         dnl *********************************
1466         dnl *** Check for Console 2.0 I/O ***
1467         dnl *********************************
1468         AC_CHECK_HEADERS([curses.h])
1469         AC_CHECK_HEADERS([term.h], [], [],
1470         [#if HAVE_CURSES_H
1471          #include <curses.h>
1472          #endif
1473         ])
1474         AC_CHECK_HEADERS([termios.h])
1475
1476         dnl * This is provided in io-layer, but on windows it's only available
1477         dnl * on xp+
1478         AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1479 else
1480         jdk_headers_found=no
1481         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1482         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1483         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1484         AC_CHECK_LIB(winmm, main, LIBS="$LIBS -lwinmm", AC_ERROR(bad mingw install?))
1485         AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1486         AC_CHECK_LIB(advapi32, main, LIBS="$LIBS -ladvapi32", AC_ERROR(bad mingw install?))
1487
1488         dnl *********************************
1489         dnl *** Check for struct ip_mreqn ***
1490         dnl *********************************
1491         AC_MSG_CHECKING(for struct ip_mreqn)
1492         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1493                 struct ip_mreqn mreq;
1494                 mreq.imr_address.s_addr = 0;
1495         ], [
1496                 # Yes, we have it...
1497                 AC_MSG_RESULT(yes)
1498                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1499         ], [
1500                 # We'll just have to try and use struct ip_mreq
1501                 AC_MSG_RESULT(no)
1502                 AC_MSG_CHECKING(for struct ip_mreq)
1503                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1504                         struct ip_mreq mreq;
1505                         mreq.imr_interface.s_addr = 0;
1506                 ], [
1507                         # Yes, we have it...
1508                         AC_MSG_RESULT(yes)
1509                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1510                 ], [
1511                         # No multicast support
1512                         AC_MSG_RESULT(no)
1513                 ])
1514         ])
1515         AC_CHECK_FUNCS(GetProcessId)
1516 fi
1517
1518 dnl socklen_t check
1519 AC_MSG_CHECKING(for socklen_t)
1520 AC_TRY_COMPILE([
1521 #include <sys/types.h>
1522 #include <sys/socket.h>
1523 ],[
1524   socklen_t foo;
1525 ],[
1526 ac_cv_c_socklen_t=yes
1527         AC_DEFINE(HAVE_SOCKLEN_T)
1528         AC_MSG_RESULT(yes)
1529 ],[
1530         AC_MSG_RESULT(no)
1531 ])
1532
1533 AC_MSG_CHECKING(for array element initalizer support)
1534 AC_TRY_COMPILE([#include <sys/socket.h>], [
1535         const int array[] = {[1] = 2,};
1536 ], [
1537         # Yes, we have it...
1538         AC_MSG_RESULT(yes)
1539         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1540 ], [
1541         # We'll have to use signals
1542         AC_MSG_RESULT(no)
1543 ])
1544
1545 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1546         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1547         AC_TRY_LINK([#include <math.h>],
1548         [ static void *p = &trunc; ],
1549         [
1550                 AC_DEFINE(HAVE_TRUNC)
1551                 AC_MSG_RESULT(yes)
1552                 ac_cv_trunc=yes
1553         ],
1554         AC_MSG_RESULT(no)))
1555
1556 if test "x$ac_cv_truncl" != "xyes"; then
1557    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1558 fi
1559
1560 dnl ****************************
1561 dnl *** Look for /dev/random ***
1562 dnl ****************************
1563
1564 AC_MSG_CHECKING([if usage of random device is requested])
1565 AC_ARG_ENABLE(dev-random,
1566 [  --disable-dev-random    disable the use of the random device],
1567 try_dev_random=$enableval, try_dev_random=yes)
1568 AC_MSG_RESULT($try_dev_random)
1569
1570 case "{$target}" in
1571     *-openbsd*)
1572     NAME_DEV_RANDOM="/dev/srandom"
1573     ;;
1574
1575 dnl Win32 does not have /dev/random, they have their own method...
1576
1577     *-*-mingw*|*-*-cygwin*)
1578     ac_cv_have_dev_random=no
1579     ;;
1580
1581 dnl Everywhere else, it's /dev/random
1582
1583     *)
1584     NAME_DEV_RANDOM="/dev/random"
1585     ;;
1586 esac
1587
1588 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1589
1590 dnl Now check if the device actually exists
1591
1592 if test "x$try_dev_random" = "xyes"; then
1593     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1594     [if test -r "$NAME_DEV_RANDOM" ; then
1595         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1596     if test "x$ac_cv_have_dev_random" = "xyes"; then
1597         AC_DEFINE(HAVE_CRYPT_RNG)
1598     fi
1599 else
1600     AC_MSG_CHECKING(for random device)
1601     ac_cv_have_dev_random=no
1602     AC_MSG_RESULT(has been disabled)
1603 fi
1604
1605 if test "x$platform_win32" = "xyes"; then
1606     AC_DEFINE(HAVE_CRYPT_RNG)
1607 fi
1608
1609 if test "x$ac_cv_have_dev_random" = "xno" \
1610     && test "x$platform_win32" = "xno"; then
1611     AC_MSG_WARN([[
1612 ***
1613 *** A system-provided entropy source was not found on this system.
1614 *** Because of this, the System.Security.Cryptography random number generator
1615 *** will throw a NotImplemented exception.
1616 ***
1617 *** If you are seeing this message, and you know your system DOES have an
1618 *** entropy collection in place, please contact <crichton@gimp.org> and
1619 *** provide information about the system and how to access the random device.
1620 ***
1621 *** Otherwise you can install either egd or prngd and set the environment
1622 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1623 ***]])
1624 fi
1625
1626 AC_MSG_CHECKING([if inter-process shared handles are requested])
1627 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1628 AC_MSG_RESULT($try_shared_handles)
1629 if test "x$try_shared_handles" != "xyes"; then
1630         AC_DEFINE(DISABLE_SHARED_HANDLES)
1631         AC_SUBST(DISABLE_SHARED_HANDLES)
1632 fi
1633
1634 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1635 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1636
1637 TARGET="unknown"
1638 ACCESS_UNALIGNED="yes"
1639
1640 JIT_SUPPORTED=no
1641 INTERP_SUPPORTED=no
1642 LIBC="libc.so.6"
1643 INTL="libc.so.6"
1644 SQLITE="libsqlite.so.0"
1645 SQLITE3="libsqlite3.so.0"
1646 X11="libX11.so"
1647
1648 jit_wanted=false
1649 interp_wanted=false
1650 case "$host" in
1651 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1652 #               TARGET=MIPS;
1653 #               ACCESS_UNALIGNED="no"
1654 #               ;;
1655         mips*)
1656                 TARGET=MIPS;
1657                 arch_target=mips;
1658                 ACCESS_UNALIGNED="no"
1659                 JIT_SUPPORTED=yes
1660                 jit_wanted=true
1661                 ;;
1662         i*86-*-*)
1663                 TARGET=X86;
1664                 arch_target=x86;
1665                 JIT_SUPPORTED=yes
1666                 jit_wanted=true
1667                 case $host_os in
1668                   solaris*)
1669                         LIBC="libc.so"
1670                         INTL="libintl.so"
1671                         if test "x$ac_cv_sizeof_void_p" = "x8"; then
1672                                 TARGET=AMD64
1673                                 arch_target=amd64
1674                         fi
1675
1676                         # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
1677                         # int astruct __attribute__ ((visibility ("hidden")));
1678                         # void foo ()
1679                         # {
1680                         #       void *p = &astruct;
1681                         # }
1682                         # gcc -fPIC --shared -o libfoo.so foo.c
1683                         # yields:
1684                         # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
1685                         # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
1686                         have_visibility_hidden=no
1687
1688                 esac
1689                 ;;
1690         x86_64-*-* | amd64-*-*)
1691                 TARGET=AMD64;
1692                 arch_target=amd64;
1693                 JIT_SUPPORTED=yes
1694                 jit_wanted=true
1695                 ;;
1696         ia64-*-*)
1697                 TARGET=IA64
1698                 arch_target=ia64
1699                 ACCESS_UNALIGNED="no"
1700                 JIT_SUPPORTED=yes
1701                 jit_wanted=true
1702                 LIBC="libc.so.6.1"
1703                 INTL="libc.so.6.1"
1704                 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
1705                 libmono_ldflags="-lunwind"
1706                 ;;
1707         sparc*-*-*)
1708                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1709                    TARGET=SPARC64
1710                 else
1711                         TARGET=SPARC
1712                 fi
1713                 arch_target=sparc;
1714                 JIT_SUPPORTED=yes
1715                 ACCESS_UNALIGNED="no"
1716                 case $host_os in
1717                   linux*) ;;
1718                   *)
1719                         LIBC="libc.so"
1720                         INTL="libintl.so"
1721                 esac
1722                 jit_wanted=true
1723                 if test x"$GCC" = xyes; then
1724                         # We don't support v8 cpus
1725                         CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
1726                 fi
1727                 if test x"$AR" = xfalse; then
1728                         AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
1729                 fi
1730                 ;;
1731        alpha*-*-linux* | alpha*-*-osf*)
1732                 TARGET=ALPHA;
1733                 ACCESS_UNALIGNED="no"
1734                 JIT_SUPPORTED=yes
1735                 jit_wanted=true
1736                 arch_target=alpha;
1737                 CFLAGS="$CFLAGS -mieee -O0"
1738                 case $host_os in
1739                   linux*)
1740                         LIBC="libc.so.6.1"
1741                         INTL="libc.so.6.1"
1742                 esac
1743                ;;
1744         *-*-mingw*|*-*-cygwin*)
1745                 # When this is enabled, it leads to very strange crashes at runtime (gcc-3.4.4)
1746                 have_visibility_hidden=no
1747                 INTL="intl"
1748                 ;;
1749         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1750                 TARGET=HPPA;
1751                 arch_target=hppa;
1752                 LIBC="libc.sl"
1753                 ACCESS_UNALIGNED="no"
1754                 INTERP_SUPPORTED=yes
1755                 interp_wanted=true
1756                 ;;
1757         hppa*linux*)
1758                 TARGET=HPPA;
1759                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1760                 arch_target=hppa;
1761                 ACCESS_UNALIGNED="no"
1762                 JIT_SUPPORTED=yes
1763                 jit_wanted=true
1764                 ;;
1765         macppc-*-openbsd* | powerpc*-*-linux* | powerpc-*-openbsd* | \
1766         powerpc-*-sysv* | powerpc-*-darwin* | powerpc-*-netbsd* )
1767                 TARGET=POWERPC;
1768                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1769                 arch_target=ppc;
1770                 JIT_SUPPORTED=yes
1771                 jit_wanted=true
1772                 ;;
1773         arm*-linux*)
1774                 TARGET=ARM;
1775                 arch_target=arm;
1776                 ACCESS_UNALIGNED="no"
1777                 JIT_SUPPORTED=yes
1778                 jit_wanted=true
1779                 ;;
1780         s390-*-linux*)
1781                 TARGET=S390;
1782                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1783                 arch_target=s390;
1784                 ACCESS_UNALIGNED="no"
1785                 JIT_SUPPORTED=yes
1786                 jit_wanted=true
1787                 # Required CFLAGS for s390[x].  USE_STRING_INLINES is automatic with gcc 4.1
1788                 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
1789                 ;;
1790         s390x-*-linux*)
1791                 TARGET=S390x;
1792                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1793                 arch_target=s390x;
1794                 ACCESS_UNALIGNED="no"
1795                 JIT_SUPPORTED=yes
1796                 jit_wanted=true
1797                 CFLAGS="$CFLAGS -mbackchain -D__USE_STRING_INLINES"
1798                 ;;
1799 esac
1800
1801 if test "x$have_visibility_hidden" = "xyes"; then
1802    AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
1803 fi
1804
1805 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1806         if test x$withval = xyes; then
1807            jit_wanted=true
1808         else
1809            jit_wanted=false
1810         fi
1811 ])
1812
1813 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1814         if test x$withval = xyes; then
1815            interp_wanted=true
1816         else
1817            interp_wanted=false
1818         fi
1819 ])
1820
1821 USEJIT=false
1822 if test x$JIT_SUPPORTED = xyes; then
1823    if $jit_wanted; then
1824       USEJIT=true
1825       jit_status="Building and using the JIT"
1826    else
1827       if $interp_wanted; then
1828          jit_status="Building the JIT, defaulting to the interpreter"
1829       else
1830          AC_ERROR(No JIT or interpreter support available or selected.)
1831       fi
1832    fi
1833 else
1834    if test x$interp_wanted = xtrue; then
1835       jit_status="interpreter"
1836    else
1837       AC_ERROR(No JIT or interpreter support available or selected.)
1838    fi
1839 fi
1840
1841 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1842
1843 libsuffix=".so"
1844
1845 case "$host" in
1846      *-*-darwin*)
1847         libsuffix=".dylib"
1848         LIBC="libc.dylib"
1849         INTL="libintl.dylib"
1850         SQLITE="libsqlite.0.dylib"
1851         SQLITE3="libsqlite3.0.dylib"
1852         X11="libX11.dylib"
1853         ;;
1854      *-*-*netbsd*)
1855         LIBC="libc.so.12"
1856         INTL="libintl.so.0"
1857         ;;
1858     *-*-*freebsd*)
1859         LIBC="libc.so"
1860         INTL="libintl.so"
1861         ;;
1862     *-*-*openbsd*)
1863         LIBC="libc.so"
1864         INTL="libintl.so"
1865         ;;
1866     *-*-*linux*)
1867         AC_PATH_X
1868         AC_MSG_CHECKING(for the soname of libX11.so)
1869         for i in $x_libraries /usr/lib /usr/lib64; do
1870                 for r in 4 5 6; do
1871                         if test -f $i/libX11.so.$r; then
1872                                 X11=libX11.so.$r
1873                                 AC_MSG_RESULT($X11)
1874                         fi
1875                 done
1876         done
1877
1878         if test "x$X11" = "xlibX11.so"; then
1879                 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
1880         fi
1881         ;;
1882 esac
1883
1884
1885 AC_SUBST(libsuffix)
1886
1887 if test "x$TARGET" != "xAMD64"; then
1888    # valgrind headers don't compile under x86-64
1889    AC_CHECK_HEADERS(valgrind/memcheck.h)
1890 fi
1891
1892 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1893         if test "x$with_tls" = "x__thread"; then
1894                 #
1895                 # On some linux distributions, TLS works in executables, but linking
1896                 # against a shared library containing TLS fails with:
1897                 # undefined reference to `__tls_get_addr'
1898                 #
1899                 rm -f conftest.c conftest.so conftest
1900                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1901                 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1902                 $CC -o conftest conftest.so > /dev/null 2>&1
1903                 if test ! -f conftest; then
1904                    AC_MSG_WARN([Disabling usage of __thread.]);
1905                    with_tls=pthread
1906                 fi
1907                 rm -f conftest.c conftest.so conftest
1908         fi
1909 fi
1910
1911 mono_debugger_supported=no
1912 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86" -o "x$TARGET" = "xALPHA"; then
1913         if test x$use_included_gc = xyes; then
1914                 case "$host" in
1915                 *-*-*linux*)
1916                         mono_debugger_supported=yes
1917                         ;;
1918                 esac
1919         fi
1920 fi
1921
1922 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
1923 if test "x$mono_debugger_supported" = "xyes"; then
1924         AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
1925 fi
1926 AC_MSG_RESULT($mono_debugger_supported)
1927 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
1928
1929 if test "x$with_tls" = "x__thread"; then
1930         AC_DEFINE(HAVE_KW_THREAD)
1931         # Pass the information to libgc
1932         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1933         AC_MSG_CHECKING(if the tls_model attribute is supported)
1934         AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
1935                 ], [
1936                         AC_MSG_RESULT(yes)
1937                         AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
1938                 ], [
1939                         AC_MSG_RESULT(no)
1940         ])
1941 fi
1942
1943 if test ${TARGET} = ARM; then
1944         dnl ******************************************
1945         dnl *** Check to see what FPU is available ***
1946         dnl ******************************************
1947         AC_MSG_CHECKING(which FPU to use)
1948
1949         AC_TRY_COMPILE([], [
1950                 __asm__ ("ldfd f0, [r0]");
1951                 ], fpu=FPA, fpu=NONE)
1952
1953         AC_MSG_RESULT($fpu)
1954         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu=1"
1955         unset fpu
1956 fi
1957
1958 if test ${TARGET} = unknown; then
1959         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1960         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1961 fi
1962
1963 if test ${ACCESS_UNALIGNED} = no; then
1964         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1965 fi
1966
1967 PREVIEW=yes
1968 AC_ARG_WITH(preview,  [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1969         if test x$with_preview = xno; then
1970               PREVIEW=no
1971         fi
1972 ])
1973
1974 MOONLIGHT=no
1975 AC_ARG_WITH(moonlight,[ --with-moonlight=yes,no   If you want to build the Moonlight 2.1 assemblies],[
1976         if test x$with_moonlight = xyes; then
1977               MOONLIGHT=yes
1978         fi
1979 ])
1980
1981 libmono_ldflags="$libmono_ldflags $LIBS"
1982
1983 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1984 AM_CONDITIONAL(INSTALL_2_1, test x$MOONLIGHT = xyes)
1985
1986 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1987 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1988 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1989 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1990 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1991 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1992 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1993 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1994 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1995 AM_CONDITIONAL(MIPS, test x$TARGET = xMIPS)
1996 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1997 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1998 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1999 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
2000 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
2001
2002 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
2003 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
2004 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
2005
2006 AC_SUBST(LIBC)
2007 AC_SUBST(INTL)
2008 AC_SUBST(SQLITE)
2009 AC_SUBST(SQLITE3)
2010 AC_SUBST(X11)
2011 AC_DEFINE_UNQUOTED(ARCHITECTURE,"$arch_target",[The architecture this is running on])
2012 AC_SUBST(arch_target)
2013 AC_SUBST(CFLAGS)
2014 AC_SUBST(CPPFLAGS)
2015 AC_SUBST(LDFLAGS)
2016
2017 mono_build_root=`pwd`
2018 AC_SUBST(mono_build_root)
2019
2020 if test x$USEJIT = xtrue; then
2021   mono_runtime=mono/mini/mono
2022 else
2023   mono_runtime=mono/interpreter/mint
2024 fi
2025 AC_SUBST(mono_runtime)
2026
2027 mono_cfg_root=$mono_build_root/runtime
2028 if test x$platform_win32 = xyes; then
2029   mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
2030 else
2031   mono_cfg_dir=$mono_cfg_root/etc
2032 fi
2033 AC_SUBST(mono_cfg_dir)
2034
2035 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
2036 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
2037 AC_CONFIG_FILES([runtime/semdel-wrapper],[chmod +x runtime/semdel-wrapper])
2038
2039 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
2040 [   depth=../../../..
2041     case $srcdir in
2042     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2043     .) reldir=$depth ;;
2044     *) reldir=$depth/$srcdir ;;
2045     esac
2046     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
2047     cd runtime/etc/mono/1.0
2048     rm -f machine.config
2049     $LN_S $reldir/data/net_1_1/machine.config machine.config
2050     cd $depth
2051 ],[LN_S='$LN_S'])
2052
2053 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
2054 [   depth=../../../..
2055     case $srcdir in
2056     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2057     .) reldir=$depth ;;
2058     *) reldir=$depth/$srcdir ;;
2059     esac
2060     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2061     cd runtime/etc/mono/2.0
2062     rm -f machine.config
2063     $LN_S $reldir/data/net_2_0/machine.config machine.config
2064     cd $depth
2065 ],[LN_S='$LN_S'])
2066
2067 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
2068 [   depth=../../../..
2069     case $srcdir in
2070     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2071     .) reldir=$depth ;;
2072     *) reldir=$depth/$srcdir ;;
2073     esac
2074     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
2075     cd runtime/etc/mono/2.0
2076     rm -f web.config
2077     $LN_S $reldir/data/net_2_0/web.config web.config
2078     cd $depth
2079 ],[LN_S='$LN_S'])
2080
2081 AC_CONFIG_COMMANDS([runtime/etc/mono/browscap.ini],
2082 [   depth=../../..
2083     case $srcdir in
2084     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
2085     .) reldir=$depth ;;
2086     *) reldir=$depth/$srcdir ;;
2087     esac
2088     $ac_aux_dir/install-sh -d runtime/etc/mono/
2089     cd runtime/etc/mono/
2090     rm -f browscap.ini
2091     $LN_S $reldir/data/browscap.ini browscap.ini
2092     cd $depth
2093 ],[LN_S='$LN_S'])
2094
2095 AC_OUTPUT([
2096 Makefile
2097 mono-uninstalled.pc
2098 scripts/mono-nunit.pc
2099 scripts/mono-find-provides
2100 scripts/mono-find-requires
2101 mono/Makefile
2102 mono/utils/Makefile
2103 mono/metadata/Makefile
2104 mono/dis/Makefile
2105 mono/cil/Makefile
2106 mono/arch/Makefile
2107 mono/os/Makefile
2108 mono/arch/x86/Makefile
2109 mono/arch/amd64/Makefile
2110 mono/arch/hppa/Makefile
2111 mono/arch/ppc/Makefile
2112 mono/arch/sparc/Makefile
2113 mono/arch/s390/Makefile
2114 mono/arch/s390x/Makefile
2115 mono/arch/arm/Makefile
2116 mono/arch/alpha/Makefile
2117 mono/arch/ia64/Makefile
2118 mono/arch/mips/Makefile
2119 mono/interpreter/Makefile
2120 mono/tests/Makefile
2121 mono/tests/tests-config
2122 mono/tests/assemblyresolve/Makefile
2123 mono/tests/cas/Makefile
2124 mono/tests/cas/assembly/Makefile
2125 mono/tests/cas/demand/Makefile
2126 mono/tests/cas/inheritance/Makefile
2127 mono/tests/cas/linkdemand/Makefile
2128 mono/tests/cas/threads/Makefile
2129 mono/benchmark/Makefile
2130 mono/monoburg/Makefile
2131 mono/monograph/Makefile
2132 mono/io-layer/Makefile
2133 mono/mini/Makefile
2134 mono/profiler/Makefile
2135 ikvm-native/Makefile
2136 scripts/Makefile
2137 man/Makefile
2138 web/Makefile
2139 docs/Makefile
2140 data/Makefile
2141 data/net_1_1/Makefile
2142 data/net_2_0/Makefile
2143 data/mint.pc
2144 data/mono.pc
2145 data/mono-cairo.pc
2146 data/dotnet.pc
2147 data/cecil.pc
2148 samples/Makefile
2149 support/Makefile
2150 data/config
2151 tools/Makefile
2152 tools/locale-builder/Makefile
2153 runtime/Makefile
2154 msvc/Makefile
2155 ])
2156
2157 if test x$platform_win32 = xyes; then
2158    # Get rid of 'cyg' prefixes in library names
2159    sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2160    # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
2161    # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
2162    # executable doesn't work...
2163    sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
2164 fi
2165
2166 (
2167   case $prefix in
2168   NONE) prefix=$ac_default_prefix ;;
2169   esac
2170   case $exec_prefix in
2171   NONE) exec_prefix='${prefix}' ;;
2172   esac
2173
2174   test -w $srcdir/$mcsdir/build || chmod +w $srcdir/$mcsdir/build
2175
2176   #
2177   # If we are cross compiling, we don't build in the mcs/ tree.  Let us not clobber
2178   # any existing config.make.  This allows people to share the same source tree
2179   # with different build directories, one native and one cross
2180   #
2181   if test x$cross_compiling = xno && test x$enable_mcs_build != xno; then
2182     echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
2183     echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
2184     echo "sysconfdir=$sysconfdir" >> $srcdir/$mcsdir/build/config.make
2185     echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$mcsdir/build/config.make
2186     echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
2187     echo 'IL_FLAGS = /debug' >> $srcdir/$mcsdir/build/config.make
2188     echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$mcsdir/build/config.make
2189     echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $srcdir/$mcsdir/build/config.make
2190
2191     case $INSTALL in
2192     [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
2193     *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
2194     esac
2195
2196     echo "INSTALL = $mcs_INSTALL" >> $srcdir/$mcsdir/build/config.make
2197
2198     export VERSION
2199     [myver=$($AWK 'BEGIN {
2200       split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
2201       if(length(vsplit [1]) > 4) {
2202         split (substr(ENVIRON["VERSION"], 0, 4) "." substr(ENVIRON["VERSION"], 5) ".0.0", vsplit, ".")
2203       }
2204       print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
2205     }')]
2206
2207     echo "MONO_VERSION = $myver" >> $srcdir/$mcsdir/build/config.make
2208   fi
2209
2210   # if we have an olive folder, override the default settings
2211   if test -d $olivedir; then
2212
2213     test -w $srcdir/$olivedir/build || chmod +w $srcdir/$olivedir/build
2214
2215     if test x$cross_compiling = xno && test x$enable_olive_build != xno; then
2216       echo "prefix=$prefix" > $srcdir/$olivedir/build/config.make
2217       echo "exec_prefix=$exec_prefix" >> $srcdir/$olivedir/build/config.make
2218       echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$olivedir/build/config.make
2219       echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$olivedir/build/config.make
2220       echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$olivedir/build/config.make
2221       echo "MONO_VERSION = $myver" >> $srcdir/$olivedir/build/config.make
2222           if test x$with_moonlight = xyes; then
2223         echo "WITH_MOONLIGHT = yes" >> $srcdir/$olivedir/build/config.make
2224       fi
2225     fi
2226   fi
2227 )
2228
2229 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2230
2231 echo "
2232         mcs source:    $mcs_topdir
2233         olive source:  $olive_topdir
2234
2235         GC:          $gc
2236         TLS:         $with_tls
2237         SIGALTSTACK: $with_sigaltstack
2238         Engine:      $jit_status
2239         2.0 Beta:    $PREVIEW
2240         2.1 Alpha:   $MOONLIGHT
2241         JNI support: $jdk_headers_found
2242         libgdiplus:  $libgdiplus_msg
2243         zlib:        $zlib_msg
2244         $disabled
2245
2246 "
2247 if test x$with_static_mono = xno -a "x$platform_win32" != "xyes"; then
2248    AC_MSG_WARN(Turning off static Mono is a risk, you might run into unexepcted bugs)
2249 fi
2250
2251 if test x$gc = xsgen; then
2252         echo IMPORTANT:
2253         echo IMPORTANT: You have selected an experimental, work-in-progress
2254         echo IMPORTANT: GC engine.  This GC engine is currently not supported
2255         echo IMPORTANT: and is not yet ready for use.
2256         echo IMPORTANT:
2257         echo IMPORTANT: There are known problems with it, use at your own risk.
2258 fi