configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.31.99)
   5 AM_MAINTAINER_MODE
   6
   7 dnl
   8 dnl libgc checks
   9 dnl
  10
  11 gc_headers=no
  12 gc=included
  13 use_included_gc=no
  14
  15 if test -d $srcdir/libgc ; then
  16   gc_default=included
  17 else
  18   gc_default=boehm
  19 fi
  20
  21 #
  22 # These are the flags that need to be stored in the mono.pc file for
  23 # compiling code that will embed Mono
  24 #
  25 libmono_cflags=""
  26 libmono_ldflags=""
  27 AC_SUBST(libmono_cflags)
  28 AC_SUBST(libmono_ldflags)
  29
  30 dnl if linker handles the version script
  31 no_version_script=no
  32
  33 # Thread configuration inspired by sleepycat's db
  34 AC_MSG_CHECKING([host platform characteristics])
  35 libgc_threads=no
  36 case "$host" in
  37         *-*-mingw*|*-*-cygwin*)
  38                 platform_win32=yes
  39                 AC_DEFINE(PLATFORM_WIN32)
  40                 CC="gcc -mno-cygwin"
  41                 HOST_CC="gcc"
  42 # latest libgc already defines GC_WIN32_THREADS
  43 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  44                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  45                 libdl=
  46                 libgc_threads=win32
  47                 gc_default=boehm
  48                 ;;
  49         *-*-*netbsd*)
  50                 platform_win32=no
  51                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  52                 libmono_cflags="-D_REENTRANT"
  53                 LDFLAGS="$LDFLAGS -pthread"
  54                 libmono_ldflags="-pthread"
  55                 AC_DEFINE(NEED_LINK_UNLINK)
  56                 libdl=
  57                 libgc_threads=pthreads
  58                 ;;
  59         *-*-*freebsd*|*-*-*openbsd*)
  60                 platform_win32=no
  61                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE"
  62                 libmono_cflags="-D_THREAD_SAFE"
  63                 LDFLAGS="$LDFLAGS -pthread"
  64                 libmono_ldflags="-pthread"
  65                 AC_DEFINE(NEED_LINK_UNLINK)
  66                 AC_DEFINE(PTHREAD_POINTER_ID)
  67                 libdl=
  68                 libgc_threads=pthreads
  69                 ;;
  70         *-*-linux*)
  71                 platform_win32=no
  72                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -DMONO_USE_EXC_TABLES -D_GNU_SOURCE -D_REENTRANT -fexceptions"
  73                 libmono_cflags="-DMONO_USE_EXC_TABLES -fexceptions -D_REENTRANT"
  74                 libmono_ldflags="-lpthread"
  75                 libdl="-ldl"
  76                 libgc_threads=pthreads
  77                 ;;
  78         *-*-hpux*)
  79                 platform_win32=no
  80                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
  81                 CFLAGS="$CFLAGS +ESdbgasm"
  82                 LDFLAGS="$LDFLAGS -z"
  83                 libmono_cflags="-D_REENTRANT"
  84                 libmono_ldflags="-lpthread"
  85                 libgc_threads=pthreads
  86                 AC_DEFINE(NEED_LINK_UNLINK)
  87                 ;;
  88         *-*-solaris*)
  89                 platform_win32=no
  90                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
  91                 AC_DEFINE(NEED_LINK_UNLINK)
  92                 libmono_cflags="-D_REENTRANT"
  93                 libgc_threads=pthreads
  94                 ;;
  95         *-*-darwin*)
  96                 platform_win32=no
  97                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE"
  98                 libmono_cflags="-D_THREAD_SAFE"
  99                 LDFLAGS="$LDFLAGS -pthread"
 100                 libmono_ldflags="-pthread"
 101                 AC_DEFINE(NEED_LINK_UNLINK)
 102                 AC_DEFINE(PTHREAD_POINTER_ID)
 103                 AC_DEFINE(USE_MACH_SEMA)
 104                 no_version_script=yes
 105                 libdl=
 106                 libgc_threads=no
 107                 gc_default=none
 108                 ;;
 109         *)
 110                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 111                 platform_win32=no
 112                 libdl="-ldl"
 113                 ;;
 114 esac
 115 AC_MSG_RESULT(ok)
 116 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 117
 118 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 119
 120 AC_CHECK_TOOL(CC, gcc, gcc)
 121 AC_PROG_CC
 122 AM_PROG_CC_STDC
 123 AC_PROG_INSTALL
 124 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 125 : ${CCAS='$(CC)'}
 126 # Set ASFLAGS if not already set.
 127 : ${CCASFLAGS='$(CFLAGS)'}
 128 AC_SUBST(CCAS)
 129 AC_SUBST(CCASFLAGS)
 130
 131 AC_CHECK_PROG(BISON, bison,yes,no)
 132 if test "x$BISON" = "xno";
 133 then
 134         AC_MSG_ERROR([You need to install bison])
 135 fi
 136
 137 dnl may require a specific autoconf version
 138 dnl AC_PROG_CC_FOR_BUILD
 139 dnl CC_FOR_BUILD not automatically detected
 140 CC_FOR_BUILD=$CC
 141 BUILD_EXEEXT=
 142 if test "x$cross_compiling" = "xyes"; then
 143         CC_FOR_BUILD=cc
 144         BUILD_EXEEXT=""
 145 fi
 146 AC_SUBST(CC_FOR_BUILD)
 147 AC_SUBST(HOST_CC)
 148 AC_SUBST(BUILD_EXEEXT)
 149
 150 # Set STDC_HEADERS
 151 AC_HEADER_STDC
 152 AC_LIBTOOL_WIN32_DLL
 153 AM_PROG_LIBTOOL
 154
 155 # Test whenever ld supports -version-script
 156 AC_PROG_LD
 157 AC_PROG_LD_GNU
 158 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 159    no_version_script=yes
 160 fi
 161
 162 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
 163
 164 # for mono/mini/tramp-x86.c
 165 AC_CHECK_HEADERS(valgrind/memcheck.h)
 166
 167 # for mono/metadata/debug-symfile.c
 168 AC_CHECK_HEADERS(elf.h)
 169
 170 # for mono/dis
 171 AC_CHECK_HEADERS(wchar.h)
 172
 173 # not 64 bit clean in cross-compile
 174 AC_CHECK_SIZEOF(void *, 4)
 175
 176 WARN=''
 177 if test x"$GCC" = xyes; then
 178         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 179                 # The runtime code does not respect ANSI C strict aliasing rules
 180                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 181 else
 182         # The Sun Forte compiler complains about inline functions that access static variables
 183         # so disable all inlining.
 184         case "$host" in
 185         *-*-solaris*)
 186                 CFLAGS="$CFLAGS -Dinline="
 187                 ;;
 188         esac
 189 fi
 190 CFLAGS="$CFLAGS -g $WARN"
 191
 192 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 193 if test "x$PKG_CONFIG" = "xno"; then
 194         AC_MSG_ERROR([You need to install pkg-config])
 195 fi
 196
 197 dnl for use on the build system
 198 dnl pkg-config is stupid
 199 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 200 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 201 AC_SUBST(BUILD_GLIB_CFLAGS)
 202 AC_SUBST(BUILD_GLIB_LIBS)
 203
 204 PKG_PATH=
 205 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 206         if test x$with_crosspkgdir = "x"; then
 207                 if test -s $PKG_CONFIG_PATH; then
 208                         PKG_PATH=$PKG_CONFIG_PATH
 209                 fi
 210         else
 211                 PKG_PATH=$with_crosspkgdir
 212                 PKG_CONFIG_PATH=$PKG_PATH
 213                 export PKG_CONFIG_PATH
 214         fi
 215 )
 216
 217 ## Versions of dependencies
 218 GLIB_REQUIRED_VERSION=1.3.11
 219
 220 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 221
 222 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 223 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 224 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 225 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 226
 227 AC_SUBST(GLIB_CFLAGS)
 228 AC_SUBST(GLIB_LIBS)
 229 AC_SUBST(GMODULE_CFLAGS)
 230 AC_SUBST(GMODULE_LIBS)
 231
 232 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 233
 234 # Enable support for NPTL only features like fast thread-local storage
 235 # We can't reliably detect nptl at compile & run time
 236 # so this option will stay until nptl becomes more widespread
 237 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      enable/disable support for NPTL],[],[with_nptl=yes])
 238
 239 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 240 # This does not work on some platforms (bug #55253)
 241 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 242
 243 # assembly bundle support, see metadata/make-bundle.pl for more info
 244 AC_ARG_WITH(bundle, [  --with-bundle=bundle_template],[
 245         BUNDLE_FILE=$with_bundle
 246         AC_SUBST(BUNDLE_FILE)
 247         AC_DEFINE(WITH_BUNDLE)
 248 ],[with_bundle=no])
 249 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
 250
 251 LIBGC_CFLAGS=
 252 LIBGC_LIBS=
 253 libgc_dir=
 254 case "x$gc" in
 255         xboehm|xbohem|xyes)
 256                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 257                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 258
 259                 if test "x$found_boehm" != "xyes"; then
 260                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 261                 fi
 262                 if test "x$gc_headers" != "xyes"; then
 263                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 264                 fi
 265
 266                 AC_DEFINE(HAVE_BOEHM_GC)
 267                 AC_SUBST(HAVE_BOEHM_GC)
 268                 LIBGC_LIBS="-lgc $libdl"
 269
 270                 # AC_CHECK_FUNCS does not work for some reason...
 271                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 272                 if test "x$found_gcj_malloc" = "xyes"; then
 273                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 274                 fi
 275                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 276                 if test "x$found_gc_enable" = "xyes"; then
 277                         AC_DEFINE(HAVE_GC_ENABLE)
 278                 fi
 279                 ;;
 280
 281         xincluded)
 282                 AC_CONFIG_SUBDIRS(libgc)
 283
 284                 found_boehm=yes
 285                 gc_headers=yes
 286                 use_included_gc=yes
 287                 libgc_dir=libgc
 288
 289                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 290                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 291
 292                 AC_DEFINE(HAVE_BOEHM_GC)
 293                 AC_SUBST(HAVE_BOEHM_GC)
 294
 295                 AC_DEFINE(HAVE_GC_H)
 296                 AC_DEFINE(USE_INCLUDED_LIBGC)
 297
 298                 # The included libgc contains GCJ support
 299                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 300                 AC_DEFINE(HAVE_GC_ENABLE)
 301                 ;;
 302
 303         xnone)
 304                 AC_MSG_WARN("Compiling mono without GC.")
 305                 ;;
 306         *)
 307                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 308                 ;;
 309 esac
 310
 311 we_are_embedded_in_mono=yes
 312 export we_are_embedded_in_mono
 313 export libgc_threads
 314
 315 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 316 AC_SUBST(LIBGC_CFLAGS)
 317 AC_SUBST(LIBGC_LIBS)
 318 AC_SUBST(libgc_dir)
 319
 320 dnl
 321 dnl End of libgc checks
 322 dnl
 323
 324 if test x$platform_win32 = xno; then
 325         AC_CHECK_FUNCS(getpwuid_r)
 326         dnl ******************************************************************
 327         dnl *** Check for large file support                               ***
 328         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 329         dnl ******************************************************************
 330
 331         # Check that off_t can represent 2**63 - 1 correctly, working around
 332         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 333         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 334         large_offt=no
 335         AC_DEFUN(LARGE_FILES, [
 336                 large_CPPFLAGS=$CPPFLAGS
 337                 CPPFLAGS="$CPPFLAGS $1"
 338                 AC_TRY_RUN([
 339                         #include <sys/types.h>
 340
 341                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 342
 343                         int main(void) {
 344                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 345                                                (BIG_OFF_T%2147483647==1));
 346                                 if(big_off_t) {
 347                                         exit(0);
 348                                 } else {
 349                                         exit(1);
 350                                 }
 351                         }
 352                 ], [
 353                         AC_MSG_RESULT(ok)
 354                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 355                         large_CPPFLAGS="$large_CPPFLAGS $1"
 356                         large_offt=yes
 357                 ], [
 358                         AC_MSG_RESULT(no)
 359                 ], "")
 360                 CPPFLAGS=$large_CPPFLAGS
 361         ])
 362
 363         AC_MSG_CHECKING(if off_t is 64 bits wide)
 364         LARGE_FILES("")
 365         if test $large_offt = no; then
 366                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 367                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 368         fi
 369         if test $large_offt = no; then
 370                 AC_MSG_WARN([No 64 bit file size support available])
 371         fi
 372
 373         dnl *****************************
 374         dnl *** Checks for libsocket  ***
 375         dnl *****************************
 376         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 377
 378         dnl *******************************
 379         dnl *** Checks for MSG_NOSIGNAL ***
 380         dnl *******************************
 381         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 382         AC_TRY_COMPILE([#include <sys/socket.h>], [
 383                 int f = MSG_NOSIGNAL;
 384         ], [
 385                 # Yes, we have it...
 386                 AC_MSG_RESULT(yes)
 387                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 388         ], [
 389                 # We'll have to use signals
 390                 AC_MSG_RESULT(no)
 391         ])
 392
 393         dnl *****************************
 394         dnl *** Checks for SOL_IP     ***
 395         dnl *****************************
 396         AC_MSG_CHECKING(for SOL_IP)
 397         AC_TRY_COMPILE([#include <netdb.h>], [
 398                 int level = SOL_IP;
 399         ], [
 400                 # Yes, we have it...
 401                 AC_MSG_RESULT(yes)
 402                 AC_DEFINE(HAVE_SOL_IP)
 403         ], [
 404                 # We'll have to use getprotobyname
 405                 AC_MSG_RESULT(no)
 406         ])
 407
 408         dnl *****************************
 409         dnl *** Checks for SOL_IPV6     ***
 410         dnl *****************************
 411         AC_MSG_CHECKING(for SOL_IPV6)
 412         AC_TRY_COMPILE([#include <netdb.h>], [
 413                 int level = SOL_IPV6;
 414         ], [
 415                 # Yes, we have it...
 416                 AC_MSG_RESULT(yes)
 417                 AC_DEFINE(HAVE_SOL_IPV6)
 418         ], [
 419                 # We'll have to use getprotobyname
 420                 AC_MSG_RESULT(no)
 421         ])
 422
 423         dnl *****************************
 424         dnl *** Checks for SOL_TCP    ***
 425         dnl *****************************
 426         AC_MSG_CHECKING(for SOL_TCP)
 427         AC_TRY_COMPILE([#include <netdb.h>], [
 428                 int level = SOL_TCP;
 429         ], [
 430                 # Yes, we have it...
 431                 AC_MSG_RESULT(yes)
 432                 AC_DEFINE(HAVE_SOL_TCP)
 433         ], [
 434                 # We'll have to use getprotobyname
 435                 AC_MSG_RESULT(no)
 436         ])
 437
 438         dnl *****************************
 439         dnl *** Checks for IP_PKTINFO ***
 440         dnl *****************************
 441         AC_MSG_CHECKING(for IP_PKTINFO)
 442         AC_TRY_COMPILE([#include <netdb.h>], [
 443                 int level = IP_PKTINFO;
 444         ], [
 445                 # Yes, we have it...
 446                 AC_MSG_RESULT(yes)
 447                 AC_DEFINE(HAVE_IP_PKTINFO)
 448         ], [
 449                 AC_MSG_RESULT(no)
 450         ])
 451
 452         dnl *********************************
 453         dnl *** Check for struct ip_mreqn ***
 454         dnl *********************************
 455         AC_MSG_CHECKING(for struct ip_mreqn)
 456         AC_TRY_COMPILE([#include <netinet/in.h>], [
 457                 struct ip_mreqn mreq;
 458                 mreq.imr_address.s_addr = 0;
 459         ], [
 460                 # Yes, we have it...
 461                 AC_MSG_RESULT(yes)
 462                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 463         ], [
 464                 # We'll just have to try and use struct ip_mreq
 465                 AC_MSG_RESULT(no)
 466                 AC_MSG_CHECKING(for struct ip_mreq)
 467                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 468                         struct ip_mreq mreq;
 469                         mreq.imr_interface.s_addr = 0;
 470                 ], [
 471                         # Yes, we have it...
 472                         AC_MSG_RESULT(yes)
 473                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 474                 ], [
 475                         # No multicast support
 476                         AC_MSG_RESULT(no)
 477                 ])
 478         ])
 479
 480         dnl **********************************
 481         dnl *** Check for gethostbyname2_r ***
 482         dnl **********************************
 483         AC_MSG_CHECKING(for gethostbyname2_r)
 484                 AC_TRY_LINK([#include <netdb.h>], [
 485                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 486         ], [
 487                 # Yes, we have it...
 488                 AC_MSG_RESULT(yes)
 489                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 490         ], [
 491                 AC_MSG_RESULT(no)
 492         ])
 493
 494         dnl *****************************
 495         dnl *** Checks for libnsl     ***
 496         dnl *****************************
 497         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 498
 499         AC_CHECK_FUNCS(inet_pton inet_aton)
 500
 501         dnl ***********************************************
 502         dnl *** Checks for size of sockaddr_un.sun_path ***
 503         dnl ***********************************************
 504         # AC_CHECK_SIZEOF can't cope with struct members :-(
 505         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 506         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 507                 [AC_TRY_RUN([
 508                         #include <sys/types.h>
 509                         #include <stdio.h>
 510                         #include <sys/un.h>
 511
 512                         int main(void) {
 513                                 struct sockaddr_un sock_un;
 514                                 FILE *f=fopen("conftestval", "w");
 515                                 if(!f) exit(1);
 516                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 517                                 exit(0);
 518                         }
 519                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 520                    cv_mono_sizeof_sunpath=0,
 521                    cv_mono_sizeof_sunpath=0)])dnl
 522         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 523         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 524
 525         dnl *************************************
 526         dnl *** Checks for zero length arrays ***
 527         dnl *************************************
 528         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 529         AC_TRY_COMPILE([
 530                 struct s {
 531                         int  length;
 532                         char data [0];
 533                 };
 534         ], [], [
 535                 AC_MSG_RESULT(yes)
 536                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 537         ], [
 538                 AC_MSG_RESULT(no)
 539                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 540         ])
 541
 542         dnl *****************************
 543         dnl *** Checks for libxnet    ***
 544         dnl *****************************
 545         case "${host}" in
 546                 *solaris* )
 547                         AC_MSG_CHECKING(for Solaris XPG4 support)
 548                         if test -f /usr/lib/libxnet.so; then
 549                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 550                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 551                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 552                                 LIBS="$LIBS -lxnet"
 553                                 AC_MSG_RESULT(yes)
 554                         else
 555                                 AC_MSG_RESULT(no)
 556                         fi
 557
 558                         if test "$GCC" = "yes"; then
 559                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 560                         fi
 561                 ;;
 562         esac
 563
 564         dnl *****************************
 565         dnl *** Checks for libpthread ***
 566         dnl *****************************
 567         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 568         AC_CHECK_HEADERS(pthread.h)
 569         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 570         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 571         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 572         AC_TRY_COMPILE([ #include <pthread.h>], [
 573                 pthread_mutexattr_t attr;
 574                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 575         ], [
 576                 AC_MSG_RESULT(ok)
 577         ], [
 578                 AC_MSG_RESULT(no)
 579                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 580                 AC_DEFINE(USE_MONO_MUTEX)
 581         ])
 582         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 583
 584         dnl ***********************************
 585         dnl *** Checks for working __thread ***
 586         dnl ***********************************
 587         AC_MSG_CHECKING(for working __thread)
 588         if test "x$with_nptl" != "xyes"; then
 589                 AC_MSG_RESULT(disabled)
 590         else
 591                 AC_TRY_RUN([
 592                         #include <pthread.h>
 593
 594                         __thread int i;
 595                         static int res1, res2;
 596
 597                         void thread_main (void *arg)
 598                         {
 599                                 i = arg;
 600                                 sleep (1);
 601                                 if (arg == 1)
 602                                         res1 = (i == arg);
 603                                 else
 604                                         res2 = (i == arg);
 605                         }
 606
 607                         int main () {
 608                                 pthread_t t1, t2;
 609
 610                                 i = 5;
 611
 612                                 pthread_create (&t1, NULL, thread_main, 1);
 613                                 pthread_create (&t2, NULL, thread_main, 2);
 614
 615                                 pthread_join (t1, NULL);
 616                                 pthread_join (t2, NULL);
 617
 618                                 return !(res1 + res2 == 2);
 619                         }
 620                 ], [
 621                                 AC_MSG_RESULT(yes)
 622                                 AC_DEFINE(HAVE_KW_THREAD)
 623                 ], [
 624                                 AC_MSG_RESULT(no)
 625                 ])
 626         fi
 627
 628         dnl **************************************
 629         dnl *** Checks for working sigaltstack ***
 630         dnl **************************************
 631         AC_MSG_CHECKING(for working sigaltstack)
 632         if test "x$with_sigaltstack" != "xyes"; then
 633                 AC_MSG_RESULT(disabled)
 634         else
 635                 AC_TRY_RUN([
 636                         #include <stdio.h>
 637                         #include <stdlib.h>
 638                         #include <unistd.h>
 639                         #include <signal.h>
 640                         #include <pthread.h>
 641                         #include <sys/wait.h>
 642
 643                         static void
 644                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 645                         {
 646                                 exit (0);
 647                         }
 648
 649                         static void *
 650                         loop (void *ignored)
 651                         {
 652                                 char *ptr = NULL;
 653
 654                                 *ptr = 0;
 655                                 return NULL;
 656                         }
 657
 658                         static void
 659                         child ()
 660                         {
 661                                 struct sigaction sa;
 662                                 struct sigaltstack sas;
 663                                 pthread_t id;
 664                                 pthread_attr_t attr;
 665
 666                                 sa.sa_sigaction = sigsegv_signal_handler;
 667                                 sigemptyset (&sa.sa_mask);
 668                                 sa.sa_flags = SA_SIGINFO | SA_STACK;
 669                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 670                                         perror ("lala");
 671                                         return;
 672                                 }
 673
 674                                 sas.ss_sp = malloc (SIGSTKSZ);
 675                                 sas.ss_size = SIGSTKSZ;
 676                                 sas.ss_flags = SS_ONSTACK;
 677                                 if (sigaltstack (&sas, NULL) == -1) {
 678                                         perror ("lala");
 679                                         return;
 680                                 }
 681
 682                                 pthread_attr_init (&attr);
 683                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 684                                         printf ("failed\n");
 685                                         return;
 686                                 }
 687
 688                                 sleep (100);
 689                         }
 690
 691                         int
 692                         main ()
 693                         {
 694                                 pid_t son;
 695                                 int status;
 696                                 int i;
 697
 698                                 son = fork ();
 699                                 if (son == -1) {
 700                                         return 1;
 701                                 }
 702
 703                                 if (son == 0) {
 704                                         child ();
 705                                         return 0;
 706                                 }
 707
 708                                 for (i = 0; i < 3; ++i) {
 709                                         sleep (1);
 710                                         waitpid (son, &status, WNOHANG);
 711                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 712                                                 return 0;
 713                                 }
 714
 715                                 kill (son, SIGKILL);
 716                                 return 1;
 717                         }
 718
 719                 ], [
 720                                 AC_MSG_RESULT(yes)
 721                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 722                 ], [
 723                                 with_sigaltstack=no
 724                                 AC_MSG_RESULT(no)
 725                 ])
 726         fi
 727
 728         dnl ********************************
 729         dnl *** Checks for semaphore lib ***
 730         dnl ********************************
 731         # 'Real Time' functions on Solaris
 732         # posix4 on Solaris 2.6
 733         # pthread (first!) on Linux
 734         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 735
 736         dnl ********************************
 737         dnl *** Checks for timezone stuff **
 738         dnl ********************************
 739         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 740                 AC_TRY_COMPILE([
 741                         #include <time.h>
 742                         ], [
 743                         struct tm tm;
 744                         tm.tm_gmtoff = 1;
 745                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 746         if test $ac_cv_struct_tm_gmtoff = yes; then
 747                 AC_DEFINE(HAVE_TM_GMTOFF)
 748         else
 749                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 750                         AC_TRY_COMPILE([
 751                                 #include <time.h>
 752                         ], [
 753                                 timezone = 1;
 754                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 755                 if test $ac_cv_var_timezone = yes; then
 756                         AC_DEFINE(HAVE_TIMEZONE)
 757                 else
 758                         AC_ERROR(unable to find a way to determine timezone)
 759                 fi
 760         fi
 761
 762         dnl *********************************
 763         dnl *** Checks for math functions ***
 764         dnl *********************************
 765         LIBS="$LIBS -lm";
 766         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 767                 AC_TRY_LINK([#include <math.h>],
 768                 [ finite(0.0); ],
 769                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 770                 AC_MSG_RESULT(no)))
 771         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 772                 AC_TRY_LINK([#include <math.h>],
 773                 [ isfinite(0.0); ],
 774                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 775                 AC_MSG_RESULT(no)))
 776
 777         dnl ****************************************************************
 778         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 779         dnl *** have it in the library (duh))                            ***
 780         dnl ****************************************************************
 781         AC_CHECK_FUNCS(poll)
 782
 783         dnl *************************
 784         dnl *** Check for signbit ***
 785         dnl *************************
 786         AC_MSG_CHECKING(for signbit)
 787         AC_TRY_LINK([#include <math.h>], [
 788                 int s = signbit(1.0);
 789         ], [
 790                 AC_MSG_RESULT(yes)
 791                 AC_DEFINE(HAVE_SIGNBIT)
 792         ], [
 793                 AC_MSG_RESULT(no)
 794         ])
 795
 796         dnl *********************
 797         dnl *** Check for AIO ***
 798         dnl *********************
 799         AC_CHECK_HEADERS(aio.h)
 800         AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
 801 else
 802         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 803         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 804 fi
 805
 806 dnl socklen_t check
 807 AC_MSG_CHECKING(for socklen_t)
 808 AC_TRY_COMPILE([
 809 #include <sys/types.h>
 810 #include <sys/socket.h>
 811 ],[
 812   socklen_t foo;
 813 ],[
 814 ac_cv_c_socklen_t=yes
 815         AC_DEFINE(HAVE_SOCKLEN_T)
 816         AC_MSG_RESULT(yes)
 817 ],[
 818         AC_MSG_RESULT(no)
 819 ])
 820
 821 AC_CHECK_FUNCS(truncl, , AC_MSG_CHECKING(for truncl in math.h)
 822         AC_TRY_LINK([#include <math.h>],
 823         [ truncl(0.0); ],
 824         [
 825                 AC_DEFINE(HAVE_TRUNCL)
 826                 AC_MSG_RESULT(yes)
 827                 ac_cv_truncl=yes
 828         ],
 829         AC_MSG_RESULT(no)))
 830
 831 if test "x$ac_cv_truncl" != "xyes"; then
 832    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
 833 fi
 834
 835 dnl ****************************
 836 dnl *** Look for /dev/random ***
 837 dnl ****************************
 838
 839 AC_MSG_CHECKING([if usage of random device is requested])
 840 AC_ARG_ENABLE(dev-random,
 841 [  --disable-dev-random    disable the use of the random device],
 842 try_dev_random=$enableval, try_dev_random=yes)
 843 AC_MSG_RESULT($try_dev_random)
 844
 845 case "{$target}" in
 846     *-openbsd*)
 847     NAME_DEV_RANDOM="/dev/srandom"
 848     ;;
 849
 850 dnl Win32 does not have /dev/random, they have their own method...
 851
 852     *-*-mingw*|*-*-cygwin*)
 853     ac_cv_have_dev_random = no
 854     ;;
 855
 856 dnl Everywhere else, it's /dev/random
 857
 858     *)
 859     NAME_DEV_RANDOM="/dev/random"
 860     ;;
 861 esac
 862
 863 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 864
 865 dnl Now check if the device actually exists
 866
 867 if test "x$try_dev_random" = "xyes"; then
 868     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 869     [if test -r "$NAME_DEV_RANDOM" ; then
 870         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 871     if test "x$ac_cv_have_dev_random" = "xyes"; then
 872         AC_DEFINE(HAVE_CRYPT_RNG)
 873     fi
 874 else
 875     AC_MSG_CHECKING(for random device)
 876     ac_cv_have_dev_random=no
 877     AC_MSG_RESULT(has been disabled)
 878 fi
 879
 880 if test "x$platform_win32" = "xyes"; then
 881     AC_DEFINE(HAVE_CRYPT_RNG)
 882 fi
 883
 884 if test "x$ac_cv_have_dev_random" = "xno" \
 885     && test "x$platform_win32" = "xno"; then
 886     AC_MSG_WARN([[
 887 ***
 888 *** A system-provided entropy source was not found on this system.
 889 *** Because of this, the System.Security.Cryptography random number generator
 890 *** will throw a NotImplemented exception.
 891 ***
 892 *** If you are seeing this message, and you know your system DOES have an
 893 *** entropy collection in place, please contact <crichton@gimp.org> and
 894 *** provide information about the system and how to access the random device.
 895 ***
 896 *** For those systems who lack a random device, EGD support is forthcoming.
 897 ***]])
 898 fi
 899
 900 AC_MSG_CHECKING([if inter-process shared handles are requested])
 901 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
 902 AC_MSG_RESULT($try_shared_handles)
 903 if test "x$try_shared_handles" != "xyes"; then
 904         AC_DEFINE(DISABLE_SHARED_HANDLES)
 905         AC_SUBST(DISABLE_SHARED_HANDLES)
 906 fi
 907
 908 ICU_CFLAGS=""
 909 ICU_LIBS=""
 910 enable_icu=no
 911 AC_PATH_PROG(ICU_CONFIG, icu-config, no)
 912 if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
 913         AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
 914         enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
 915 else
 916         enable_icu="yes. Version: `$ICU_CONFIG --version`"
 917         AC_DEFINE(HAVE_ICU)
 918         ICU_CFLAGS=`$ICU_CONFIG --cppflags`
 919         ICU_LIBS=`$ICU_CONFIG --ldflags`
 920 fi
 921 AC_SUBST(ICU_CFLAGS)
 922 AC_SUBST(ICU_LIBS)
 923
 924 TARGET="unknown"
 925 ACCESS_UNALIGNED="yes"
 926
 927 JIT_SUPPORTED=no
 928 LIBC="libc.so.6"
 929
 930 jit_wanted=false
 931 case "$host" in
 932 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
 933 #               TARGET=MIPS;
 934 #               ACCESS_UNALIGNED="no"
 935 #               ;;
 936         i*86-*-*)
 937                 TARGET=X86;
 938                 arch_target=x86;
 939                 JIT_SUPPORTED=yes
 940                 jit_wanted=true
 941                 ;;
 942         x86_64-*-* | amd64-*-*)
 943                 TARGET=AMD64;
 944                 arch_target=amd64;
 945                 JIT_SUPPORTED=no
 946                 ;;
 947         sparc*-*-*)
 948                 TARGET=SPARC;
 949                 arch_target=sparc;
 950                 JIT_SUPPORTED=yes
 951                 ACCESS_UNALIGNED="no"
 952                 jit_wanted=true
 953                 ;;
 954 #       alpha*-*-linux* | alpha*-*-osf*)
 955 #               TARGET=ALPHA;
 956 #               ACCESS_UNALIGNED="no"
 957 #              ;;
 958 #       ia64-*-linux* | ia64-*-hpux*)
 959 #               TARGET=IA64;
 960 #               arch_target=ia64;
 961 #               JIT_SUPPORTED=no;
 962 #               ACCESS_UNALIGNED="no";
 963 #               case "$host_os" in
 964 #                       linux*) LIBC="libc.so.6.1";;
 965 #                       hpux*)  LIBC="libc.so.1";;
 966 #               esac
 967 #               ;;
 968 #       m68k-*-linux*)
 969 #               TARGET=M68K
 970 #               ;;
 971         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
 972                 TARGET=HPPA;
 973                 arch_target=hppa;
 974                 ACCESS_UNALIGNED="no"
 975                 ;;
 976         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
 977         powerpc-*-sysv* | powerpc-*-darwin*)
 978                 TARGET=POWERPC;
 979                 arch_target=ppc;
 980                 JIT_SUPPORTED=yes
 981                 ;;
 982         arm-*-linux-* | armv4l-*-linux-*)
 983                 TARGET=ARM;
 984                 arch_target=arm;
 985                 ACCESS_UNALIGNED="no"
 986                 ;;
 987         s390-*-linux*)
 988                 TARGET=S390;
 989                 arch_target=s390;
 990                 ACCESS_UNALIGNED="no"
 991                 ;;
 992 esac
 993
 994 AC_ARG_WITH(jit, [  --with-jit=yes,no    If you want to build scripts that default to the JIT],[
 995         jit_wanted=true
 996 ])
 997
 998 USEJIT=false
 999 if test x$JIT_SUPPORTED = xyes; then
1000    if $jit_wanted; then
1001       USEJIT=true
1002       jit_status="Building and using the JIT"
1003    else
1004       jit_status="Building the JIT, defaulting to the interpreter"
1005    fi
1006 else
1007    jit_status="interpreter"
1008 fi
1009
1010 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1011
1012 libsuffix=".so"
1013
1014 case "$host" in
1015      powerpc-*-darwin*)
1016         libsuffix=".dylib"
1017         ;;
1018 esac
1019 AC_SUBST(libsuffix)
1020
1021 if test ${TARGET} = ARM; then
1022         dnl ******************************************
1023         dnl *** Check to see what FPU is available ***
1024         dnl ******************************************
1025         AC_MSG_CHECKING(which FPU to use)
1026
1027         AC_TRY_COMPILE([], [
1028                 __asm__ ("ldfd f0, [r0]");
1029                 ], fpu=FPA, [
1030                         AC_TRY_COMPILE([], [
1031                                 __asm__ ("fldd d0, [r0]");
1032                         ], fpu=VFP, fpu=NONE)
1033                 ])
1034
1035         AC_MSG_RESULT($fpu)
1036         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1037         unset fpu
1038 fi
1039
1040 if test ${TARGET} = unknown; then
1041         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1042         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1043 fi
1044
1045 if test ${ACCESS_UNALIGNED} = no; then
1046         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1047 fi
1048
1049 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1050 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1051 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1052 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1053 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1054 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1055 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1056 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1057 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1058 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1059 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1060 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1061
1062 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1063
1064 AC_SUBST(LIBC)
1065
1066 AC_SUBST(arch_target)
1067 AC_SUBST(CFLAGS)
1068 AC_SUBST(CPPFLAGS)
1069 AC_SUBST(LDFLAGS)
1070
1071 AC_OUTPUT([
1072 Makefile
1073 mint.pc
1074 mono.pc
1075 mono/Makefile
1076 mono/utils/Makefile
1077 mono/metadata/Makefile
1078 mono/dis/Makefile
1079 mono/cil/Makefile
1080 mono/arch/Makefile
1081 mono/os/Makefile
1082 mono/os/win32/Makefile
1083 mono/os/unix/Makefile
1084 mono/arch/x86/Makefile
1085 mono/arch/amd64/Makefile
1086 mono/arch/hppa/Makefile
1087 mono/arch/ppc/Makefile
1088 mono/arch/sparc/Makefile
1089 mono/arch/s390/Makefile
1090 mono/arch/arm/Makefile
1091 mono/arch/alpha/Makefile
1092 mono/interpreter/Makefile
1093 mono/tests/Makefile
1094 mono/tests/tests-config
1095 mono/benchmark/Makefile
1096 mono/monoburg/Makefile
1097 mono/monograph/Makefile
1098 mono/io-layer/Makefile
1099 mono/handles/Makefile
1100 mono/mini/Makefile
1101 mono/profiler/Makefile
1102 runtime/Makefile
1103 scripts/Makefile
1104 man/Makefile
1105 web/Makefile
1106 docs/Makefile
1107 data/Makefile
1108 samples/Makefile
1109 support/Makefile
1110 data/config
1111 mono.spec
1112 ])
1113
1114 echo "
1115
1116         GC:          $gc
1117         ICU:         $enable_icu
1118         NPTL:        $with_nptl
1119         SIGALTSTACK: $with_sigaltstack
1120         Engine:      $jit_status
1121
1122 "