configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,1.1.7)
  10 AM_MAINTAINER_MODE
  11
  12 AC_PROG_LN_S
  13
  14 # In case of cygwin, override LN_S, irrespective of what it determines.
  15 # The build uses cygwin, but the actual runtime doesn't.
  16 case $host_os in
  17 *cygwin* ) LN_S='cp -p';;
  18 esac
  19
  20
  21 dnl
  22 dnl libgc checks
  23 dnl
  24
  25 gc_headers=no
  26 gc=included
  27 use_included_gc=no
  28
  29 if test -d $srcdir/libgc ; then
  30   gc_default=included
  31 else
  32   gc_default=boehm
  33 fi
  34
  35 #
  36 # These are the flags that need to be stored in the mono.pc file for
  37 # compiling code that will embed Mono
  38 #
  39 libmono_cflags=""
  40 libmono_ldflags=""
  41 AC_SUBST(libmono_cflags)
  42 AC_SUBST(libmono_ldflags)
  43
  44 dnl if linker handles the version script
  45 no_version_script=no
  46
  47 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  48 need_link_unlink=no
  49
  50 # Thread configuration inspired by sleepycat's db
  51 AC_MSG_CHECKING([host platform characteristics])
  52 libgc_threads=no
  53 case "$host" in
  54         *-*-mingw*|*-*-cygwin*)
  55                 platform_win32=yes
  56                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  57                 CC="gcc -mno-cygwin -g"
  58                 HOST_CC="gcc"
  59                 # So libgc configure gets -mno-cygwin
  60                 export CC
  61 # latest libgc already defines GC_WIN32_THREADS
  62 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  63                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  64                 libdl=
  65                 libgc_threads=win32
  66                 gc_default=included
  67                 with_nptl=default
  68                 with_sigaltstack=no
  69                 LN_S=cp
  70                 ;;
  71         *-*-*netbsd*)
  72                 platform_win32=no
  73                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  74                 libmono_cflags="-D_REENTRANT"
  75                 LDFLAGS="$LDFLAGS -pthread"
  76                 libmono_ldflags="-pthread"
  77                 need_link_unlink=yes
  78                 libdl=
  79                 libgc_threads=no
  80                 ;;
  81 # these flags will work for all versions of -STABLE
  82 #
  83         *-*-*freebsd4*)
  84                 platform_win32=no
  85                 if test "x$PTHREAD_CFLAGS" = "x"; then
  86                         CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  87                         libmono_cflags="-D_THREAD_SAFE"
  88                 else
  89                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
  90                         libmono_cflags="$PTHREAD_CFLAGS"
  91                 fi
  92                 if test "x$PTHREAD_LIBS" = "x"; then
  93                         LDFLAGS="$LDFLAGS -pthread"
  94                         libmono_ldflags="-pthread"
  95                 else
  96                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
  97                         libmono_ldflags="$PTHREAD_LIBS"
  98                 fi
  99                 need_link_unlink=yes
 100                 AC_DEFINE(PTHREAD_POINTER_ID)
 101                 libdl=
 102                 libgc_threads=pthreads
 103 # TLS isn't implemented at all on -STABLE
 104                 with_nptl=no
 105                 with_tls=pthread
 106                 ;;
 107 # older versions of -CURRENT will break with these flags but testing
 108 # indicates these older versions won't run Mono anyway
 109 #
 110         *-*-*freebsd5*)
 111                 platform_win32=no
 112                 if test "x$PTHREAD_CFLAGS" = "x"; then
 113                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 114                         libmono_cflags=
 115                 else
 116                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 117                         libmono_cflags="$PTHREAD_CFLAGS"
 118                 fi
 119                 if test "x$PTHREAD_LIBS" = "x"; then
 120                         LDFLAGS="$LDFLAGS -lpthread"
 121                         libmono_ldflags="-lpthread"
 122                 else
 123                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 124                         libmono_ldflags="$PTHREAD_LIBS"
 125                 fi
 126                 need_link_unlink=yes
 127                 AC_DEFINE(PTHREAD_POINTER_ID)
 128                 libdl=
 129                 libgc_threads=pthreads
 130 # TLS is only partially implemented on -CURRENT (compiler support
 131 # but NOT library support)
 132 #
 133                 with_nptl=no
 134                 with_tls=pthread
 135                 ;;
 136         *-*-*openbsd*)
 137                 platform_win32=no
 138                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 139                 libmono_cflags="-D_THREAD_SAFE"
 140                 LDFLAGS="$LDFLAGS -pthread"
 141                 libmono_ldflags="-pthread"
 142                 need_link_unlink=yes
 143                 AC_DEFINE(PTHREAD_POINTER_ID)
 144                 libdl=
 145                 libgc_threads=pthreads
 146                 ;;
 147         *-*-linux*)
 148                 platform_win32=no
 149                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
 150                 libmono_cflags="-D_REENTRANT"
 151                 libmono_ldflags="-lpthread"
 152                 libdl="-ldl"
 153                 libgc_threads=pthreads
 154                 ;;
 155         *-*-hpux*)
 156                 platform_win32=no
 157                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 158                 CFLAGS="$CFLAGS +ESdbgasm"
 159                 LDFLAGS="$LDFLAGS -z"
 160                 libmono_cflags="-D_REENTRANT"
 161                 libmono_ldflags="-lpthread"
 162                 libgc_threads=pthreads
 163                 need_link_unlink=yes
 164                 ;;
 165         *-*-solaris*)
 166                 platform_win32=no
 167                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
 168                 need_link_unlink=yes
 169                 libmono_cflags="-D_REENTRANT"
 170                 libgc_threads=pthreads
 171                 ;;
 172         *-*-darwin*)
 173                 platform_win32=no
 174                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
 175                 libmono_cflags="-D_THREAD_SAFE"
 176                 LDFLAGS="$LDFLAGS -pthread"
 177                 libmono_ldflags="-pthread"
 178                 need_link_unlink=yes
 179                 AC_DEFINE(PTHREAD_POINTER_ID)
 180                 AC_DEFINE(USE_MACH_SEMA)
 181                 no_version_script=yes
 182                 libdl=
 183                 libgc_threads=pthreads
 184                 ;;
 185         *)
 186                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 187                 platform_win32=no
 188                 libdl="-ldl"
 189                 ;;
 190 esac
 191 AC_MSG_RESULT(ok)
 192
 193 if test x$need_link_unlink = xyes; then
 194    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 195 fi
 196
 197 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 198
 199 AC_CHECK_TOOL(CC, gcc, gcc)
 200 AC_PROG_CC
 201 AM_PROG_CC_STDC
 202 AC_PROG_INSTALL
 203 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 204 : ${CCAS='$(CC)'}
 205 # Set ASFLAGS if not already set.
 206 : ${CCASFLAGS='$(CFLAGS)'}
 207 AC_SUBST(CCAS)
 208 AC_SUBST(CCASFLAGS)
 209
 210 AC_CHECK_PROG(BISON, bison,yes,no)
 211 if test "x$BISON" = "xno";
 212 then
 213         AC_MSG_ERROR([You need to install bison])
 214 fi
 215
 216 dnl may require a specific autoconf version
 217 dnl AC_PROG_CC_FOR_BUILD
 218 dnl CC_FOR_BUILD not automatically detected
 219 CC_FOR_BUILD=$CC
 220 BUILD_EXEEXT=
 221 if test "x$cross_compiling" = "xyes"; then
 222         CC_FOR_BUILD=cc
 223         BUILD_EXEEXT=""
 224 fi
 225 AC_SUBST(CC_FOR_BUILD)
 226 AC_SUBST(HOST_CC)
 227 AC_SUBST(BUILD_EXEEXT)
 228
 229 # Set STDC_HEADERS
 230 AC_HEADER_STDC
 231 AC_LIBTOOL_WIN32_DLL
 232 AM_PROG_LIBTOOL
 233
 234 # Test whenever ld supports -version-script
 235 AC_PROG_LD
 236 AC_PROG_LD_GNU
 237 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 238    no_version_script=yes
 239 fi
 240
 241 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 242
 243 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h linux/rtc.h)
 244
 245 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 246
 247 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 248
 249 # for mono/metadata/debug-symfile.c
 250 AC_CHECK_HEADERS(elf.h)
 251
 252 # for support
 253 AC_CHECK_HEADERS(poll.h)
 254 AC_CHECK_HEADERS(sys/poll.h)
 255 AC_CHECK_HEADERS(sys/wait.h)
 256 AC_CHECK_HEADERS(grp.h)
 257 AC_CHECK_HEADERS(syslog.h)
 258
 259 # for mono/dis
 260 AC_CHECK_HEADERS(wchar.h)
 261 AC_CHECK_HEADERS(ieeefp.h)
 262 AC_MSG_CHECKING(for isinf)
 263 AC_TRY_LINK([#include <math.h>], [
 264         int f = isinf (1);
 265 ], [
 266         AC_MSG_RESULT(yes)
 267         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 268 ], [
 269         # We'll have to use signals
 270         AC_MSG_RESULT(no)
 271 ])
 272
 273
 274 # not 64 bit clean in cross-compile
 275 AC_CHECK_SIZEOF(void *, 4)
 276
 277 WARN=''
 278 if test x"$GCC" = xyes; then
 279         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 280                 # The runtime code does not respect ANSI C strict aliasing rules
 281                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 282
 283                 ORIG_CFLAGS=$CFLAGS
 284                 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 285                 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
 286                 AC_TRY_COMPILE([], [
 287                                                    void main () { }
 288                 ], [
 289                    AC_MSG_RESULT(yes)
 290                 ], [
 291                    AC_MSG_RESULT(no)
 292                    CFLAGS=$ORIG_CFLAGS
 293                 ])
 294 else
 295         # The Sun Forte compiler complains about inline functions that access static variables
 296         # so disable all inlining.
 297         case "$host" in
 298         *-*-solaris*)
 299                 CFLAGS="$CFLAGS -Dinline="
 300                 ;;
 301         esac
 302 fi
 303 CFLAGS="$CFLAGS -g $WARN"
 304
 305 # Where's the 'mcs' source tree?
 306 if test -d $srcdir/mcs; then
 307   mcsdir=mcs
 308 else
 309   mcsdir=../mcs
 310 fi
 311
 312 mcs_topdir='$(top_srcdir)/'$mcsdir
 313 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 314
 315 AC_SUBST([mcs_topdir])
 316 AC_SUBST([mcs_topdir_from_srcdir])
 317
 318 AC_ARG_WITH([libgdiplus],
 319         [  --with-libgdiplus=installed|sibling|<path>   Override the libgdiplus used for System.Drawing tests (defaults to NO)],
 320         [], [with_libgdiplus=installed])
 321
 322 case $with_libgdiplus in
 323 no|installed) libgdiplus_loc= ;;
 324 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
 325 /*) libgdiplus_loc=$with_libgdiplus ;;
 326 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
 327 esac
 328 AC_SUBST([libgdiplus_loc])
 329
 330 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 331 if test "x$PKG_CONFIG" = "xno"; then
 332         AC_MSG_ERROR([You need to install pkg-config])
 333 fi
 334
 335 dnl for use on the build system
 336 dnl pkg-config is stupid
 337 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 338 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 339 AC_SUBST(BUILD_GLIB_CFLAGS)
 340 AC_SUBST(BUILD_GLIB_LIBS)
 341
 342 pkg_config_path=
 343 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 344         if test x$with_crosspkgdir = "x"; then
 345                 if test -s $PKG_CONFIG_PATH; then
 346                         pkg_config_path=$PKG_CONFIG_PATH
 347                 fi
 348         else
 349                 pkg_config_path=$with_crosspkgdir
 350                 PKG_CONFIG_PATH=$pkg_config_path
 351                 export PKG_CONFIG_PATH
 352         fi
 353 )
 354
 355 ## Versions of dependencies
 356 GLIB_REQUIRED_VERSION=1.3.11
 357
 358 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 359
 360 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 361 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 362 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 363 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 364
 365 AC_SUBST(GLIB_CFLAGS)
 366 AC_SUBST(GLIB_LIBS)
 367 AC_SUBST(GMODULE_CFLAGS)
 368 AC_SUBST(GMODULE_LIBS)
 369
 370 if test x$platform_win32 = xyes; then
 371    AC_MSG_CHECKING(for cygwin glib2-dev package)
 372    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 373       AC_MSG_RESULT(found)
 374           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 375    else
 376       AC_MSG_RESULT(not found, ok)
 377    fi
 378
 379    AC_MSG_CHECKING(for broken gwin32.h)
 380    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 381    if test -f $glib_include/glib/gwin32.h; then
 382           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 383                  AC_MSG_RESULT(failed)
 384                  hashmark='#'
 385                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 386           fi
 387    fi
 388    AC_MSG_RESULT(ok)
 389 fi
 390
 391 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 392
 393 # Enable support for fast thread-local storage
 394 # Some systems have broken support, so we allow to disable it.
 395 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 396
 397 # Kept for compatibility
 398 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      deprecated, use --with-tls instead],[],[with_nptl=default])
 399
 400 if test "x$with_nptl" != "xdefault"; then
 401    if test "x$with_nptl" = "xyes"; then
 402       AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
 403           with_tls=__thread
 404    fi
 405    if test "x$with_nptl" = "xno"; then
 406       AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
 407           with_tls=pthread
 408    fi
 409 fi
 410
 411 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 412 # This does not work on some platforms (bug #55253)
 413 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=no])
 414
 415 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 416
 417 if test "x$enable_static" = "xno"; then
 418    with_static_mono=no
 419 fi
 420
 421 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 422
 423 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 424   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug, reflection_emit.],
 425 [
 426         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 427                 eval "mono_feature_disable_$feature='yes'"
 428                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 429         done
 430         disabled="Disabled:    $enable_minimal"
 431 ],[])
 432
 433 if test "x$mono_feature_disable_aot" = "xyes"; then
 434         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 435 fi
 436
 437 if test "x$mono_feature_disable_profiler" = "xyes"; then
 438         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 439 fi
 440
 441 if test "x$mono_feature_disable_decimal" = "xyes"; then
 442         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 443 fi
 444
 445 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 446         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 447 fi
 448
 449 if test "x$mono_feature_disable_debug" = "xyes"; then
 450         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 451 fi
 452
 453 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 454         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 455 fi
 456
 457 LIBGC_CFLAGS=
 458 LIBGC_LIBS=
 459 LIBGC_STATIC_LIBS=
 460 libgc_dir=
 461 case "x$gc" in
 462         xboehm|xbohem|xyes)
 463                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 464                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 465
 466                 if test "x$found_boehm" != "xyes"; then
 467                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 468                 fi
 469                 if test "x$gc_headers" != "xyes"; then
 470                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 471                 fi
 472
 473                 AC_DEFINE(HAVE_BOEHM_GC)
 474                 AC_SUBST(HAVE_BOEHM_GC)
 475                 LIBGC_LIBS="-lgc $libdl"
 476                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 477
 478                 # AC_CHECK_FUNCS does not work for some reason...
 479                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 480                 if test "x$found_gcj_malloc" = "xyes"; then
 481                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 482                 fi
 483                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 484                 if test "x$found_gc_enable" = "xyes"; then
 485                         AC_DEFINE(HAVE_GC_ENABLE)
 486                 fi
 487                 ;;
 488
 489         xincluded)
 490                 AC_CONFIG_SUBDIRS(libgc)
 491
 492                 found_boehm=yes
 493                 gc_headers=yes
 494                 use_included_gc=yes
 495                 libgc_dir=libgc
 496
 497                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 498                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 499                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 500
 501                 AC_DEFINE(HAVE_BOEHM_GC)
 502                 AC_SUBST(HAVE_BOEHM_GC)
 503
 504                 AC_DEFINE(HAVE_GC_H)
 505                 AC_DEFINE(USE_INCLUDED_LIBGC)
 506
 507                 # The included libgc contains GCJ support
 508                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 509                 AC_DEFINE(HAVE_GC_ENABLE)
 510                 ;;
 511
 512         xnone)
 513                 AC_MSG_WARN("Compiling mono without GC.")
 514                 ;;
 515         *)
 516                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 517                 ;;
 518 esac
 519
 520
 521 # tell libgc/configure about what we want
 522 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
 523
 524 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 525 AC_SUBST(LIBGC_CFLAGS)
 526 AC_SUBST(LIBGC_LIBS)
 527 AC_SUBST(LIBGC_STATIC_LIBS)
 528 AC_SUBST(libgc_dir)
 529
 530 dnl
 531 dnl End of libgc checks
 532 dnl
 533
 534 if test x$platform_win32 = xno; then
 535
 536         dnl ******************************************************************
 537         dnl *** Checks for the IKVM JNI interface library                  ***
 538         dnl ******************************************************************
 539         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 540
 541         ikvm_native_dir=
 542         if test x$with_ikvm_native = xyes; then
 543                 ikvm_native_dir=ikvm-native
 544                 jdk_headers_found="IKVM Native"
 545         fi
 546
 547         AC_SUBST(ikvm_native_dir)
 548
 549         AC_CHECK_FUNCS(getgrgid_r)
 550         AC_CHECK_FUNCS(getgrnam_r)
 551         AC_CHECK_FUNCS(getpwnam_r)
 552         AC_CHECK_FUNCS(getpwuid_r)
 553         AC_CHECK_FUNCS(getresuid)
 554         AC_CHECK_FUNCS(setresuid)
 555         AC_CHECK_FUNCS(kqueue)
 556         AC_CHECK_FUNCS(backtrace_symbols)
 557
 558         dnl ******************************************************************
 559         dnl *** Check for large file support                               ***
 560         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 561         dnl ******************************************************************
 562
 563         # Check that off_t can represent 2**63 - 1 correctly, working around
 564         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 565         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 566         large_offt=no
 567         AC_DEFUN(LARGE_FILES, [
 568                 large_CPPFLAGS=$CPPFLAGS
 569                 CPPFLAGS="$CPPFLAGS $1"
 570                 AC_TRY_RUN([
 571                         #include <sys/types.h>
 572
 573                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 574
 575                         int main(void) {
 576                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 577                                                (BIG_OFF_T%2147483647==1));
 578                                 if(big_off_t) {
 579                                         exit(0);
 580                                 } else {
 581                                         exit(1);
 582                                 }
 583                         }
 584                 ], [
 585                         AC_MSG_RESULT(ok)
 586                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 587                         large_CPPFLAGS="$large_CPPFLAGS $1"
 588                         large_offt=yes
 589                 ], [
 590                         AC_MSG_RESULT(no)
 591                 ], "")
 592                 CPPFLAGS=$large_CPPFLAGS
 593         ])
 594
 595         AC_MSG_CHECKING(if off_t is 64 bits wide)
 596         LARGE_FILES("")
 597         if test $large_offt = no; then
 598                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 599                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 600         fi
 601         if test $large_offt = no; then
 602                 AC_MSG_WARN([No 64 bit file size support available])
 603         fi
 604
 605         dnl *****************************
 606         dnl *** Checks for libsocket  ***
 607         dnl *****************************
 608         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 609
 610         dnl *******************************
 611         dnl *** Checks for MSG_NOSIGNAL ***
 612         dnl *******************************
 613         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 614         AC_TRY_COMPILE([#include <sys/socket.h>], [
 615                 int f = MSG_NOSIGNAL;
 616         ], [
 617                 # Yes, we have it...
 618                 AC_MSG_RESULT(yes)
 619                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 620         ], [
 621                 # We'll have to use signals
 622                 AC_MSG_RESULT(no)
 623         ])
 624
 625         dnl *****************************
 626         dnl *** Checks for SOL_IP     ***
 627         dnl *****************************
 628         AC_MSG_CHECKING(for SOL_IP)
 629         AC_TRY_COMPILE([#include <netdb.h>], [
 630                 int level = SOL_IP;
 631         ], [
 632                 # Yes, we have it...
 633                 AC_MSG_RESULT(yes)
 634                 AC_DEFINE(HAVE_SOL_IP)
 635         ], [
 636                 # We'll have to use getprotobyname
 637                 AC_MSG_RESULT(no)
 638         ])
 639
 640         dnl *****************************
 641         dnl *** Checks for SOL_IPV6     ***
 642         dnl *****************************
 643         AC_MSG_CHECKING(for SOL_IPV6)
 644         AC_TRY_COMPILE([#include <netdb.h>], [
 645                 int level = SOL_IPV6;
 646         ], [
 647                 # Yes, we have it...
 648                 AC_MSG_RESULT(yes)
 649                 AC_DEFINE(HAVE_SOL_IPV6)
 650         ], [
 651                 # We'll have to use getprotobyname
 652                 AC_MSG_RESULT(no)
 653         ])
 654
 655         dnl *****************************
 656         dnl *** Checks for SOL_TCP    ***
 657         dnl *****************************
 658         AC_MSG_CHECKING(for SOL_TCP)
 659         AC_TRY_COMPILE([#include <netdb.h>], [
 660                 int level = SOL_TCP;
 661         ], [
 662                 # Yes, we have it...
 663                 AC_MSG_RESULT(yes)
 664                 AC_DEFINE(HAVE_SOL_TCP)
 665         ], [
 666                 # We'll have to use getprotobyname
 667                 AC_MSG_RESULT(no)
 668         ])
 669
 670         dnl *****************************
 671         dnl *** Checks for IP_PKTINFO ***
 672         dnl *****************************
 673         AC_MSG_CHECKING(for IP_PKTINFO)
 674         AC_TRY_COMPILE([#include <netdb.h>], [
 675                 int level = IP_PKTINFO;
 676         ], [
 677                 # Yes, we have it...
 678                 AC_MSG_RESULT(yes)
 679                 AC_DEFINE(HAVE_IP_PKTINFO)
 680         ], [
 681                 AC_MSG_RESULT(no)
 682         ])
 683
 684         dnl *********************************
 685         dnl *** Check for struct ip_mreqn ***
 686         dnl *********************************
 687         AC_MSG_CHECKING(for struct ip_mreqn)
 688         AC_TRY_COMPILE([#include <netinet/in.h>], [
 689                 struct ip_mreqn mreq;
 690                 mreq.imr_address.s_addr = 0;
 691         ], [
 692                 # Yes, we have it...
 693                 AC_MSG_RESULT(yes)
 694                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 695         ], [
 696                 # We'll just have to try and use struct ip_mreq
 697                 AC_MSG_RESULT(no)
 698                 AC_MSG_CHECKING(for struct ip_mreq)
 699                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 700                         struct ip_mreq mreq;
 701                         mreq.imr_interface.s_addr = 0;
 702                 ], [
 703                         # Yes, we have it...
 704                         AC_MSG_RESULT(yes)
 705                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 706                 ], [
 707                         # No multicast support
 708                         AC_MSG_RESULT(no)
 709                 ])
 710         ])
 711
 712         dnl **********************************
 713         dnl *** Check for gethostbyname2_r ***
 714         dnl **********************************
 715         AC_MSG_CHECKING(for gethostbyname2_r)
 716                 AC_TRY_LINK([#include <netdb.h>], [
 717                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 718         ], [
 719                 # Yes, we have it...
 720                 AC_MSG_RESULT(yes)
 721                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 722         ], [
 723                 AC_MSG_RESULT(no)
 724         ])
 725
 726         dnl *****************************
 727         dnl *** Checks for libnsl     ***
 728         dnl *****************************
 729         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 730
 731         AC_CHECK_FUNCS(inet_pton inet_aton)
 732
 733         dnl ***********************************************
 734         dnl *** Checks for size of sockaddr_un.sun_path ***
 735         dnl ***********************************************
 736         # AC_CHECK_SIZEOF can't cope with struct members :-(
 737         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 738         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 739                 [AC_TRY_RUN([
 740                         #include <sys/types.h>
 741                         #include <stdio.h>
 742                         #include <sys/un.h>
 743
 744                         int main(void) {
 745                                 struct sockaddr_un sock_un;
 746                                 FILE *f=fopen("conftestval", "w");
 747                                 if(!f) exit(1);
 748                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 749                                 exit(0);
 750                         }
 751                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 752                    cv_mono_sizeof_sunpath=0,
 753                    cv_mono_sizeof_sunpath=0)])dnl
 754         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 755         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 756
 757         dnl *************************************
 758         dnl *** Checks for zero length arrays ***
 759         dnl *************************************
 760         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 761         AC_TRY_COMPILE([
 762                 struct s {
 763                         int  length;
 764                         char data [0];
 765                 };
 766         ], [], [
 767                 AC_MSG_RESULT(yes)
 768                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 769         ], [
 770                 AC_MSG_RESULT(no)
 771                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 772         ])
 773
 774         dnl *****************************
 775         dnl *** Checks for libxnet    ***
 776         dnl *****************************
 777         case "${host}" in
 778                 *solaris* )
 779                         AC_MSG_CHECKING(for Solaris XPG4 support)
 780                         if test -f /usr/lib/libxnet.so; then
 781                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 782                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 783                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 784                                 LIBS="$LIBS -lxnet"
 785                                 AC_MSG_RESULT(yes)
 786                         else
 787                                 AC_MSG_RESULT(no)
 788                         fi
 789
 790                         if test "$GCC" = "yes"; then
 791                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 792                         fi
 793                 ;;
 794         esac
 795
 796         dnl *****************************
 797         dnl *** Checks for libpthread ***
 798         dnl *****************************
 799 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
 800 # and libpthread does not exist
 801 #
 802         case "${host}" in
 803                 *-*-*freebsd4*)
 804                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 805                 ;;
 806                 *)
 807                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 808                 ;;
 809         esac
 810         AC_CHECK_HEADERS(pthread.h)
 811         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 812         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 813         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 814         AC_TRY_COMPILE([ #include <pthread.h>], [
 815                 pthread_mutexattr_t attr;
 816                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 817         ], [
 818                 AC_MSG_RESULT(ok)
 819         ], [
 820                 AC_MSG_RESULT(no)
 821                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 822                 AC_DEFINE(USE_MONO_MUTEX)
 823         ])
 824         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 825
 826         dnl ***********************************
 827         dnl *** Checks for working __thread ***
 828         dnl ***********************************
 829         AC_MSG_CHECKING(for working __thread)
 830         if test "x$with_tls" != "x__thread"; then
 831                 AC_MSG_RESULT(disabled)
 832         else
 833                 AC_TRY_RUN([
 834                         #include <pthread.h>
 835
 836                         __thread int i;
 837                         static int res1, res2;
 838
 839                         void thread_main (void *arg)
 840                         {
 841                                 i = arg;
 842                                 sleep (1);
 843                                 if (arg == 1)
 844                                         res1 = (i == arg);
 845                                 else
 846                                         res2 = (i == arg);
 847                         }
 848
 849                         int main () {
 850                                 pthread_t t1, t2;
 851
 852                                 i = 5;
 853
 854                                 pthread_create (&t1, NULL, thread_main, 1);
 855                                 pthread_create (&t2, NULL, thread_main, 2);
 856
 857                                 pthread_join (t1, NULL);
 858                                 pthread_join (t2, NULL);
 859
 860                                 return !(res1 + res2 == 2);
 861                         }
 862                 ], [
 863                                 AC_MSG_RESULT(yes)
 864                 ], [
 865                                 AC_MSG_RESULT(no)
 866                                 with_tls=pthread
 867                 ])
 868         fi
 869
 870         dnl **************************************
 871         dnl *** Checks for working sigaltstack ***
 872         dnl **************************************
 873         AC_MSG_CHECKING(for working sigaltstack)
 874         if test "x$with_sigaltstack" != "xyes"; then
 875                 AC_MSG_RESULT(disabled)
 876         else
 877                 AC_TRY_RUN([
 878                         #include <stdio.h>
 879                         #include <stdlib.h>
 880                         #include <unistd.h>
 881                         #include <signal.h>
 882                         #include <pthread.h>
 883                         #include <sys/wait.h>
 884
 885                         static void
 886                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 887                         {
 888                                 exit (0);
 889                         }
 890
 891                         static void *
 892                         loop (void *ignored)
 893                         {
 894                                 char *ptr = NULL;
 895
 896                                 *ptr = 0;
 897                                 return NULL;
 898                         }
 899
 900                         static void
 901                         child ()
 902                         {
 903                                 struct sigaction sa;
 904                                 struct sigaltstack sas;
 905                                 pthread_t id;
 906                                 pthread_attr_t attr;
 907
 908                                 sa.sa_sigaction = sigsegv_signal_handler;
 909                                 sigemptyset (&sa.sa_mask);
 910                                 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
 911                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 912                                         perror ("sigaction");
 913                                         return;
 914                                 }
 915
 916                                 sas.ss_sp = malloc (SIGSTKSZ);
 917                                 sas.ss_size = SIGSTKSZ;
 918                                 sas.ss_flags = 0;
 919                                 if (sigaltstack (&sas, NULL) == -1) {
 920                                         perror ("sigaltstack");
 921                                         return;
 922                                 }
 923
 924                                 pthread_attr_init (&attr);
 925                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 926                                         printf ("pthread_create\n");
 927                                         return;
 928                                 }
 929
 930                                 sleep (100);
 931                         }
 932
 933                         int
 934                         main ()
 935                         {
 936                                 pid_t son;
 937                                 int status;
 938                                 int i;
 939
 940                                 son = fork ();
 941                                 if (son == -1) {
 942                                         return 1;
 943                                 }
 944
 945                                 if (son == 0) {
 946                                         child ();
 947                                         return 0;
 948                                 }
 949
 950                                 for (i = 0; i < 3; ++i) {
 951                                         sleep (1);
 952                                         waitpid (son, &status, WNOHANG);
 953                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 954                                                 return 0;
 955                                 }
 956
 957                                 kill (son, SIGKILL);
 958                                 return 1;
 959                         }
 960
 961                 ], [
 962                                 AC_MSG_RESULT(yes)
 963                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 964                 ], [
 965                                 with_sigaltstack=no
 966                                 AC_MSG_RESULT(no)
 967                 ])
 968         fi
 969
 970         dnl ********************************
 971         dnl *** Checks for semaphore lib ***
 972         dnl ********************************
 973         # 'Real Time' functions on Solaris
 974         # posix4 on Solaris 2.6
 975         # pthread (first!) on Linux
 976         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 977
 978         dnl ********************************
 979         dnl *** Checks for timezone stuff **
 980         dnl ********************************
 981         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 982                 AC_TRY_COMPILE([
 983                         #include <time.h>
 984                         ], [
 985                         struct tm tm;
 986                         tm.tm_gmtoff = 1;
 987                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 988         if test $ac_cv_struct_tm_gmtoff = yes; then
 989                 AC_DEFINE(HAVE_TM_GMTOFF)
 990         else
 991                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 992                         AC_TRY_COMPILE([
 993                                 #include <time.h>
 994                         ], [
 995                                 timezone = 1;
 996                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 997                 if test $ac_cv_var_timezone = yes; then
 998                         AC_DEFINE(HAVE_TIMEZONE)
 999                 else
1000                         AC_ERROR(unable to find a way to determine timezone)
1001                 fi
1002         fi
1003
1004         dnl *********************************
1005         dnl *** Checks for math functions ***
1006         dnl *********************************
1007         LIBS="$LIBS -lm";
1008         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1009                 AC_TRY_LINK([#include <math.h>],
1010                 [ finite(0.0); ],
1011                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
1012                 AC_MSG_RESULT(no)))
1013         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1014                 AC_TRY_LINK([#include <math.h>],
1015                 [ isfinite(0.0); ],
1016                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
1017                 AC_MSG_RESULT(no)))
1018
1019         dnl ****************************************************************
1020         dnl *** Checks for working poll() (macosx defines it but doesn't ***
1021         dnl *** have it in the library (duh))                            ***
1022         dnl ****************************************************************
1023         AC_CHECK_FUNCS(poll)
1024
1025         dnl *************************
1026         dnl *** Check for signbit ***
1027         dnl *************************
1028         AC_MSG_CHECKING(for signbit)
1029         AC_TRY_LINK([#include <math.h>], [
1030                 int s = signbit(1.0);
1031         ], [
1032                 AC_MSG_RESULT(yes)
1033                 AC_DEFINE(HAVE_SIGNBIT)
1034         ], [
1035                 AC_MSG_RESULT(no)
1036         ])
1037
1038         dnl **********************************
1039         dnl *** Checks for MonoPosixHelper ***
1040         dnl **********************************
1041         AC_CHECK_HEADERS(checklist.h)
1042         AC_CHECK_HEADERS(fstab.h)
1043         AC_CHECK_HEADERS(sys/sendfile.h)
1044         AC_CHECK_HEADERS(sys/statvfs.h)
1045         AC_CHECK_HEADERS(sys/vfstab.h)
1046         AC_CHECK_FUNCS(getdomainname)
1047         AC_CHECK_FUNCS(setdomainname)
1048         AC_CHECK_FUNCS(fgetgrent)
1049         AC_CHECK_FUNCS(fgetpwent)
1050         AC_CHECK_FUNCS(fgetpwent)
1051         AC_CHECK_FUNCS(getfsstat)
1052         AC_CHECK_FUNCS(posix_fadvise)
1053         AC_CHECK_FUNCS(posix_fallocate)
1054         AC_CHECK_FUNCS(posix_madvise)
1055         AC_CHECK_FUNCS(vsnprintf)
1056         AC_CHECK_FUNCS(sendfile)
1057         AC_CHECK_FUNCS(sethostid)
1058         AC_CHECK_FUNCS(statfs)
1059         AC_CHECK_FUNCS(fstatfs)
1060         AC_CHECK_FUNCS(statvfs)
1061         AC_CHECK_FUNCS(fstatvfs)
1062         AC_CHECK_FUNCS(stime)
1063         AC_CHECK_FUNCS(strerror_r)
1064         AC_CHECK_FUNCS(ttyname_r)
1065         AC_CHECK_SIZEOF(size_t)
1066         AC_CHECK_MEMBERS(
1067                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1068                 [#include <sys/types.h>
1069                  #include <dirent.h>])
1070
1071         dnl *********************************
1072         dnl *** Check for Console 2.0 I/O ***
1073         dnl *********************************
1074         AC_CHECK_HEADERS([curses.h])
1075         AC_CHECK_HEADERS([term.h], [], [],
1076         [#if HAVE_CURSES_H
1077          #include <curses.h>
1078          #endif
1079         ])
1080         AC_CHECK_HEADERS([termios.h])
1081 else
1082         jdk_headers_found=no
1083         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1084         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1085         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1086
1087         dnl *********************************
1088         dnl *** Check for struct ip_mreqn ***
1089         dnl *********************************
1090         AC_MSG_CHECKING(for struct ip_mreqn)
1091         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1092                 struct ip_mreqn mreq;
1093                 mreq.imr_address.s_addr = 0;
1094         ], [
1095                 # Yes, we have it...
1096                 AC_MSG_RESULT(yes)
1097                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1098         ], [
1099                 # We'll just have to try and use struct ip_mreq
1100                 AC_MSG_RESULT(no)
1101                 AC_MSG_CHECKING(for struct ip_mreq)
1102                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1103                         struct ip_mreq mreq;
1104                         mreq.imr_interface.s_addr = 0;
1105                 ], [
1106                         # Yes, we have it...
1107                         AC_MSG_RESULT(yes)
1108                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1109                 ], [
1110                         # No multicast support
1111                         AC_MSG_RESULT(no)
1112                 ])
1113         ])
1114 fi
1115
1116 dnl socklen_t check
1117 AC_MSG_CHECKING(for socklen_t)
1118 AC_TRY_COMPILE([
1119 #include <sys/types.h>
1120 #include <sys/socket.h>
1121 ],[
1122   socklen_t foo;
1123 ],[
1124 ac_cv_c_socklen_t=yes
1125         AC_DEFINE(HAVE_SOCKLEN_T)
1126         AC_MSG_RESULT(yes)
1127 ],[
1128         AC_MSG_RESULT(no)
1129 ])
1130
1131 AC_MSG_CHECKING(for array element initalizer support)
1132 AC_TRY_COMPILE([#include <sys/socket.h>], [
1133         const int array[] = {[1] = 2,};
1134 ], [
1135         # Yes, we have it...
1136         AC_MSG_RESULT(yes)
1137         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1138 ], [
1139         # We'll have to use signals
1140         AC_MSG_RESULT(no)
1141 ])
1142
1143 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1144         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1145         AC_TRY_LINK([#include <math.h>],
1146         [ static void *p = &trunc; ],
1147         [
1148                 AC_DEFINE(HAVE_TRUNC)
1149                 AC_MSG_RESULT(yes)
1150                 ac_cv_trunc=yes
1151         ],
1152         AC_MSG_RESULT(no)))
1153
1154 if test "x$ac_cv_truncl" != "xyes"; then
1155    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1156 fi
1157
1158 dnl ****************************
1159 dnl *** Look for /dev/random ***
1160 dnl ****************************
1161
1162 AC_MSG_CHECKING([if usage of random device is requested])
1163 AC_ARG_ENABLE(dev-random,
1164 [  --disable-dev-random    disable the use of the random device],
1165 try_dev_random=$enableval, try_dev_random=yes)
1166 AC_MSG_RESULT($try_dev_random)
1167
1168 case "{$target}" in
1169     *-openbsd*)
1170     NAME_DEV_RANDOM="/dev/srandom"
1171     ;;
1172
1173 dnl Win32 does not have /dev/random, they have their own method...
1174
1175     *-*-mingw*|*-*-cygwin*)
1176     ac_cv_have_dev_random=no
1177     ;;
1178
1179 dnl Everywhere else, it's /dev/random
1180
1181     *)
1182     NAME_DEV_RANDOM="/dev/random"
1183     ;;
1184 esac
1185
1186 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1187
1188 dnl Now check if the device actually exists
1189
1190 if test "x$try_dev_random" = "xyes"; then
1191     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1192     [if test -r "$NAME_DEV_RANDOM" ; then
1193         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1194     if test "x$ac_cv_have_dev_random" = "xyes"; then
1195         AC_DEFINE(HAVE_CRYPT_RNG)
1196     fi
1197 else
1198     AC_MSG_CHECKING(for random device)
1199     ac_cv_have_dev_random=no
1200     AC_MSG_RESULT(has been disabled)
1201 fi
1202
1203 if test "x$platform_win32" = "xyes"; then
1204     AC_DEFINE(HAVE_CRYPT_RNG)
1205 fi
1206
1207 if test "x$ac_cv_have_dev_random" = "xno" \
1208     && test "x$platform_win32" = "xno"; then
1209     AC_MSG_WARN([[
1210 ***
1211 *** A system-provided entropy source was not found on this system.
1212 *** Because of this, the System.Security.Cryptography random number generator
1213 *** will throw a NotImplemented exception.
1214 ***
1215 *** If you are seeing this message, and you know your system DOES have an
1216 *** entropy collection in place, please contact <crichton@gimp.org> and
1217 *** provide information about the system and how to access the random device.
1218 ***
1219 *** Otherwise you can install either egd or prngd and set the environment
1220 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1221 ***]])
1222 fi
1223
1224 AC_MSG_CHECKING([if inter-process shared handles are requested])
1225 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1226 AC_MSG_RESULT($try_shared_handles)
1227 if test "x$try_shared_handles" != "xyes"; then
1228         AC_DEFINE(DISABLE_SHARED_HANDLES)
1229         AC_SUBST(DISABLE_SHARED_HANDLES)
1230 fi
1231
1232 #
1233 # ICU
1234 #
1235 ICU_CFLAGS=""
1236 ICU_LIBS=""
1237 enable_glob="normal;  default"
1238
1239 probe_icu=false
1240 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1241         if test x$with_icu = xno; then
1242            probe_icu=false;
1243            AC_MSG_RESULT(Will not probe for ICU)
1244         fi
1245         if test x$with_icu = xyes; then
1246            probe_icu=true;
1247         fi
1248 )
1249
1250 if $probe_icu; then
1251         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1252         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1253                 enable_glob="ICU not found, using non-ICU globalization code."
1254         else
1255                 enable_glob="ICU, unsupported. Version: `$ICU_CONFIG --version`"
1256                 AC_DEFINE(HAVE_ICU)
1257                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1258                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1259         fi
1260 fi
1261 AC_SUBST(ICU_CFLAGS)
1262 AC_SUBST(ICU_LIBS)
1263
1264 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1265 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1266
1267 TARGET="unknown"
1268 ACCESS_UNALIGNED="yes"
1269
1270 JIT_SUPPORTED=no
1271 INTERP_SUPPORTED=no
1272 LIBC="libc.so.6"
1273 INTL="libc.so.6"
1274
1275 jit_wanted=false
1276 interp_wanted=false
1277 case "$host" in
1278 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1279 #               TARGET=MIPS;
1280 #               ACCESS_UNALIGNED="no"
1281 #               ;;
1282         i*86-*-*)
1283                 TARGET=X86;
1284                 arch_target=x86;
1285                 JIT_SUPPORTED=yes
1286                 jit_wanted=true
1287                 ;;
1288         x86_64-*-* | amd64-*-*)
1289                 TARGET=AMD64;
1290                 arch_target=amd64;
1291                 JIT_SUPPORTED=yes
1292                 jit_wanted=true
1293                 ;;
1294         sparc*-*-*)
1295                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1296                    TARGET=SPARC64
1297                 else
1298                         TARGET=SPARC
1299                 fi
1300                 arch_target=sparc;
1301                 JIT_SUPPORTED=yes
1302                 ACCESS_UNALIGNED="no"
1303                 LIBC="libc.so"
1304                 INTL="libintl.so"
1305                 jit_wanted=true
1306                 if test x"$GCC" = xyes; then
1307                         CFLAGS="$CFLAGS -Wno-cast-align"
1308                 fi
1309                 ;;
1310        alpha*-*-linux* | alpha*-*-osf*)
1311                 TARGET=ALPHA;
1312                 ACCESS_UNALIGNED="no"
1313                 JIT_SUPPORTED=no
1314                 INTERP_SUPPORTED=yes
1315                 interp_wanted=true
1316                 arch_target=alpha;
1317                ;;
1318         *-*-mingw*|*-*-cygwin*)
1319                 INTL="intl"
1320                 ;;
1321 #       ia64-*-linux* | ia64-*-hpux*)
1322 #               TARGET=IA64;
1323 #               arch_target=ia64;
1324 #               JIT_SUPPORTED=no;
1325 #               ACCESS_UNALIGNED="no";
1326 #               case "$host_os" in
1327 #                       linux*) LIBC="libc.so.6.1";;
1328 #                       hpux*)  LIBC="libc.so.1";;
1329 #               esac
1330 #               ;;
1331 #       m68k-*-linux*)
1332 #               TARGET=M68K
1333 #               ;;
1334         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1335                 TARGET=HPPA;
1336                 arch_target=hppa;
1337                 LIBC="libc.sl"
1338                 ACCESS_UNALIGNED="no"
1339                 INTERP_SUPPORTED=yes
1340                 interp_wanted=true
1341                 ;;
1342         hppa*linux*)
1343                 TARGET=HPPA;
1344                 arch_target=hppa;
1345                 ACCESS_UNALIGNED="no"
1346                 INTERP_SUPPORTED=yes
1347                 interp_wanted=true
1348                 ;;
1349         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1350         powerpc-*-sysv* | powerpc-*-darwin*)
1351                 TARGET=POWERPC;
1352                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1353                 arch_target=ppc;
1354                 JIT_SUPPORTED=yes
1355                 jit_wanted=true
1356                 ;;
1357         arm-*-linux-* | armv4l-*-linux-*)
1358                 TARGET=ARM;
1359                 arch_target=arm;
1360                 ACCESS_UNALIGNED="no"
1361                 INTERP_SUPPORTED=yes
1362                 interp_wanted=true
1363                 ;;
1364         s390-*-linux*)
1365                 TARGET=S390;
1366                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1367                 arch_target=s390;
1368                 ACCESS_UNALIGNED="no"
1369                 JIT_SUPPORTED=yes
1370                 ;;
1371         s390x-*-linux*)
1372                 TARGET=S390x;
1373                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1374                 arch_target=s390x;
1375                 ACCESS_UNALIGNED="no"
1376                 JIT_SUPPORTED=yes
1377                 ;;
1378 esac
1379
1380 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1381         if test x$withval = xyes; then
1382            jit_wanted=true
1383         else
1384            jit_wanted=false
1385         fi
1386 ])
1387
1388 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1389         if test x$withval = xyes; then
1390            interp_wanted=true
1391         else
1392            interp_wanted=false
1393         fi
1394 ])
1395
1396 USEJIT=false
1397 if test x$JIT_SUPPORTED = xyes; then
1398    if $jit_wanted; then
1399       USEJIT=true
1400       jit_status="Building and using the JIT"
1401    else
1402       if $interp_wanted; then
1403          jit_status="Building the JIT, defaulting to the interpreter"
1404       else
1405          AC_ERROR(No JIT or interpreter support available or selected.)
1406       fi
1407    fi
1408 else
1409    if $interp_wanted; then
1410       jit_status="interpreter"
1411    else
1412       AC_ERROR(No JIT or interpreter support available or selected.)
1413    fi
1414 fi
1415
1416 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1417
1418 libsuffix=".so"
1419
1420 case "$host" in
1421      powerpc-*-darwin*)
1422         libsuffix=".dylib"
1423         LIBC="libc.dylib"
1424         INTL="libintl.dylib"
1425         ;;
1426      *-*-*netbsd*)
1427         LIBC="libc.so.12"
1428         INTL="libintl.so.0"
1429         ;;
1430     *-*-*freebsd*)
1431         LIBC="libc.so"
1432         INTL="libintl.so"
1433         ;;
1434     *-*-*openbsd*)
1435         LIBC="libc.so"
1436         INTL="libintl.so"
1437         ;;
1438 esac
1439 AC_SUBST(libsuffix)
1440
1441 if test "x$TARGET" != "xAMD64"; then
1442    # valgrind headers don't compile under x86-64
1443    AC_CHECK_HEADERS(valgrind/memcheck.h)
1444 fi
1445
1446 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1447         if test "x$with_tls" = "x__thread"; then
1448                 #
1449                 # On some linux distributions, TLS works in executables, but linking
1450                 # against a shared library containing TLS fails with:
1451                 # undefined reference to `__tls_get_addr'
1452                 #
1453                 rm -f conftest.c conftest.so conftest
1454                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1455                 gcc -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1456                 gcc -o conftest conftest.so > /dev/null 2>&1
1457                 if test ! -f conftest; then
1458                    AC_MSG_WARN([Disabling usage of __thread.]);
1459                    with_tls=pthread
1460                 fi
1461                 rm -f conftest.c conftest.so conftest
1462         fi
1463 fi
1464
1465 if test "x$with_tls" = "x__thread"; then
1466         AC_DEFINE(HAVE_KW_THREAD)
1467    # Pass the information to libgc
1468         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1469         export CPPFLAGS
1470         AC_MSG_CHECKING(if the tls_model attribute is supported)
1471         AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
1472                 ], [
1473                         AC_MSG_RESULT(yes)
1474                         AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
1475                 ], [
1476                         AC_MSG_RESULT(no)
1477         ])
1478 fi
1479
1480 if test ${TARGET} = ARM; then
1481         dnl ******************************************
1482         dnl *** Check to see what FPU is available ***
1483         dnl ******************************************
1484         AC_MSG_CHECKING(which FPU to use)
1485
1486         AC_TRY_COMPILE([], [
1487                 __asm__ ("ldfd f0, [r0]");
1488                 ], fpu=FPA, [
1489                         AC_TRY_COMPILE([], [
1490                                 __asm__ ("fldd d0, [r0]");
1491                         ], fpu=VFP, fpu=NONE)
1492                 ])
1493
1494         AC_MSG_RESULT($fpu)
1495         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1496         unset fpu
1497 fi
1498
1499 if test ${TARGET} = unknown; then
1500         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1501         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1502 fi
1503
1504 if test ${ACCESS_UNALIGNED} = no; then
1505         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1506 fi
1507
1508 PREVIEW=yes
1509 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1510         if test x$with_preview = xyes; then
1511               PREVIEW=yes
1512         fi
1513 ])
1514
1515 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1516
1517 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1518 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1519 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1520 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1521 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1522 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1523 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1524 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1525 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1526 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1527 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1528 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1529 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1530 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1531
1532 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1533 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
1534 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
1535
1536 AC_SUBST(LIBC)
1537 AC_SUBST(INTL)
1538
1539 AC_SUBST(arch_target)
1540 AC_SUBST(CFLAGS)
1541 AC_SUBST(CPPFLAGS)
1542 AC_SUBST(LDFLAGS)
1543
1544 mono_build_root=`pwd`
1545 AC_SUBST(mono_build_root)
1546
1547 if test x$USEJIT = xtrue; then
1548   mono_runtime=mono/mini/mono
1549 else
1550   mono_runtime=mono/interpreter/mint
1551 fi
1552 AC_SUBST(mono_runtime)
1553
1554 mono_cfg_root=$mono_build_root/runtime
1555 if test x$platform_win32 = xyes; then
1556   mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
1557 else
1558   mono_cfg_dir=$mono_cfg_root/etc
1559 fi
1560 AC_SUBST(mono_cfg_dir)
1561
1562 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
1563
1564 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
1565 [   depth=../../../..
1566     case $srcdir in
1567     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1568     .) reldir=$depth ;;
1569     *) reldir=$depth/$srcdir ;;
1570     esac
1571     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
1572     cd runtime/etc/mono/1.0
1573     rm -f machine.config
1574     $LN_S $reldir/data/net_1_1/machine.config machine.config
1575     cd $depth
1576 ],[LN_S='$LN_S'])
1577
1578 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
1579 [   depth=../../../..
1580     case $srcdir in
1581     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1582     .) reldir=$depth ;;
1583     *) reldir=$depth/$srcdir ;;
1584     esac
1585     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1586     cd runtime/etc/mono/2.0
1587     rm -f machine.config
1588     $LN_S $reldir/data/net_2_0/machine.config machine.config
1589     cd $depth
1590 ],[LN_S='$LN_S'])
1591
1592 AC_OUTPUT([
1593 Makefile
1594 mint.pc
1595 mono.pc
1596 scripts/mono-nunit.pc
1597 mono/Makefile
1598 mono/utils/Makefile
1599 mono/metadata/Makefile
1600 mono/dis/Makefile
1601 mono/cil/Makefile
1602 mono/arch/Makefile
1603 mono/os/Makefile
1604 mono/os/win32/Makefile
1605 mono/os/unix/Makefile
1606 mono/arch/x86/Makefile
1607 mono/arch/amd64/Makefile
1608 mono/arch/hppa/Makefile
1609 mono/arch/ppc/Makefile
1610 mono/arch/sparc/Makefile
1611 mono/arch/s390/Makefile
1612 mono/arch/s390x/Makefile
1613 mono/arch/arm/Makefile
1614 mono/arch/alpha/Makefile
1615 mono/interpreter/Makefile
1616 mono/tests/Makefile
1617 mono/tests/tests-config
1618 mono/benchmark/Makefile
1619 mono/monoburg/Makefile
1620 mono/monograph/Makefile
1621 mono/io-layer/Makefile
1622 mono/handles/Makefile
1623 mono/mini/Makefile
1624 mono/profiler/Makefile
1625 ikvm-native/Makefile
1626 scripts/Makefile
1627 man/Makefile
1628 web/Makefile
1629 docs/Makefile
1630 data/Makefile
1631 data/net_1_1/Makefile
1632 data/net_2_0/Makefile
1633 samples/Makefile
1634 support/Makefile
1635 data/config
1636 mono.spec
1637 tools/Makefile
1638 tools/locale-builder/Makefile
1639 runtime/Makefile
1640 ])
1641
1642 (
1643   case $prefix in
1644   NONE) prefix=/usr/local ;;
1645   esac
1646   case $exec_prefix in
1647   NONE | '${prefix}') exec_prefix=$prefix ;;
1648   esac
1649
1650   echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
1651   echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
1652   echo "mono_libdir=$exec_prefix/lib" >> $srcdir/$mcsdir/build/config.make
1653   echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
1654 )
1655
1656 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
1657
1658 echo "
1659         mcs source:  $mcs_topdir
1660         GC:          $gc
1661         Globalization:     $enable_glob
1662         TLS:         $with_tls
1663         SIGALTSTACK: $with_sigaltstack
1664         Engine:      $jit_status
1665         2.0 Alpha:   $PREVIEW
1666         JNI support: $jdk_headers_found
1667         libgdiplus:  $libgdiplus_msg
1668         $disabled
1669
1670 "