configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.92cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl system type
  16 case "$host_cpu" in
  17 alpha | alphaev56 | alphapca56 )
  18         ARCH_DIR="alpha"
  19         CFLAGS="-mieee -D__ALPHA__"
  20         ;;
  21
  22 arm )
  23         ARCH_DIR="arm"
  24         ENABLE_STATICVM="1"
  25         CFLAGS="-D__ARM__"
  26         ;;
  27
  28 i386 | i486 | i586 | i686 )
  29         ARCH_DIR="i386"
  30         CFLAGS="-D__I386__ $CFLAGS"
  31         ;;
  32
  33 mips )
  34         ARCH_DIR="mips"
  35
  36 dnl for MIPSPro Compiler
  37 dnl     CFLAGS="-64 -OPT:Olimit=0 -woff 1110,1164,1515 -D__MIPS__ -D__MIPSEB__"
  38         CFLAGS="-64 -OPT:Olimit=0 -D__MIPS__ -D__MIPSEB__"
  39 dnl     CFLAGS="-D__MIPS__ -D__MIPSEB__"
  40
  41 dnl for GCC
  42 dnl     CFLAGS="-mabi=64 -D__MIPS__ -D__MIPSEB__"
  43 dnl     LDFLAGS="-mabi=64"
  44         ;;
  45
  46 powerpc )
  47         ARCH_DIR="powerpc"
  48         CFLAGS="-D__POWERPC__"
  49         ;;
  50
  51 x86_64 )
  52         ARCH_DIR="x86_64"
  53         CFLAGS="-D__X86_64__"
  54         ;;
  55
  56 xdspcore )
  57         ARCH_DIR="xdspcore"
  58         ENABLE_STATICVM="1"
  59         CFLAGS="-D__XDSPCORE__"
  60         USE_SCHEDULER="1"
  61         ;;
  62 * )
  63         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  64         ;;
  65 esac
  66
  67
  68 dnl set optimization and debugging for all architectures and systems
  69 CFLAGS="-O0 -g3 $CFLAGS"
  70
  71
  72 case "$host_os" in
  73 *linux* | *Linux* )
  74         OS_DIR="linux"
  75         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__LINUX__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  76         ;;
  77 *darwin* )
  78         OS_DIR="darwin"
  79         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__DARWIN__"
  80         ;;
  81 *freebsd* )
  82         OS_DIR="freebsd"
  83         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__FREEBSD__ -D_XOPEN_SOURCE_EXTENDED"
  84         ;;
  85 *irix* )
  86         OS_DIR="irix"
  87         CFLAGS="$CFLAGS -D__IRIX__"
  88         ;;
  89 * )
  90         ;;
  91 esac
  92
  93
  94 dnl define and substitute some architecture specific variables
  95 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [Architecture directory])
  96 AC_SUBST(ARCH_DIR)
  97 AC_SUBST(OS_DIR)
  98 AC_SUBST(USE_SCHEDULER)
  99
 100
 101 dnl Checks for programs.
 102 AC_PROG_CC
 103 AM_PROG_AS
 104 AC_PROG_LD
 105 AC_PROG_LD_GNU
 106 AC_PROG_RANLIB
 107 AC_DISABLE_SHARED
 108 AC_PROG_LN_S
 109 AC_PROG_MAKE_SET
 110
 111 dnl libtool stuff
 112 AC_LIBTOOL_DLOPEN
 113 AC_LIBLTDL_CONVENIENCE
 114 AC_PROG_LIBTOOL
 115 AC_SUBST(LIBLTDL)
 116
 117 dnl Checks for header files.
 118 AC_HEADER_DIRENT
 119 AC_HEADER_STDC
 120 AC_CHECK_HEADERS([fcntl.h])
 121 AC_CHECK_HEADERS([sys/time.h])
 122 AC_CHECK_HEADERS([unistd.h])
 123 AC_CHECK_HEADERS([sys/ioctl.h])
 124
 125 dnl Checks for typedefs, structures, and compiler characteristics.
 126 AC_C_CONST
 127 AC_C_INLINE
 128 AC_TYPE_OFF_T
 129 AC_TYPE_SIZE_T
 130 AC_HEADER_TIME
 131 AC_STRUCT_TM
 132
 133 dnl Checks for library functions.
 134 AC_PROG_GCC_TRADITIONAL
 135 AC_FUNC_MEMCMP
 136 AC_FUNC_MMAP
 137 AC_TYPE_SIGNAL
 138 AC_CHECK_FUNCS(getcwd gettimeofday mkdir mktime select socket)
 139
 140 dnl Checks for libraries.
 141
 142 dnl Checking sizeof void *
 143 AC_COMPILE_CHECK_SIZEOF(void *)
 144 AC_C_BIGENDIAN
 145
 146 dnl Check for mmap header anomalies (missing MAP_FAILED, etc.)
 147 if test $ac_cv_func_mmap_fixed_mapped = yes; then
 148         AC_CACHE_CHECK(whether MAP_FAILED is defined,
 149                        ac_cv_map_failed,
 150                        AC_EGREP_CPP(yes,
 151                                     [#include <sys/mman.h>
 152                                      #ifdef MAP_FAILED
 153                                         yes
 154                                      #endif],
 155                                     ac_cv_map_failed=yes,
 156                                     ac_cv_map_failed=no))
 157
 158         AC_CACHE_CHECK(whether MAP_ANONYMOUS is defined,
 159                        ac_cv_map_anonymous,
 160                        AC_EGREP_CPP(yes,
 161                                     [#include <sys/mman.h>
 162                                      #ifdef MAP_ANONYMOUS
 163                                         yes
 164                                      #endif],
 165                                     ac_cv_map_anonymous=yes,
 166                                     ac_cv_map_anonymous=no))
 167
 168         AC_CACHE_CHECK(whether MAP_ANON is defined,
 169                        ac_cv_map_anon,
 170                        AC_EGREP_CPP(yes,
 171                                     [#include <sys/mman.h>
 172                                      #ifdef MAP_ANON
 173                                         yes
 174                                      #endif],
 175                                     ac_cv_map_anon=yes,
 176                                     ac_cv_map_anon=no))
 177
 178         if test $ac_cv_map_failed = yes; then
 179                 AC_DEFINE([HAVE_MAP_FAILED], 1, [Define if <sys/mman.h> defines MAP_FAILED])
 180         fi
 181
 182         if test $ac_cv_map_anonymous = yes; then
 183                 AC_DEFINE([HAVE_MAP_ANONYMOUS], 1, [Define if <sys/mman.h> defines MAP_ANONYMOUS])
 184         fi
 185
 186         if test $ac_cv_map_anon = yes; then
 187                 AC_DEFINE([HAVE_MAP_ANON], 1, [Define if <sys/mman.h> defines MAP_ANON])
 188         fi
 189 fi
 190
 191
 192 dnl check which ld flags are required to export symbols
 193 if test x"$with_gnu_ld" = "xyes"; then
 194         EXPORT_SYMBOLS_FLAGS="-Wl,--export-dynamic"
 195 else
 196         EXPORT_SYMBOLS_FLAGS=""
 197 fi
 198 AC_SUBST(EXPORT_SYMBOLS_FLAGS)
 199
 200
 201 dnl define install prefix
 202 if test "x$prefix" = "xNONE"; then
 203         CACAO_INSTALL_PREFIX=$ac_default_prefix
 204 else
 205         CACAO_INSTALL_PREFIX=$prefix
 206 fi
 207 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [Installation prefix])
 208 AC_SUBST(CACAO_INSTALL_PREFIX)
 209
 210
 211 dnl Features
 212
 213 dnl check arguments
 214
 215 dnl check for garbage collector usage
 216 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-gc,disable garbage collector (for debugging only!) [[default=yes]])])
 217
 218 AC_MSG_CHECKING(whether GC should be used)
 219 if test x"$enable_gc" = "xno"; then
 220         AC_MSG_RESULT(no)
 221         AM_CONDITIONAL([DISABLE_GC], [true])
 222 else
 223         AC_MSG_RESULT(yes)
 224         AM_CONDITIONAL([DISABLE_GC], [false])
 225 fi
 226
 227 dnl check for dump memory usage
 228 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])])
 229
 230 AC_MSG_CHECKING(whether dump memory should be used)
 231 if test x"$enable_dump" = "xno"; then
 232         AC_MSG_RESULT(no)
 233         AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 234 else
 235         AC_MSG_RESULT(yes)
 236 fi
 237
 238 dnl check for statistics
 239 AC_ARG_ENABLE([statistics], [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])])
 240
 241 AC_MSG_CHECKING(whether statistics generation should be enabled)
 242 if test x"$enable_statistics" = "xno"; then
 243         AC_MSG_RESULT(no)
 244         AM_CONDITIONAL([STATISTICS], [false])
 245 else
 246         AC_MSG_RESULT(yes)
 247         AC_DEFINE([STATISTICS], 1, [use statistics])
 248         AM_CONDITIONAL([STATISTICS], [true])
 249 fi
 250
 251
 252 dnl threads
 253 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 254 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 255
 256 AC_MSG_CHECKING(whether to include threads support)
 257 enable_threads=${enable_threads:-native}
 258 case "$enable_threads" in
 259 no | none | single)
 260         AC_MSG_RESULT(no)
 261         dnl no threads for boehm
 262         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 263         AM_CONDITIONAL([USE_THREADS], [false])
 264         AM_CONDITIONAL([NATIVE_THREADS], [false])
 265         ;;
 266
 267 green | native | posix | pthreads)
 268         AC_DEFINE([USE_THREADS], 1, [use threads])
 269         AC_DEFINE([EXTERNAL_OVERFLOW], 1, [external overflow])
 270         AC_DEFINE([DONT_FREE_FIRST], 1, [don't free first])
 271
 272         AM_CONDITIONAL([USE_THREADS], [true])
 273
 274         if test x"$enable_threads" != "xgreen"; then
 275                 AC_MSG_RESULT(yes, native)
 276                 AC_CHECK_LIB(pthread, main)
 277                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 278
 279                 CFLAGS="$CFLAGS -D_REENTRANT"
 280
 281                 dnl tell boehm to support threads as well
 282                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-boehm-threads=posix"
 283                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 284
 285         else
 286                 AC_MSG_RESULT(yes, green)
 287
 288                 dnl no threads for boehm
 289                 CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-boehm-threads"
 290                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 291         fi
 292     ;;
 293 *)
 294     AC_MSG_ERROR($enable_threads is an unknown thread package)
 295     ;;
 296 esac
 297
 298
 299 dnl Check whether the compiler supports the __thread keyword.
 300 if test "x$use__thread" != xno; then
 301   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 302   [cat > conftest.c <<\EOF
 303 __thread int a = 42;
 304 EOF
 305   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 306     ac_cv_gcc___thread=yes
 307   else
 308     ac_cv_gcc___thread=no
 309   fi
 310   rm -f conftest*])
 311   if test "$ac_cv_gcc___thread" = yes; then
 312     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 313   fi
 314 else
 315   ac_cv_gcc___thread=no
 316 fi
 317
 318
 319 dnl check if linear scan register allocator(lsra) should be used
 320 AC_ARG_ENABLE([lsra], [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])])
 321
 322 AC_MSG_CHECKING(whether lsra should be supported)
 323 if test x"$enable_lsra" = "xno"; then
 324         AC_MSG_RESULT(no)
 325 else
 326         AC_MSG_RESULT(yes)
 327         AC_DEFINE([LSRA], 1, [use lsra])
 328 fi
 329
 330
 331 dnl check for inlining
 332 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 333
 334 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 335 dnl if test x"$enable_inlining" = "xno"; then
 336 dnl     AC_MSG_RESULT(yes)
 337 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 338 dnl else
 339 dnl     AC_MSG_RESULT(no)
 340         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 341         AM_CONDITIONAL([USE_INLINING], [true])
 342 dnl fi
 343
 344
 345 dnl check for instruction scheduler
 346 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 347
 348 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 349 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 350         case "${ARCH_DIR}" in
 351                 xdspcore )
 352                         ;;
 353                 * )
 354                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 355                         ;;
 356         esac
 357
 358         AC_MSG_RESULT(yes)
 359         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 360         AM_CONDITIONAL([USE_SCHEDULER], [true])
 361 else
 362         AC_MSG_RESULT(no)
 363         AM_CONDITIONAL([USE_SCHEDULER], [false])
 364 fi
 365
 366
 367 dnl check if zlib should be used
 368 AC_ARG_ENABLE([zlib], [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])])
 369
 370 AC_MSG_CHECKING(whether zip archives should be supported)
 371 if test x"$enable_zlib" = "xno"; then
 372         AC_MSG_RESULT(no)
 373         AM_CONDITIONAL([USE_ZLIB], [false])
 374 else
 375         AC_MSG_RESULT(yes)
 376         AC_DEFINE([USE_ZLIB], 1, [use zlib])
 377         AC_CHECK_HEADERS([zlib.h])
 378         AC_CHECK_LIB(z, main)
 379         AM_CONDITIONAL([USE_ZLIB], [true])
 380 fi
 381
 382
 383 dnl check if CACAO should be linked statically
 384 AC_ARG_ENABLE([staticvm], [AS_HELP_STRING(--enable-staticvm, link GNU classpath's native libraries statically into CACAO [[default=no]])])
 385
 386 AC_MSG_CHECKING(whether to link GNU classpath statically into CACAO)
 387 if test x"$enable_staticvm" = "xyes"; then
 388         ENABLE_STATICVM="1"
 389 fi
 390
 391 if test x"${ENABLE_STATICVM}" = "x1"; then
 392         AC_MSG_RESULT(yes)
 393         AM_CONDITIONAL([ENABLE_STATICVM], [true])
 394 else
 395         AC_MSG_RESULT(no)
 396         AM_CONDITIONAL([ENABLE_STATICVM], [false])
 397 fi
 398 AC_SUBST(ENABLE_STATICVM)
 399
 400
 401 dnl check if we build gtk peers
 402 AC_ARG_ENABLE([gtk-peer], [AS_HELP_STRING(--disable-gtk-peer,compile GTK native peers [[default=yes]])])
 403
 404 AC_MSG_CHECKING(whether to compile GTK awt peers)
 405 if test x"$enable_gtk_peer" = "xno"; then
 406         AC_MSG_RESULT(no)
 407         AM_CONDITIONAL([USE_GTK_PEER], [false])
 408         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-gtk-peer"
 409         USE_GTK_PEER=no
 410 else
 411         AC_MSG_RESULT(yes)
 412         AC_DEFINE([USE_GTK], 1, [use gtk])
 413         AM_CONDITIONAL([USE_GTK_PEER], [true])
 414         USE_GTK_PEER=yes
 415 fi
 416 AC_SUBST(USE_GTK_PEER)
 417
 418
 419 dnl pass configure options to classpath
 420 if test x"${ENABLE_STATICVM}" = "x1"; then
 421         AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 422         AM_CONDITIONAL([ENABLE_STATICVM], [true])
 423         CONFIGURE_ARGS="${CONFIGURE_ARGS} --enable-static --disable-shared"
 424
 425         dnl check for some classpath related stuff when we link statically
 426         AM_ICONV_LINK
 427
 428         dnl taken from GNU classpath configure.ac
 429         if test x"${USE_GTK_PEER}" = "xyes"; then
 430                 AC_ERROR(XXX this is not supported yet)
 431                 AC_PATH_XTRA
 432                 if test "$no_x" = yes; then
 433                         AC_MSG_ERROR([GTK+ peers requested but no X library available])
 434                 fi
 435                 dnl We explicitly want the XTest Extension for Robot support.
 436                 AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
 437                              [AC_MSG_ERROR([libXtst NOT found, required for GdkRobot])],
 438                              [${X_LIBS}])
 439                 PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4 gthread-2.0 >= 2.2 libart-2.0 gdk-pixbuf-2.0)
 440                 AC_SUBST(GTK_CFLAGS)
 441                 AC_SUBST(GTK_LIBS)
 442
 443                 AC_SUBST(CAIRO_LIBS)
 444                 AC_SUBST(CAIRO_CFLAGS)
 445                 PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 446                 AC_SUBST(PANGOFT2_LIBS)
 447                 AC_SUBST(PANGOFT2_CFLAGS)
 448         fi
 449 else
 450         AM_CONDITIONAL([ENABLE_STATICVM], [false])
 451         CONFIGURE_ARGS="${CONFIGURE_ARGS} --disable-static --enable-shared"
 452 fi
 453
 454
 455 dnl should we use an external classpath installation
 456 AC_ARG_WITH([external-classpath], [AS_HELP_STRING(--with-external-classpath=<dir>,installation directory of external GNU classpath [[default=no]])])
 457
 458 AC_MSG_CHECKING(whether to use an external GNU classpath)
 459 if test x"$with_external_classpath" != "x"; then
 460         if test x"$with_external_classpath" = "xyes"; then
 461                 AC_MSG_ERROR(please specify the installation prefix)
 462         fi
 463         AC_MSG_RESULT($with_external_classpath)
 464         AC_DEFINE([WITH_EXTERNAL_CLASSPATH], 1, [external classpath])
 465         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [true])
 466         EXTERNAL_CLASSPATH_PREFIX="$with_external_classpath"
 467         AC_DEFINE_UNQUOTED([EXTERNAL_CLASSPATH_PREFIX], "${EXTERNAL_CLASSPATH_PREFIX}", [external classpath directory])
 468         AC_SUBST(EXTERNAL_CLASSPATH_PREFIX)
 469 else
 470         AC_MSG_RESULT(no)
 471         AM_CONDITIONAL([WITH_EXTERNAL_CLASSPATH], [false])
 472 fi
 473
 474
 475 dnl set some essential classpath options, even if their classpath default is
 476 dnl suitable for us
 477 ac_configure_args="$ac_configure_args --libdir=${CACAO_INSTALL_PREFIX}/jre/lib/${ARCH_DIR} --enable-jni --disable-cni --disable-regen-headers ${CONFIGURE_ARGS}"
 478
 479
 480 dnl now configure boehm gc and gnu classpath
 481 dnl the export is not my favorite (is there another way?)
 482 export CFLAGS
 483 AC_CONFIG_SUBDIRS(src/boehm-gc src/classpath src/libltdl)
 484
 485
 486 AC_CONFIG_FILES([Makefile]
 487                 [contrib/Makefile]
 488                 [doc/Makefile]
 489                 [doc/handbook/Makefile]
 490                 [man/Makefile]
 491                 [src/Makefile]
 492                 [src/cacao/Makefile]
 493                 [src/cacaoh/Makefile]
 494                 [src/lib/Makefile]
 495                 [src/mm/Makefile]
 496                 [src/native/Makefile]
 497                 [src/native/include/Makefile]
 498                 [src/native/tools/Makefile]
 499                 [src/native/vm/Makefile]
 500                 [src/scripts/Makefile]
 501                 [src/scripts/cacao]
 502                 [src/scripts/java]
 503                 [src/scripts/javac]
 504                 [src/scripts/kjc]
 505                 [src/scripts/rmiregistry]
 506                 [src/threads/Makefile]
 507                 [src/threads/green/Makefile]
 508                 [src/threads/native/Makefile]
 509                 [src/toolbox/Makefile]
 510                 [src/vm/Makefile]
 511                 [src/vm/jit/Makefile]
 512                 [src/vm/jit/alpha/Makefile]
 513                 [src/vm/jit/arm/Makefile]
 514                 [src/vm/jit/i386/Makefile]
 515                 [src/vm/jit/i386/linux/Makefile]
 516                 [src/vm/jit/i386/freebsd/Makefile]
 517                 [src/vm/jit/inline/Makefile]
 518                 [src/vm/jit/loop/Makefile]
 519                 [src/vm/jit/mips/Makefile]
 520                 [src/vm/jit/powerpc/Makefile]
 521                 [src/vm/jit/powerpc/darwin/Makefile]
 522                 [src/vm/jit/powerpc/linux/Makefile]
 523                 [src/vm/jit/schedule/Makefile]
 524                 [src/vm/jit/tools/Makefile]
 525                 [src/vm/jit/verify/Makefile]
 526                 [src/vm/jit/x86_64/Makefile]
 527                 [tests/Makefile]
 528                 [tests/codepatching/Makefile]
 529                 [tests/native/Makefile])
 530
 531 AC_OUTPUT
 532
 533
 534 ## Local variables:
 535 ## mode: m4
 536 ## indent-tabs-mode: t
 537 ## c-basic-offset: 4
 538 ## tab-width: 8
 539 ## compile-command: "automake --add-missing"
 540 ## End: