configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.96)
   5 AM_MAINTAINER_MODE
   6
   7 AC_PROG_LN_S
   8
   9 dnl
  10 dnl libgc checks
  11 dnl
  12
  13 gc_headers=no
  14 gc=included
  15 use_included_gc=no
  16
  17 if test -d $srcdir/libgc ; then
  18   gc_default=included
  19 else
  20   gc_default=boehm
  21 fi
  22
  23 #
  24 # These are the flags that need to be stored in the mono.pc file for
  25 # compiling code that will embed Mono
  26 #
  27 libmono_cflags=""
  28 libmono_ldflags=""
  29 AC_SUBST(libmono_cflags)
  30 AC_SUBST(libmono_ldflags)
  31
  32 dnl if linker handles the version script
  33 no_version_script=no
  34
  35 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  36 need_link_unlink=no
  37
  38 # Thread configuration inspired by sleepycat's db
  39 AC_MSG_CHECKING([host platform characteristics])
  40 libgc_threads=no
  41 case "$host" in
  42         *-*-mingw*|*-*-cygwin*)
  43                 platform_win32=yes
  44                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  45                 CC="gcc -mno-cygwin"
  46                 HOST_CC="gcc"
  47                 # So libgc configure gets -mno-cygwin
  48                 export CC
  49 # latest libgc already defines GC_WIN32_THREADS
  50 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  51                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  52                 libdl=
  53                 libgc_threads=win32
  54                 gc_default=boehm
  55                 with_nptl=no
  56                 with_sigaltstack=no
  57                 LN_S=cp
  58
  59                 ;;
  60         *-*-*netbsd*)
  61                 platform_win32=no
  62                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  63                 libmono_cflags="-D_REENTRANT"
  64                 LDFLAGS="$LDFLAGS -pthread"
  65                 libmono_ldflags="-pthread"
  66                 need_link_unlink=yes
  67                 libdl=
  68                 libgc_threads=no
  69                 ;;
  70         *-*-*freebsd*|*-*-*openbsd*)
  71                 platform_win32=no
  72                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  73                 libmono_cflags="-D_THREAD_SAFE"
  74                 LDFLAGS="$LDFLAGS -pthread"
  75                 libmono_ldflags="-pthread"
  76                 need_link_unlink=yes
  77                 AC_DEFINE(PTHREAD_POINTER_ID)
  78                 libdl=
  79                 libgc_threads=pthreads
  80                 ;;
  81         *-*-linux*)
  82                 platform_win32=no
  83                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
  84                 libmono_cflags="-D_REENTRANT"
  85                 libmono_ldflags="-lpthread"
  86                 libdl="-ldl"
  87                 libgc_threads=pthreads
  88                 ;;
  89         *-*-hpux*)
  90                 platform_win32=no
  91                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
  92                 CFLAGS="$CFLAGS +ESdbgasm"
  93                 LDFLAGS="$LDFLAGS -z"
  94                 libmono_cflags="-D_REENTRANT"
  95                 libmono_ldflags="-lpthread"
  96                 libgc_threads=pthreads
  97                 need_link_unlink=yes
  98                 ;;
  99         *-*-solaris*)
 100                 platform_win32=no
 101                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
 102                 need_link_unlink=yes
 103                 libmono_cflags="-D_REENTRANT"
 104                 libgc_threads=pthreads
 105                 ;;
 106         *-*-darwin*)
 107                 platform_win32=no
 108                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
 109                 libmono_cflags="-D_THREAD_SAFE"
 110                 LDFLAGS="$LDFLAGS -pthread"
 111                 libmono_ldflags="-pthread"
 112                 need_link_unlink=yes
 113                 AC_DEFINE(PTHREAD_POINTER_ID)
 114                 AC_DEFINE(USE_MACH_SEMA)
 115                 no_version_script=yes
 116                 libdl=
 117                 libgc_threads=pthreads
 118                 ;;
 119         *)
 120                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 121                 platform_win32=no
 122                 libdl="-ldl"
 123                 ;;
 124 esac
 125 AC_MSG_RESULT(ok)
 126
 127 if test x$need_link_unlink = xyes; then
 128    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 129 fi
 130
 131 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 132
 133 AC_CHECK_TOOL(CC, gcc, gcc)
 134 AC_PROG_CC
 135 AM_PROG_CC_STDC
 136 AC_PROG_INSTALL
 137 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 138 : ${CCAS='$(CC)'}
 139 # Set ASFLAGS if not already set.
 140 : ${CCASFLAGS='$(CFLAGS)'}
 141 AC_SUBST(CCAS)
 142 AC_SUBST(CCASFLAGS)
 143
 144 AC_CHECK_PROG(BISON, bison,yes,no)
 145 if test "x$BISON" = "xno";
 146 then
 147         AC_MSG_ERROR([You need to install bison])
 148 fi
 149
 150 dnl may require a specific autoconf version
 151 dnl AC_PROG_CC_FOR_BUILD
 152 dnl CC_FOR_BUILD not automatically detected
 153 CC_FOR_BUILD=$CC
 154 BUILD_EXEEXT=
 155 if test "x$cross_compiling" = "xyes"; then
 156         CC_FOR_BUILD=cc
 157         BUILD_EXEEXT=""
 158 fi
 159 AC_SUBST(CC_FOR_BUILD)
 160 AC_SUBST(HOST_CC)
 161 AC_SUBST(BUILD_EXEEXT)
 162
 163 # Set STDC_HEADERS
 164 AC_HEADER_STDC
 165 AC_LIBTOOL_WIN32_DLL
 166 AM_PROG_LIBTOOL
 167
 168 # Test whenever ld supports -version-script
 169 AC_PROG_LD
 170 AC_PROG_LD_GNU
 171 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 172    no_version_script=yes
 173 fi
 174
 175 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 176
 177 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
 178
 179 # for mono/mini/tramp-x86.c
 180 AC_CHECK_HEADERS(valgrind/memcheck.h)
 181
 182 # for mono/metadata/debug-symfile.c
 183 AC_CHECK_HEADERS(elf.h)
 184
 185 # for mono/dis
 186 AC_CHECK_HEADERS(wchar.h)
 187
 188 # not 64 bit clean in cross-compile
 189 AC_CHECK_SIZEOF(void *, 4)
 190
 191 WARN=''
 192 if test x"$GCC" = xyes; then
 193         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 194                 # The runtime code does not respect ANSI C strict aliasing rules
 195                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 196 else
 197         # The Sun Forte compiler complains about inline functions that access static variables
 198         # so disable all inlining.
 199         case "$host" in
 200         *-*-solaris*)
 201                 CFLAGS="$CFLAGS -Dinline="
 202                 ;;
 203         esac
 204 fi
 205 CFLAGS="$CFLAGS -g $WARN"
 206
 207 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 208 if test "x$PKG_CONFIG" = "xno"; then
 209         AC_MSG_ERROR([You need to install pkg-config])
 210 fi
 211
 212 dnl for use on the build system
 213 dnl pkg-config is stupid
 214 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 215 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 216 AC_SUBST(BUILD_GLIB_CFLAGS)
 217 AC_SUBST(BUILD_GLIB_LIBS)
 218
 219 PKG_PATH=
 220 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 221         if test x$with_crosspkgdir = "x"; then
 222                 if test -s $PKG_CONFIG_PATH; then
 223                         PKG_PATH=$PKG_CONFIG_PATH
 224                 fi
 225         else
 226                 PKG_PATH=$with_crosspkgdir
 227                 PKG_CONFIG_PATH=$PKG_PATH
 228                 export PKG_CONFIG_PATH
 229         fi
 230 )
 231
 232 ## Versions of dependencies
 233 GLIB_REQUIRED_VERSION=1.3.11
 234
 235 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 236
 237 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 238 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 239 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 240 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 241
 242 AC_SUBST(GLIB_CFLAGS)
 243 AC_SUBST(GLIB_LIBS)
 244 AC_SUBST(GMODULE_CFLAGS)
 245 AC_SUBST(GMODULE_LIBS)
 246
 247 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 248
 249 # Enable support for NPTL only features like fast thread-local storage
 250 # We can't reliably detect nptl at compile & run time
 251 # so this option will stay until nptl becomes more widespread
 252 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      enable/disable support for NPTL],[],[with_nptl=yes])
 253
 254 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 255 # This does not work on some platforms (bug #55253)
 256 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 257
 258 # assembly bundle support, see metadata/make-bundle.pl for more info
 259 AC_ARG_WITH(bundle, [  --with-bundle=bundle_template],[
 260         BUNDLE_FILE=$with_bundle
 261         AC_SUBST(BUNDLE_FILE)
 262         AC_DEFINE(WITH_BUNDLE)
 263 ],[with_bundle=no])
 264 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
 265
 266 LIBGC_CFLAGS=
 267 LIBGC_LIBS=
 268 libgc_dir=
 269 case "x$gc" in
 270         xboehm|xbohem|xyes)
 271                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 272                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 273
 274                 if test "x$found_boehm" != "xyes"; then
 275                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 276                 fi
 277                 if test "x$gc_headers" != "xyes"; then
 278                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 279                 fi
 280
 281                 AC_DEFINE(HAVE_BOEHM_GC)
 282                 AC_SUBST(HAVE_BOEHM_GC)
 283                 LIBGC_LIBS="-lgc $libdl"
 284
 285                 # AC_CHECK_FUNCS does not work for some reason...
 286                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 287                 if test "x$found_gcj_malloc" = "xyes"; then
 288                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 289                 fi
 290                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 291                 if test "x$found_gc_enable" = "xyes"; then
 292                         AC_DEFINE(HAVE_GC_ENABLE)
 293                 fi
 294                 ;;
 295
 296         xincluded)
 297                 AC_CONFIG_SUBDIRS(libgc)
 298
 299                 found_boehm=yes
 300                 gc_headers=yes
 301                 use_included_gc=yes
 302                 libgc_dir=libgc
 303
 304                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 305                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 306
 307                 AC_DEFINE(HAVE_BOEHM_GC)
 308                 AC_SUBST(HAVE_BOEHM_GC)
 309
 310                 AC_DEFINE(HAVE_GC_H)
 311                 AC_DEFINE(USE_INCLUDED_LIBGC)
 312
 313                 # The included libgc contains GCJ support
 314                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 315                 AC_DEFINE(HAVE_GC_ENABLE)
 316                 ;;
 317
 318         xnone)
 319                 AC_MSG_WARN("Compiling mono without GC.")
 320                 ;;
 321         *)
 322                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 323                 ;;
 324 esac
 325
 326
 327 # tell libgc/configure about what we want
 328 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
 329
 330 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 331 AC_SUBST(LIBGC_CFLAGS)
 332 AC_SUBST(LIBGC_LIBS)
 333 AC_SUBST(libgc_dir)
 334
 335 dnl
 336 dnl End of libgc checks
 337 dnl
 338
 339 if test x$platform_win32 = xno; then
 340
 341         dnl ******************************************************************
 342         dnl *** Checks for the IKVM JNI interface library                  ***
 343         dnl ******************************************************************
 344         AC_ARG_WITH(ikvm-jni, [  --with-ikvm-jni=yes,no  build the IKVM JNI interface library],[with_ikvm_jni=$withval],[with_ikvm_jni=yes])
 345         AC_ARG_WITH(jdk, [  --with-jdk=DIRECTORY    Use JDK from DIRECTORY],[with_jdk_dir=$withval],[with_jdk_dir=])
 346
 347         ikvm_jni_dir=
 348         if test x$with_ikvm_jni = xyes; then
 349                 AC_MSG_CHECKING([JDK headers])
 350
 351                 if test x$with_jdk_dir = x; then
 352                         # Try JAVA_HOME variable
 353                         if test x$JAVA_HOME != x; then
 354                                 with_jdk_dir=$JAVA_HOME
 355                         fi
 356                 fi
 357
 358                 jdk_platform=
 359                 if test -d $with_jdk_dir/include; then
 360                         jdk_headers_found=yes
 361
 362                         if test -d $with_jdk_dir/include/linux; then
 363                                 jdk_platform=linux
 364                         else
 365                         if test -d $with_jdk_dir/include/solaris; then
 366                                 jdk_platform=solaris
 367                         else
 368                         if test -f $with_jdk_dir/include/jni_md.h; then
 369                                 # GNU Classpath sources
 370                                 jdk_platform=
 371                         else
 372                                 jdk_headers_found=no
 373                         fi
 374                         fi
 375                         fi
 376                 else
 377                         jdk_headers_found=no
 378                 fi
 379
 380                 if test x$jdk_headers_found = xyes; then
 381                         AC_MSG_RESULT($with_jdk_dir/include $with_jdk_dir/include/$jdk_platform)
 382                 else
 383                         AC_MSG_RESULT(not found)
 384                 fi
 385
 386                 if test x$jdk_headers_found = xyes; then
 387                         ikvm_jni_dir=ikvm-jni
 388                         IKVM_JNI_CFLAGS="-I$with_jdk_dir/include -I$with_jdk_dir/include/$jdk_platform"
 389                 fi
 390         fi
 391
 392         AC_SUBST(ikvm_jni_dir)
 393         AC_SUBST(IKVM_JNI_CFLAGS)
 394
 395         AC_CHECK_FUNCS(getgrgid_r)
 396         AC_CHECK_FUNCS(getgrnam_r)
 397         AC_CHECK_FUNCS(getpwnam_r)
 398         AC_CHECK_FUNCS(getpwuid_r)
 399         AC_CHECK_FUNCS(getresuid)
 400         AC_CHECK_FUNCS(setresuid)
 401
 402         dnl ******************************************************************
 403         dnl *** Check for large file support                               ***
 404         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 405         dnl ******************************************************************
 406
 407         # Check that off_t can represent 2**63 - 1 correctly, working around
 408         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 409         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 410         large_offt=no
 411         AC_DEFUN(LARGE_FILES, [
 412                 large_CPPFLAGS=$CPPFLAGS
 413                 CPPFLAGS="$CPPFLAGS $1"
 414                 AC_TRY_RUN([
 415                         #include <sys/types.h>
 416
 417                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 418
 419                         int main(void) {
 420                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 421                                                (BIG_OFF_T%2147483647==1));
 422                                 if(big_off_t) {
 423                                         exit(0);
 424                                 } else {
 425                                         exit(1);
 426                                 }
 427                         }
 428                 ], [
 429                         AC_MSG_RESULT(ok)
 430                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 431                         large_CPPFLAGS="$large_CPPFLAGS $1"
 432                         large_offt=yes
 433                 ], [
 434                         AC_MSG_RESULT(no)
 435                 ], "")
 436                 CPPFLAGS=$large_CPPFLAGS
 437         ])
 438
 439         AC_MSG_CHECKING(if off_t is 64 bits wide)
 440         LARGE_FILES("")
 441         if test $large_offt = no; then
 442                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 443                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 444         fi
 445         if test $large_offt = no; then
 446                 AC_MSG_WARN([No 64 bit file size support available])
 447         fi
 448
 449         dnl *****************************
 450         dnl *** Checks for libsocket  ***
 451         dnl *****************************
 452         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 453
 454         dnl *******************************
 455         dnl *** Checks for MSG_NOSIGNAL ***
 456         dnl *******************************
 457         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 458         AC_TRY_COMPILE([#include <sys/socket.h>], [
 459                 int f = MSG_NOSIGNAL;
 460         ], [
 461                 # Yes, we have it...
 462                 AC_MSG_RESULT(yes)
 463                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 464         ], [
 465                 # We'll have to use signals
 466                 AC_MSG_RESULT(no)
 467         ])
 468
 469         dnl *****************************
 470         dnl *** Checks for SOL_IP     ***
 471         dnl *****************************
 472         AC_MSG_CHECKING(for SOL_IP)
 473         AC_TRY_COMPILE([#include <netdb.h>], [
 474                 int level = SOL_IP;
 475         ], [
 476                 # Yes, we have it...
 477                 AC_MSG_RESULT(yes)
 478                 AC_DEFINE(HAVE_SOL_IP)
 479         ], [
 480                 # We'll have to use getprotobyname
 481                 AC_MSG_RESULT(no)
 482         ])
 483
 484         dnl *****************************
 485         dnl *** Checks for SOL_IPV6     ***
 486         dnl *****************************
 487         AC_MSG_CHECKING(for SOL_IPV6)
 488         AC_TRY_COMPILE([#include <netdb.h>], [
 489                 int level = SOL_IPV6;
 490         ], [
 491                 # Yes, we have it...
 492                 AC_MSG_RESULT(yes)
 493                 AC_DEFINE(HAVE_SOL_IPV6)
 494         ], [
 495                 # We'll have to use getprotobyname
 496                 AC_MSG_RESULT(no)
 497         ])
 498
 499         dnl *****************************
 500         dnl *** Checks for SOL_TCP    ***
 501         dnl *****************************
 502         AC_MSG_CHECKING(for SOL_TCP)
 503         AC_TRY_COMPILE([#include <netdb.h>], [
 504                 int level = SOL_TCP;
 505         ], [
 506                 # Yes, we have it...
 507                 AC_MSG_RESULT(yes)
 508                 AC_DEFINE(HAVE_SOL_TCP)
 509         ], [
 510                 # We'll have to use getprotobyname
 511                 AC_MSG_RESULT(no)
 512         ])
 513
 514         dnl *****************************
 515         dnl *** Checks for IP_PKTINFO ***
 516         dnl *****************************
 517         AC_MSG_CHECKING(for IP_PKTINFO)
 518         AC_TRY_COMPILE([#include <netdb.h>], [
 519                 int level = IP_PKTINFO;
 520         ], [
 521                 # Yes, we have it...
 522                 AC_MSG_RESULT(yes)
 523                 AC_DEFINE(HAVE_IP_PKTINFO)
 524         ], [
 525                 AC_MSG_RESULT(no)
 526         ])
 527
 528         dnl *********************************
 529         dnl *** Check for struct ip_mreqn ***
 530         dnl *********************************
 531         AC_MSG_CHECKING(for struct ip_mreqn)
 532         AC_TRY_COMPILE([#include <netinet/in.h>], [
 533                 struct ip_mreqn mreq;
 534                 mreq.imr_address.s_addr = 0;
 535         ], [
 536                 # Yes, we have it...
 537                 AC_MSG_RESULT(yes)
 538                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 539         ], [
 540                 # We'll just have to try and use struct ip_mreq
 541                 AC_MSG_RESULT(no)
 542                 AC_MSG_CHECKING(for struct ip_mreq)
 543                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 544                         struct ip_mreq mreq;
 545                         mreq.imr_interface.s_addr = 0;
 546                 ], [
 547                         # Yes, we have it...
 548                         AC_MSG_RESULT(yes)
 549                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 550                 ], [
 551                         # No multicast support
 552                         AC_MSG_RESULT(no)
 553                 ])
 554         ])
 555
 556         dnl **********************************
 557         dnl *** Check for gethostbyname2_r ***
 558         dnl **********************************
 559         AC_MSG_CHECKING(for gethostbyname2_r)
 560                 AC_TRY_LINK([#include <netdb.h>], [
 561                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 562         ], [
 563                 # Yes, we have it...
 564                 AC_MSG_RESULT(yes)
 565                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 566         ], [
 567                 AC_MSG_RESULT(no)
 568         ])
 569
 570         dnl *****************************
 571         dnl *** Checks for libnsl     ***
 572         dnl *****************************
 573         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 574
 575         AC_CHECK_FUNCS(inet_pton inet_aton)
 576
 577         dnl ***********************************************
 578         dnl *** Checks for size of sockaddr_un.sun_path ***
 579         dnl ***********************************************
 580         # AC_CHECK_SIZEOF can't cope with struct members :-(
 581         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 582         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 583                 [AC_TRY_RUN([
 584                         #include <sys/types.h>
 585                         #include <stdio.h>
 586                         #include <sys/un.h>
 587
 588                         int main(void) {
 589                                 struct sockaddr_un sock_un;
 590                                 FILE *f=fopen("conftestval", "w");
 591                                 if(!f) exit(1);
 592                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 593                                 exit(0);
 594                         }
 595                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 596                    cv_mono_sizeof_sunpath=0,
 597                    cv_mono_sizeof_sunpath=0)])dnl
 598         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 599         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 600
 601         dnl *************************************
 602         dnl *** Checks for zero length arrays ***
 603         dnl *************************************
 604         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 605         AC_TRY_COMPILE([
 606                 struct s {
 607                         int  length;
 608                         char data [0];
 609                 };
 610         ], [], [
 611                 AC_MSG_RESULT(yes)
 612                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 613         ], [
 614                 AC_MSG_RESULT(no)
 615                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 616         ])
 617
 618         dnl *****************************
 619         dnl *** Checks for libxnet    ***
 620         dnl *****************************
 621         case "${host}" in
 622                 *solaris* )
 623                         AC_MSG_CHECKING(for Solaris XPG4 support)
 624                         if test -f /usr/lib/libxnet.so; then
 625                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 626                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 627                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 628                                 LIBS="$LIBS -lxnet"
 629                                 AC_MSG_RESULT(yes)
 630                         else
 631                                 AC_MSG_RESULT(no)
 632                         fi
 633
 634                         if test "$GCC" = "yes"; then
 635                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 636                         fi
 637                 ;;
 638         esac
 639
 640         dnl *****************************
 641         dnl *** Checks for libpthread ***
 642         dnl *****************************
 643         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 644         AC_CHECK_HEADERS(pthread.h)
 645         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 646         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 647         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 648         AC_TRY_COMPILE([ #include <pthread.h>], [
 649                 pthread_mutexattr_t attr;
 650                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 651         ], [
 652                 AC_MSG_RESULT(ok)
 653         ], [
 654                 AC_MSG_RESULT(no)
 655                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 656                 AC_DEFINE(USE_MONO_MUTEX)
 657         ])
 658         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 659
 660         dnl ***********************************
 661         dnl *** Checks for working __thread ***
 662         dnl ***********************************
 663         AC_MSG_CHECKING(for working __thread)
 664         if test "x$with_nptl" != "xyes"; then
 665                 AC_MSG_RESULT(disabled)
 666         else
 667                 AC_TRY_RUN([
 668                         #include <pthread.h>
 669
 670                         __thread int i;
 671                         static int res1, res2;
 672
 673                         void thread_main (void *arg)
 674                         {
 675                                 i = arg;
 676                                 sleep (1);
 677                                 if (arg == 1)
 678                                         res1 = (i == arg);
 679                                 else
 680                                         res2 = (i == arg);
 681                         }
 682
 683                         int main () {
 684                                 pthread_t t1, t2;
 685
 686                                 i = 5;
 687
 688                                 pthread_create (&t1, NULL, thread_main, 1);
 689                                 pthread_create (&t2, NULL, thread_main, 2);
 690
 691                                 pthread_join (t1, NULL);
 692                                 pthread_join (t2, NULL);
 693
 694                                 return !(res1 + res2 == 2);
 695                         }
 696                 ], [
 697                                 AC_MSG_RESULT(yes)
 698                                 AC_DEFINE(HAVE_KW_THREAD)
 699                 ], [
 700                                 AC_MSG_RESULT(no)
 701                 ])
 702         fi
 703
 704         dnl **************************************
 705         dnl *** Checks for working sigaltstack ***
 706         dnl **************************************
 707         AC_MSG_CHECKING(for working sigaltstack)
 708         if test "x$with_sigaltstack" != "xyes"; then
 709                 AC_MSG_RESULT(disabled)
 710         else
 711                 AC_TRY_RUN([
 712                         #include <stdio.h>
 713                         #include <stdlib.h>
 714                         #include <unistd.h>
 715                         #include <signal.h>
 716                         #include <pthread.h>
 717                         #include <sys/wait.h>
 718
 719                         static void
 720                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 721                         {
 722                                 exit (0);
 723                         }
 724
 725                         static void *
 726                         loop (void *ignored)
 727                         {
 728                                 char *ptr = NULL;
 729
 730                                 *ptr = 0;
 731                                 return NULL;
 732                         }
 733
 734                         static void
 735                         child ()
 736                         {
 737                                 struct sigaction sa;
 738                                 struct sigaltstack sas;
 739                                 pthread_t id;
 740                                 pthread_attr_t attr;
 741
 742                                 sa.sa_sigaction = sigsegv_signal_handler;
 743                                 sigemptyset (&sa.sa_mask);
 744                                 sa.sa_flags = SA_SIGINFO | SA_STACK;
 745                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 746                                         perror ("lala");
 747                                         return;
 748                                 }
 749
 750                                 sas.ss_sp = malloc (SIGSTKSZ);
 751                                 sas.ss_size = SIGSTKSZ;
 752                                 sas.ss_flags = SS_ONSTACK;
 753                                 if (sigaltstack (&sas, NULL) == -1) {
 754                                         perror ("lala");
 755                                         return;
 756                                 }
 757
 758                                 pthread_attr_init (&attr);
 759                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 760                                         printf ("failed\n");
 761                                         return;
 762                                 }
 763
 764                                 sleep (100);
 765                         }
 766
 767                         int
 768                         main ()
 769                         {
 770                                 pid_t son;
 771                                 int status;
 772                                 int i;
 773
 774                                 son = fork ();
 775                                 if (son == -1) {
 776                                         return 1;
 777                                 }
 778
 779                                 if (son == 0) {
 780                                         child ();
 781                                         return 0;
 782                                 }
 783
 784                                 for (i = 0; i < 3; ++i) {
 785                                         sleep (1);
 786                                         waitpid (son, &status, WNOHANG);
 787                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 788                                                 return 0;
 789                                 }
 790
 791                                 kill (son, SIGKILL);
 792                                 return 1;
 793                         }
 794
 795                 ], [
 796                                 AC_MSG_RESULT(yes)
 797                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 798                 ], [
 799                                 with_sigaltstack=no
 800                                 AC_MSG_RESULT(no)
 801                 ])
 802         fi
 803
 804         dnl ********************************
 805         dnl *** Checks for semaphore lib ***
 806         dnl ********************************
 807         # 'Real Time' functions on Solaris
 808         # posix4 on Solaris 2.6
 809         # pthread (first!) on Linux
 810         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 811
 812         dnl ********************************
 813         dnl *** Checks for timezone stuff **
 814         dnl ********************************
 815         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 816                 AC_TRY_COMPILE([
 817                         #include <time.h>
 818                         ], [
 819                         struct tm tm;
 820                         tm.tm_gmtoff = 1;
 821                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 822         if test $ac_cv_struct_tm_gmtoff = yes; then
 823                 AC_DEFINE(HAVE_TM_GMTOFF)
 824         else
 825                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 826                         AC_TRY_COMPILE([
 827                                 #include <time.h>
 828                         ], [
 829                                 timezone = 1;
 830                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 831                 if test $ac_cv_var_timezone = yes; then
 832                         AC_DEFINE(HAVE_TIMEZONE)
 833                 else
 834                         AC_ERROR(unable to find a way to determine timezone)
 835                 fi
 836         fi
 837
 838         dnl *********************************
 839         dnl *** Checks for math functions ***
 840         dnl *********************************
 841         LIBS="$LIBS -lm";
 842         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 843                 AC_TRY_LINK([#include <math.h>],
 844                 [ finite(0.0); ],
 845                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 846                 AC_MSG_RESULT(no)))
 847         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 848                 AC_TRY_LINK([#include <math.h>],
 849                 [ isfinite(0.0); ],
 850                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 851                 AC_MSG_RESULT(no)))
 852
 853         dnl ****************************************************************
 854         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 855         dnl *** have it in the library (duh))                            ***
 856         dnl ****************************************************************
 857         AC_CHECK_FUNCS(poll)
 858
 859         dnl *************************
 860         dnl *** Check for signbit ***
 861         dnl *************************
 862         AC_MSG_CHECKING(for signbit)
 863         AC_TRY_LINK([#include <math.h>], [
 864                 int s = signbit(1.0);
 865         ], [
 866                 AC_MSG_RESULT(yes)
 867                 AC_DEFINE(HAVE_SIGNBIT)
 868         ], [
 869                 AC_MSG_RESULT(no)
 870         ])
 871
 872         dnl *********************
 873         dnl *** Check for AIO ***
 874         dnl *********************
 875         AC_MSG_CHECKING([for SIGEV_THREAD definition])
 876         dnl Some systems (FreeBSD at least) may have aio_read
 877         dnl but don't support/define SIGEV_THREAD.
 878         AC_TRY_COMPILE([
 879         #include <sys/signal.h>
 880         ],[
 881         int x = SIGEV_THREAD;
 882         ],[
 883                 ac_cv_c_sigev_thread=yes
 884                 AC_MSG_RESULT(yes)
 885         ],[
 886                 AC_MSG_RESULT(no)
 887         ])
 888
 889         if test "$ac_cv_c_sigev_thread" = "yes" ; then
 890                 AC_CHECK_HEADERS(aio.h sys/aio.h)
 891                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
 892                 SIGVAL_PTR="undefined"
 893                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
 894                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
 895                                         #include <sys/signal.h>
 896                                         ])
 897                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
 898                                         #include <sys/signal.h>
 899                                         ])
 900                         if test "$SIGVAL_PTR" = "undefined" ; then
 901                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
 902                         fi
 903                 fi
 904                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
 905         fi
 906 else
 907         jdk_headers_found=no
 908         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 909         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 910 fi
 911
 912 dnl socklen_t check
 913 AC_MSG_CHECKING(for socklen_t)
 914 AC_TRY_COMPILE([
 915 #include <sys/types.h>
 916 #include <sys/socket.h>
 917 ],[
 918   socklen_t foo;
 919 ],[
 920 ac_cv_c_socklen_t=yes
 921         AC_DEFINE(HAVE_SOCKLEN_T)
 922         AC_MSG_RESULT(yes)
 923 ],[
 924         AC_MSG_RESULT(no)
 925 ])
 926
 927 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
 928         AC_TRY_LINK([#include <math.h>],
 929         [ trunc(0.0); ],
 930         [
 931                 AC_DEFINE(HAVE_TRUNC)
 932                 AC_MSG_RESULT(yes)
 933                 ac_cv_trunc=yes
 934         ],
 935         AC_MSG_RESULT(no)))
 936
 937 if test "x$ac_cv_truncl" != "xyes"; then
 938    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
 939 fi
 940
 941 dnl ****************************
 942 dnl *** Look for /dev/random ***
 943 dnl ****************************
 944
 945 AC_MSG_CHECKING([if usage of random device is requested])
 946 AC_ARG_ENABLE(dev-random,
 947 [  --disable-dev-random    disable the use of the random device],
 948 try_dev_random=$enableval, try_dev_random=yes)
 949 AC_MSG_RESULT($try_dev_random)
 950
 951 case "{$target}" in
 952     *-openbsd*)
 953     NAME_DEV_RANDOM="/dev/srandom"
 954     ;;
 955
 956 dnl Win32 does not have /dev/random, they have their own method...
 957
 958     *-*-mingw*|*-*-cygwin*)
 959     ac_cv_have_dev_random=no
 960     ;;
 961
 962 dnl Everywhere else, it's /dev/random
 963
 964     *)
 965     NAME_DEV_RANDOM="/dev/random"
 966     ;;
 967 esac
 968
 969 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 970
 971 dnl Now check if the device actually exists
 972
 973 if test "x$try_dev_random" = "xyes"; then
 974     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 975     [if test -r "$NAME_DEV_RANDOM" ; then
 976         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 977     if test "x$ac_cv_have_dev_random" = "xyes"; then
 978         AC_DEFINE(HAVE_CRYPT_RNG)
 979     fi
 980 else
 981     AC_MSG_CHECKING(for random device)
 982     ac_cv_have_dev_random=no
 983     AC_MSG_RESULT(has been disabled)
 984 fi
 985
 986 if test "x$platform_win32" = "xyes"; then
 987     AC_DEFINE(HAVE_CRYPT_RNG)
 988 fi
 989
 990 if test "x$ac_cv_have_dev_random" = "xno" \
 991     && test "x$platform_win32" = "xno"; then
 992     AC_MSG_WARN([[
 993 ***
 994 *** A system-provided entropy source was not found on this system.
 995 *** Because of this, the System.Security.Cryptography random number generator
 996 *** will throw a NotImplemented exception.
 997 ***
 998 *** If you are seeing this message, and you know your system DOES have an
 999 *** entropy collection in place, please contact <crichton@gimp.org> and
1000 *** provide information about the system and how to access the random device.
1001 ***
1002 *** Otherwise you can install either egd or prngd and set the environment
1003 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1004 ***]])
1005 fi
1006
1007 AC_MSG_CHECKING([if inter-process shared handles are requested])
1008 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1009 AC_MSG_RESULT($try_shared_handles)
1010 if test "x$try_shared_handles" != "xyes"; then
1011         AC_DEFINE(DISABLE_SHARED_HANDLES)
1012         AC_SUBST(DISABLE_SHARED_HANDLES)
1013 fi
1014
1015 #
1016 # ICU
1017 #
1018 ICU_CFLAGS=""
1019 ICU_LIBS=""
1020 enable_icu=no
1021
1022 probe_icu=true
1023 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1024         if test x$with_icu = xno; then
1025            probe_icu=false;
1026            AC_MSG_RESULT(Will not probe for ICU)
1027         fi
1028 )
1029
1030 if $probe_icu; then
1031         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1032         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1033                 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1034                 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1035         else
1036                 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1037                 AC_DEFINE(HAVE_ICU)
1038                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1039                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1040         fi
1041 fi
1042 AC_SUBST(ICU_CFLAGS)
1043 AC_SUBST(ICU_LIBS)
1044
1045 TARGET="unknown"
1046 ACCESS_UNALIGNED="yes"
1047
1048 JIT_SUPPORTED=no
1049 LIBC="libc.so.6"
1050
1051 jit_wanted=false
1052 case "$host" in
1053 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1054 #               TARGET=MIPS;
1055 #               ACCESS_UNALIGNED="no"
1056 #               ;;
1057         i*86-*-*)
1058                 TARGET=X86;
1059                 arch_target=x86;
1060                 JIT_SUPPORTED=yes
1061                 jit_wanted=true
1062                 ;;
1063         x86_64-*-* | amd64-*-*)
1064                 TARGET=AMD64;
1065                 arch_target=amd64;
1066                 JIT_SUPPORTED=no
1067                 ;;
1068         sparc*-*-*)
1069                 TARGET=SPARC;
1070                 arch_target=sparc;
1071                 JIT_SUPPORTED=yes
1072                 ACCESS_UNALIGNED="no"
1073                 LIBC="libc.so"
1074                 jit_wanted=true
1075                 ;;
1076 #       alpha*-*-linux* | alpha*-*-osf*)
1077 #               TARGET=ALPHA;
1078 #               ACCESS_UNALIGNED="no"
1079 #              ;;
1080 #       ia64-*-linux* | ia64-*-hpux*)
1081 #               TARGET=IA64;
1082 #               arch_target=ia64;
1083 #               JIT_SUPPORTED=no;
1084 #               ACCESS_UNALIGNED="no";
1085 #               case "$host_os" in
1086 #                       linux*) LIBC="libc.so.6.1";;
1087 #                       hpux*)  LIBC="libc.so.1";;
1088 #               esac
1089 #               ;;
1090 #       m68k-*-linux*)
1091 #               TARGET=M68K
1092 #               ;;
1093         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1094                 TARGET=HPPA;
1095                 arch_target=hppa;
1096                 LIBC="libc.sl"
1097                 ACCESS_UNALIGNED="no"
1098                 ;;
1099         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1100         powerpc-*-sysv* | powerpc-*-darwin*)
1101                 TARGET=POWERPC;
1102                 arch_target=ppc;
1103                 JIT_SUPPORTED=yes
1104                 jit_wanted=true
1105                 ;;
1106         arm-*-linux-* | armv4l-*-linux-*)
1107                 TARGET=ARM;
1108                 arch_target=arm;
1109                 ACCESS_UNALIGNED="no"
1110                 ;;
1111         s390-*-linux*)
1112                 TARGET=S390;
1113                 arch_target=s390;
1114                 ACCESS_UNALIGNED="no"
1115                 JIT_SUPPORTED=yes
1116                 ;;
1117 esac
1118
1119 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1120         jit_wanted=true
1121 ])
1122
1123 USEJIT=false
1124 if test x$JIT_SUPPORTED = xyes; then
1125    if $jit_wanted; then
1126       USEJIT=true
1127       jit_status="Building and using the JIT"
1128    else
1129       jit_status="Building the JIT, defaulting to the interpreter"
1130    fi
1131 else
1132    jit_status="interpreter"
1133 fi
1134
1135 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1136
1137 libsuffix=".so"
1138
1139 case "$host" in
1140      powerpc-*-darwin*)
1141         libsuffix=".dylib"
1142         LIBC="libc.dylib"
1143         ;;
1144      *-*-*netbsd*)
1145         LIBC="libc.so.12"
1146         ;;
1147 esac
1148 AC_SUBST(libsuffix)
1149
1150 if test ${TARGET} = ARM; then
1151         dnl ******************************************
1152         dnl *** Check to see what FPU is available ***
1153         dnl ******************************************
1154         AC_MSG_CHECKING(which FPU to use)
1155
1156         AC_TRY_COMPILE([], [
1157                 __asm__ ("ldfd f0, [r0]");
1158                 ], fpu=FPA, [
1159                         AC_TRY_COMPILE([], [
1160                                 __asm__ ("fldd d0, [r0]");
1161                         ], fpu=VFP, fpu=NONE)
1162                 ])
1163
1164         AC_MSG_RESULT($fpu)
1165         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1166         unset fpu
1167 fi
1168
1169 if test ${TARGET} = unknown; then
1170         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1171         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1172 fi
1173
1174 if test ${ACCESS_UNALIGNED} = no; then
1175         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1176 fi
1177
1178 PREVIEW=no
1179 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1180         if test x$with_preview = xyes; then
1181               PREVIEW=yes
1182         fi
1183 ])
1184
1185 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1186
1187 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1188 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1189 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1190 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1191 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1192 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1193 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1194 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1195 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1196 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1197 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1198 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1199
1200 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1201
1202 AC_SUBST(LIBC)
1203
1204 AC_SUBST(arch_target)
1205 AC_SUBST(CFLAGS)
1206 AC_SUBST(CPPFLAGS)
1207 AC_SUBST(LDFLAGS)
1208
1209 AC_OUTPUT([
1210 Makefile
1211 mint.pc
1212 mono.pc
1213 mono/Makefile
1214 mono/utils/Makefile
1215 mono/metadata/Makefile
1216 mono/dis/Makefile
1217 mono/cil/Makefile
1218 mono/arch/Makefile
1219 mono/os/Makefile
1220 mono/os/win32/Makefile
1221 mono/os/unix/Makefile
1222 mono/arch/x86/Makefile
1223 mono/arch/amd64/Makefile
1224 mono/arch/hppa/Makefile
1225 mono/arch/ppc/Makefile
1226 mono/arch/sparc/Makefile
1227 mono/arch/s390/Makefile
1228 mono/arch/arm/Makefile
1229 mono/arch/alpha/Makefile
1230 mono/interpreter/Makefile
1231 mono/tests/Makefile
1232 mono/tests/tests-config
1233 mono/benchmark/Makefile
1234 mono/monoburg/Makefile
1235 mono/monograph/Makefile
1236 mono/io-layer/Makefile
1237 mono/handles/Makefile
1238 mono/mini/Makefile
1239 mono/profiler/Makefile
1240 ikvm-jni/Makefile
1241 runtime/Makefile
1242 runtime/net_1_1/Makefile
1243 runtime/net_2_0/Makefile
1244 scripts/Makefile
1245 man/Makefile
1246 web/Makefile
1247 docs/Makefile
1248 data/Makefile
1249 samples/Makefile
1250 support/Makefile
1251 data/config
1252 mono.spec
1253 tools/Makefile
1254 tools/locale-builder/Makefile
1255 ])
1256
1257 echo "
1258
1259         GC:          $gc
1260         ICU:         $enable_icu
1261         NPTL:        $with_nptl
1262         SIGALTSTACK: $with_sigaltstack
1263         Engine:      $jit_status
1264         2.0 Alpha:   $PREVIEW
1265         JNI support: $jdk_headers_found
1266
1267 "