configure.in

   1
   2 AC_INIT(README)
   3 AC_CANONICAL_SYSTEM
   4 AM_CONFIG_HEADER(config.h)
   5 AM_INIT_AUTOMAKE(mono, 0.11)
   6 AM_MAINTAINER_MODE
   7
   8 dnl ****************************************
   9 dnl *** Check if we're building on win32 ***
  10 dnl ****************************************
  11 AC_MSG_CHECKING([if building for some Win32 platform])
  12 case "$host" in
  13         *-*-mingw*|*-*-cygwin*)
  14                 platform_win32=yes
  15                 AC_DEFINE(PLATFORM_WIN32)
  16                 CC="gcc -mno-cygwin"
  17                 ;;
  18         *)
  19                 platform_win32=no
  20                 ;;
  21 esac
  22 AC_MSG_RESULT($platform_win32)
  23 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
  24
  25 AC_CHECK_TOOL(CC, gcc, gcc)
  26 AC_PROG_CC
  27 AM_PROG_CC_STDC
  28 AC_PROG_INSTALL
  29
  30 dnl may require a specific autoconf version
  31 dnl AC_PROG_CC_FOR_BUILD
  32 dnl CC_FOR_BUILD not automatically detected
  33 CC_FOR_BUILD=$CC
  34 BUILD_EXEEXT=
  35 if test "x$cross_compiling" = "xyes"; then
  36         CC_FOR_BUILD=cc
  37         BUILD_EXEEXT=""
  38 fi
  39 AC_SUBST(CC_FOR_BUILD)
  40 AC_SUBST(HOST_CC)
  41 AC_SUBST(BUILD_EXEEXT)
  42
  43 # Set STDC_HEADERS
  44 AC_HEADER_STDC
  45 AC_LIBTOOL_WIN32_DLL
  46 AM_PROG_LIBTOOL
  47
  48 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h)
  49
  50 AC_CHECK_HEADERS(iconv.h)
  51 AC_CHECK_HEADERS(giconv.h)
  52
  53 # for mono/metadata/debug-symfile.c
  54 AC_CHECK_HEADERS(elf.h)
  55
  56 # not 64 bit clean in cross-compile
  57 AC_CHECK_SIZEOF(void *, 4)
  58
  59 CFLAGS='-g -Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
  60
  61 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  62 if test "x$PKG_CONFIG" = "xno"; then
  63         AC_MSG_ERROR([You need to install pkg-config])
  64 fi
  65
  66 dnl for use on the build system
  67 dnl pkg-config is stupid
  68 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
  69 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
  70 AC_SUBST(BUILD_GLIB_CFLAGS)
  71 AC_SUBST(BUILD_GLIB_LIBS)
  72
  73 PKG_PATH=
  74 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
  75         if test x$with_crosspkgdir = "x"; then
  76                 if test -s $PKG_CONFIG_PATH; then
  77                         PKG_PATH=$PKG_CONFIG_PATH
  78                 fi
  79         else
  80                 PKG_PATH=$with_crosspkgdir
  81                 PKG_CONFIG_PATH=$PKG_PATH
  82                 export PKG_CONFIG_PATH
  83         fi
  84 )
  85
  86 ## Versions of dependencies
  87 GLIB_REQUIRED_VERSION=1.3.11
  88
  89 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
  90
  91 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
  92 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
  93 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
  94 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
  95
  96 AC_SUBST(GLIB_CFLAGS)
  97 AC_SUBST(GLIB_LIBS)
  98 AC_SUBST(GMODULE_CFLAGS)
  99 AC_SUBST(GMODULE_LIBS)
 100
 101 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes")
 102 gc=auto
 103 AC_ARG_WITH(gc, [  --with-gc=boehm,none],[gc=$with_gc])
 104
 105 case "x$gc" in
 106         xboehm|xyes)
 107                 if test "x$found_boehm" != "xyes"; then
 108                         AC_MSG_ERROR("GC requested but libgc not found!")
 109                 fi
 110
 111                 AC_DEFINE(HAVE_BOEHM_GC)
 112                 AC_SUBST(HAVE_BOEHM_GC)
 113                 LIBS="$LIBS -lgc"
 114                 ;;
 115         xnone)
 116                 AC_MSG_WARN("Compiling mono without GC.")
 117                 ;;
 118         *)
 119 dnl When the JIT works with libgc, use this chunk.
 120 dnl             # If libgc was found, use it.  Otherwise just warn.
 121                 if test "x$found_boehm" != "xyes"; then
 122                         AC_MSG_WARN("Compiling mono without GC.")
 123                 else
 124                         AC_DEFINE(HAVE_BOEHM_GC)
 125                         AC_SUBST(HAVE_BOEHM_GC)
 126                         LIBS="$LIBS -lgc"
 127                         gc="boehm"
 128                 fi
 129 dnl             AC_MSG_WARN("Compiling mono without GC.")
 130                 ;;
 131 esac
 132
 133 if test x$platform_win32 = xno; then
 134         dnl ******************************************************************
 135         dnl *** Check for large file support                               ***
 136         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 137         dnl ******************************************************************
 138
 139         # Check that off_t can represent 2**63 - 1 correctly, working around
 140         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 141         # CFLAGS and sets $large_offt to yes if the test succeeds
 142         large_offt=no
 143         AC_DEFUN(LARGE_FILES, [
 144                 large_CPPFLAGS=$CPPFLAGS
 145                 CPPFLAGS="$CPPFLAGS $1"
 146                 AC_TRY_RUN([
 147                         #include <sys/types.h>
 148
 149                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 150
 151                         int main(void) {
 152                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 153                                                (BIG_OFF_T%2147483647==1));
 154                                 if(big_off_t) {
 155                                         exit(0);
 156                                 } else {
 157                                         exit(1);
 158                                 }
 159                         }
 160                 ], [
 161                         AC_MSG_RESULT(ok)
 162                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 163                         CFLAGS="$CFLAGS $1"
 164                         large_offt=yes
 165                 ], [
 166                         AC_MSG_RESULT(no)
 167                 ], "")
 168                 CPPFLAGS=$large_CPPFLAGS
 169         ])
 170
 171         AC_MSG_CHECKING(if off_t is 64 bits wide)
 172         LARGE_FILES("")
 173         if test $large_offt = no; then
 174                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 175                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 176         fi
 177         if test $large_offt = no; then
 178                 AC_MSG_WARN([No 64 bit file size support available])
 179         fi
 180
 181         dnl *****************************
 182         dnl *** Checks for libsocket  ***
 183         dnl *****************************
 184         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 185
 186         dnl *****************************
 187         dnl *** Checks for SOL_IP     ***
 188         dnl *****************************
 189         AC_MSG_CHECKING(for SOL_IP)
 190         AC_TRY_COMPILE([#include <netdb.h>], [
 191                 int level = SOL_IP;
 192         ], [
 193                 # Yes, we have it...
 194                 AC_MSG_RESULT(yes)
 195                 AC_DEFINE(HAVE_SOL_IP)
 196         ], [
 197                 # We'll have to use getprotobyname
 198                 AC_MSG_RESULT(no)
 199         ])
 200
 201         dnl *****************************
 202         dnl *** Checks for SOL_TCP    ***
 203         dnl *****************************
 204         AC_MSG_CHECKING(for SOL_TCP)
 205         AC_TRY_COMPILE([#include <netdb.h>], [
 206                 int level = SOL_TCP;
 207         ], [
 208                 # Yes, we have it...
 209                 AC_MSG_RESULT(yes)
 210                 AC_DEFINE(HAVE_SOL_TCP)
 211         ], [
 212                 # We'll have to use getprotobyname
 213                 AC_MSG_RESULT(no)
 214         ])
 215
 216         dnl *****************************
 217         dnl *** Checks for IP_PKTINFO ***
 218         dnl *****************************
 219         AC_MSG_CHECKING(for IP_PKTINFO)
 220         AC_TRY_COMPILE([#include <netdb.h>], [
 221                 int level = IP_PKTINFO;
 222         ], [
 223                 # Yes, we have it...
 224                 AC_MSG_RESULT(yes)
 225                 AC_DEFINE(HAVE_IP_PKTINFO)
 226         ], [
 227                 AC_MSG_RESULT(no)
 228         ])
 229
 230         dnl *********************************
 231         dnl *** Check for struct ip_mreqn ***
 232         dnl *********************************
 233         AC_MSG_CHECKING(for struct ip_mreqn)
 234         AC_TRY_COMPILE([#include <netinet/in.h>], [
 235                 struct ip_mreqn mreq;
 236                 mreq.imr_address.s_addr = 0;
 237         ], [
 238                 # Yes, we have it...
 239                 AC_MSG_RESULT(yes)
 240                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 241         ], [
 242                 # We'll just have to use struct ip_mreq
 243                 AC_MSG_RESULT(no)
 244         ])
 245
 246         dnl *****************************
 247         dnl *** Checks for libnsl     ***
 248         dnl *****************************
 249         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 250
 251         AC_CHECK_FUNCS(inet_pton inet_aton)
 252
 253         dnl *****************************
 254         dnl *** Checks for libpthread ***
 255         dnl *****************************
 256         AC_SEARCH_LIBS(pthread_create, pthread, [
 257                 AM_CONDITIONAL(THREADS_PTHREAD, true)
 258                 AC_DEFINE(HAVE_PTHREAD)
 259
 260                 # Need pthread_mutex_timedlock
 261                 pthread_CFLAGS=""
 262                 orig_CPPFLAGS=$CPPFLAGS
 263                 # This is a gcc-specific error, but we already set
 264                 # gcc-specific options in CFLAGS
 265                 CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
 266                 AC_MSG_CHECKING(for pthread_mutex_timedlock)
 267                 AC_TRY_COMPILE([ #include <pthread.h>], [
 268                         pthread_mutex_t mut=PTHREAD_MUTEX_INITIALIZER;
 269                         pthread_mutex_timedlock(&mut, NULL);
 270                 ], [
 271                         # Works!
 272                         AC_MSG_RESULT(yes)
 273                         AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 274                 ], [
 275                         AC_MSG_RESULT(no)
 276
 277                         # glibc requires -D_GNU_SOURCE before it will declare
 278                         # this function
 279                         AC_MSG_CHECKING(whether _GNU_SOURCE is needed for pthread_mutex_timedlock)
 280                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 281                         AC_TRY_COMPILE([ #include <pthread.h>], [
 282                                 pthread_mutex_t mut=PTHREAD_MUTEX_INITIALIZER;
 283                                 pthread_mutex_timedlock(&mut, NULL);
 284                         ], [
 285                                 AC_MSG_RESULT(yes)
 286                                 pthread_CFLAGS="-D_GNU_SOURCE"
 287                                 AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 288                         ], [
 289                                 AC_MSG_RESULT(no)
 290                                 dnl Add other variants here
 291                                 AC_MSG_WARN(Working around pthread_mutex_timedlock)
 292                         ])
 293                 ])
 294                 CPPFLAGS=$orig_CPPFLAGS
 295                 CFLAGS="$CFLAGS $pthread_CFLAGS"
 296
 297                 # Need PTHREAD_MUTEX_RECURSIVE
 298                 pthread_CFLAGS=""
 299                 orig_CPPFLAGS=$CPPFLAGS
 300                 # This is a gcc-specific error, but we already set
 301                 # gcc-specific options in CFLAGS
 302                 CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
 303                 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 304                 AC_TRY_COMPILE([ #include <pthread.h>], [
 305                         pthread_mutexattr_t attr;
 306                         pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 307                 ], [
 308                         # Works!
 309                         AC_MSG_RESULT(ok)
 310                 ], [
 311                         AC_MSG_RESULT(no)
 312
 313                         # glibc requires -D_GNU_SOURCE before it will declare
 314                         # this macro
 315                         AC_MSG_CHECKING(whether _GNU_SOURCE is needed for PTHREAD_MUTEX_RECURSIVE)
 316                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 317                         AC_TRY_COMPILE([ #include <pthread.h>], [
 318                                 pthread_mutexattr_t attr;
 319                                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 320                         ], [
 321                                 AC_MSG_RESULT(ok)
 322                                 pthread_CFLAGS="-D_GNU_SOURCE"
 323                         ], [
 324                                 AC_MSG_RESULT(no)
 325                                 dnl Add other variants here
 326                                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 327                                 AC_DEFINE(USE_MONO_MUTEX)
 328                         ])
 329                 ])
 330                 CPPFLAGS=$orig_CPPFLAGS
 331                 CFLAGS="$CFLAGS $pthread_CFLAGS"
 332         ], [
 333                 AC_MSG_ERROR([libpthread is required on non-win32 hosts])
 334         ])
 335
 336         dnl ********************************
 337         dnl *** Checks for semaphore lib ***
 338         dnl ********************************
 339         AC_CHECK_LIB(rt, sem_init, LIBS="$LIBS -lrt")
 340 else
 341         AM_CONDITIONAL(THREADS_PTHREAD, false)
 342         # This is a kludge, we really ought to test for libws2_32, but
 343         # I can't make AC_CHECK_LIB link (the symbols seem to be mangled
 344         # with @num suffixes)
 345         LIBS="$LIBS -lws2_32"
 346         CFLAGS="$CFLAGS -mno-cygwin"
 347 fi
 348
 349 dnl ****************************
 350 dnl *** Look for /dev/random ***
 351 dnl ****************************
 352
 353 AC_MSG_CHECKING([if usage of random device is requested])
 354 AC_ARG_ENABLE(dev-random,
 355 [  --disable-dev-random    disable the use of the random device],
 356 try_dev_random=$enableval, try_dev_random=yes)
 357 AC_MSG_RESULT($try_dev_random)
 358
 359 case "{$target}" in
 360     *-openbsd*)
 361     NAME_DEV_RANDOM="/dev/srandom"
 362     ;;
 363
 364 dnl Win32 does not have /dev/random, they have their own method...
 365
 366     *-*-mingw*|*-*-cygwin*)
 367     ac_cv_have_dev_random = no
 368     ;;
 369
 370 dnl Everywhere else, it's /dev/random
 371
 372     *)
 373     NAME_DEV_RANDOM="/dev/random"
 374     ;;
 375 esac
 376
 377 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
 378
 379 dnl Now check if the device actually exists
 380
 381 if test "x$try_dev_random" = "xyes"; then
 382     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
 383     [if test -r "$NAME_DEV_RANDOM" ; then
 384         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
 385     if test "x$ac_cv_have_dev_random" = "xyes"; then
 386         AC_DEFINE(HAVE_CRYPT_RNG)
 387     fi
 388 else
 389     AC_MSG_CHECKING(for random device)
 390     ac_cv_have_dev_random=no
 391     AC_MSG_RESULT(has been disabled)
 392 fi
 393
 394 if test "x$platform_win32" = "xyes"; then
 395     AC_DEFINE(HAVE_CRYPT_RNG)
 396 fi
 397
 398 if test "x$ac_cv_have_dev_random" = "xno" \
 399     && test "x$platform_win32" = "xno"; then
 400     AC_MSG_WARN([[
 401 ***
 402 *** A system-provided entropy source was not found on this system.
 403 *** Because of this, the System.Security.Cryptography random number generator
 404 *** will throw a NotImplemented exception.
 405 ***
 406 *** If you are seeing this message, and you know your system DOES have an
 407 *** entropy collection in place, please contact <crichton@gimp.org> and
 408 *** provide information about the system and how to access the random device.
 409 ***
 410 *** For those systems who lack a random device, EGD support is forthcoming.
 411 ***]])
 412 fi
 413
 414 if test "x$cross_compiling" = "xno"; then
 415 # check for new iconv version
 416 AC_MSG_CHECKING(for new iconv)
 417 AC_CACHE_VAL(new_iconv,[
 418         AC_TRY_RUN([#include <stdio.h>
 419                 #include <iconv.h>
 420
 421                 int main()
 422                 {
 423                   exit (iconv_open ("UTF-16le", "UTF-8") == (iconv_t)-1);
 424                 }
 425                 ],
 426                 new_iconv=yes,new_iconv=)])
 427 if test -n "$new_iconv"; then
 428         AC_MSG_RESULT(yes)
 429         AC_DEFINE(HAVE_NEW_ICONV)
 430 else
 431         AC_MSG_RESULT(no)
 432 fi
 433 fi
 434
 435 TARGET="unknown"
 436 ACCESS_UNALIGNED="yes"
 437
 438 case "$host" in
 439 #mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; ACCESS_UNALIGNED="no";;
 440 i*86-*-*) TARGET=X86; arch_target=x86;;
 441 sparc*-*-*) TARGET=SPARC; arch_target=sparc; ACCESS_UNALIGNED="no";;
 442 #alpha*-*-linux* | alpha*-*-osf*) TARGET=ALPHA; ACCESS_UNALIGNED="no";;
 443 #m68k-*-linux*) TARGET=M68K;;
 444 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; arch_target=ppc;;
 445 arm-*-linux-*) TARGET=ARM; arch_target=arm; ACCESS_UNALIGNED="no";;
 446 esac
 447
 448 if test ${TARGET} = unknown; then
 449         CFLAGS="$CFLAGS -DNO_PORT"
 450         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
 451 fi
 452
 453 if test ${ACCESS_UNALIGNED} = no; then
 454         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
 455 fi
 456
 457 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
 458 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
 459 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 460 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 461 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 462 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 463 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 464 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 465
 466 AC_SUBST(arch_target)
 467 AC_SUBST(CFLAGS)
 468
 469 AC_OUTPUT([
 470 Makefile
 471 mono/Makefile
 472 mono/utils/Makefile
 473 mono/metadata/Makefile
 474 mono/dis/Makefile
 475 mono/cil/Makefile
 476 mono/arch/Makefile
 477 mono/arch/x86/Makefile
 478 mono/arch/ppc/Makefile
 479 mono/arch/sparc/Makefile
 480 mono/arch/arm/Makefile
 481 mono/interpreter/Makefile
 482 mono/tests/Makefile
 483 mono/benchmark/Makefile
 484 mono/monoburg/Makefile
 485 mono/monograph/Makefile
 486 mono/jit/Makefile
 487 mono/io-layer/Makefile
 488 runtime/Makefile
 489 scripts/Makefile
 490 man/Makefile
 491 doc/Makefile
 492 docs/Makefile
 493 ])
 494
 495 echo "
 496
 497         GC:     $gc
 498
 499 "