configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3 AM_CONFIG_HEADER(config.h)
   4 AM_INIT_AUTOMAKE(mono,0.24)
   5 AM_MAINTAINER_MODE
   6
   7 #
   8 # These are the flags that need to be stored in the mono.pc file for
   9 # compiling code that will embed Mono
  10 #
  11 libmono_cflags=""
  12 libmono_ldflags=""
  13 AC_SUBST(libmono_cflags)
  14 AC_SUBST(libmono_ldflags)
  15
  16 # Thread configuration inspired by sleepycat's db
  17 AC_MSG_CHECKING([host platform characteristics])
  18 case "$host" in
  19         *-*-mingw*|*-*-cygwin*)
  20                 platform_win32=yes
  21                 AC_DEFINE(PLATFORM_WIN32)
  22                 CC="gcc -mno-cygwin"
  23                 HOST_CC="gcc"
  24                 CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  25                 libdl=
  26                 ;;
  27         *-*-*bsd*)
  28                 platform_win32=no
  29                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE"
  30                 libmono_cflags="-D_THREAD_SAFE"
  31                 LDFLAGS="$LDFLAGS -pthread"
  32                 libmono_ldflags="-pthread"
  33                 AC_DEFINE(NEED_LINK_UNLINK)
  34                 AC_DEFINE(PTHREAD_POINTER_ID)
  35                 libdl=
  36                 ;;
  37         *-*-linux*)
  38                 platform_win32=no
  39                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -DMONO_USE_EXC_TABLES -D_GNU_SOURCE -D_REENTRANT -fexceptions"
  40                 libmono_cflags="-DMONO_USE_EXC_TABLES -fexceptions -D_REENTRANT"
  41                 libmono_ldflags="-lpthread"
  42                 libdl="-ldl"
  43                 ;;
  44         *-*-solaris*)
  45                 platform_win32=no
  46                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
  47                 AC_DEFINE(NEED_LINK_UNLINK)
  48                 libmono_cflags="-D_REENTRANT"
  49                 ;;
  50         *-*-darwin*)
  51                 platform_win32=no
  52                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE"
  53                 libmono_cflags="-D_THREAD_SAFE"
  54                 LDFLAGS="$LDFLAGS -pthread"
  55                 libmono_ldflags="-pthread"
  56                 AC_DEFINE(NEED_LINK_UNLINK)
  57                 AC_DEFINE(PTHREAD_POINTER_ID)
  58                 libdl=
  59                 ;;
  60         *)
  61                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
  62                 platform_win32=no
  63                 libdl="-ldl"
  64                 ;;
  65 esac
  66 AC_MSG_RESULT(ok)
  67 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
  68
  69 AC_CHECK_TOOL(CC, gcc, gcc)
  70 AC_PROG_CC
  71 AM_PROG_CC_STDC
  72 AC_PROG_INSTALL
  73
  74 AC_CHECK_PROG(BISON, bison,yes,no)
  75 if test "x$BISON" = "xno";
  76 then
  77         AC_MSG_ERROR([You need to install bison])
  78 fi
  79
  80 dnl may require a specific autoconf version
  81 dnl AC_PROG_CC_FOR_BUILD
  82 dnl CC_FOR_BUILD not automatically detected
  83 CC_FOR_BUILD=$CC
  84 BUILD_EXEEXT=
  85 if test "x$cross_compiling" = "xyes"; then
  86         CC_FOR_BUILD=cc
  87         BUILD_EXEEXT=""
  88 fi
  89 AC_SUBST(CC_FOR_BUILD)
  90 AC_SUBST(HOST_CC)
  91 AC_SUBST(BUILD_EXEEXT)
  92
  93 # Set STDC_HEADERS
  94 AC_HEADER_STDC
  95 AC_LIBTOOL_WIN32_DLL
  96 AM_PROG_LIBTOOL
  97
  98 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h)
  99
 100 # for mono/metadata/debug-symfile.c
 101 AC_CHECK_HEADERS(elf.h)
 102
 103 # for mono/dis
 104 AC_CHECK_HEADERS(wchar.h)
 105
 106 # not 64 bit clean in cross-compile
 107 AC_CHECK_SIZEOF(void *, 4)
 108
 109 CFLAGS='-g -Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 110
 111 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 112 if test "x$PKG_CONFIG" = "xno"; then
 113         AC_MSG_ERROR([You need to install pkg-config])
 114 fi
 115
 116 dnl for use on the build system
 117 dnl pkg-config is stupid
 118 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
 119 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
 120 AC_SUBST(BUILD_GLIB_CFLAGS)
 121 AC_SUBST(BUILD_GLIB_LIBS)
 122
 123 PKG_PATH=
 124 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 125         if test x$with_crosspkgdir = "x"; then
 126                 if test -s $PKG_CONFIG_PATH; then
 127                         PKG_PATH=$PKG_CONFIG_PATH
 128                 fi
 129         else
 130                 PKG_PATH=$with_crosspkgdir
 131                 PKG_CONFIG_PATH=$PKG_PATH
 132                 export PKG_CONFIG_PATH
 133         fi
 134 )
 135
 136 ## Versions of dependencies
 137 GLIB_REQUIRED_VERSION=1.3.11
 138
 139 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 140
 141 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
 142 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
 143 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 144 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 145
 146 AC_SUBST(GLIB_CFLAGS)
 147 AC_SUBST(GLIB_LIBS)
 148 AC_SUBST(GMODULE_CFLAGS)
 149 AC_SUBST(GMODULE_LIBS)
 150
 151 gc_headers=no
 152 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 153 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 154 gc=auto
 155 AC_ARG_WITH(gc, [  --with-gc=boehm,none],[gc=$with_gc])
 156
 157 case "x$gc" in
 158         xboehm|xbohem|xyes)
 159                 if test "x$found_boehm" != "xyes"; then
 160                         AC_MSG_ERROR("GC requested but libgc not found!")
 161                 fi
 162                 if test "x$gc_headers" != "xyes"; then
 163                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 164                 fi
 165
 166                 AC_DEFINE(HAVE_BOEHM_GC)
 167                 AC_SUBST(HAVE_BOEHM_GC)
 168                 LIBS="$LIBS -lgc $libdl"
 169                 ;;
 170         xnone)
 171                 AC_MSG_WARN("Compiling mono without GC.")
 172                 ;;
 173         *)
 174                 # If libgc was found, use it.  Otherwise just warn.
 175                 if test "x$found_boehm" != "xyes"; then
 176                         AC_MSG_WARN("Compiling mono without GC.")
 177                 else
 178                         if test "x$gc_headers" != "xyes"; then
 179                                 AC_MSG_ERROR("Found libgc but not its header files! You may need to install them by hand.")
 180                         fi
 181                         AC_DEFINE(HAVE_BOEHM_GC)
 182                         AC_SUBST(HAVE_BOEHM_GC)
 183                         LIBS="$LIBS -lgc $libdl"
 184                         gc="boehm"
 185                 fi
 186                 ;;
 187 esac
 188
 189 if test "x$gc" = xboehm; then
 190         AC_CHECK_FUNCS(GC_gcj_malloc)
 191 fi
 192
 193 if test x$platform_win32 = xno; then
 194         dnl ******************************************************************
 195         dnl *** Check for large file support                               ***
 196         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 197         dnl ******************************************************************
 198
 199         # Check that off_t can represent 2**63 - 1 correctly, working around
 200         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 201         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 202         large_offt=no
 203         AC_DEFUN(LARGE_FILES, [
 204                 large_CPPFLAGS=$CPPFLAGS
 205                 CPPFLAGS="$CPPFLAGS $1"
 206                 AC_TRY_RUN([
 207                         #include <sys/types.h>
 208
 209                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 210
 211                         int main(void) {
 212                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 213                                                (BIG_OFF_T%2147483647==1));
 214                                 if(big_off_t) {
 215                                         exit(0);
 216                                 } else {
 217                                         exit(1);
 218                                 }
 219                         }
 220                 ], [
 221                         AC_MSG_RESULT(ok)
 222                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 223                         large_CPPFLAGS="$large_CPPFLAGS $1"
 224                         large_offt=yes
 225                 ], [
 226                         AC_MSG_RESULT(no)
 227                 ], "")
 228                 CPPFLAGS=$large_CPPFLAGS
 229         ])
 230
 231         AC_MSG_CHECKING(if off_t is 64 bits wide)
 232         LARGE_FILES("")
 233         if test $large_offt = no; then
 234                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 235                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 236         fi
 237         if test $large_offt = no; then
 238                 AC_MSG_WARN([No 64 bit file size support available])
 239         fi
 240
 241         dnl *****************************
 242         dnl *** Checks for libsocket  ***
 243         dnl *****************************
 244         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 245
 246         dnl *******************************
 247         dnl *** Checks for MSG_NOSIGNAL ***
 248         dnl *******************************
 249         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 250         AC_TRY_COMPILE([#include <sys/socket.h>], [
 251                 int f = MSG_NOSIGNAL;
 252         ], [
 253                 # Yes, we have it...
 254                 AC_MSG_RESULT(yes)
 255                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 256         ], [
 257                 # We'll have to use signals
 258                 AC_MSG_RESULT(no)
 259         ])
 260
 261         dnl *****************************
 262         dnl *** Checks for SOL_IP     ***
 263         dnl *****************************
 264         AC_MSG_CHECKING(for SOL_IP)
 265         AC_TRY_COMPILE([#include <netdb.h>], [
 266                 int level = SOL_IP;
 267         ], [
 268                 # Yes, we have it...
 269                 AC_MSG_RESULT(yes)
 270                 AC_DEFINE(HAVE_SOL_IP)
 271         ], [
 272                 # We'll have to use getprotobyname
 273                 AC_MSG_RESULT(no)
 274         ])
 275
 276         dnl *****************************
 277         dnl *** Checks for SOL_TCP    ***
 278         dnl *****************************
 279         AC_MSG_CHECKING(for SOL_TCP)
 280         AC_TRY_COMPILE([#include <netdb.h>], [
 281                 int level = SOL_TCP;
 282         ], [
 283                 # Yes, we have it...
 284                 AC_MSG_RESULT(yes)
 285                 AC_DEFINE(HAVE_SOL_TCP)
 286         ], [
 287                 # We'll have to use getprotobyname
 288                 AC_MSG_RESULT(no)
 289         ])
 290
 291         dnl *****************************
 292         dnl *** Checks for IP_PKTINFO ***
 293         dnl *****************************
 294         AC_MSG_CHECKING(for IP_PKTINFO)
 295         AC_TRY_COMPILE([#include <netdb.h>], [
 296                 int level = IP_PKTINFO;
 297         ], [
 298                 # Yes, we have it...
 299                 AC_MSG_RESULT(yes)
 300                 AC_DEFINE(HAVE_IP_PKTINFO)
 301         ], [
 302                 AC_MSG_RESULT(no)
 303         ])
 304
 305         dnl *********************************
 306         dnl *** Check for struct ip_mreqn ***
 307         dnl *********************************
 308         AC_MSG_CHECKING(for struct ip_mreqn)
 309         AC_TRY_COMPILE([#include <netinet/in.h>], [
 310                 struct ip_mreqn mreq;
 311                 mreq.imr_address.s_addr = 0;
 312         ], [
 313                 # Yes, we have it...
 314                 AC_MSG_RESULT(yes)
 315                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 316         ], [
 317                 # We'll just have to use struct ip_mreq
 318                 AC_MSG_RESULT(no)
 319         ])
 320
 321         dnl *****************************
 322         dnl *** Checks for libnsl     ***
 323         dnl *****************************
 324         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 325
 326         AC_CHECK_FUNCS(inet_pton inet_aton)
 327
 328         dnl ***********************************************
 329         dnl *** Checks for size of sockaddr_un.sun_path ***
 330         dnl ***********************************************
 331         # AC_CHECK_SIZEOF can't cope with struct members :-(
 332         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 333         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 334                 [AC_TRY_RUN([
 335                         #include <sys/types.h>
 336                         #include <stdio.h>
 337                         #include <sys/un.h>
 338
 339                         int main(void) {
 340                                 struct sockaddr_un sock_un;
 341                                 FILE *f=fopen("conftestval", "w");
 342                                 if(!f) exit(1);
 343                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 344                                 exit(0);
 345                         }
 346                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 347                    cv_mono_sizeof_sunpath=0,
 348                    cv_mono_sizeof_sunpath=0)])dnl
 349         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 350         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 351
 352         dnl *****************************
 353         dnl *** Checks for libxnet    ***
 354         dnl *****************************
 355         case "${host}" in
 356                 *solaris* )
 357                         AC_MSG_CHECKING(for Solaris XPG4 support)
 358                         if test -f /usr/lib/libxnet.so; then
 359                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 360                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 361                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 362                                 LIBS="$LIBS -lxnet"
 363                                 AC_MSG_RESULT(yes)
 364                         else
 365                                 AC_MSG_RESULT(no)
 366                         fi
 367
 368                         if test "$GCC" = "yes"; then
 369                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 370                         fi
 371                 ;;
 372         esac
 373
 374         dnl *****************************
 375         dnl *** Checks for libpthread ***
 376         dnl *****************************
 377         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 378         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 379         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 380         AC_TRY_COMPILE([ #include <pthread.h>], [
 381                 pthread_mutexattr_t attr;
 382                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 383         ], [
 384                 AC_MSG_RESULT(ok)
 385         ], [
 386                 AC_MSG_RESULT(no)
 387                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 388                 AC_DEFINE(USE_MONO_MUTEX)
 389         ])
 390
 391         dnl ********************************
 392         dnl *** Checks for semaphore lib ***
 393         dnl ********************************
 394         AC_CHECK_LIB(rt, sem_init, LIBS="$LIBS -lrt")
 395
 396         dnl ********************************
 397         dnl *** Checks for timezone stuff **
 398         dnl ********************************
 399         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 400                 AC_TRY_COMPILE([
 401                         #include <time.h>
 402                         ], [
 403                         struct tm tm;
 404                         tm.tm_gmtoff = 1;
 405                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 406         if test $ac_cv_struct_tm_gmtoff = yes; then
 407                 AC_DEFINE(HAVE_TM_GMTOFF)
 408         else
 409                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 410                         AC_TRY_COMPILE([
 411                                 #include <time.h>
 412                         ], [
 413                                 timezone = 1;
 414                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 415                 if test $ac_cv_var_timezone = yes; then
 416                         AC_DEFINE(HAVE_TIMEZONE)
 417                 else
 418                         AC_ERROR(unable to find a way to determine timezone)
 419                 fi
 420         fi
 421 else
 422         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
 423         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
 424 fi
 425
 426 dnl ****************************
 427 dnl *** Look for /dev/random ***
 428 dnl ****************************
 429
 430 AC_MSG_CHECKING([if usage of random device is requested])
 431 AC_ARG_ENABLE(dev-random,
 432 [  --disable-dev-random    disable the use of the random device],
 433 try_dev_random=$enableval, try_dev_random=yes)
 434 AC_MSG_RESULT($try_dev_random)
 435
 436 case "{$target}" in
 437     *-openbsd*)
 438     NAME_DEV_RANDOM="/dev/srandom"
 439     ;;
 440
 441 dnl Win32 does not have /dev/random, they have their own method...
 442
 443     *-*-mingw*|*-*-cygwin*)
 444     ac_cv_have_dev_random = no
 445     ;;
 446
 447 dnl Everywhere else, it's /dev/random
 448
 449     *)
 450     NAME_DEV_RANDOM="/dev/random"
 451     ;;
 452 esac
 453
 454 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 455
 456 dnl Now check if the device actually exists
 457
 458 if test "x$try_dev_random" = "xyes"; then
 459     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 460     [if test -r "$NAME_DEV_RANDOM" ; then
 461         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 462     if test "x$ac_cv_have_dev_random" = "xyes"; then
 463         AC_DEFINE(HAVE_CRYPT_RNG)
 464     fi
 465 else
 466     AC_MSG_CHECKING(for random device)
 467     ac_cv_have_dev_random=no
 468     AC_MSG_RESULT(has been disabled)
 469 fi
 470
 471 if test "x$platform_win32" = "xyes"; then
 472     AC_DEFINE(HAVE_CRYPT_RNG)
 473 fi
 474
 475 if test "x$ac_cv_have_dev_random" = "xno" \
 476     && test "x$platform_win32" = "xno"; then
 477     AC_MSG_WARN([[
 478 ***
 479 *** A system-provided entropy source was not found on this system.
 480 *** Because of this, the System.Security.Cryptography random number generator
 481 *** will throw a NotImplemented exception.
 482 ***
 483 *** If you are seeing this message, and you know your system DOES have an
 484 *** entropy collection in place, please contact <crichton@gimp.org> and
 485 *** provide information about the system and how to access the random device.
 486 ***
 487 *** For those systems who lack a random device, EGD support is forthcoming.
 488 ***]])
 489 fi
 490
 491 AC_MSG_CHECKING([if inter-process shared handles are requested])
 492 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
 493 AC_MSG_RESULT($try_shared_handles)
 494 if test "x$try_shared_handles" != "xyes"; then
 495         AC_DEFINE(DISABLE_SHARED_HANDLES)
 496         AC_SUBST(DISABLE_SHARED_HANDLES)
 497 fi
 498
 499 TARGET="unknown"
 500 ACCESS_UNALIGNED="yes"
 501
 502 case "$host" in
 503 #mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; ACCESS_UNALIGNED="no";;
 504 i*86-*-*) TARGET=X86; arch_target=x86;;
 505 sparc*-*-*) TARGET=SPARC; arch_target=sparc; ACCESS_UNALIGNED="no";;
 506 #alpha*-*-linux* | alpha*-*-osf*) TARGET=ALPHA; ACCESS_UNALIGNED="no";;
 507 #m68k-*-linux*) TARGET=M68K;;
 508 macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | powerpc-*-sysv* | powerpc-*-darwin*) TARGET=POWERPC; arch_target=ppc;;
 509 arm-*-linux-* | armv4l-*-linux-*) TARGET=ARM; arch_target=arm; ACCESS_UNALIGNED="no";;
 510 s390-*-linux*) TARGET=S390; arch_target=s390; ACCESS_UNALIGNED="no";;
 511 esac
 512
 513 if test ${TARGET} = unknown; then
 514         CPPFLAGS="$CPPFLAGS -DNO_PORT"
 515         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
 516 fi
 517
 518 if test ${ACCESS_UNALIGNED} = no; then
 519         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
 520 fi
 521
 522 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
 523 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
 524 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 525 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 526 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 527 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 528 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 529 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 530 AM_CONDITIONAL(S390, test x$TARGET = xS390)
 531
 532 LIBC="libc.so.6"
 533 AC_SUBST(LIBC)
 534
 535 AC_SUBST(arch_target)
 536 AC_SUBST(CFLAGS)
 537 AC_SUBST(CPPFLAGS)
 538 AC_SUBST(LDFLAGS)
 539
 540 AC_OUTPUT([
 541 Makefile
 542 mono.pc
 543 mono/Makefile
 544 mono/utils/Makefile
 545 mono/metadata/Makefile
 546 mono/dis/Makefile
 547 mono/cil/Makefile
 548 mono/arch/Makefile
 549 mono/os/Makefile
 550 mono/os/win32/Makefile
 551 mono/os/unix/Makefile
 552 mono/arch/x86/Makefile
 553 mono/arch/ppc/Makefile
 554 mono/arch/sparc/Makefile
 555 mono/arch/s390/Makefile
 556 mono/arch/arm/Makefile
 557 mono/arch/alpha/Makefile
 558 mono/interpreter/Makefile
 559 mono/tests/Makefile
 560 mono/benchmark/Makefile
 561 mono/monoburg/Makefile
 562 mono/monograph/Makefile
 563 mono/jit/Makefile
 564 mono/io-layer/Makefile
 565 mono/handles/Makefile
 566 mono/mini/Makefile
 567 runtime/Makefile
 568 scripts/Makefile
 569 man/Makefile
 570 doc/Makefile
 571 docs/Makefile
 572 data/Makefile
 573 mono.spec
 574 ])
 575
 576 echo "
 577
 578         GC:     $gc
 579
 580 "