configure.in

   1
   2 AC_INIT(README)
   3 AC_CANONICAL_SYSTEM
   4 AM_CONFIG_HEADER(config.h)
   5 AM_INIT_AUTOMAKE(mono, 0.14)
   6 AM_MAINTAINER_MODE
   7
   8 dnl ****************************************
   9 dnl *** Check if we're building on win32 ***
  10 dnl ****************************************
  11 AC_MSG_CHECKING([if building for some Win32 platform])
  12 case "$host" in
  13         *-*-mingw*|*-*-cygwin*)
  14                 platform_win32=yes
  15                 AC_DEFINE(PLATFORM_WIN32)
  16                 CC="gcc -mno-cygwin"
  17                 libdl=
  18                 ;;
  19         *)
  20                 platform_win32=no
  21                 libdl="-ldl"
  22                 ;;
  23 esac
  24 AC_MSG_RESULT($platform_win32)
  25 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
  26
  27 AC_CHECK_TOOL(CC, gcc, gcc)
  28 AC_PROG_CC
  29 AM_PROG_CC_STDC
  30 AC_PROG_INSTALL
  31
  32 dnl may require a specific autoconf version
  33 dnl AC_PROG_CC_FOR_BUILD
  34 dnl CC_FOR_BUILD not automatically detected
  35 CC_FOR_BUILD=$CC
  36 BUILD_EXEEXT=
  37 if test "x$cross_compiling" = "xyes"; then
  38         CC_FOR_BUILD=cc
  39         BUILD_EXEEXT=""
  40 fi
  41 AC_SUBST(CC_FOR_BUILD)
  42 AC_SUBST(HOST_CC)
  43 AC_SUBST(BUILD_EXEEXT)
  44
  45 # Set STDC_HEADERS
  46 AC_HEADER_STDC
  47 AC_LIBTOOL_WIN32_DLL
  48 AM_PROG_LIBTOOL
  49
  50 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h)
  51
  52 AC_CHECK_HEADERS(iconv.h)
  53 AC_CHECK_HEADERS(giconv.h)
  54
  55 # for mono/metadata/debug-symfile.c
  56 AC_CHECK_HEADERS(elf.h)
  57
  58 # not 64 bit clean in cross-compile
  59 AC_CHECK_SIZEOF(void *, 4)
  60
  61 CFLAGS='-g -Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
  62
  63 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  64 if test "x$PKG_CONFIG" = "xno"; then
  65         AC_MSG_ERROR([You need to install pkg-config])
  66 fi
  67
  68 dnl for use on the build system
  69 dnl pkg-config is stupid
  70 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
  71 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
  72 AC_SUBST(BUILD_GLIB_CFLAGS)
  73 AC_SUBST(BUILD_GLIB_LIBS)
  74
  75 PKG_PATH=
  76 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
  77         if test x$with_crosspkgdir = "x"; then
  78                 if test -s $PKG_CONFIG_PATH; then
  79                         PKG_PATH=$PKG_CONFIG_PATH
  80                 fi
  81         else
  82                 PKG_PATH=$with_crosspkgdir
  83                 PKG_CONFIG_PATH=$PKG_PATH
  84                 export PKG_CONFIG_PATH
  85         fi
  86 )
  87
  88 ## Versions of dependencies
  89 GLIB_REQUIRED_VERSION=1.3.11
  90
  91 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
  92
  93 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
  94 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
  95 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
  96 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
  97
  98 AC_SUBST(GLIB_CFLAGS)
  99 AC_SUBST(GLIB_LIBS)
 100 AC_SUBST(GMODULE_CFLAGS)
 101 AC_SUBST(GMODULE_LIBS)
 102
 103 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 104 gc=auto
 105 AC_ARG_WITH(gc, [  --with-gc=boehm,none],[gc=$with_gc])
 106
 107 case "x$gc" in
 108         xboehm|xyes)
 109                 if test "x$found_boehm" != "xyes"; then
 110                         AC_MSG_ERROR("GC requested but libgc not found!")
 111                 fi
 112
 113                 AC_DEFINE(HAVE_BOEHM_GC)
 114                 AC_SUBST(HAVE_BOEHM_GC)
 115                 LIBS="$LIBS -lgc $libdl"
 116                 ;;
 117         xnone)
 118                 AC_MSG_WARN("Compiling mono without GC.")
 119                 ;;
 120         *)
 121 dnl When the JIT works with libgc, use this chunk.
 122 dnl             # If libgc was found, use it.  Otherwise just warn.
 123                 if test "x$found_boehm" != "xyes"; then
 124                         AC_MSG_WARN("Compiling mono without GC.")
 125                 else
 126                         AC_DEFINE(HAVE_BOEHM_GC)
 127                         AC_SUBST(HAVE_BOEHM_GC)
 128                         LIBS="$LIBS -lgc $libdl"
 129                         gc="boehm"
 130                 fi
 131 dnl             AC_MSG_WARN("Compiling mono without GC.")
 132                 ;;
 133 esac
 134
 135 if test x$platform_win32 = xno; then
 136         dnl ******************************************************************
 137         dnl *** Check for large file support                               ***
 138         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 139         dnl ******************************************************************
 140
 141         # Check that off_t can represent 2**63 - 1 correctly, working around
 142         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 143         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 144         large_offt=no
 145         AC_DEFUN(LARGE_FILES, [
 146                 large_CPPFLAGS=$CPPFLAGS
 147                 CPPFLAGS="$CPPFLAGS $1"
 148                 AC_TRY_RUN([
 149                         #include <sys/types.h>
 150
 151                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 152
 153                         int main(void) {
 154                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 155                                                (BIG_OFF_T%2147483647==1));
 156                                 if(big_off_t) {
 157                                         exit(0);
 158                                 } else {
 159                                         exit(1);
 160                                 }
 161                         }
 162                 ], [
 163                         AC_MSG_RESULT(ok)
 164                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 165                         large_CPPFLAGS="$large_CPPFLAGS $1"
 166                         large_offt=yes
 167                 ], [
 168                         AC_MSG_RESULT(no)
 169                 ], "")
 170                 CPPFLAGS=$large_CPPFLAGS
 171         ])
 172
 173         AC_MSG_CHECKING(if off_t is 64 bits wide)
 174         LARGE_FILES("")
 175         if test $large_offt = no; then
 176                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 177                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 178         fi
 179         if test $large_offt = no; then
 180                 AC_MSG_WARN([No 64 bit file size support available])
 181         fi
 182
 183         dnl *****************************
 184         dnl *** Checks for libsocket  ***
 185         dnl *****************************
 186         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 187
 188         dnl *******************************
 189         dnl *** Checks for MSG_NOSIGNAL ***
 190         dnl *******************************
 191         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 192         AC_TRY_COMPILE([#include <sys/socket.h>], [
 193                 int f = MSG_NOSIGNAL;
 194         ], [
 195                 # Yes, we have it...
 196                 AC_MSG_RESULT(yes)
 197                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 198         ], [
 199                 # We'll have to use signals
 200                 AC_MSG_RESULT(no)
 201         ])
 202
 203         dnl *****************************
 204         dnl *** Checks for SOL_IP     ***
 205         dnl *****************************
 206         AC_MSG_CHECKING(for SOL_IP)
 207         AC_TRY_COMPILE([#include <netdb.h>], [
 208                 int level = SOL_IP;
 209         ], [
 210                 # Yes, we have it...
 211                 AC_MSG_RESULT(yes)
 212                 AC_DEFINE(HAVE_SOL_IP)
 213         ], [
 214                 # We'll have to use getprotobyname
 215                 AC_MSG_RESULT(no)
 216         ])
 217
 218         dnl *****************************
 219         dnl *** Checks for SOL_TCP    ***
 220         dnl *****************************
 221         AC_MSG_CHECKING(for SOL_TCP)
 222         AC_TRY_COMPILE([#include <netdb.h>], [
 223                 int level = SOL_TCP;
 224         ], [
 225                 # Yes, we have it...
 226                 AC_MSG_RESULT(yes)
 227                 AC_DEFINE(HAVE_SOL_TCP)
 228         ], [
 229                 # We'll have to use getprotobyname
 230                 AC_MSG_RESULT(no)
 231         ])
 232
 233         dnl *****************************
 234         dnl *** Checks for IP_PKTINFO ***
 235         dnl *****************************
 236         AC_MSG_CHECKING(for IP_PKTINFO)
 237         AC_TRY_COMPILE([#include <netdb.h>], [
 238                 int level = IP_PKTINFO;
 239         ], [
 240                 # Yes, we have it...
 241                 AC_MSG_RESULT(yes)
 242                 AC_DEFINE(HAVE_IP_PKTINFO)
 243         ], [
 244                 AC_MSG_RESULT(no)
 245         ])
 246
 247         dnl *********************************
 248         dnl *** Check for struct ip_mreqn ***
 249         dnl *********************************
 250         AC_MSG_CHECKING(for struct ip_mreqn)
 251         AC_TRY_COMPILE([#include <netinet/in.h>], [
 252                 struct ip_mreqn mreq;
 253                 mreq.imr_address.s_addr = 0;
 254         ], [
 255                 # Yes, we have it...
 256                 AC_MSG_RESULT(yes)
 257                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 258         ], [
 259                 # We'll just have to use struct ip_mreq
 260                 AC_MSG_RESULT(no)
 261         ])
 262
 263         dnl *****************************
 264         dnl *** Checks for libnsl     ***
 265         dnl *****************************
 266         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 267
 268         AC_CHECK_FUNCS(inet_pton inet_aton)
 269
 270         dnl ***********************************************
 271         dnl *** Checks for size of sockaddr_un.sun_path ***
 272         dnl ***********************************************
 273         # AC_CHECK_SIZEOF can't cope with struct members :-(
 274         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 275         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 276                 [AC_TRY_RUN([
 277                         #include <stdio.h>
 278                         #include <sys/un.h>
 279
 280                         int main(void) {
 281                                 struct sockaddr_un sock_un;
 282                                 FILE *f=fopen("conftestval", "w");
 283                                 if(!f) exit(1);
 284                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 285                                 exit(0);
 286                         }
 287                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 288                    cv_mono_sizeof_sunpath=0,
 289                    cv_mono_sizeof_sunpath=0)])dnl
 290         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 291         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 292
 293         dnl *****************************
 294         dnl *** Checks for libpthread ***
 295         dnl *****************************
 296         AC_SEARCH_LIBS(pthread_create, pthread, [
 297                 AM_CONDITIONAL(THREADS_PTHREAD, true)
 298                 AC_DEFINE(HAVE_PTHREAD)
 299
 300                 # Need pthread_mutex_timedlock
 301                 pthread_CFLAGS=""
 302                 orig_CPPFLAGS=$CPPFLAGS
 303                 # This is a gcc-specific error, but we already set
 304                 # gcc-specific options in CFLAGS
 305                 CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
 306                 AC_MSG_CHECKING(for pthread_mutex_timedlock)
 307                 AC_TRY_COMPILE([ #include <pthread.h>], [
 308                         pthread_mutex_t mut=PTHREAD_MUTEX_INITIALIZER;
 309                         pthread_mutex_timedlock(&mut, NULL);
 310                 ], [
 311                         # Works!
 312                         AC_MSG_RESULT(yes)
 313                         AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 314                 ], [
 315                         AC_MSG_RESULT(no)
 316
 317                         # glibc requires -D_GNU_SOURCE before it will declare
 318                         # this function
 319                         AC_MSG_CHECKING(whether _GNU_SOURCE is needed for pthread_mutex_timedlock)
 320                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 321                         AC_TRY_COMPILE([ #include <pthread.h>], [
 322                                 pthread_mutex_t mut=PTHREAD_MUTEX_INITIALIZER;
 323                                 pthread_mutex_timedlock(&mut, NULL);
 324                         ], [
 325                                 AC_MSG_RESULT(yes)
 326                                 pthread_CFLAGS="-D_GNU_SOURCE"
 327                                 AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 328                         ], [
 329                                 AC_MSG_RESULT(no)
 330                                 dnl Add other variants here
 331                                 AC_MSG_WARN(Working around pthread_mutex_timedlock)
 332                         ])
 333                 ])
 334                 CPPFLAGS=$orig_CPPFLAGS
 335                 CPPFLAGS="$CPPFLAGS $pthread_CFLAGS"
 336
 337                 # Need PTHREAD_MUTEX_RECURSIVE
 338                 pthread_CFLAGS=""
 339                 orig_CPPFLAGS=$CPPFLAGS
 340                 # This is a gcc-specific error, but we already set
 341                 # gcc-specific options in CFLAGS
 342                 CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
 343                 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 344                 AC_TRY_COMPILE([ #include <pthread.h>], [
 345                         pthread_mutexattr_t attr;
 346                         pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 347                 ], [
 348                         # Works!
 349                         AC_MSG_RESULT(ok)
 350                 ], [
 351                         AC_MSG_RESULT(no)
 352
 353                         # glibc requires -D_GNU_SOURCE before it will declare
 354                         # this macro
 355                         AC_MSG_CHECKING(whether _GNU_SOURCE is needed for PTHREAD_MUTEX_RECURSIVE)
 356                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 357                         AC_TRY_COMPILE([ #include <pthread.h>], [
 358                                 pthread_mutexattr_t attr;
 359                                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 360                         ], [
 361                                 AC_MSG_RESULT(ok)
 362                                 pthread_CFLAGS="-D_GNU_SOURCE"
 363                         ], [
 364                                 AC_MSG_RESULT(no)
 365                                 dnl Add other variants here
 366                                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 367                                 AC_DEFINE(USE_MONO_MUTEX)
 368                         ])
 369                 ])
 370                 CPPFLAGS=$orig_CPPFLAGS
 371                 CPPFLAGS="$CPPFLAGS $pthread_CFLAGS"
 372         ], [
 373                 AC_MSG_ERROR([libpthread is required on non-win32 hosts])
 374         ])
 375
 376         dnl ********************************
 377         dnl *** Checks for semaphore lib ***
 378         dnl ********************************
 379         AC_CHECK_LIB(rt, sem_init, LIBS="$LIBS -lrt")
 380
 381         dnl ********************************
 382         dnl *** Checks for timezone stuff **
 383         dnl ********************************
 384         AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 385                 AC_TRY_COMPILE([
 386                         #include <time.h>
 387                 ], [
 388                         timezone = 1;
 389                 ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 390         if test $ac_cv_var_timezone = yes; then
 391                 AC_DEFINE(HAVE_TIMEZONE)
 392         else
 393                 AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 394                         AC_TRY_COMPILE([
 395                                 #include <time.h>
 396                                 ], [
 397                                 struct tm tm;
 398                                 tm.tm_gmtoff = 1;
 399                                 ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 400                 if test $ac_cv_struct_tm_gmtoff = yes; then
 401                         AC_DEFINE(HAVE_TM_GMTOFF)
 402                 else
 403                         AC_ERROR(unable to find a way to determine timezone)
 404                 fi
 405         fi
 406 else
 407         AM_CONDITIONAL(THREADS_PTHREAD, false)
 408         # This is a kludge, we really ought to test for libws2_32, but
 409         # I can't make AC_CHECK_LIB link (the symbols seem to be mangled
 410         # with @num suffixes)
 411         LIBS="$LIBS -lws2_32"
 412         CFLAGS="$CFLAGS -mno-cygwin"
 413 fi
 414
 415 dnl ****************************
 416 dnl *** Look for /dev/random ***
 417 dnl ****************************
 418
 419 AC_MSG_CHECKING([if usage of random device is requested])
 420 AC_ARG_ENABLE(dev-random,
 421 [  --disable-dev-random    disable the use of the random device],
 422 try_dev_random=$enableval, try_dev_random=yes)
 423 AC_MSG_RESULT($try_dev_random)
 424
 425 case "{$target}" in
 426     *-openbsd*)
 427     NAME_DEV_RANDOM="/dev/srandom"
 428     ;;
 429
 430 dnl Win32 does not have /dev/random, they have their own method...
 431
 432     *-*-mingw*|*-*-cygwin*)
 433     ac_cv_have_dev_random = no
 434     ;;
 435
 436 dnl Everywhere else, it's /dev/random
 437
 438     *)
 439     NAME_DEV_RANDOM="/dev/random"
 440     ;;
 441 esac
 442
 443 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 444
 445 dnl Now check if the device actually exists
 446
 447 if test "x$try_dev_random" = "xyes"; then
 448     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 449     [if test -r "$NAME_DEV_RANDOM" ; then
 450         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 451     if test "x$ac_cv_have_dev_random" = "xyes"; then
 452         AC_DEFINE(HAVE_CRYPT_RNG)
 453     fi
 454 else
 455     AC_MSG_CHECKING(for random device)
 456     ac_cv_have_dev_random=no
 457     AC_MSG_RESULT(has been disabled)
 458 fi
 459
 460 if test "x$platform_win32" = "xyes"; then
 461     AC_DEFINE(HAVE_CRYPT_RNG)
 462 fi
 463
 464 if test "x$ac_cv_have_dev_random" = "xno" \
 465     && test "x$platform_win32" = "xno"; then
 466     AC_MSG_WARN([[
 467 ***
 468 *** A system-provided entropy source was not found on this system.
 469 *** Because of this, the System.Security.Cryptography random number generator
 470 *** will throw a NotImplemented exception.
 471 ***
 472 *** If you are seeing this message, and you know your system DOES have an
 473 *** entropy collection in place, please contact <crichton@gimp.org> and
 474 *** provide information about the system and how to access the random device.
 475 ***
 476 *** For those systems who lack a random device, EGD support is forthcoming.
 477 ***]])
 478 fi
 479
 480 if test "x$cross_compiling" = "xno"; then
 481 # check for new iconv version
 482 AC_MSG_CHECKING(for new iconv)
 483 AC_CACHE_VAL(new_iconv,[
 484         AC_TRY_RUN([#include <stdio.h>
 485                 #include <iconv.h>
 486
 487                 int main()
 488                 {
 489                   exit (iconv_open ("UTF-16le", "UTF-8") == (iconv_t)-1);
 490                 }
 491                 ],
 492                 new_iconv=yes,new_iconv=)])
 493 if test -n "$new_iconv"; then
 494         AC_MSG_RESULT(yes)
 495         AC_DEFINE(HAVE_NEW_ICONV)
 496 else
 497         AC_MSG_RESULT(no)
 498 fi
 499 fi
 500
 501 AC_MSG_CHECKING([if inter-process shared handles are requested])
 502 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
 503 AC_MSG_RESULT($try_shared_handles)
 504 if test "x$try_shared_handles" != "xyes"; then
 505         AC_DEFINE(DISABLE_SHARED_HANDLES)
 506         AC_SUBST(DISABLE_SHARED_HANDLES)
 507 fi
 508
 509 TARGET="unknown"
 510 ACCESS_UNALIGNED="yes"
 511
 512 case "$host" in
 513 #mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; ACCESS_UNALIGNED="no";;
 514 i*86-*-*) TARGET=X86; arch_target=x86;;
 515 sparc*-*-*) TARGET=SPARC; arch_target=sparc; ACCESS_UNALIGNED="no";;
 516 #alpha*-*-linux* | alpha*-*-osf*) TARGET=ALPHA; ACCESS_UNALIGNED="no";;
 517 #m68k-*-linux*) TARGET=M68K;;
 518 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; arch_target=ppc;;
 519 arm-*-linux-* | armv4l-*-linux-*) TARGET=ARM; arch_target=arm; ACCESS_UNALIGNED="no";;
 520 esac
 521
 522 if test ${TARGET} = unknown; then
 523         CPPFLAGS="$CPPFLAGS -DNO_PORT"
 524         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
 525 fi
 526
 527 if test ${ACCESS_UNALIGNED} = no; then
 528         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
 529 fi
 530
 531 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
 532 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
 533 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 534 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 535 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 536 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 537 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 538 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 539
 540 AC_SUBST(arch_target)
 541 AC_SUBST(CFLAGS)
 542 AC_SUBST(CPPFLAGS)
 543
 544 AC_OUTPUT([
 545 Makefile
 546 mono.pc
 547 mono/Makefile
 548 mono/utils/Makefile
 549 mono/metadata/Makefile
 550 mono/dis/Makefile
 551 mono/cil/Makefile
 552 mono/arch/Makefile
 553 mono/os/Makefile
 554 mono/os/win32/Makefile
 555 mono/os/unix/Makefile
 556 mono/arch/x86/Makefile
 557 mono/arch/ppc/Makefile
 558 mono/arch/sparc/Makefile
 559 mono/arch/arm/Makefile
 560 mono/interpreter/Makefile
 561 mono/tests/Makefile
 562 mono/benchmark/Makefile
 563 mono/monoburg/Makefile
 564 mono/monograph/Makefile
 565 mono/jit/Makefile
 566 mono/io-layer/Makefile
 567 mono/handles/Makefile
 568 runtime/Makefile
 569 scripts/Makefile
 570 man/Makefile
 571 doc/Makefile
 572 docs/Makefile
 573 ])
 574
 575 echo "
 576
 577         GC:     $gc
 578
 579 "