configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.91.99)
   5 AM_MAINTAINER_MODE
   6
   7 dnl
   8 dnl libgc checks
   9 dnl
  10
  11 gc_headers=no
  12 gc=included
  13 use_included_gc=no
  14
  15 if test -d $srcdir/libgc ; then
  16   gc_default=included
  17 else
  18   gc_default=boehm
  19 fi
  20
  21 #
  22 # These are the flags that need to be stored in the mono.pc file for
  23 # compiling code that will embed Mono
  24 #
  25 libmono_cflags=""
  26 libmono_ldflags=""
  27 AC_SUBST(libmono_cflags)
  28 AC_SUBST(libmono_ldflags)
  29
  30 dnl if linker handles the version script
  31 no_version_script=no
  32
  33 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  34 need_link_unlink=no
  35
  36 # Thread configuration inspired by sleepycat's db
  37 AC_MSG_CHECKING([host platform characteristics])
  38 libgc_threads=no
  39 case "$host" in
  40         *-*-mingw*|*-*-cygwin*)
  41                 platform_win32=yes
  42                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  43                 CC="gcc -mno-cygwin"
  44                 HOST_CC="gcc"
  45 # latest libgc already defines GC_WIN32_THREADS
  46 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  47                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  48                 libdl=
  49                 libgc_threads=win32
  50                 gc_default=boehm
  51                 ;;
  52         *-*-*netbsd*)
  53                 platform_win32=no
  54                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  55                 libmono_cflags="-D_REENTRANT"
  56                 LDFLAGS="$LDFLAGS -pthread"
  57                 libmono_ldflags="-pthread"
  58                 need_link_unlink=yes
  59                 libdl=
  60                 libgc_threads=no
  61                 ;;
  62         *-*-*freebsd*|*-*-*openbsd*)
  63                 platform_win32=no
  64                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  65                 libmono_cflags="-D_THREAD_SAFE"
  66                 LDFLAGS="$LDFLAGS -pthread"
  67                 libmono_ldflags="-pthread"
  68                 need_link_unlink=yes
  69                 AC_DEFINE(PTHREAD_POINTER_ID)
  70                 libdl=
  71                 libgc_threads=pthreads
  72                 ;;
  73         *-*-linux*)
  74                 platform_win32=no
  75                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -DMONO_USE_EXC_TABLES -D_GNU_SOURCE -D_REENTRANT -fexceptions"
  76                 libmono_cflags="-DMONO_USE_EXC_TABLES -fexceptions -D_REENTRANT"
  77                 libmono_ldflags="-lpthread"
  78                 libdl="-ldl"
  79                 libgc_threads=pthreads
  80                 ;;
  81         *-*-hpux*)
  82                 platform_win32=no
  83                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
  84                 CFLAGS="$CFLAGS +ESdbgasm"
  85                 LDFLAGS="$LDFLAGS -z"
  86                 libmono_cflags="-D_REENTRANT"
  87                 libmono_ldflags="-lpthread"
  88                 libgc_threads=pthreads
  89                 need_link_unlink=yes
  90                 ;;
  91         *-*-solaris*)
  92                 platform_win32=no
  93                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
  94                 need_link_unlink=yes
  95                 libmono_cflags="-D_REENTRANT"
  96                 libgc_threads=pthreads
  97                 ;;
  98         *-*-darwin*)
  99                 platform_win32=no
 100                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
 101                 libmono_cflags="-D_THREAD_SAFE"
 102                 LDFLAGS="$LDFLAGS -pthread"
 103                 libmono_ldflags="-pthread"
 104                 need_link_unlink=yes
 105                 AC_DEFINE(PTHREAD_POINTER_ID)
 106                 AC_DEFINE(USE_MACH_SEMA)
 107                 no_version_script=yes
 108                 libdl=
 109                 libgc_threads=no
 110                 gc_default=none
 111                 ;;
 112         *)
 113                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 114                 platform_win32=no
 115                 libdl="-ldl"
 116                 ;;
 117 esac
 118 AC_MSG_RESULT(ok)
 119
 120 if test x$need_link_unlink = xyes; then
 121    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 122 fi
 123
 124 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 125
 126 AC_CHECK_TOOL(CC, gcc, gcc)
 127 AC_PROG_CC
 128 AM_PROG_CC_STDC
 129 AC_PROG_INSTALL
 130 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 131 : ${CCAS='$(CC)'}
 132 # Set ASFLAGS if not already set.
 133 : ${CCASFLAGS='$(CFLAGS)'}
 134 AC_SUBST(CCAS)
 135 AC_SUBST(CCASFLAGS)
 136
 137 AC_CHECK_PROG(BISON, bison,yes,no)
 138 if test "x$BISON" = "xno";
 139 then
 140         AC_MSG_ERROR([You need to install bison])
 141 fi
 142
 143 dnl may require a specific autoconf version
 144 dnl AC_PROG_CC_FOR_BUILD
 145 dnl CC_FOR_BUILD not automatically detected
 146 CC_FOR_BUILD=$CC
 147 BUILD_EXEEXT=
 148 if test "x$cross_compiling" = "xyes"; then
 149         CC_FOR_BUILD=cc
 150         BUILD_EXEEXT=""
 151 fi
 152 AC_SUBST(CC_FOR_BUILD)
 153 AC_SUBST(HOST_CC)
 154 AC_SUBST(BUILD_EXEEXT)
 155
 156 # Set STDC_HEADERS
 157 AC_HEADER_STDC
 158 AC_LIBTOOL_WIN32_DLL
 159 AM_PROG_LIBTOOL
 160
 161 # Test whenever ld supports -version-script
 162 AC_PROG_LD
 163 AC_PROG_LD_GNU
 164 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 165    no_version_script=yes
 166 fi
 167
 168 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 169
 170 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
 171
 172 # for mono/mini/tramp-x86.c
 173 AC_CHECK_HEADERS(valgrind/memcheck.h)
 174
 175 # for mono/metadata/debug-symfile.c
 176 AC_CHECK_HEADERS(elf.h)
 177
 178 # for mono/dis
 179 AC_CHECK_HEADERS(wchar.h)
 180
 181 # not 64 bit clean in cross-compile
 182 AC_CHECK_SIZEOF(void *, 4)
 183
 184 WARN=''
 185 if test x"$GCC" = xyes; then
 186         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 187                 # The runtime code does not respect ANSI C strict aliasing rules
 188                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 189 else
 190         # The Sun Forte compiler complains about inline functions that access static variables
 191         # so disable all inlining.
 192         case "$host" in
 193         *-*-solaris*)
 194                 CFLAGS="$CFLAGS -Dinline="
 195                 ;;
 196         esac
 197 fi
 198 CFLAGS="$CFLAGS -g $WARN"
 199
 200 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 201 if test "x$PKG_CONFIG" = "xno"; then
 202         AC_MSG_ERROR([You need to install pkg-config])
 203 fi
 204
 205 dnl for use on the build system
 206 dnl pkg-config is stupid
 207 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 208 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 209 AC_SUBST(BUILD_GLIB_CFLAGS)
 210 AC_SUBST(BUILD_GLIB_LIBS)
 211
 212 PKG_PATH=
 213 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 214         if test x$with_crosspkgdir = "x"; then
 215                 if test -s $PKG_CONFIG_PATH; then
 216                         PKG_PATH=$PKG_CONFIG_PATH
 217                 fi
 218         else
 219                 PKG_PATH=$with_crosspkgdir
 220                 PKG_CONFIG_PATH=$PKG_PATH
 221                 export PKG_CONFIG_PATH
 222         fi
 223 )
 224
 225 ## Versions of dependencies
 226 GLIB_REQUIRED_VERSION=1.3.11
 227
 228 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 229
 230 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 231 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 232 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 233 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 234
 235 AC_SUBST(GLIB_CFLAGS)
 236 AC_SUBST(GLIB_LIBS)
 237 AC_SUBST(GMODULE_CFLAGS)
 238 AC_SUBST(GMODULE_LIBS)
 239
 240 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 241
 242 # Enable support for NPTL only features like fast thread-local storage
 243 # We can't reliably detect nptl at compile & run time
 244 # so this option will stay until nptl becomes more widespread
 245 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      enable/disable support for NPTL],[],[with_nptl=yes])
 246
 247 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 248 # This does not work on some platforms (bug #55253)
 249 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=yes])
 250
 251 # assembly bundle support, see metadata/make-bundle.pl for more info
 252 AC_ARG_WITH(bundle, [  --with-bundle=bundle_template],[
 253         BUNDLE_FILE=$with_bundle
 254         AC_SUBST(BUNDLE_FILE)
 255         AC_DEFINE(WITH_BUNDLE)
 256 ],[with_bundle=no])
 257 AM_CONDITIONAL(WITH_BUNDLE, test x$with_bundle != xno)
 258
 259 LIBGC_CFLAGS=
 260 LIBGC_LIBS=
 261 libgc_dir=
 262 case "x$gc" in
 263         xboehm|xbohem|xyes)
 264                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 265                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 266
 267                 if test "x$found_boehm" != "xyes"; then
 268                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 269                 fi
 270                 if test "x$gc_headers" != "xyes"; then
 271                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 272                 fi
 273
 274                 AC_DEFINE(HAVE_BOEHM_GC)
 275                 AC_SUBST(HAVE_BOEHM_GC)
 276                 LIBGC_LIBS="-lgc $libdl"
 277
 278                 # AC_CHECK_FUNCS does not work for some reason...
 279                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 280                 if test "x$found_gcj_malloc" = "xyes"; then
 281                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 282                 fi
 283                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 284                 if test "x$found_gc_enable" = "xyes"; then
 285                         AC_DEFINE(HAVE_GC_ENABLE)
 286                 fi
 287                 ;;
 288
 289         xincluded)
 290                 AC_CONFIG_SUBDIRS(libgc)
 291
 292                 found_boehm=yes
 293                 gc_headers=yes
 294                 use_included_gc=yes
 295                 libgc_dir=libgc
 296
 297                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 298                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 299
 300                 AC_DEFINE(HAVE_BOEHM_GC)
 301                 AC_SUBST(HAVE_BOEHM_GC)
 302
 303                 AC_DEFINE(HAVE_GC_H)
 304                 AC_DEFINE(USE_INCLUDED_LIBGC)
 305
 306                 # The included libgc contains GCJ support
 307                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 308                 AC_DEFINE(HAVE_GC_ENABLE)
 309                 ;;
 310
 311         xnone)
 312                 AC_MSG_WARN("Compiling mono without GC.")
 313                 ;;
 314         *)
 315                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 316                 ;;
 317 esac
 318
 319
 320 # tell libgc/configure about what we want
 321 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
 322
 323 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 324 AC_SUBST(LIBGC_CFLAGS)
 325 AC_SUBST(LIBGC_LIBS)
 326 AC_SUBST(libgc_dir)
 327
 328 dnl
 329 dnl End of libgc checks
 330 dnl
 331
 332 if test x$platform_win32 = xno; then
 333
 334         dnl ******************************************************************
 335         dnl *** Checks for the IKVM JNI interface library                  ***
 336         dnl ******************************************************************
 337         AC_ARG_WITH(ikvm-jni, [  --with-ikvm-jni=yes,no  build the IKVM JNI interface library],[with_ikvm_jni=$withval],[with_ikvm_jni=yes])
 338         AC_ARG_WITH(jdk, [  --with-jdk=DIRECTORY    Use JDK from DIRECTORY],[with_jdk_dir=$withval],[with_jdk_dir=])
 339
 340         ikvm_jni_dir=
 341         if test x$with_ikvm_jni = xyes; then
 342                 AC_MSG_CHECKING([JDK headers])
 343
 344                 if test x$with_jdk_dir = x; then
 345                         # Try JAVA_HOME variable
 346                         if test x$JAVA_HOME != x; then
 347                                 with_jdk_dir=$JAVA_HOME
 348                         fi
 349                 fi
 350
 351                 jdk_platform=
 352                 if test -d $with_jdk_dir/include; then
 353                         jdk_headers_found=yes
 354
 355                         if test -d $with_jdk_dir/include/linux; then
 356                                 jdk_platform=linux
 357                         else
 358                         if test -d $with_jdk_dir/include/solaris; then
 359                                 jdk_platform=solaris
 360                         else
 361                         if test -f $with_jdk_dir/include/jni_md.h; then
 362                                 # GNU Classpath sources
 363                                 jdk_platform=
 364                         else
 365                                 jdk_headers_found=no
 366                         fi
 367                         fi
 368                         fi
 369                 else
 370                         jdk_headers_found=no
 371                 fi
 372
 373                 if test x$jdk_headers_found = xyes; then
 374                         AC_MSG_RESULT($with_jdk_dir/include $with_jdk_dir/include/$jdk_platform)
 375                 else
 376                         AC_MSG_RESULT(not found)
 377                 fi
 378
 379                 if test x$jdk_headers_found = xyes; then
 380                         ikvm_jni_dir=ikvm-jni
 381                         IKVM_JNI_CFLAGS="-I$with_jdk_dir/include -I$with_jdk_dir/include/$jdk_platform"
 382                 fi
 383         fi
 384
 385         AC_SUBST(ikvm_jni_dir)
 386         AC_SUBST(IKVM_JNI_CFLAGS)
 387
 388         AC_CHECK_FUNCS(getgrgid_r)
 389         AC_CHECK_FUNCS(getgrnam_r)
 390         AC_CHECK_FUNCS(getpwnam_r)
 391         AC_CHECK_FUNCS(getpwuid_r)
 392         AC_CHECK_FUNCS(getresuid)
 393         AC_CHECK_FUNCS(setresuid)
 394
 395         dnl ******************************************************************
 396         dnl *** Check for large file support                               ***
 397         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 398         dnl ******************************************************************
 399
 400         # Check that off_t can represent 2**63 - 1 correctly, working around
 401         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 402         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 403         large_offt=no
 404         AC_DEFUN(LARGE_FILES, [
 405                 large_CPPFLAGS=$CPPFLAGS
 406                 CPPFLAGS="$CPPFLAGS $1"
 407                 AC_TRY_RUN([
 408                         #include <sys/types.h>
 409
 410                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 411
 412                         int main(void) {
 413                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 414                                                (BIG_OFF_T%2147483647==1));
 415                                 if(big_off_t) {
 416                                         exit(0);
 417                                 } else {
 418                                         exit(1);
 419                                 }
 420                         }
 421                 ], [
 422                         AC_MSG_RESULT(ok)
 423                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 424                         large_CPPFLAGS="$large_CPPFLAGS $1"
 425                         large_offt=yes
 426                 ], [
 427                         AC_MSG_RESULT(no)
 428                 ], "")
 429                 CPPFLAGS=$large_CPPFLAGS
 430         ])
 431
 432         AC_MSG_CHECKING(if off_t is 64 bits wide)
 433         LARGE_FILES("")
 434         if test $large_offt = no; then
 435                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 436                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 437         fi
 438         if test $large_offt = no; then
 439                 AC_MSG_WARN([No 64 bit file size support available])
 440         fi
 441
 442         dnl *****************************
 443         dnl *** Checks for libsocket  ***
 444         dnl *****************************
 445         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 446
 447         dnl *******************************
 448         dnl *** Checks for MSG_NOSIGNAL ***
 449         dnl *******************************
 450         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 451         AC_TRY_COMPILE([#include <sys/socket.h>], [
 452                 int f = MSG_NOSIGNAL;
 453         ], [
 454                 # Yes, we have it...
 455                 AC_MSG_RESULT(yes)
 456                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 457         ], [
 458                 # We'll have to use signals
 459                 AC_MSG_RESULT(no)
 460         ])
 461
 462         dnl *****************************
 463         dnl *** Checks for SOL_IP     ***
 464         dnl *****************************
 465         AC_MSG_CHECKING(for SOL_IP)
 466         AC_TRY_COMPILE([#include <netdb.h>], [
 467                 int level = SOL_IP;
 468         ], [
 469                 # Yes, we have it...
 470                 AC_MSG_RESULT(yes)
 471                 AC_DEFINE(HAVE_SOL_IP)
 472         ], [
 473                 # We'll have to use getprotobyname
 474                 AC_MSG_RESULT(no)
 475         ])
 476
 477         dnl *****************************
 478         dnl *** Checks for SOL_IPV6     ***
 479         dnl *****************************
 480         AC_MSG_CHECKING(for SOL_IPV6)
 481         AC_TRY_COMPILE([#include <netdb.h>], [
 482                 int level = SOL_IPV6;
 483         ], [
 484                 # Yes, we have it...
 485                 AC_MSG_RESULT(yes)
 486                 AC_DEFINE(HAVE_SOL_IPV6)
 487         ], [
 488                 # We'll have to use getprotobyname
 489                 AC_MSG_RESULT(no)
 490         ])
 491
 492         dnl *****************************
 493         dnl *** Checks for SOL_TCP    ***
 494         dnl *****************************
 495         AC_MSG_CHECKING(for SOL_TCP)
 496         AC_TRY_COMPILE([#include <netdb.h>], [
 497                 int level = SOL_TCP;
 498         ], [
 499                 # Yes, we have it...
 500                 AC_MSG_RESULT(yes)
 501                 AC_DEFINE(HAVE_SOL_TCP)
 502         ], [
 503                 # We'll have to use getprotobyname
 504                 AC_MSG_RESULT(no)
 505         ])
 506
 507         dnl *****************************
 508         dnl *** Checks for IP_PKTINFO ***
 509         dnl *****************************
 510         AC_MSG_CHECKING(for IP_PKTINFO)
 511         AC_TRY_COMPILE([#include <netdb.h>], [
 512                 int level = IP_PKTINFO;
 513         ], [
 514                 # Yes, we have it...
 515                 AC_MSG_RESULT(yes)
 516                 AC_DEFINE(HAVE_IP_PKTINFO)
 517         ], [
 518                 AC_MSG_RESULT(no)
 519         ])
 520
 521         dnl *********************************
 522         dnl *** Check for struct ip_mreqn ***
 523         dnl *********************************
 524         AC_MSG_CHECKING(for struct ip_mreqn)
 525         AC_TRY_COMPILE([#include <netinet/in.h>], [
 526                 struct ip_mreqn mreq;
 527                 mreq.imr_address.s_addr = 0;
 528         ], [
 529                 # Yes, we have it...
 530                 AC_MSG_RESULT(yes)
 531                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 532         ], [
 533                 # We'll just have to try and use struct ip_mreq
 534                 AC_MSG_RESULT(no)
 535                 AC_MSG_CHECKING(for struct ip_mreq)
 536                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 537                         struct ip_mreq mreq;
 538                         mreq.imr_interface.s_addr = 0;
 539                 ], [
 540                         # Yes, we have it...
 541                         AC_MSG_RESULT(yes)
 542                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 543                 ], [
 544                         # No multicast support
 545                         AC_MSG_RESULT(no)
 546                 ])
 547         ])
 548
 549         dnl **********************************
 550         dnl *** Check for gethostbyname2_r ***
 551         dnl **********************************
 552         AC_MSG_CHECKING(for gethostbyname2_r)
 553                 AC_TRY_LINK([#include <netdb.h>], [
 554                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 555         ], [
 556                 # Yes, we have it...
 557                 AC_MSG_RESULT(yes)
 558                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 559         ], [
 560                 AC_MSG_RESULT(no)
 561         ])
 562
 563         dnl *****************************
 564         dnl *** Checks for libnsl     ***
 565         dnl *****************************
 566         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 567
 568         AC_CHECK_FUNCS(inet_pton inet_aton)
 569
 570         dnl ***********************************************
 571         dnl *** Checks for size of sockaddr_un.sun_path ***
 572         dnl ***********************************************
 573         # AC_CHECK_SIZEOF can't cope with struct members :-(
 574         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 575         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 576                 [AC_TRY_RUN([
 577                         #include <sys/types.h>
 578                         #include <stdio.h>
 579                         #include <sys/un.h>
 580
 581                         int main(void) {
 582                                 struct sockaddr_un sock_un;
 583                                 FILE *f=fopen("conftestval", "w");
 584                                 if(!f) exit(1);
 585                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 586                                 exit(0);
 587                         }
 588                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 589                    cv_mono_sizeof_sunpath=0,
 590                    cv_mono_sizeof_sunpath=0)])dnl
 591         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 592         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 593
 594         dnl *************************************
 595         dnl *** Checks for zero length arrays ***
 596         dnl *************************************
 597         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 598         AC_TRY_COMPILE([
 599                 struct s {
 600                         int  length;
 601                         char data [0];
 602                 };
 603         ], [], [
 604                 AC_MSG_RESULT(yes)
 605                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 606         ], [
 607                 AC_MSG_RESULT(no)
 608                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 609         ])
 610
 611         dnl *****************************
 612         dnl *** Checks for libxnet    ***
 613         dnl *****************************
 614         case "${host}" in
 615                 *solaris* )
 616                         AC_MSG_CHECKING(for Solaris XPG4 support)
 617                         if test -f /usr/lib/libxnet.so; then
 618                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 619                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 620                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 621                                 LIBS="$LIBS -lxnet"
 622                                 AC_MSG_RESULT(yes)
 623                         else
 624                                 AC_MSG_RESULT(no)
 625                         fi
 626
 627                         if test "$GCC" = "yes"; then
 628                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 629                         fi
 630                 ;;
 631         esac
 632
 633         dnl *****************************
 634         dnl *** Checks for libpthread ***
 635         dnl *****************************
 636         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 637         AC_CHECK_HEADERS(pthread.h)
 638         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 639         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 640         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 641         AC_TRY_COMPILE([ #include <pthread.h>], [
 642                 pthread_mutexattr_t attr;
 643                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 644         ], [
 645                 AC_MSG_RESULT(ok)
 646         ], [
 647                 AC_MSG_RESULT(no)
 648                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 649                 AC_DEFINE(USE_MONO_MUTEX)
 650         ])
 651         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 652
 653         dnl ***********************************
 654         dnl *** Checks for working __thread ***
 655         dnl ***********************************
 656         AC_MSG_CHECKING(for working __thread)
 657         if test "x$with_nptl" != "xyes"; then
 658                 AC_MSG_RESULT(disabled)
 659         else
 660                 AC_TRY_RUN([
 661                         #include <pthread.h>
 662
 663                         __thread int i;
 664                         static int res1, res2;
 665
 666                         void thread_main (void *arg)
 667                         {
 668                                 i = arg;
 669                                 sleep (1);
 670                                 if (arg == 1)
 671                                         res1 = (i == arg);
 672                                 else
 673                                         res2 = (i == arg);
 674                         }
 675
 676                         int main () {
 677                                 pthread_t t1, t2;
 678
 679                                 i = 5;
 680
 681                                 pthread_create (&t1, NULL, thread_main, 1);
 682                                 pthread_create (&t2, NULL, thread_main, 2);
 683
 684                                 pthread_join (t1, NULL);
 685                                 pthread_join (t2, NULL);
 686
 687                                 return !(res1 + res2 == 2);
 688                         }
 689                 ], [
 690                                 AC_MSG_RESULT(yes)
 691                                 AC_DEFINE(HAVE_KW_THREAD)
 692                 ], [
 693                                 AC_MSG_RESULT(no)
 694                 ])
 695         fi
 696
 697         dnl **************************************
 698         dnl *** Checks for working sigaltstack ***
 699         dnl **************************************
 700         AC_MSG_CHECKING(for working sigaltstack)
 701         if test "x$with_sigaltstack" != "xyes"; then
 702                 AC_MSG_RESULT(disabled)
 703         else
 704                 AC_TRY_RUN([
 705                         #include <stdio.h>
 706                         #include <stdlib.h>
 707                         #include <unistd.h>
 708                         #include <signal.h>
 709                         #include <pthread.h>
 710                         #include <sys/wait.h>
 711
 712                         static void
 713                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 714                         {
 715                                 exit (0);
 716                         }
 717
 718                         static void *
 719                         loop (void *ignored)
 720                         {
 721                                 char *ptr = NULL;
 722
 723                                 *ptr = 0;
 724                                 return NULL;
 725                         }
 726
 727                         static void
 728                         child ()
 729                         {
 730                                 struct sigaction sa;
 731                                 struct sigaltstack sas;
 732                                 pthread_t id;
 733                                 pthread_attr_t attr;
 734
 735                                 sa.sa_sigaction = sigsegv_signal_handler;
 736                                 sigemptyset (&sa.sa_mask);
 737                                 sa.sa_flags = SA_SIGINFO | SA_STACK;
 738                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 739                                         perror ("lala");
 740                                         return;
 741                                 }
 742
 743                                 sas.ss_sp = malloc (SIGSTKSZ);
 744                                 sas.ss_size = SIGSTKSZ;
 745                                 sas.ss_flags = SS_ONSTACK;
 746                                 if (sigaltstack (&sas, NULL) == -1) {
 747                                         perror ("lala");
 748                                         return;
 749                                 }
 750
 751                                 pthread_attr_init (&attr);
 752                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 753                                         printf ("failed\n");
 754                                         return;
 755                                 }
 756
 757                                 sleep (100);
 758                         }
 759
 760                         int
 761                         main ()
 762                         {
 763                                 pid_t son;
 764                                 int status;
 765                                 int i;
 766
 767                                 son = fork ();
 768                                 if (son == -1) {
 769                                         return 1;
 770                                 }
 771
 772                                 if (son == 0) {
 773                                         child ();
 774                                         return 0;
 775                                 }
 776
 777                                 for (i = 0; i < 3; ++i) {
 778                                         sleep (1);
 779                                         waitpid (son, &status, WNOHANG);
 780                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 781                                                 return 0;
 782                                 }
 783
 784                                 kill (son, SIGKILL);
 785                                 return 1;
 786                         }
 787
 788                 ], [
 789                                 AC_MSG_RESULT(yes)
 790                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 791                 ], [
 792                                 with_sigaltstack=no
 793                                 AC_MSG_RESULT(no)
 794                 ])
 795         fi
 796
 797         dnl ********************************
 798         dnl *** Checks for semaphore lib ***
 799         dnl ********************************
 800         # 'Real Time' functions on Solaris
 801         # posix4 on Solaris 2.6
 802         # pthread (first!) on Linux
 803         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 804
 805         dnl ********************************
 806         dnl *** Checks for timezone stuff **
 807         dnl ********************************
 808         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 809                 AC_TRY_COMPILE([
 810                         #include <time.h>
 811                         ], [
 812                         struct tm tm;
 813                         tm.tm_gmtoff = 1;
 814                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 815         if test $ac_cv_struct_tm_gmtoff = yes; then
 816                 AC_DEFINE(HAVE_TM_GMTOFF)
 817         else
 818                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 819                         AC_TRY_COMPILE([
 820                                 #include <time.h>
 821                         ], [
 822                                 timezone = 1;
 823                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 824                 if test $ac_cv_var_timezone = yes; then
 825                         AC_DEFINE(HAVE_TIMEZONE)
 826                 else
 827                         AC_ERROR(unable to find a way to determine timezone)
 828                 fi
 829         fi
 830
 831         dnl *********************************
 832         dnl *** Checks for math functions ***
 833         dnl *********************************
 834         LIBS="$LIBS -lm";
 835         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 836                 AC_TRY_LINK([#include <math.h>],
 837                 [ finite(0.0); ],
 838                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 839                 AC_MSG_RESULT(no)))
 840         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 841                 AC_TRY_LINK([#include <math.h>],
 842                 [ isfinite(0.0); ],
 843                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 844                 AC_MSG_RESULT(no)))
 845
 846         dnl ****************************************************************
 847         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 848         dnl *** have it in the library (duh))                            ***
 849         dnl ****************************************************************
 850         AC_CHECK_FUNCS(poll)
 851
 852         dnl *************************
 853         dnl *** Check for signbit ***
 854         dnl *************************
 855         AC_MSG_CHECKING(for signbit)
 856         AC_TRY_LINK([#include <math.h>], [
 857                 int s = signbit(1.0);
 858         ], [
 859                 AC_MSG_RESULT(yes)
 860                 AC_DEFINE(HAVE_SIGNBIT)
 861         ], [
 862                 AC_MSG_RESULT(no)
 863         ])
 864
 865         dnl *********************
 866         dnl *** Check for AIO ***
 867         dnl *********************
 868         AC_MSG_CHECKING([for SIGEV_THREAD definition])
 869         dnl Some systems (FreeBSD at least) may have aio_read
 870         dnl but don't support/define SIGEV_THREAD.
 871         AC_TRY_COMPILE([
 872         #include <sys/signal.h>
 873         ],[
 874         int x = SIGEV_THREAD;
 875         ],[
 876                 ac_cv_c_sigev_thread=yes
 877                 AC_MSG_RESULT(yes)
 878         ],[
 879                 AC_MSG_RESULT(no)
 880         ])
 881
 882         if test "$ac_cv_c_sigev_thread" = "yes" ; then
 883                 AC_CHECK_HEADERS(aio.h sys/aio.h)
 884                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
 885                 SIGVAL_PTR="undefined"
 886                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
 887                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
 888                                         #include <sys/signal.h>
 889                                         ])
 890                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
 891                                         #include <sys/signal.h>
 892                                         ])
 893                         if test "$SIGVAL_PTR" = "undefined" ; then
 894                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
 895                         fi
 896                 fi
 897                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
 898         fi
 899 else
 900         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 901         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 902 fi
 903
 904 dnl socklen_t check
 905 AC_MSG_CHECKING(for socklen_t)
 906 AC_TRY_COMPILE([
 907 #include <sys/types.h>
 908 #include <sys/socket.h>
 909 ],[
 910   socklen_t foo;
 911 ],[
 912 ac_cv_c_socklen_t=yes
 913         AC_DEFINE(HAVE_SOCKLEN_T)
 914         AC_MSG_RESULT(yes)
 915 ],[
 916         AC_MSG_RESULT(no)
 917 ])
 918
 919 AC_CHECK_FUNCS(truncl, , AC_MSG_CHECKING(for truncl in math.h)
 920         AC_TRY_LINK([#include <math.h>],
 921         [ truncl(0.0); ],
 922         [
 923                 AC_DEFINE(HAVE_TRUNCL)
 924                 AC_MSG_RESULT(yes)
 925                 ac_cv_truncl=yes
 926         ],
 927         AC_MSG_RESULT(no)))
 928
 929 if test "x$ac_cv_truncl" != "xyes"; then
 930    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
 931 fi
 932
 933 dnl ****************************
 934 dnl *** Look for /dev/random ***
 935 dnl ****************************
 936
 937 AC_MSG_CHECKING([if usage of random device is requested])
 938 AC_ARG_ENABLE(dev-random,
 939 [  --disable-dev-random    disable the use of the random device],
 940 try_dev_random=$enableval, try_dev_random=yes)
 941 AC_MSG_RESULT($try_dev_random)
 942
 943 case "{$target}" in
 944     *-openbsd*)
 945     NAME_DEV_RANDOM="/dev/srandom"
 946     ;;
 947
 948 dnl Win32 does not have /dev/random, they have their own method...
 949
 950     *-*-mingw*|*-*-cygwin*)
 951     ac_cv_have_dev_random = no
 952     ;;
 953
 954 dnl Everywhere else, it's /dev/random
 955
 956     *)
 957     NAME_DEV_RANDOM="/dev/random"
 958     ;;
 959 esac
 960
 961 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 962
 963 dnl Now check if the device actually exists
 964
 965 if test "x$try_dev_random" = "xyes"; then
 966     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 967     [if test -r "$NAME_DEV_RANDOM" ; then
 968         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 969     if test "x$ac_cv_have_dev_random" = "xyes"; then
 970         AC_DEFINE(HAVE_CRYPT_RNG)
 971     fi
 972 else
 973     AC_MSG_CHECKING(for random device)
 974     ac_cv_have_dev_random=no
 975     AC_MSG_RESULT(has been disabled)
 976 fi
 977
 978 if test "x$platform_win32" = "xyes"; then
 979     AC_DEFINE(HAVE_CRYPT_RNG)
 980 fi
 981
 982 if test "x$ac_cv_have_dev_random" = "xno" \
 983     && test "x$platform_win32" = "xno"; then
 984     AC_MSG_WARN([[
 985 ***
 986 *** A system-provided entropy source was not found on this system.
 987 *** Because of this, the System.Security.Cryptography random number generator
 988 *** will throw a NotImplemented exception.
 989 ***
 990 *** If you are seeing this message, and you know your system DOES have an
 991 *** entropy collection in place, please contact <crichton@gimp.org> and
 992 *** provide information about the system and how to access the random device.
 993 ***
 994 *** Otherwise you can install either egd or prngd and set the environment
 995 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
 996 ***]])
 997 fi
 998
 999 AC_MSG_CHECKING([if inter-process shared handles are requested])
1000 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1001 AC_MSG_RESULT($try_shared_handles)
1002 if test "x$try_shared_handles" != "xyes"; then
1003         AC_DEFINE(DISABLE_SHARED_HANDLES)
1004         AC_SUBST(DISABLE_SHARED_HANDLES)
1005 fi
1006
1007 #
1008 # ICU
1009 #
1010 ICU_CFLAGS=""
1011 ICU_LIBS=""
1012 enable_icu=no
1013
1014 probe_icu=true
1015 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1016         if test x$with_icu = xno; then
1017            probe_icu=false;
1018            AC_MSG_RESULT(Will not probe for ICU)
1019         fi
1020 )
1021
1022 if $probe_icu; then
1023         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1024         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1025                 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1026                 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1027         else
1028                 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1029                 AC_DEFINE(HAVE_ICU)
1030                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1031                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1032         fi
1033 fi
1034 AC_SUBST(ICU_CFLAGS)
1035 AC_SUBST(ICU_LIBS)
1036
1037 TARGET="unknown"
1038 ACCESS_UNALIGNED="yes"
1039
1040 JIT_SUPPORTED=no
1041 LIBC="libc.so.6"
1042
1043 jit_wanted=false
1044 case "$host" in
1045 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1046 #               TARGET=MIPS;
1047 #               ACCESS_UNALIGNED="no"
1048 #               ;;
1049         i*86-*-*)
1050                 TARGET=X86;
1051                 arch_target=x86;
1052                 JIT_SUPPORTED=yes
1053                 jit_wanted=true
1054                 ;;
1055         x86_64-*-* | amd64-*-*)
1056                 TARGET=AMD64;
1057                 arch_target=amd64;
1058                 JIT_SUPPORTED=no
1059                 ;;
1060         sparc*-*-*)
1061                 TARGET=SPARC;
1062                 arch_target=sparc;
1063                 JIT_SUPPORTED=yes
1064                 ACCESS_UNALIGNED="no"
1065                 LIBC="libc.so"
1066                 jit_wanted=true
1067                 ;;
1068 #       alpha*-*-linux* | alpha*-*-osf*)
1069 #               TARGET=ALPHA;
1070 #               ACCESS_UNALIGNED="no"
1071 #              ;;
1072 #       ia64-*-linux* | ia64-*-hpux*)
1073 #               TARGET=IA64;
1074 #               arch_target=ia64;
1075 #               JIT_SUPPORTED=no;
1076 #               ACCESS_UNALIGNED="no";
1077 #               case "$host_os" in
1078 #                       linux*) LIBC="libc.so.6.1";;
1079 #                       hpux*)  LIBC="libc.so.1";;
1080 #               esac
1081 #               ;;
1082 #       m68k-*-linux*)
1083 #               TARGET=M68K
1084 #               ;;
1085         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1086                 TARGET=HPPA;
1087                 arch_target=hppa;
1088                 LIBC="libc.sl"
1089                 ACCESS_UNALIGNED="no"
1090                 ;;
1091         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1092         powerpc-*-sysv* | powerpc-*-darwin*)
1093                 TARGET=POWERPC;
1094                 arch_target=ppc;
1095                 JIT_SUPPORTED=yes
1096                 jit_wanted=true
1097                 ;;
1098         arm-*-linux-* | armv4l-*-linux-*)
1099                 TARGET=ARM;
1100                 arch_target=arm;
1101                 ACCESS_UNALIGNED="no"
1102                 ;;
1103         s390-*-linux*)
1104                 TARGET=S390;
1105                 arch_target=s390;
1106                 ACCESS_UNALIGNED="no"
1107                 JIT_SUPPORTED=yes
1108                 ;;
1109 esac
1110
1111 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1112         jit_wanted=true
1113 ])
1114
1115 USEJIT=false
1116 if test x$JIT_SUPPORTED = xyes; then
1117    if $jit_wanted; then
1118       USEJIT=true
1119       jit_status="Building and using the JIT"
1120    else
1121       jit_status="Building the JIT, defaulting to the interpreter"
1122    fi
1123 else
1124    jit_status="interpreter"
1125 fi
1126
1127 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1128
1129 libsuffix=".so"
1130
1131 case "$host" in
1132      powerpc-*-darwin*)
1133         libsuffix=".dylib"
1134         LIBC="libc.dylib"
1135         ;;
1136 esac
1137 AC_SUBST(libsuffix)
1138
1139 if test ${TARGET} = ARM; then
1140         dnl ******************************************
1141         dnl *** Check to see what FPU is available ***
1142         dnl ******************************************
1143         AC_MSG_CHECKING(which FPU to use)
1144
1145         AC_TRY_COMPILE([], [
1146                 __asm__ ("ldfd f0, [r0]");
1147                 ], fpu=FPA, [
1148                         AC_TRY_COMPILE([], [
1149                                 __asm__ ("fldd d0, [r0]");
1150                         ], fpu=VFP, fpu=NONE)
1151                 ])
1152
1153         AC_MSG_RESULT($fpu)
1154         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1155         unset fpu
1156 fi
1157
1158 if test ${TARGET} = unknown; then
1159         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1160         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1161 fi
1162
1163 if test ${ACCESS_UNALIGNED} = no; then
1164         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1165 fi
1166
1167 PREVIEW=no
1168 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1169         if test x$with_preview = xyes; then
1170               PREVIEW=yes
1171         fi
1172 ])
1173
1174 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1175
1176 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1177 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1178 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1179 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1180 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1181 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1182 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1183 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1184 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1185 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1186 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1187 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1188
1189 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1190
1191 AC_SUBST(LIBC)
1192
1193 AC_SUBST(arch_target)
1194 AC_SUBST(CFLAGS)
1195 AC_SUBST(CPPFLAGS)
1196 AC_SUBST(LDFLAGS)
1197
1198 AC_OUTPUT([
1199 Makefile
1200 mint.pc
1201 mono.pc
1202 mono/Makefile
1203 mono/utils/Makefile
1204 mono/metadata/Makefile
1205 mono/dis/Makefile
1206 mono/cil/Makefile
1207 mono/arch/Makefile
1208 mono/os/Makefile
1209 mono/os/win32/Makefile
1210 mono/os/unix/Makefile
1211 mono/arch/x86/Makefile
1212 mono/arch/amd64/Makefile
1213 mono/arch/hppa/Makefile
1214 mono/arch/ppc/Makefile
1215 mono/arch/sparc/Makefile
1216 mono/arch/s390/Makefile
1217 mono/arch/arm/Makefile
1218 mono/arch/alpha/Makefile
1219 mono/interpreter/Makefile
1220 mono/tests/Makefile
1221 mono/tests/tests-config
1222 mono/benchmark/Makefile
1223 mono/monoburg/Makefile
1224 mono/monograph/Makefile
1225 mono/io-layer/Makefile
1226 mono/handles/Makefile
1227 mono/mini/Makefile
1228 mono/profiler/Makefile
1229 ikvm-jni/Makefile
1230 runtime/Makefile
1231 runtime/net_1_1/Makefile
1232 runtime/net_2_0/Makefile
1233 scripts/Makefile
1234 man/Makefile
1235 web/Makefile
1236 docs/Makefile
1237 data/Makefile
1238 samples/Makefile
1239 support/Makefile
1240 data/config
1241 mono.spec
1242 ])
1243
1244 echo "
1245
1246         GC:          $gc
1247         ICU:         $enable_icu
1248         NPTL:        $with_nptl
1249         SIGALTSTACK: $with_sigaltstack
1250         Engine:      $jit_status
1251         2.0 Alpha:   $PREVIEW
1252         JNI support: $jdk_headers_found
1253
1254 "