configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,1.1.10)
  10 AM_MAINTAINER_MODE
  11
  12 AC_PROG_LN_S
  13
  14 # In case of cygwin, override LN_S, irrespective of what it determines.
  15 # The build uses cygwin, but the actual runtime doesn't.
  16 case $host_os in
  17 *cygwin* ) LN_S='cp -p';;
  18 esac
  19
  20
  21 dnl
  22 dnl libgc checks
  23 dnl
  24
  25 gc_headers=no
  26 gc=included
  27 use_included_gc=no
  28 libgc_configure_args=
  29
  30 if test -d $srcdir/libgc ; then
  31   gc_default=included
  32 else
  33   gc_default=boehm
  34 fi
  35
  36 #
  37 # These are the flags that need to be stored in the mono.pc file for
  38 # compiling code that will embed Mono
  39 #
  40 libmono_cflags=""
  41 libmono_ldflags=""
  42 AC_SUBST(libmono_cflags)
  43 AC_SUBST(libmono_ldflags)
  44
  45 # Variable to have relocatable .pc files (lib, or lib64)
  46 reloc_libdir=`basename ${libdir}`
  47 AC_SUBST(reloc_libdir)
  48
  49
  50 dnl if linker handles the version script
  51 no_version_script=no
  52
  53 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  54 need_link_unlink=no
  55
  56 # Thread configuration inspired by sleepycat's db
  57 AC_MSG_CHECKING([host platform characteristics])
  58 libgc_threads=no
  59 case "$host" in
  60         *-*-mingw*|*-*-cygwin*)
  61                 platform_win32=yes
  62                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  63                 if test "x$cross_compiling" = "xno"; then
  64                         CC="gcc -mno-cygwin -g"
  65                         # So libgc configure gets -mno-cygwin
  66                         export CC
  67                 fi
  68                 HOST_CC="gcc"
  69                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS -DFD_SETSIZE=1024"
  70                 libdl=
  71                 libgc_threads=win32
  72                 gc_default=included
  73                 with_nptl=default
  74                 with_sigaltstack=no
  75                 LN_S=cp
  76                 # This forces libgc to use the DllMain based thread registration code on win32
  77                 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
  78                 ;;
  79         *-*-*netbsd*)
  80                 platform_win32=no
  81                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  82                 libmono_cflags="-D_REENTRANT"
  83                 LDFLAGS="$LDFLAGS -pthread"
  84                 libmono_ldflags="-pthread"
  85                 need_link_unlink=yes
  86                 libdl=
  87                 libgc_threads=no
  88                 ;;
  89 # these flags will work for all versions of -STABLE
  90 #
  91         *-*-*freebsd4*)
  92                 platform_win32=no
  93                 if test "x$PTHREAD_CFLAGS" = "x"; then
  94                         CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  95                         libmono_cflags="-D_THREAD_SAFE"
  96                 else
  97                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
  98                         libmono_cflags="$PTHREAD_CFLAGS"
  99                 fi
 100                 if test "x$PTHREAD_LIBS" = "x"; then
 101                         LDFLAGS="$LDFLAGS -pthread"
 102                         libmono_ldflags="-pthread"
 103                 else
 104                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 105                         libmono_ldflags="$PTHREAD_LIBS"
 106                 fi
 107                 need_link_unlink=yes
 108                 AC_DEFINE(PTHREAD_POINTER_ID)
 109                 libdl=
 110                 libgc_threads=pthreads
 111 # TLS isn't implemented at all on 4-STABLE
 112                 with_nptl=no
 113                 with_tls=pthread
 114                 ;;
 115         *-*-*freebsd5*)
 116                 platform_win32=no
 117                 if test "x$PTHREAD_CFLAGS" = "x"; then
 118                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 119                         libmono_cflags=
 120                 else
 121                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 122                         libmono_cflags="$PTHREAD_CFLAGS"
 123                 fi
 124                 if test "x$PTHREAD_LIBS" = "x"; then
 125                         LDFLAGS="$LDFLAGS -pthread"
 126                         libmono_ldflags="-pthread"
 127                 else
 128                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 129                         libmono_ldflags="$PTHREAD_LIBS"
 130                 fi
 131                 need_link_unlink=yes
 132                 AC_DEFINE(PTHREAD_POINTER_ID)
 133                 libdl=
 134                 with_sigaltstack=yes
 135                 libgc_threads=pthreads
 136 # TLS is only partially implemented on 5-STABLE (compiler support
 137 # but NOT library support)
 138 #
 139                 with_tls=pthread
 140                 ;;
 141         *-*-*freebsd6*)
 142                 platform_win32=no
 143                 if test "x$PTHREAD_CFLAGS" = "x"; then
 144                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 145                         libmono_cflags=
 146                 else
 147                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 148                         libmono_cflags="$PTHREAD_CFLAGS"
 149                 fi
 150                 if test "x$PTHREAD_LIBS" = "x"; then
 151                         LDFLAGS="$LDFLAGS -pthread"
 152                         libmono_ldflags="-pthread"
 153                 else
 154                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 155                         libmono_ldflags="$PTHREAD_LIBS"
 156                 fi
 157                 need_link_unlink=yes
 158                 AC_DEFINE(PTHREAD_POINTER_ID)
 159                 libdl=
 160                 libgc_threads=pthreads
 161                 with_sigaltstack=yes
 162 # TLS is only partially implemented on -CURRENT (compiler support
 163 # but NOT library support)
 164 #
 165                 with_tls=pthread
 166                 ;;
 167         *-*-*openbsd*)
 168                 platform_win32=no
 169                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 170                 libmono_cflags="-D_THREAD_SAFE"
 171                 LDFLAGS="$LDFLAGS -pthread"
 172                 libmono_ldflags="-pthread"
 173                 need_link_unlink=yes
 174                 AC_DEFINE(PTHREAD_POINTER_ID)
 175                 libdl=
 176                 libgc_threads=pthreads
 177                 ;;
 178         *-*-linux*)
 179                 platform_win32=no
 180                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP -DUSE_MUNMAP"
 181                 libmono_cflags="-D_REENTRANT"
 182                 libmono_ldflags="-lpthread"
 183                 libdl="-ldl"
 184                 libgc_threads=pthreads
 185                 ;;
 186         *-*-hpux*)
 187                 platform_win32=no
 188                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 189                 CFLAGS="$CFLAGS +ESdbgasm"
 190                 LDFLAGS="$LDFLAGS -z"
 191                 libmono_cflags="-D_REENTRANT"
 192                 libmono_ldflags="-lpthread"
 193                 libgc_threads=pthreads
 194                 need_link_unlink=yes
 195                 ;;
 196         *-*-solaris*)
 197                 platform_win32=no
 198                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP"
 199                 need_link_unlink=yes
 200                 libmono_cflags="-D_REENTRANT"
 201                 libgc_threads=pthreads
 202                 ;;
 203         *-*-darwin*)
 204                 platform_win32=no
 205                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX"
 206                 libmono_cflags="-D_THREAD_SAFE"
 207                 LDFLAGS="$LDFLAGS -pthread"
 208                 libmono_ldflags="-pthread"
 209                 need_link_unlink=yes
 210                 AC_DEFINE(PTHREAD_POINTER_ID)
 211                 AC_DEFINE(USE_MACH_SEMA)
 212                 no_version_script=yes
 213                 libdl=
 214                 libgc_threads=pthreads
 215                 ;;
 216         *)
 217                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 218                 platform_win32=no
 219                 libdl="-ldl"
 220                 ;;
 221 esac
 222 AC_MSG_RESULT(ok)
 223
 224 if test x$need_link_unlink = xyes; then
 225    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 226 fi
 227
 228 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 229
 230 AC_CHECK_TOOL(CC, gcc, gcc)
 231 AC_PROG_CC
 232 AM_PROG_CC_STDC
 233 AC_PROG_INSTALL
 234 AC_PROG_AWK
 235 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 236 : ${CCAS='$(CC)'}
 237 # Set ASFLAGS if not already set.
 238 : ${CCASFLAGS='$(CFLAGS)'}
 239 AC_SUBST(CCAS)
 240 AC_SUBST(CCASFLAGS)
 241
 242 AC_CHECK_PROG(BISON, bison,yes,no)
 243 if test "x$BISON" = "xno";
 244 then
 245         AC_MSG_ERROR([You need to install bison])
 246 fi
 247
 248 dnl may require a specific autoconf version
 249 dnl AC_PROG_CC_FOR_BUILD
 250 dnl CC_FOR_BUILD not automatically detected
 251 CC_FOR_BUILD=$CC
 252 BUILD_EXEEXT=
 253 if test "x$cross_compiling" = "xyes"; then
 254         CC_FOR_BUILD=cc
 255         BUILD_EXEEXT=""
 256 fi
 257 AC_SUBST(CC_FOR_BUILD)
 258 AC_SUBST(HOST_CC)
 259 AC_SUBST(BUILD_EXEEXT)
 260
 261 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
 262
 263 # Set STDC_HEADERS
 264 AC_HEADER_STDC
 265 AC_LIBTOOL_WIN32_DLL
 266 AC_DISABLE_FAST_INSTALL
 267 AM_PROG_LIBTOOL
 268
 269 # Test whenever ld supports -version-script
 270 AC_PROG_LD
 271 AC_PROG_LD_GNU
 272 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 273    no_version_script=yes
 274 fi
 275
 276 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 277
 278 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h linux/rtc.h)
 279
 280 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 281
 282 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 283
 284 # for mono/metadata/debug-symfile.c
 285 AC_CHECK_HEADERS(elf.h)
 286
 287 # for support
 288 AC_CHECK_HEADERS(poll.h)
 289 AC_CHECK_HEADERS(sys/poll.h)
 290 AC_CHECK_HEADERS(sys/wait.h)
 291 AC_CHECK_HEADERS(grp.h)
 292 AC_CHECK_HEADERS(syslog.h)
 293
 294 # for mono/dis
 295 AC_CHECK_HEADERS(wchar.h)
 296 case "$host" in
 297         *-*-*freebsd6*)
 298                 AC_CHECK_HEADERS(ieeefp.h)
 299         ;;
 300         *-*-*freebsd*)
 301                 /* Only freebsd6 has a working ieeefp.h */
 302         ;;
 303         *)
 304                 AC_CHECK_HEADERS(ieeefp.h)
 305         ;;
 306 esac
 307 AC_MSG_CHECKING(for isinf)
 308 AC_TRY_LINK([#include <math.h>], [
 309         int f = isinf (1);
 310 ], [
 311         AC_MSG_RESULT(yes)
 312         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 313 ], [
 314         # We'll have to use signals
 315         AC_MSG_RESULT(no)
 316 ])
 317
 318
 319 # not 64 bit clean in cross-compile
 320 AC_CHECK_SIZEOF(void *, 4)
 321
 322 WARN=''
 323 if test x"$GCC" = xyes; then
 324         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 325                 # The runtime code does not respect ANSI C strict aliasing rules
 326                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 327
 328                 ORIG_CFLAGS=$CFLAGS
 329                 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 330                 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
 331                 AC_TRY_COMPILE([], [
 332                                                    void main () { }
 333                 ], [
 334                    AC_MSG_RESULT(yes)
 335                 ], [
 336                    AC_MSG_RESULT(no)
 337                    CFLAGS=$ORIG_CFLAGS
 338                 ])
 339 else
 340         # The Sun Forte compiler complains about inline functions that access static variables
 341         # so disable all inlining.
 342         case "$host" in
 343         *-*-solaris*)
 344                 CFLAGS="$CFLAGS -Dinline="
 345                 ;;
 346         esac
 347 fi
 348 CFLAGS="$CFLAGS -g $WARN"
 349
 350 # Where's the 'mcs' source tree?
 351 if test -d $srcdir/mcs; then
 352   mcsdir=mcs
 353 else
 354   mcsdir=../mcs
 355 fi
 356
 357 mcs_topdir='$(top_srcdir)/'$mcsdir
 358 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 359
 360 ## Maybe should also disable if mcsdir is invalid.  Let's punt the issue for now.
 361 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno])
 362
 363 AC_SUBST([mcs_topdir])
 364 AC_SUBST([mcs_topdir_from_srcdir])
 365
 366 AC_ARG_WITH([libgdiplus],
 367         [  --with-libgdiplus=installed|sibling|<path>   Override the libgdiplus used for System.Drawing tests (defaults to NO)],
 368         [], [with_libgdiplus=installed])
 369
 370 case $with_libgdiplus in
 371 no|installed) libgdiplus_loc= ;;
 372 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
 373 /*) libgdiplus_loc=$with_libgdiplus ;;
 374 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
 375 esac
 376 AC_SUBST([libgdiplus_loc])
 377
 378 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 379 if test "x$PKG_CONFIG" = "xno"; then
 380         AC_MSG_ERROR([You need to install pkg-config])
 381 fi
 382
 383 dnl for use on the build system
 384 dnl pkg-config is stupid
 385 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 386 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 387 AC_SUBST(BUILD_GLIB_CFLAGS)
 388 AC_SUBST(BUILD_GLIB_LIBS)
 389
 390 pkg_config_path=
 391 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 392         if test x$with_crosspkgdir = "x"; then
 393                 if test -s $PKG_CONFIG_PATH; then
 394                         pkg_config_path=$PKG_CONFIG_PATH
 395                 fi
 396         else
 397                 pkg_config_path=$with_crosspkgdir
 398                 PKG_CONFIG_PATH=$pkg_config_path
 399                 export PKG_CONFIG_PATH
 400         fi
 401 )
 402
 403 ## Versions of dependencies
 404 GLIB_REQUIRED_VERSION=1.3.11
 405
 406 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 407
 408 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 409 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 410 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 411 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 412
 413 AC_SUBST(GLIB_CFLAGS)
 414 AC_SUBST(GLIB_LIBS)
 415 AC_SUBST(GMODULE_CFLAGS)
 416 AC_SUBST(GMODULE_LIBS)
 417
 418 if test x$cross_compiling$platform_win32 = xnoyes; then
 419    AC_MSG_CHECKING(for cygwin glib2-dev package)
 420    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 421       AC_MSG_RESULT(found)
 422           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 423    else
 424       AC_MSG_RESULT(not found, ok)
 425    fi
 426
 427    AC_MSG_CHECKING(for broken gwin32.h)
 428    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 429    if test -f $glib_include/glib/gwin32.h; then
 430           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 431                  AC_MSG_RESULT(failed)
 432                  hashmark='#'
 433                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 434           fi
 435    fi
 436    AC_MSG_RESULT(ok)
 437 fi
 438
 439 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 440
 441 # Enable support for fast thread-local storage
 442 # Some systems have broken support, so we allow to disable it.
 443 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 444
 445 # Kept for compatibility
 446 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      deprecated, use --with-tls instead],[],[with_nptl=default])
 447
 448 if test "x$with_nptl" != "xdefault"; then
 449    if test "x$with_nptl" = "xyes"; then
 450       AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
 451           with_tls=__thread
 452    fi
 453    if test "x$with_nptl" = "xno"; then
 454       AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
 455           with_tls=pthread
 456    fi
 457 fi
 458
 459 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 460 # This does not work on some platforms (bug #55253)
 461 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=no])
 462
 463 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 464
 465 if test "x$enable_static" = "xno"; then
 466    with_static_mono=no
 467 fi
 468
 469 if test "x$platform_win32" = "xyes"; then
 470    # Boehm GC requires the runtime to be in its own dll
 471    with_static_mono=no
 472 fi
 473
 474 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 475
 476 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 477   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug, reflection_emit.],
 478 [
 479         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 480                 eval "mono_feature_disable_$feature='yes'"
 481                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 482         done
 483         disabled="Disabled:    $enable_minimal"
 484 ],[])
 485
 486 if test "x$mono_feature_disable_aot" = "xyes"; then
 487         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 488 fi
 489
 490 if test "x$mono_feature_disable_profiler" = "xyes"; then
 491         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 492 fi
 493
 494 if test "x$mono_feature_disable_decimal" = "xyes"; then
 495         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 496 fi
 497
 498 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 499         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 500 fi
 501
 502 if test "x$mono_feature_disable_debug" = "xyes"; then
 503         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 504 fi
 505
 506 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 507         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 508 fi
 509
 510 LIBGC_CFLAGS=
 511 LIBGC_LIBS=
 512 LIBGC_STATIC_LIBS=
 513 libgc_dir=
 514 case "x$gc" in
 515         xboehm|xbohem|xyes)
 516                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 517                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 518
 519                 if test "x$found_boehm" != "xyes"; then
 520                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 521                 fi
 522                 if test "x$gc_headers" != "xyes"; then
 523                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 524                 fi
 525
 526                 AC_DEFINE(HAVE_BOEHM_GC)
 527                 AC_SUBST(HAVE_BOEHM_GC)
 528                 LIBGC_LIBS="-lgc $libdl"
 529                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 530
 531                 # AC_CHECK_FUNCS does not work for some reason...
 532                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 533                 if test "x$found_gcj_malloc" = "xyes"; then
 534                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 535                 fi
 536                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 537                 if test "x$found_gc_enable" = "xyes"; then
 538                         AC_DEFINE(HAVE_GC_ENABLE)
 539                 fi
 540                 ;;
 541
 542         xincluded)
 543                 AC_CONFIG_SUBDIRS(libgc)
 544
 545                 found_boehm=yes
 546                 gc_headers=yes
 547                 use_included_gc=yes
 548                 libgc_dir=libgc
 549
 550                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 551                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 552                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 553
 554                 AC_DEFINE(HAVE_BOEHM_GC)
 555                 AC_SUBST(HAVE_BOEHM_GC)
 556
 557                 AC_DEFINE(HAVE_GC_H)
 558                 AC_DEFINE(USE_INCLUDED_LIBGC)
 559
 560                 # The included libgc contains GCJ support
 561                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 562                 AC_DEFINE(HAVE_GC_ENABLE)
 563                 ;;
 564
 565         xnone)
 566                 AC_MSG_WARN("Compiling mono without GC.")
 567                 ;;
 568         *)
 569                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 570                 ;;
 571 esac
 572
 573 AC_ARG_WITH(large-heap, [  --with-large-heap=yes,no    Enable support for GC heaps larger than 3GB], [large_heap=$withval], [large_heap=no])
 574 if test "x$large_heap" = "xyes"; then
 575    echo "FOO"
 576    CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
 577 fi
 578
 579 # tell libgc/configure about what we want
 580 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args"
 581
 582 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 583 AC_SUBST(LIBGC_CFLAGS)
 584 AC_SUBST(LIBGC_LIBS)
 585 AC_SUBST(LIBGC_STATIC_LIBS)
 586 AC_SUBST(libgc_dir)
 587
 588 dnl
 589 dnl End of libgc checks
 590 dnl
 591
 592 if test x$platform_win32 = xno; then
 593
 594         dnl ******************************************************************
 595         dnl *** Checks for the IKVM JNI interface library                  ***
 596         dnl ******************************************************************
 597         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 598
 599         ikvm_native_dir=
 600         if test x$with_ikvm_native = xyes; then
 601                 ikvm_native_dir=ikvm-native
 602                 jdk_headers_found="IKVM Native"
 603         fi
 604
 605         AC_SUBST(ikvm_native_dir)
 606
 607         AC_CHECK_HEADERS(execinfo.h)
 608
 609         AC_CHECK_FUNCS(getgrgid_r)
 610         AC_CHECK_FUNCS(getgrnam_r)
 611         AC_CHECK_FUNCS(getpwnam_r)
 612         AC_CHECK_FUNCS(getpwuid_r)
 613         AC_CHECK_FUNCS(getresuid)
 614         AC_CHECK_FUNCS(setresuid)
 615         AC_CHECK_FUNCS(kqueue)
 616         AC_CHECK_FUNCS(backtrace_symbols)
 617
 618         dnl ******************************************************************
 619         dnl *** Check for large file support                               ***
 620         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 621         dnl ******************************************************************
 622
 623         # Check that off_t can represent 2**63 - 1 correctly, working around
 624         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 625         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 626         large_offt=no
 627         AC_DEFUN([LARGE_FILES], [
 628                 large_CPPFLAGS=$CPPFLAGS
 629                 CPPFLAGS="$CPPFLAGS $1"
 630                 AC_TRY_RUN([
 631                         #include <sys/types.h>
 632
 633                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 634
 635                         int main(void) {
 636                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 637                                                (BIG_OFF_T%2147483647==1));
 638                                 if(big_off_t) {
 639                                         exit(0);
 640                                 } else {
 641                                         exit(1);
 642                                 }
 643                         }
 644                 ], [
 645                         AC_MSG_RESULT(ok)
 646                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 647                         large_CPPFLAGS="$large_CPPFLAGS $1"
 648                         large_offt=yes
 649                 ], [
 650                         AC_MSG_RESULT(no)
 651                 ], "")
 652                 CPPFLAGS=$large_CPPFLAGS
 653         ])
 654
 655         AC_MSG_CHECKING(if off_t is 64 bits wide)
 656         LARGE_FILES("")
 657         if test $large_offt = no; then
 658                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 659                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 660         fi
 661         if test $large_offt = no; then
 662                 AC_MSG_WARN([No 64 bit file size support available])
 663         fi
 664
 665         dnl *****************************
 666         dnl *** Checks for libsocket  ***
 667         dnl *****************************
 668         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 669
 670         dnl *******************************
 671         dnl *** Checks for MSG_NOSIGNAL ***
 672         dnl *******************************
 673         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 674         AC_TRY_COMPILE([#include <sys/socket.h>], [
 675                 int f = MSG_NOSIGNAL;
 676         ], [
 677                 # Yes, we have it...
 678                 AC_MSG_RESULT(yes)
 679                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 680         ], [
 681                 # We'll have to use signals
 682                 AC_MSG_RESULT(no)
 683         ])
 684
 685         dnl *****************************
 686         dnl *** Checks for SOL_IP     ***
 687         dnl *****************************
 688         AC_MSG_CHECKING(for SOL_IP)
 689         AC_TRY_COMPILE([#include <netdb.h>], [
 690                 int level = SOL_IP;
 691         ], [
 692                 # Yes, we have it...
 693                 AC_MSG_RESULT(yes)
 694                 AC_DEFINE(HAVE_SOL_IP)
 695         ], [
 696                 # We'll have to use getprotobyname
 697                 AC_MSG_RESULT(no)
 698         ])
 699
 700         dnl *****************************
 701         dnl *** Checks for SOL_IPV6     ***
 702         dnl *****************************
 703         AC_MSG_CHECKING(for SOL_IPV6)
 704         AC_TRY_COMPILE([#include <netdb.h>], [
 705                 int level = SOL_IPV6;
 706         ], [
 707                 # Yes, we have it...
 708                 AC_MSG_RESULT(yes)
 709                 AC_DEFINE(HAVE_SOL_IPV6)
 710         ], [
 711                 # We'll have to use getprotobyname
 712                 AC_MSG_RESULT(no)
 713         ])
 714
 715         dnl *****************************
 716         dnl *** Checks for SOL_TCP    ***
 717         dnl *****************************
 718         AC_MSG_CHECKING(for SOL_TCP)
 719         AC_TRY_COMPILE([#include <netdb.h>], [
 720                 int level = SOL_TCP;
 721         ], [
 722                 # Yes, we have it...
 723                 AC_MSG_RESULT(yes)
 724                 AC_DEFINE(HAVE_SOL_TCP)
 725         ], [
 726                 # We'll have to use getprotobyname
 727                 AC_MSG_RESULT(no)
 728         ])
 729
 730         dnl *****************************
 731         dnl *** Checks for IP_PKTINFO ***
 732         dnl *****************************
 733         AC_MSG_CHECKING(for IP_PKTINFO)
 734         AC_TRY_COMPILE([#include <netdb.h>], [
 735                 int level = IP_PKTINFO;
 736         ], [
 737                 # Yes, we have it...
 738                 AC_MSG_RESULT(yes)
 739                 AC_DEFINE(HAVE_IP_PKTINFO)
 740         ], [
 741                 AC_MSG_RESULT(no)
 742         ])
 743
 744         dnl *****************************
 745     dnl *** Checks for IPV6_PKTINFO ***
 746     dnl *****************************
 747     AC_MSG_CHECKING(for IPV6_PKTINFO)
 748     AC_TRY_COMPILE([#include <netdb.h>], [
 749         int level = IPV6_PKTINFO;
 750     ], [
 751         # Yes, we have it...
 752         AC_MSG_RESULT(yes)
 753         AC_DEFINE(HAVE_IPV6_PKTINFO)
 754     ], [
 755         AC_MSG_RESULT(no)
 756     ])
 757
 758         dnl *********************************
 759         dnl *** Check for struct ip_mreqn ***
 760         dnl *********************************
 761         AC_MSG_CHECKING(for struct ip_mreqn)
 762         AC_TRY_COMPILE([#include <netinet/in.h>], [
 763                 struct ip_mreqn mreq;
 764                 mreq.imr_address.s_addr = 0;
 765         ], [
 766                 # Yes, we have it...
 767                 AC_MSG_RESULT(yes)
 768                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 769         ], [
 770                 # We'll just have to try and use struct ip_mreq
 771                 AC_MSG_RESULT(no)
 772                 AC_MSG_CHECKING(for struct ip_mreq)
 773                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 774                         struct ip_mreq mreq;
 775                         mreq.imr_interface.s_addr = 0;
 776                 ], [
 777                         # Yes, we have it...
 778                         AC_MSG_RESULT(yes)
 779                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 780                 ], [
 781                         # No multicast support
 782                         AC_MSG_RESULT(no)
 783                 ])
 784         ])
 785
 786         dnl **********************************
 787         dnl *** Check for gethostbyname2_r ***
 788         dnl **********************************
 789         AC_MSG_CHECKING(for gethostbyname2_r)
 790                 AC_TRY_LINK([#include <netdb.h>], [
 791                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 792         ], [
 793                 # Yes, we have it...
 794                 AC_MSG_RESULT(yes)
 795                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 796         ], [
 797                 AC_MSG_RESULT(no)
 798         ])
 799
 800         dnl *****************************
 801         dnl *** Checks for libnsl     ***
 802         dnl *****************************
 803         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 804
 805         AC_CHECK_FUNCS(inet_pton inet_aton)
 806
 807         dnl ***********************************************
 808         dnl *** Checks for size of sockaddr_un.sun_path ***
 809         dnl ***********************************************
 810         # AC_CHECK_SIZEOF can't cope with struct members :-(
 811         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 812         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 813                 [AC_TRY_RUN([
 814                         #include <sys/types.h>
 815                         #include <stdio.h>
 816                         #include <sys/un.h>
 817
 818                         int main(void) {
 819                                 struct sockaddr_un sock_un;
 820                                 FILE *f=fopen("conftestval", "w");
 821                                 if(!f) exit(1);
 822                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 823                                 exit(0);
 824                         }
 825                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 826                    cv_mono_sizeof_sunpath=0,
 827                    cv_mono_sizeof_sunpath=0)])dnl
 828         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 829         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 830
 831         dnl *************************************
 832         dnl *** Checks for zero length arrays ***
 833         dnl *************************************
 834         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 835         AC_TRY_COMPILE([
 836                 struct s {
 837                         int  length;
 838                         char data [0];
 839                 };
 840         ], [], [
 841                 AC_MSG_RESULT(yes)
 842                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 843         ], [
 844                 AC_MSG_RESULT(no)
 845                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 846         ])
 847
 848         dnl *****************************
 849         dnl *** Checks for libxnet    ***
 850         dnl *****************************
 851         case "${host}" in
 852                 *solaris* )
 853                         AC_MSG_CHECKING(for Solaris XPG4 support)
 854                         if test -f /usr/lib/libxnet.so; then
 855                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 856                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 857                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 858                                 LIBS="$LIBS -lxnet"
 859                                 AC_MSG_RESULT(yes)
 860                         else
 861                                 AC_MSG_RESULT(no)
 862                         fi
 863
 864                         if test "$GCC" = "yes"; then
 865                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 866                         fi
 867                 ;;
 868         esac
 869
 870         dnl *****************************
 871         dnl *** Checks for libpthread ***
 872         dnl *****************************
 873 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
 874 # and libpthread does not exist
 875 #
 876         case "${host}" in
 877                 *-*-*freebsd4*)
 878                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 879                 ;;
 880                 *-*-*freebsd5*)
 881                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 882                 ;;
 883                 *-*-*freebsd6*)
 884                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 885                 ;;
 886                 *)
 887                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 888                 ;;
 889         esac
 890         AC_CHECK_HEADERS(pthread.h)
 891         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 892         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 893         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 894         AC_TRY_COMPILE([ #include <pthread.h>], [
 895                 pthread_mutexattr_t attr;
 896                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 897         ], [
 898                 AC_MSG_RESULT(ok)
 899         ], [
 900                 AC_MSG_RESULT(no)
 901                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 902                 AC_DEFINE(USE_MONO_MUTEX)
 903         ])
 904         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 905
 906         dnl ***********************************
 907         dnl *** Checks for working __thread ***
 908         dnl ***********************************
 909         AC_MSG_CHECKING(for working __thread)
 910         if test "x$with_tls" != "x__thread"; then
 911                 AC_MSG_RESULT(disabled)
 912         else
 913                 AC_TRY_RUN([
 914                         #include <pthread.h>
 915                         __thread int i;
 916                         static int res1, res2;
 917
 918                         void thread_main (void *arg)
 919                         {
 920                                 i = arg;
 921                                 sleep (1);
 922                                 if (arg == 1)
 923                                         res1 = (i == arg);
 924                                 else
 925                                         res2 = (i == arg);
 926                         }
 927
 928                         int main () {
 929                                 pthread_t t1, t2;
 930
 931                                 i = 5;
 932
 933                                 pthread_create (&t1, NULL, thread_main, 1);
 934                                 pthread_create (&t2, NULL, thread_main, 2);
 935
 936                                 pthread_join (t1, NULL);
 937                                 pthread_join (t2, NULL);
 938
 939                                 return !(res1 + res2 == 2);
 940                         }
 941                 ], [
 942                                 AC_MSG_RESULT(yes)
 943                 ], [
 944                                 AC_MSG_RESULT(no)
 945                                 with_tls=pthread
 946                 ])
 947         fi
 948
 949         dnl **************************************
 950         dnl *** Checks for working sigaltstack ***
 951         dnl **************************************
 952         AC_MSG_CHECKING(for working sigaltstack)
 953         if test "x$with_sigaltstack" != "xyes"; then
 954                 AC_MSG_RESULT(disabled)
 955         else
 956                 AC_TRY_RUN([
 957                         #include <stdio.h>
 958                         #include <stdlib.h>
 959                         #include <unistd.h>
 960                         #include <signal.h>
 961                         #include <pthread.h>
 962                         #include <sys/wait.h>
 963                         #if defined(__FreeBSD__) || defined(__NetBSD__)
 964                         #define SA_STACK SA_ONSTACK
 965                         #endif
 966                         static void
 967                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 968                         {
 969                                 exit (0);
 970                         }
 971
 972                         static void *
 973                         loop (void *ignored)
 974                         {
 975                                 char *ptr = NULL;
 976
 977                                 *ptr = 0;
 978                                 return NULL;
 979                         }
 980
 981                         static void
 982                         child ()
 983                         {
 984                                 struct sigaction sa;
 985                                 struct sigaltstack sas;
 986                                 pthread_t id;
 987                                 pthread_attr_t attr;
 988
 989                                 sa.sa_sigaction = sigsegv_signal_handler;
 990                                 sigemptyset (&sa.sa_mask);
 991                                 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
 992                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 993                                         perror ("sigaction");
 994                                         return;
 995                                 }
 996
 997                                 sas.ss_sp = malloc (SIGSTKSZ);
 998                                 sas.ss_size = SIGSTKSZ;
 999                                 sas.ss_flags = 0;
1000                                 if (sigaltstack (&sas, NULL) == -1) {
1001                                         perror ("sigaltstack");
1002                                         return;
1003                                 }
1004
1005                                 pthread_attr_init (&attr);
1006                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1007                                         printf ("pthread_create\n");
1008                                         return;
1009                                 }
1010
1011                                 sleep (100);
1012                         }
1013
1014                         int
1015                         main ()
1016                         {
1017                                 pid_t son;
1018                                 int status;
1019                                 int i;
1020
1021                                 son = fork ();
1022                                 if (son == -1) {
1023                                         return 1;
1024                                 }
1025
1026                                 if (son == 0) {
1027                                         child ();
1028                                         return 0;
1029                                 }
1030
1031                                 for (i = 0; i < 3; ++i) {
1032                                         sleep (1);
1033                                         waitpid (son, &status, WNOHANG);
1034                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1035                                                 return 0;
1036                                 }
1037
1038                                 kill (son, SIGKILL);
1039                                 return 1;
1040                         }
1041
1042                 ], [
1043                                 AC_MSG_RESULT(yes)
1044                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
1045                 ], [
1046                                 with_sigaltstack=no
1047                                 AC_MSG_RESULT(no)
1048                 ])
1049         fi
1050
1051         dnl ********************************
1052         dnl *** Checks for semaphore lib ***
1053         dnl ********************************
1054         # 'Real Time' functions on Solaris
1055         # posix4 on Solaris 2.6
1056         # pthread (first!) on Linux
1057         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1058
1059         dnl ********************************
1060         dnl *** Checks for timezone stuff **
1061         dnl ********************************
1062         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1063                 AC_TRY_COMPILE([
1064                         #include <time.h>
1065                         ], [
1066                         struct tm tm;
1067                         tm.tm_gmtoff = 1;
1068                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1069         if test $ac_cv_struct_tm_gmtoff = yes; then
1070                 AC_DEFINE(HAVE_TM_GMTOFF)
1071         else
1072                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1073                         AC_TRY_COMPILE([
1074                                 #include <time.h>
1075                         ], [
1076                                 timezone = 1;
1077                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1078                 if test $ac_cv_var_timezone = yes; then
1079                         AC_DEFINE(HAVE_TIMEZONE)
1080                 else
1081                         AC_ERROR(unable to find a way to determine timezone)
1082                 fi
1083         fi
1084
1085         dnl *********************************
1086         dnl *** Checks for math functions ***
1087         dnl *********************************
1088         LIBS="$LIBS -lm";
1089         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1090                 AC_TRY_LINK([#include <math.h>],
1091                 [ finite(0.0); ],
1092                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
1093                 AC_MSG_RESULT(no)))
1094         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1095                 AC_TRY_LINK([#include <math.h>],
1096                 [ isfinite(0.0); ],
1097                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
1098                 AC_MSG_RESULT(no)))
1099
1100         dnl ****************************************************************
1101         dnl *** Checks for working poll() (macosx defines it but doesn't ***
1102         dnl *** have it in the library (duh))                            ***
1103         dnl ****************************************************************
1104         AC_CHECK_FUNCS(poll)
1105
1106         dnl *************************
1107         dnl *** Check for signbit ***
1108         dnl *************************
1109         AC_MSG_CHECKING(for signbit)
1110         AC_TRY_LINK([#include <math.h>], [
1111                 int s = signbit(1.0);
1112         ], [
1113                 AC_MSG_RESULT(yes)
1114                 AC_DEFINE(HAVE_SIGNBIT)
1115         ], [
1116                 AC_MSG_RESULT(no)
1117         ])
1118
1119         dnl *********************
1120         dnl *** Check for AIO ***
1121         dnl *********************
1122         AC_MSG_CHECKING([for SIGEV_THREAD definition])
1123         dnl Some systems (FreeBSD at least) may have aio_read
1124         dnl but don't support/define SIGEV_THREAD.
1125         AC_TRY_COMPILE([
1126         #include <sys/signal.h>
1127         ],[
1128         int x = SIGEV_THREAD;
1129         ],[
1130                 ac_cv_c_sigev_thread=yes
1131                 AC_MSG_RESULT(yes)
1132         ],[
1133                 AC_MSG_RESULT(no)
1134         ])
1135
1136         if test "$ac_cv_c_sigev_thread" = "yes" ; then
1137                 AC_CHECK_HEADERS(aio.h sys/aio.h)
1138                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
1139                 SIGVAL_PTR="undefined"
1140                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
1141                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
1142                                         #include <sys/signal.h>
1143                                         ])
1144                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
1145                                         #include <sys/signal.h>
1146                                         ])
1147                         if test "$SIGVAL_PTR" = "undefined" ; then
1148                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
1149                         fi
1150                 fi
1151                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
1152         fi
1153
1154         dnl **********************************
1155         dnl *** epoll                      ***
1156         dnl **********************************
1157         AC_CHECK_HEADERS(sys/epoll.h)
1158         haveepoll=no
1159         AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1160         if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1161                 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1162         fi
1163
1164         dnl ******************************
1165         dnl *** Checks for SIOCGIFCONF ***
1166         dnl ******************************
1167         AC_CHECK_HEADERS(sys/ioctl.h)
1168         AC_CHECK_HEADERS(net/if.h)
1169         AC_MSG_CHECKING(for ifreq)
1170         AC_TRY_COMPILE([
1171                 #include <sys/ioctl.h>
1172                 #include <net/if.h>
1173                 ], [
1174                 struct ifconf ifc;
1175                 struct ifreq *ifr;
1176                 void *x;
1177                 ifc.ifc_len = 0;
1178                 ifc.ifc_buf = NULL;
1179                 x = (void *) &ifr->ifr_addr;
1180                 ],[
1181                         AC_MSG_RESULT(yes)
1182                         AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1183                 ], [
1184                         AC_MSG_RESULT(no)
1185                 ])
1186         dnl **********************************
1187         dnl *** Checks for MonoPosixHelper ***
1188         dnl **********************************
1189         AC_CHECK_FUNC(setkey, ,
1190                 AC_CHECK_LIB(crypt, setkey, [
1191                         AC_DEFINE(HAVE_SETKEY, 1, [Define if setkey(3) is available])
1192                         CRYPT_LIBS="-lcrypt"
1193                 ])
1194         )
1195         AC_SUBST(CRYPT_LIBS)
1196         AC_CHECK_HEADERS(checklist.h)
1197         AC_CHECK_HEADERS(fstab.h)
1198         AC_CHECK_HEADERS(attr/xattr.h)
1199         AC_CHECK_HEADERS(sys/extattr.h)
1200         AC_CHECK_HEADERS(sys/sendfile.h)
1201         AC_CHECK_HEADERS(sys/statvfs.h)
1202         AC_CHECK_HEADERS(sys/vfstab.h)
1203         AC_CHECK_HEADERS(sys/xattr.h)
1204         AC_CHECK_FUNCS(getdomainname)
1205         AC_CHECK_FUNCS(setdomainname)
1206         AC_CHECK_FUNCS(fgetgrent)
1207         AC_CHECK_FUNCS(fgetpwent)
1208         AC_CHECK_FUNCS(fgetpwent)
1209         AC_CHECK_FUNCS(getfsstat)
1210         AC_CHECK_FUNCS(mremap)
1211         AC_CHECK_FUNCS(remap_file_pages)
1212         AC_CHECK_FUNCS(posix_fadvise)
1213         AC_CHECK_FUNCS(posix_fallocate)
1214         AC_CHECK_FUNCS(posix_madvise)
1215         AC_CHECK_FUNCS(vsnprintf)
1216         AC_CHECK_FUNCS(sendfile)
1217         AC_CHECK_FUNCS(sethostid)
1218         AC_CHECK_FUNCS(statfs)
1219         AC_CHECK_FUNCS(fstatfs)
1220         AC_CHECK_FUNCS(statvfs)
1221         AC_CHECK_FUNCS(fstatvfs)
1222         AC_CHECK_FUNCS(stime)
1223         AC_CHECK_FUNCS(strerror_r)
1224         AC_CHECK_FUNCS(ttyname_r)
1225         AC_CHECK_SIZEOF(size_t)
1226         AC_CHECK_MEMBERS(
1227                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1228                 [#include <sys/types.h>
1229                  #include <dirent.h>])
1230
1231         dnl Favour xattr through glibc, but use libattr if we have to
1232         AC_CHECK_FUNC(lsetxattr, ,
1233                 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1234         )
1235         AC_SUBST(XATTR_LIB)
1236
1237         dnl *********************************
1238         dnl *** Check for Console 2.0 I/O ***
1239         dnl *********************************
1240         AC_CHECK_HEADERS([curses.h])
1241         AC_CHECK_HEADERS([term.h], [], [],
1242         [#if HAVE_CURSES_H
1243          #include <curses.h>
1244          #endif
1245         ])
1246         AC_CHECK_HEADERS([termios.h])
1247
1248         dnl * This is provided in io-layer, but on windows it's only available
1249         dnl * on xp+
1250         AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1251 else
1252         jdk_headers_found=no
1253         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1254         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1255         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1256
1257         dnl *********************************
1258         dnl *** Check for struct ip_mreqn ***
1259         dnl *********************************
1260         AC_MSG_CHECKING(for struct ip_mreqn)
1261         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1262                 struct ip_mreqn mreq;
1263                 mreq.imr_address.s_addr = 0;
1264         ], [
1265                 # Yes, we have it...
1266                 AC_MSG_RESULT(yes)
1267                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1268         ], [
1269                 # We'll just have to try and use struct ip_mreq
1270                 AC_MSG_RESULT(no)
1271                 AC_MSG_CHECKING(for struct ip_mreq)
1272                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1273                         struct ip_mreq mreq;
1274                         mreq.imr_interface.s_addr = 0;
1275                 ], [
1276                         # Yes, we have it...
1277                         AC_MSG_RESULT(yes)
1278                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1279                 ], [
1280                         # No multicast support
1281                         AC_MSG_RESULT(no)
1282                 ])
1283         ])
1284         AC_CHECK_FUNCS(GetProcessId)
1285 fi
1286
1287 dnl socklen_t check
1288 AC_MSG_CHECKING(for socklen_t)
1289 AC_TRY_COMPILE([
1290 #include <sys/types.h>
1291 #include <sys/socket.h>
1292 ],[
1293   socklen_t foo;
1294 ],[
1295 ac_cv_c_socklen_t=yes
1296         AC_DEFINE(HAVE_SOCKLEN_T)
1297         AC_MSG_RESULT(yes)
1298 ],[
1299         AC_MSG_RESULT(no)
1300 ])
1301
1302 AC_MSG_CHECKING(for array element initalizer support)
1303 AC_TRY_COMPILE([#include <sys/socket.h>], [
1304         const int array[] = {[1] = 2,};
1305 ], [
1306         # Yes, we have it...
1307         AC_MSG_RESULT(yes)
1308         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1309 ], [
1310         # We'll have to use signals
1311         AC_MSG_RESULT(no)
1312 ])
1313
1314 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1315         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1316         AC_TRY_LINK([#include <math.h>],
1317         [ static void *p = &trunc; ],
1318         [
1319                 AC_DEFINE(HAVE_TRUNC)
1320                 AC_MSG_RESULT(yes)
1321                 ac_cv_trunc=yes
1322         ],
1323         AC_MSG_RESULT(no)))
1324
1325 if test "x$ac_cv_truncl" != "xyes"; then
1326    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1327 fi
1328
1329 dnl ****************************
1330 dnl *** Look for /dev/random ***
1331 dnl ****************************
1332
1333 AC_MSG_CHECKING([if usage of random device is requested])
1334 AC_ARG_ENABLE(dev-random,
1335 [  --disable-dev-random    disable the use of the random device],
1336 try_dev_random=$enableval, try_dev_random=yes)
1337 AC_MSG_RESULT($try_dev_random)
1338
1339 case "{$target}" in
1340     *-openbsd*)
1341     NAME_DEV_RANDOM="/dev/srandom"
1342     ;;
1343
1344 dnl Win32 does not have /dev/random, they have their own method...
1345
1346     *-*-mingw*|*-*-cygwin*)
1347     ac_cv_have_dev_random=no
1348     ;;
1349
1350 dnl Everywhere else, it's /dev/random
1351
1352     *)
1353     NAME_DEV_RANDOM="/dev/random"
1354     ;;
1355 esac
1356
1357 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1358
1359 dnl Now check if the device actually exists
1360
1361 if test "x$try_dev_random" = "xyes"; then
1362     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1363     [if test -r "$NAME_DEV_RANDOM" ; then
1364         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1365     if test "x$ac_cv_have_dev_random" = "xyes"; then
1366         AC_DEFINE(HAVE_CRYPT_RNG)
1367     fi
1368 else
1369     AC_MSG_CHECKING(for random device)
1370     ac_cv_have_dev_random=no
1371     AC_MSG_RESULT(has been disabled)
1372 fi
1373
1374 if test "x$platform_win32" = "xyes"; then
1375     AC_DEFINE(HAVE_CRYPT_RNG)
1376 fi
1377
1378 if test "x$ac_cv_have_dev_random" = "xno" \
1379     && test "x$platform_win32" = "xno"; then
1380     AC_MSG_WARN([[
1381 ***
1382 *** A system-provided entropy source was not found on this system.
1383 *** Because of this, the System.Security.Cryptography random number generator
1384 *** will throw a NotImplemented exception.
1385 ***
1386 *** If you are seeing this message, and you know your system DOES have an
1387 *** entropy collection in place, please contact <crichton@gimp.org> and
1388 *** provide information about the system and how to access the random device.
1389 ***
1390 *** Otherwise you can install either egd or prngd and set the environment
1391 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1392 ***]])
1393 fi
1394
1395 AC_MSG_CHECKING([if inter-process shared handles are requested])
1396 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1397 AC_MSG_RESULT($try_shared_handles)
1398 if test "x$try_shared_handles" != "xyes"; then
1399         AC_DEFINE(DISABLE_SHARED_HANDLES)
1400         AC_SUBST(DISABLE_SHARED_HANDLES)
1401 fi
1402
1403 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1404 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1405
1406 TARGET="unknown"
1407 ACCESS_UNALIGNED="yes"
1408
1409 JIT_SUPPORTED=no
1410 INTERP_SUPPORTED=no
1411 LIBC="libc.so.6"
1412 INTL="libc.so.6"
1413 SQLITE="libsqlite.so.0"
1414 SQLITE3="libsqlite3.so.0"
1415 X11="libX11.so"
1416
1417 jit_wanted=false
1418 interp_wanted=false
1419 case "$host" in
1420 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1421 #               TARGET=MIPS;
1422 #               ACCESS_UNALIGNED="no"
1423 #               ;;
1424         i*86-*-*)
1425                 TARGET=X86;
1426                 arch_target=x86;
1427                 JIT_SUPPORTED=yes
1428                 jit_wanted=true
1429                 ;;
1430         x86_64-*-* | amd64-*-*)
1431                 TARGET=AMD64;
1432                 arch_target=amd64;
1433                 JIT_SUPPORTED=yes
1434                 jit_wanted=true
1435                 ;;
1436         ia64-*-*)
1437                 TARGET=IA64
1438                 arch_target=ia64
1439                 ACCESS_UNALIGNED="no"
1440                 JIT_SUPPORTED=yes
1441                 jit_wanted=true
1442                 LIBC="libc.so.6.1"
1443                 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
1444                 libmono_ldflags="-lunwind"
1445                 ;;
1446         sparc*-*-*)
1447                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1448                    TARGET=SPARC64
1449                 else
1450                         TARGET=SPARC
1451                 fi
1452                 arch_target=sparc;
1453                 JIT_SUPPORTED=yes
1454                 ACCESS_UNALIGNED="no"
1455                 case $host_os in
1456                   linux*) ;;
1457                   *)
1458                         LIBC="libc.so"
1459                         INTL="libintl.so"
1460                 esac
1461                 jit_wanted=true
1462                 if test x"$GCC" = xyes; then
1463                         CFLAGS="$CFLAGS -Wno-cast-align"
1464                 fi
1465                 ;;
1466        alpha*-*-linux* | alpha*-*-osf*)
1467                 TARGET=ALPHA;
1468                 ACCESS_UNALIGNED="no"
1469                 JIT_SUPPORTED=no
1470                 INTERP_SUPPORTED=yes
1471                 interp_wanted=true
1472                 arch_target=alpha;
1473                 case $host_os in
1474                   linux*)
1475                         LIBC="libc.so.6.1"
1476                         INTL="libc.so.6.1"
1477                 esac
1478                ;;
1479         *-*-mingw*|*-*-cygwin*)
1480                 INTL="intl"
1481                 ;;
1482         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1483                 TARGET=HPPA;
1484                 arch_target=hppa;
1485                 LIBC="libc.sl"
1486                 ACCESS_UNALIGNED="no"
1487                 INTERP_SUPPORTED=yes
1488                 interp_wanted=true
1489                 ;;
1490         hppa*linux*)
1491                 TARGET=HPPA;
1492                 arch_target=hppa;
1493                 ACCESS_UNALIGNED="no"
1494                 INTERP_SUPPORTED=yes
1495                 interp_wanted=true
1496                 ;;
1497         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1498         powerpc-*-sysv* | powerpc-*-darwin*)
1499                 TARGET=POWERPC;
1500                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1501                 arch_target=ppc;
1502                 JIT_SUPPORTED=yes
1503                 jit_wanted=true
1504                 ;;
1505         arm*-linux*)
1506                 TARGET=ARM;
1507                 arch_target=arm;
1508                 ACCESS_UNALIGNED="no"
1509                 JIT_SUPPORTED=yes
1510                 jit_wanted=true
1511                 ;;
1512         s390-*-linux*)
1513                 TARGET=S390;
1514                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1515                 arch_target=s390;
1516                 ACCESS_UNALIGNED="no"
1517                 JIT_SUPPORTED=yes
1518                 ;;
1519         s390x-*-linux*)
1520                 TARGET=S390x;
1521                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1522                 arch_target=s390x;
1523                 ACCESS_UNALIGNED="no"
1524                 JIT_SUPPORTED=yes
1525                 ;;
1526 esac
1527
1528 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1529         if test x$withval = xyes; then
1530            jit_wanted=true
1531         else
1532            jit_wanted=false
1533         fi
1534 ])
1535
1536 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1537         if test x$withval = xyes; then
1538            interp_wanted=true
1539         else
1540            interp_wanted=false
1541         fi
1542 ])
1543
1544 USEJIT=false
1545 if test x$JIT_SUPPORTED = xyes; then
1546    if $jit_wanted; then
1547       USEJIT=true
1548       jit_status="Building and using the JIT"
1549    else
1550       if $interp_wanted; then
1551          jit_status="Building the JIT, defaulting to the interpreter"
1552       else
1553          AC_ERROR(No JIT or interpreter support available or selected.)
1554       fi
1555    fi
1556 else
1557    if test x$interp_wanted = xtrue; then
1558       jit_status="interpreter"
1559    else
1560       AC_ERROR(No JIT or interpreter support available or selected.)
1561    fi
1562 fi
1563
1564 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1565
1566 libsuffix=".so"
1567
1568 case "$host" in
1569      *-*-darwin*)
1570         libsuffix=".dylib"
1571         LIBC="libc.dylib"
1572         INTL="libintl.dylib"
1573         SQLITE="libsqlite.0.dylib"
1574         SQLITE3="libsqlite3.0.dylib"
1575         X11="libX11.dylib"
1576         ;;
1577      *-*-*netbsd*)
1578         LIBC="libc.so.12"
1579         INTL="libintl.so.0"
1580         ;;
1581     *-*-*freebsd*)
1582         LIBC="libc.so"
1583         INTL="libintl.so"
1584         ;;
1585     *-*-*openbsd*)
1586         LIBC="libc.so"
1587         INTL="libintl.so"
1588         ;;
1589     *-*-*linux*)
1590         AC_PATH_X
1591         AC_MSG_CHECKING(for the soname of libX11.so)
1592         for i in $x_libraries /usr/lib /usr/lib64; do
1593                 for r in 4 5 6; do
1594                         if test -f $i/libX11.so.$r; then
1595                                 X11=libX11.so.$r
1596                                 AC_MSG_RESULT($X11)
1597                         fi
1598                 done
1599         done
1600
1601         if test "x$X11" = "xlibX11.so"; then
1602                 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
1603         fi
1604         ;;
1605 esac
1606
1607
1608 AC_SUBST(libsuffix)
1609
1610 if test "x$TARGET" != "xAMD64"; then
1611    # valgrind headers don't compile under x86-64
1612    AC_CHECK_HEADERS(valgrind/memcheck.h)
1613 fi
1614
1615 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1616         if test "x$with_tls" = "x__thread"; then
1617                 #
1618                 # On some linux distributions, TLS works in executables, but linking
1619                 # against a shared library containing TLS fails with:
1620                 # undefined reference to `__tls_get_addr'
1621                 #
1622                 rm -f conftest.c conftest.so conftest
1623                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1624                 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1625                 $CC -o conftest conftest.so > /dev/null 2>&1
1626                 if test ! -f conftest; then
1627                    AC_MSG_WARN([Disabling usage of __thread.]);
1628                    with_tls=pthread
1629                 fi
1630                 rm -f conftest.c conftest.so conftest
1631         fi
1632 fi
1633
1634 if test "x$with_tls" = "x__thread"; then
1635         AC_DEFINE(HAVE_KW_THREAD)
1636    # Pass the information to libgc
1637         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1638         export CPPFLAGS
1639         AC_MSG_CHECKING(if the tls_model attribute is supported)
1640         AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
1641                 ], [
1642                         AC_MSG_RESULT(yes)
1643                         AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
1644                 ], [
1645                         AC_MSG_RESULT(no)
1646         ])
1647 fi
1648
1649 if test ${TARGET} = ARM; then
1650         dnl ******************************************
1651         dnl *** Check to see what FPU is available ***
1652         dnl ******************************************
1653         AC_MSG_CHECKING(which FPU to use)
1654
1655         AC_TRY_COMPILE([], [
1656                 __asm__ ("ldfd f0, [r0]");
1657                 ], fpu=FPA, [
1658                         AC_TRY_COMPILE([], [
1659                                 __asm__ ("fldd d0, [r0]");
1660                         ], fpu=VFP, fpu=NONE)
1661                 ])
1662
1663         AC_MSG_RESULT($fpu)
1664         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1665         unset fpu
1666 fi
1667
1668 if test ${TARGET} = unknown; then
1669         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1670         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1671 fi
1672
1673 if test ${ACCESS_UNALIGNED} = no; then
1674         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1675 fi
1676
1677 PREVIEW=yes
1678 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1679         if test x$with_preview = xno; then
1680               PREVIEW=no
1681         fi
1682 ])
1683
1684 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1685
1686 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1687 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1688 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1689 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1690 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1691 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1692 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1693 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1694 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1695 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1696 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1697 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1698 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1699 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1700
1701 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1702 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
1703 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
1704
1705 AC_SUBST(LIBC)
1706 AC_SUBST(INTL)
1707 AC_SUBST(SQLITE)
1708 AC_SUBST(SQLITE3)
1709 AC_SUBST(X11)
1710
1711 AC_SUBST(arch_target)
1712 AC_SUBST(CFLAGS)
1713 AC_SUBST(CPPFLAGS)
1714 AC_SUBST(LDFLAGS)
1715
1716 mono_build_root=`pwd`
1717 AC_SUBST(mono_build_root)
1718
1719 if test x$USEJIT = xtrue; then
1720   mono_runtime=mono/mini/mono
1721 else
1722   mono_runtime=mono/interpreter/mint
1723 fi
1724 AC_SUBST(mono_runtime)
1725
1726 mono_cfg_root=$mono_build_root/runtime
1727 if test x$platform_win32 = xyes; then
1728   mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
1729 else
1730   mono_cfg_dir=$mono_cfg_root/etc
1731 fi
1732 AC_SUBST(mono_cfg_dir)
1733
1734 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
1735 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
1736 AC_CONFIG_FILES([runtime/semdel-wrapper],[chmod +x runtime/semdel-wrapper])
1737
1738 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
1739 [   depth=../../../..
1740     case $srcdir in
1741     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1742     .) reldir=$depth ;;
1743     *) reldir=$depth/$srcdir ;;
1744     esac
1745     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
1746     cd runtime/etc/mono/1.0
1747     rm -f machine.config
1748     $LN_S $reldir/data/net_1_1/machine.config machine.config
1749     cd $depth
1750 ],[LN_S='$LN_S'])
1751
1752 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
1753 [   depth=../../../..
1754     case $srcdir in
1755     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1756     .) reldir=$depth ;;
1757     *) reldir=$depth/$srcdir ;;
1758     esac
1759     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1760     cd runtime/etc/mono/2.0
1761     rm -f machine.config
1762     $LN_S $reldir/data/net_2_0/machine.config machine.config
1763     cd $depth
1764 ],[LN_S='$LN_S'])
1765
1766 AC_OUTPUT([
1767 Makefile
1768 mint.pc
1769 mono.pc
1770 dotnet.pc
1771 mono-uninstalled.pc
1772 scripts/mono-nunit.pc
1773 scripts/mono-find-provides
1774 scripts/mono-find-requires
1775 mono/Makefile
1776 mono/utils/Makefile
1777 mono/metadata/Makefile
1778 mono/dis/Makefile
1779 mono/cil/Makefile
1780 mono/arch/Makefile
1781 mono/os/Makefile
1782 mono/os/win32/Makefile
1783 mono/os/unix/Makefile
1784 mono/arch/x86/Makefile
1785 mono/arch/amd64/Makefile
1786 mono/arch/hppa/Makefile
1787 mono/arch/ppc/Makefile
1788 mono/arch/sparc/Makefile
1789 mono/arch/s390/Makefile
1790 mono/arch/s390x/Makefile
1791 mono/arch/arm/Makefile
1792 mono/arch/alpha/Makefile
1793 mono/arch/ia64/Makefile
1794 mono/interpreter/Makefile
1795 mono/tests/Makefile
1796 mono/tests/tests-config
1797 mono/benchmark/Makefile
1798 mono/monoburg/Makefile
1799 mono/monograph/Makefile
1800 mono/io-layer/Makefile
1801 mono/mini/Makefile
1802 mono/handles/Makefile
1803 mono/profiler/Makefile
1804 ikvm-native/Makefile
1805 scripts/Makefile
1806 man/Makefile
1807 web/Makefile
1808 docs/Makefile
1809 data/Makefile
1810 data/net_1_1/Makefile
1811 data/net_2_0/Makefile
1812 samples/Makefile
1813 support/Makefile
1814 data/config
1815 tools/Makefile
1816 tools/locale-builder/Makefile
1817 runtime/Makefile
1818 ])
1819
1820 if test x$platform_win32 = xyes; then
1821    # Get rid of 'cyg' prefixes in library names
1822    sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
1823    # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
1824    # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
1825    # executable doesn't work...
1826    sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
1827 fi
1828
1829 (
1830   case $prefix in
1831   NONE) prefix=$ac_default_prefix ;;
1832   esac
1833   case $exec_prefix in
1834   NONE) exec_prefix='${prefix}' ;;
1835   esac
1836
1837   test -w $srcdir/$mcsdir/build || chmod +w $srcdir/$mcsdir/build
1838
1839   #
1840   # If we are cross compiling, we don't build in the mcs/ tree.  Let us not clobber
1841   # any existing config.make.  This allows people to share the same source tree
1842   # with different build directories, one native and one cross
1843   #
1844   if test x$cross_compiling = xno; then
1845     echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
1846     echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
1847     echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$mcsdir/build/config.make
1848     echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
1849     echo 'IL_FLAGS = /debug' >> $srcdir/$mcsdir/build/config.make
1850     echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$mcsdir/build/config.make
1851     echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $srcdir/$mcsdir/build/config.make
1852     echo "INSTALL = $INSTALL" >> $srcdir/$mcsdir/build/config.make
1853
1854     export VERSION
1855     [myver=$($AWK 'BEGIN {
1856       split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
1857       print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
1858     }')]
1859
1860     echo "MONO_VERSION = $myver" >> $srcdir/$mcsdir/build/config.make
1861   fi
1862 )
1863
1864 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
1865
1866 echo "
1867         mcs source:  $mcs_topdir
1868         GC:          $gc
1869         TLS:         $with_tls
1870         SIGALTSTACK: $with_sigaltstack
1871         Engine:      $jit_status
1872         2.0 Alpha:   $PREVIEW
1873         JNI support: $jdk_headers_found
1874         libgdiplus:  $libgdiplus_msg
1875         $disabled
1876
1877 "