configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.93+cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl set optimization and debugging for all architectures and systems
  16 if test x"$CFLAGS" = "x"; then
  17         CFLAGS="-O0 -g3"
  18 fi
  19
  20 dnl system type
  21 case "$host_cpu" in
  22 alpha | alphaev56 | alphapca56 )
  23         ARCH_DIR="alpha"
  24         CFLAGS="$CFLAGS -mieee -D__ALPHA__"
  25         ;;
  26
  27 arm | armv4tl | armv5b )
  28         ARCH_DIR="arm"
  29         CFLAGS="$CFLAGS -D__ARM__"
  30         ;;
  31
  32 i386 | i486 | i586 | i686 )
  33         ARCH_DIR="i386"
  34         CFLAGS="$CFLAGS -D__I386__"
  35         ;;
  36
  37 mips )
  38         ARCH_DIR="mips"
  39         CFLAGS="$CFLAGS -D__MIPS__"
  40         ;;
  41
  42 powerpc )
  43         ARCH_DIR="powerpc"
  44         CFLAGS="$CFLAGS -D__POWERPC__"
  45         ;;
  46
  47 x86_64 )
  48         ARCH_DIR="x86_64"
  49         CFLAGS="$CFLAGS -D__X86_64__"
  50         ;;
  51
  52 xdspcore )
  53         ARCH_DIR="xdspcore"
  54         ENABLE_STATICVM="yes"
  55         CFLAGS="$CFLAGS -D__XDSPCORE__"
  56         USE_SCHEDULER="1"
  57         ;;
  58 * )
  59         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  60         ;;
  61 esac
  62
  63 dnl host type
  64 case "$host_os" in
  65 *linux* | *Linux* )
  66         OS_DIR="linux"
  67         CFLAGS="$CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  68         ;;
  69 *darwin* )
  70         OS_DIR="darwin"
  71         CFLAGS="$CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
  72         ;;
  73 *freebsd* )
  74         OS_DIR="freebsd"
  75         CFLAGS="$CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
  76         ;;
  77 *irix* )
  78         OS_DIR="irix"
  79         CFLAGS="$CFLAGS -D__IRIX__"
  80         ;;
  81 * )
  82         ;;
  83 esac
  84
  85
  86 dnl define and substitute some architecture specific variables
  87 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
  88 AC_SUBST(ARCH_DIR)
  89 AC_SUBST(OS_DIR)
  90 AC_SUBST(USE_SCHEDULER)
  91
  92
  93 dnl Checks for programs.
  94 AC_PROG_CC
  95 AM_PROG_AS
  96 AC_PROG_LD
  97 AC_PROG_LD_GNU
  98 AC_PROG_RANLIB
  99 AC_DISABLE_SHARED
 100 AC_PROG_LN_S
 101 AC_PROG_MAKE_SET
 102 AM_PROG_MKDIR_P
 103
 104 dnl libtool stuff
 105 AC_LIBTOOL_DLOPEN
 106 AC_PROG_LIBTOOL
 107
 108 dnl Checks for header files.
 109 AC_HEADER_DIRENT
 110 AC_HEADER_STDC
 111 AC_CHECK_HEADERS([fcntl.h])
 112 AC_CHECK_HEADERS([sys/time.h])
 113 AC_CHECK_HEADERS([unistd.h])
 114 AC_CHECK_HEADERS([sys/ioctl.h])
 115
 116 dnl this is for fdlibm
 117 AC_CHECK_HEADERS([stdint.h])
 118 AC_CHECK_HEADERS([inttypes.h])
 119 AC_CHECK_HEADERS([sys/config.h])
 120 AC_CHECK_HEADERS([sys/types.h])
 121 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 122 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 123 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 124 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 125
 126 dnl Checks for typedefs, structures, and compiler characteristics.
 127 AC_C_CONST
 128 AC_C_INLINE
 129 AC_C_ATTRIBUTE
 130 AC_TYPE_OFF_T
 131 AC_TYPE_SIZE_T
 132 AC_HEADER_TIME
 133 AC_STRUCT_TM
 134
 135 dnl Checks for library functions.
 136 AC_PROG_GCC_TRADITIONAL
 137 AC_TYPE_SIGNAL
 138 AC_FUNC_MEMCMP
 139 AC_CHECK_FUNCS(calloc mprotect getpagesize free)
 140 AC_CHECK_FUNCS(getcwd gettimeofday)
 141 AC_CHECK_FUNCS(scandir)
 142 AC_CHECK_FUNCS(mmap)
 143
 144 dnl Checks for libraries.
 145
 146 dnl Checking sizeof void *
 147 AC_CHECK_SIZEOF(void *)
 148 AC_C_BIGENDIAN
 149
 150
 151 dnl check which ld flags are required to export symbols
 152 if test x"$with_gnu_ld" = "xyes"; then
 153     EXPORT_SYMBOLS_FLAGS="-Wl,--export-dynamic"
 154 else
 155     EXPORT_SYMBOLS_FLAGS=""
 156 fi
 157 AC_SUBST(EXPORT_SYMBOLS_FLAGS)
 158
 159
 160 dnl define install prefix
 161 if test "x$prefix" = "xNONE"; then
 162     CACAO_INSTALL_PREFIX=$ac_default_prefix
 163 else
 164     CACAO_INSTALL_PREFIX=$prefix
 165 fi
 166 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [installation prefix])
 167 AC_SUBST(CACAO_INSTALL_PREFIX)
 168
 169
 170 dnl Features
 171
 172 dnl check arguments
 173
 174 dnl check for JIT compiler
 175 AC_MSG_CHECKING(whether JIT compiler should be compiled)
 176 AC_ARG_ENABLE([jit],
 177               [AS_HELP_STRING(--disable-jit,disable JIT compiler [[default=yes]])],
 178               [case "${enableval}" in
 179                    no) ENABLE_JIT=no;;
 180                    *) ENABLE_JIT=yes;;
 181                esac],
 182               [ENABLE_JIT=yes])
 183 AC_MSG_RESULT(${ENABLE_JIT})
 184 AM_CONDITIONAL([ENABLE_JIT], test x"${ENABLE_JIT}" = "xyes")
 185
 186 if test x"${ENABLE_JIT}" = "xyes"; then
 187     AC_DEFINE([ENABLE_JIT], 1, [enable JIT compiler])
 188 fi
 189
 190
 191 dnl check for interpreter
 192 AC_ARG_ENABLE([intrp], [AS_HELP_STRING(--enable-intrp,enable interpreter [[default=no]])])
 193
 194 AC_MSG_CHECKING(whether interpreter should be compiled)
 195 if test x"$enable_intrp" = "xyes"; then
 196     AC_MSG_RESULT(yes)
 197     AC_DEFINE([ENABLE_INTRP], 1, [enable interpreter])
 198     AM_CONDITIONAL([ENABLE_INTRP], [true])
 199     ENABLE_INTRP=yes
 200
 201     AC_ASM_SKIP16
 202
 203     dnl check for libffi
 204     AC_ARG_WITH([ffi],
 205                 [AS_HELP_STRING(--with-ffi,use libffi to call native functions)],
 206                 [WITH_FFI=yes
 207                  AC_CHECK_HEADERS([ffi.h],, [AC_MSG_ERROR(cannot find ffi.h)])
 208                  AC_CHECK_LIB(ffi, ffi_call,, [AC_MSG_ERROR(cannot find libffi)])
 209                  AC_DEFINE([WITH_FFI], 1, [use libffi])],
 210                 [WITH_FFI=no])
 211
 212     dnl check for libffcall
 213     AC_ARG_WITH([ffcall],
 214                 [AS_HELP_STRING(--with-ffcall,use libffcall to call native functions)],
 215                 [WITH_FFCALL=yes
 216                  AC_CHECK_HEADERS([avcall.h],, [AC_MSG_ERROR(cannot find avcall.h)])
 217                  AC_CHECK_LIB(avcall, __builtin_avcall,, [AC_MSG_ERROR(cannot find libavcall (from libffcall))])
 218                  AC_DEFINE([WITH_FFCALL], 1, [use libffcall])],
 219                 [WITH_FFCALL=no])
 220
 221     dnl check for libffi or libffcall
 222     if test x"${WITH_FFI}" = "xyes" -a x"${WITH_FFCALL}" = "xyes"; then
 223         AC_ERROR(Enable only libffi or libffcall.)
 224     fi
 225     if test x"${WITH_FFI}" = "xno" -a x"${WITH_FFCALL}" = "xno"; then
 226         AC_ERROR(Enable one of libffi or libffcall.)
 227     fi
 228
 229 else
 230     AC_MSG_RESULT(no)
 231     AM_CONDITIONAL([ENABLE_INTRP], [false])
 232     ENABLE_INTRP="no"
 233 fi
 234
 235 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 236     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 237 fi
 238
 239
 240 dnl check for garbage collector usage
 241 AC_MSG_CHECKING(whether GC should be disabled)
 242 AC_ARG_ENABLE([gc],
 243               [AS_HELP_STRING(--disable-gc,disable garbage collector (for debugging only!) [[default=yes]])],
 244               [case "${enableval}" in
 245                    no) DISABLE_GC=yes
 246                        AC_DEFINE([DISABLE_GC], 1, [disable garbage collector])
 247                        ;;
 248                    *) DISABLE_GC=no;;
 249                esac],
 250               [DISABLE_GC=no])
 251 AC_MSG_RESULT(${DISABLE_GC})
 252 AM_CONDITIONAL([DISABLE_GC], test x"${DISABLE_GC}" = "xyes")
 253
 254
 255 dnl check for dump memory usage
 256 AC_MSG_CHECKING(whether dump memory should be disabled)
 257 AC_ARG_ENABLE([dump],
 258               [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])],
 259               [case "${enableval}" in
 260                    no)
 261                        DISABLE_DUMP=yes
 262                        AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 263                        ;;
 264                    *) DISABLE_DUMP=no;;
 265                esac],
 266                [DISABLE_DUMP=no])
 267 AC_MSG_RESULT(${DISABLE_DUMP})
 268
 269
 270 dnl check for debug
 271 AC_MSG_CHECKING(whether debug code generation should be enabled)
 272 AC_ARG_ENABLE([debug],
 273               [AS_HELP_STRING(--disable-debug,disable debug code generation [[default=yes]])],
 274               [case "${enableval}" in
 275                    no) NDEBUG=yes
 276                        AC_DEFINE([NDEBUG], 1, [disable debug code])
 277                        ;;
 278                    *) NDEBUG=no;;
 279                esac],
 280               [NDEBUG=no])
 281
 282 if test x"${NDEBUG}" = "xno"; then
 283     AC_MSG_RESULT(yes)
 284
 285     dnl check for binutils headers and libraries on some architectures for the
 286     dnl disassembler
 287     case "${ARCH_DIR}" in
 288         arm | i386 | powerpc | x86_64 )
 289             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 290             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from bintuils))])
 291             AC_CHECK_LIB(opcodes, init_disassemble_info,, [AC_MSG_ERROR(cannot find libopcodes (from bintuils))])
 292             ;;
 293     esac
 294
 295 else
 296     AC_MSG_RESULT(no)
 297 fi
 298
 299
 300 dnl check for statistics
 301 AC_MSG_CHECKING(whether statistics generation should be enabled)
 302 AC_ARG_ENABLE([statistics],
 303               [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])],
 304               [case "${enableval}" in
 305                    no) ENABLE_STATISTICS=no;;
 306                    *) ENABLE_STATISTICS=yes;;
 307                esac],
 308               [ENABLE_STATISTICS=yes])
 309 AC_MSG_RESULT(${ENABLE_STATISTICS})
 310 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 311
 312 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 313     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 314 fi
 315
 316
 317 dnl check for JVMTI
 318 AC_MSG_CHECKING(whether to compile JVMTI support)
 319 AC_ARG_ENABLE([jvmti],
 320               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 321               [case "${enableval}" in
 322                    yes) ENABLE_JVMTI=yes;;
 323                    *) ENABLE_JVMTI=no;;
 324                esac],
 325               [ENABLE_JVMTI=no])
 326 AC_MSG_RESULT(${ENABLE_JVMTI})
 327 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 328
 329 if test x"${ENABLE_JVMTI}" = "xyes"; then
 330     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 331 fi
 332
 333
 334 dnl threads
 335 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 336 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 337
 338 AC_MSG_CHECKING(whether to include threads support)
 339 enable_threads=${enable_threads:-native}
 340 case "$enable_threads" in
 341 no | none | single)
 342         AC_MSG_RESULT(no)
 343         dnl no threads for boehm
 344         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 345         AM_CONDITIONAL([USE_THREADS], [false])
 346         AM_CONDITIONAL([NATIVE_THREADS], [false])
 347         ;;
 348
 349 green | native | posix | pthreads)
 350         AC_DEFINE([USE_THREADS], 1, [use threads])
 351
 352         AM_CONDITIONAL([USE_THREADS], [true])
 353
 354         if test x"$enable_threads" != "xgreen"; then
 355                 AC_MSG_RESULT(yes, native)
 356                 AC_CHECK_LIB(pthread, main)
 357                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 358
 359                 CFLAGS="$CFLAGS -D_REENTRANT"
 360
 361                 dnl tell boehm to support threads as well
 362                 ac_configure_args="$ac_configure_args --enable-boehm-threads=posix"
 363                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 364
 365         else
 366                 AC_MSG_RESULT(yes, green)
 367
 368                 dnl no threads for boehm
 369                 ac_configure_args="$ac_configure_args --disable-boehm-threads"
 370                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 371         fi
 372     ;;
 373 *)
 374     AC_MSG_ERROR($enable_threads is an unknown thread package)
 375     ;;
 376 esac
 377
 378
 379 dnl Check whether the compiler supports the __thread keyword.
 380 if test "x$use__thread" != xno; then
 381   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 382   [cat > conftest.c <<\EOF
 383 __thread int a = 42;
 384 EOF
 385   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 386     ac_cv_gcc___thread=yes
 387   else
 388     ac_cv_gcc___thread=no
 389   fi
 390   rm -f conftest*])
 391   if test "$ac_cv_gcc___thread" = yes; then
 392     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 393   fi
 394 else
 395   ac_cv_gcc___thread=no
 396 fi
 397
 398
 399 dnl check if linear scan register allocator(lsra) should be used
 400 AC_MSG_CHECKING(whether lsra should be supported)
 401 AC_ARG_ENABLE([lsra],
 402               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])],
 403               [case "${enableval}" in
 404                    no) ENABLE_LSRA=no;;
 405                    *) ENABLE_LSRA=yes;;
 406                esac],
 407               [ENABLE_LSRA=yes])
 408 AC_MSG_RESULT(${ENABLE_LSRA})
 409 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 410
 411 if test x"${ENABLE_LSRA}" = "xyes"; then
 412     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 413 fi
 414
 415
 416 dnl check for inlining
 417 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 418
 419 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 420 dnl if test x"$enable_inlining" = "xno"; then
 421 dnl     AC_MSG_RESULT(yes)
 422 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 423 dnl else
 424 dnl     AC_MSG_RESULT(no)
 425         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 426         AM_CONDITIONAL([USE_INLINING], [true])
 427 dnl fi
 428
 429
 430 dnl check for instruction scheduler
 431 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 432
 433 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 434 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 435         case "${ARCH_DIR}" in
 436                 xdspcore )
 437                         ;;
 438                 * )
 439                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 440                         ;;
 441         esac
 442
 443         AC_MSG_RESULT(yes)
 444         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 445         AM_CONDITIONAL([USE_SCHEDULER], [true])
 446 else
 447         AC_MSG_RESULT(no)
 448         AM_CONDITIONAL([USE_SCHEDULER], [false])
 449 fi
 450
 451
 452 dnl check if zlib should be used
 453 AC_MSG_CHECKING(whether zip archives should be supported)
 454 AC_ARG_ENABLE([zlib],
 455               [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])],
 456               [case "${enableval}" in
 457                   no) ENABLE_ZLIB=yes;;
 458                   *) ENABLE_ZLIB=no;;
 459                esac],
 460               [ENABLE_ZLIB=yes])
 461 AC_MSG_RESULT(${ENABLE_ZLIB})
 462
 463 if test x"${ENABLE_ZLIB}" = "xyes"; then
 464     AC_CHECK_HEADERS([zlib.h],, [AC_MSG_ERROR(cannot find zlib.h)])
 465     AC_CHECK_LIB(z, inflate,, [AC_MSG_ERROR(cannot find libz)])
 466     AC_DEFINE([ENABLE_ZLIB], 1, [use zlib])
 467 fi
 468 AM_CONDITIONAL([ENABLE_ZLIB], test x"${ENABLE_ZLIB}" = "xyes")
 469
 470
 471 dnl check if CACAO should be linked statically
 472 AC_MSG_CHECKING(whether to link GNU classpath native libraries statically into CACAO)
 473 AC_ARG_ENABLE([staticvm],
 474               [AS_HELP_STRING(--enable-staticvm, link GNU classpath native libraries statically into CACAO [[default=no]])],
 475               [case "${enableval}" in
 476                   yes) ENABLE_STATICVM=yes;;
 477                   *) ENABLE_STATICVM=no;;
 478                esac],
 479               [ENABLE_STATICVM=no])
 480 AC_MSG_RESULT(${ENABLE_STATICVM})
 481
 482 if test x"${ENABLE_STATICVM}" = "xyes"; then
 483     AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 484
 485     dnl check for some classpath related stuff when we link statically
 486     AM_ICONV_LINK
 487 else
 488     AC_CHECK_HEADERS([ltdl.h],, [AC_MSG_ERROR(cannot find ltdl.h)])
 489     AC_CHECK_LIB(ltdl, lt_dlopen,, [AC_MSG_ERROR(cannot find libltdl)])
 490 fi
 491 AM_CONDITIONAL([ENABLE_STATICVM], test x"${ENABLE_STATICVM}" = "xyes")
 492 AC_SUBST(ENABLE_STATICVM)
 493
 494
 495 dnl is GNU classpath installed somewhere different
 496 AC_MSG_CHECKING(where GNU classpath is installed)
 497 AC_ARG_WITH([classpath-install-dir],
 498             [AS_HELP_STRING(--with-classpath-install-dir=<dir>,installation directory of GNU classpath [[default=/usr/local/classpath]])],
 499             [CLASSPATH_INSTALL_DIR=${withval}],
 500             [CLASSPATH_INSTALL_DIR=/usr/local/classpath])
 501 AC_MSG_RESULT(${CLASSPATH_INSTALL_DIR})
 502 AC_DEFINE_UNQUOTED([CLASSPATH_INSTALL_DIR], "${CLASSPATH_INSTALL_DIR}", [GNU classpath installation directory])
 503 AC_SUBST(CLASSPATH_INSTALL_DIR)
 504
 505
 506 dnl Maybe the user has Classpath installed 'flat'.
 507 AC_ARG_WITH([flat-classpath], [AS_HELP_STRING(--with-flat-classpath, GNU Classpath is not zipped in the install directory)])
 508 if test x"$with_flat_classpath" = "x"; then
 509         GLIBJZ=glibj.zip
 510 else
 511         GLIBJZ=
 512 fi
 513 AC_SUBST(GLIBJZ)
 514 AC_DEFINE_UNQUOTED(GLIBJZ_STRING, "$GLIBJZ", [define to the string base name of the classpath zip file])
 515
 516
 517 dnl check for some programs we need
 518 AC_PROG_JAVAC
 519 AC_PATH_PROG(ZIP, zip)
 520 if test -z "${ZIP}"; then
 521     AC_MSG_ERROR([cannot find zip])
 522 fi
 523
 524
 525 dnl now configure subpackages
 526 dnl the export is not my favorite (is there another way?)
 527 export CFLAGS
 528 AC_CONFIG_SUBDIRS(src/boehm-gc)
 529
 530 AC_CONFIG_FILES([Makefile]
 531                 [contrib/Makefile]
 532                 [contrib/setenvinstalled]
 533                 [contrib/setenvsource]
 534                 [doc/Makefile]
 535                 [doc/handbook/Makefile]
 536                 [man/Makefile]
 537                 [src/Makefile]
 538                 [src/cacao/Makefile]
 539                 [src/cacaoh/Makefile]
 540                 [src/fdlibm/Makefile]
 541                 [src/lib/Makefile]
 542                 [src/mm/Makefile]
 543                 [src/native/Makefile]
 544                 [src/native/include/Makefile]
 545                 [src/native/jvmti/Makefile]
 546                 [src/native/tools/Makefile]
 547                 [src/native/vm/Makefile]
 548                 [src/scripts/Makefile]
 549                 [src/scripts/java]
 550                 [src/scripts/rmiregistry]
 551                 [src/threads/Makefile]
 552                 [src/threads/green/Makefile]
 553                 [src/threads/native/Makefile]
 554                 [src/toolbox/Makefile]
 555                 [src/vm/Makefile]
 556                 [src/vm/jit/Makefile]
 557                 [src/vm/jit/allocator/Makefile]
 558                 [src/vm/jit/alpha/Makefile]
 559                 [src/vm/jit/alpha/freebsd/Makefile]
 560                 [src/vm/jit/alpha/linux/Makefile]
 561                 [src/vm/jit/i386/Makefile]
 562                 [src/vm/jit/i386/freebsd/Makefile]
 563                 [src/vm/jit/i386/linux/Makefile]
 564                 [src/vm/jit/intrp/Makefile]
 565                 [src/vm/jit/inline/Makefile]
 566                 [src/vm/jit/loop/Makefile]
 567                 [src/vm/jit/mips/Makefile]
 568                 [src/vm/jit/mips/irix/Makefile]
 569                 [src/vm/jit/mips/linux/Makefile]
 570                 [src/vm/jit/powerpc/Makefile]
 571                 [src/vm/jit/powerpc/darwin/Makefile]
 572                 [src/vm/jit/powerpc/linux/Makefile]
 573                 [src/vm/jit/schedule/Makefile]
 574                 [src/vm/jit/tools/Makefile]
 575                 [src/vm/jit/verify/Makefile]
 576                 [src/vm/jit/x86_64/Makefile]
 577                 [tests/Makefile]
 578                 [tests/codepatching/Makefile]
 579                 [tests/native/Makefile]
 580                 [tests/regression/Makefile])
 581
 582 AC_OUTPUT
 583
 584
 585 ## Local variables:
 586 ## mode: m4
 587 ## indent-tabs-mode: t
 588 ## c-basic-offset: 4
 589 ## tab-width: 8
 590 ## compile-command: "automake --add-missing"
 591 ## End: