configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.92cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8
   9 AM_CONFIG_HEADER([config.h])
  10
  11 AC_PREFIX_DEFAULT(/usr/local/cacao)
  12
  13
  14 dnl system type
  15 case "$host_cpu" in
  16 alpha )
  17         ARCH_DIR="alpha"
  18         STATIC_CLASSPATH="1"
  19         CFLAGS="-mieee -D__ALPHA__"
  20         ;;
  21
  22 i386 | i486 | i586 | i686 )
  23         ARCH_DIR="i386"
  24         STATIC_CLASSPATH="0"
  25         CFLAGS="-D__I386__ $CFLAGS"
  26         ;;
  27
  28 mips )
  29         ARCH_DIR="mips"
  30         STATIC_CLASSPATH="1"
  31
  32 dnl for MIPSPro Compiler
  33 dnl     CFLAGS="-64 -OPT:Olimit=0 -woff 1110,1164,1515 -D__MIPS__ -D__MIPSEB__"
  34         CFLAGS="-64 -OPT:Olimit=0 -D__MIPS__ -D__MIPSEB__"
  35
  36 dnl for GCC
  37 dnl     CFLAGS="-mabi=64 -D__MIPS__ -D__MIPSEB__"
  38 dnl     LDFLAGS="-mabi=64"
  39         ;;
  40
  41 powerpc | ppc )
  42         ARCH_DIR="powerpc"
  43         STATIC_CLASSPATH="1"
  44         CFLAGS="-D__POWERPC__"
  45         ;;
  46
  47 x86_64 )
  48         ARCH_DIR="x86_64"
  49         STATIC_CLASSPATH="0"
  50         CFLAGS="-D__X86_64__"
  51         ;;
  52
  53 * )
  54         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  55         ;;
  56 esac
  57
  58
  59 dnl set optimization and debugging for all architectures and systems
  60 CFLAGS="-O0 -g3 $CFLAGS"
  61
  62
  63 case "$host_os" in
  64 *linux* | *Linux* )
  65         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__LINUX__ -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  66         ;;
  67 *darwin* )
  68         CFLAGS="-ansi -pedantic -Wall -Wno-long-long $CFLAGS -D__DARWIN__"
  69         ;;
  70 *irix* )
  71         CFLAGS="$CFLAGS -D__IRIX__"
  72         ;;
  73 * )
  74         ;;
  75 esac
  76
  77
  78 dnl define install prefix
  79 if test "x$prefix" = xNONE; then
  80         CACAO_INSTALL_PREFIX=$ac_default_prefix
  81 else
  82         CACAO_INSTALL_PREFIX=$prefix
  83 fi
  84 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "$CACAO_INSTALL_PREFIX", [Installation prefix])
  85 AC_SUBST(CACAO_INSTALL_PREFIX)
  86
  87
  88 AC_DEFINE_UNQUOTED([ARCH_DIR], "$ARCH_DIR", [Architecture directory])
  89 AC_SUBST(ARCH_DIR)
  90
  91
  92 AC_ARG_ENABLE([dynamicclasspath], [AS_HELP_STRING(--disable-dynamicclasspath, link classpath native code static even on platforms supporting dynamic loading)], [use_dynamicclasspath=$enableval], [use_dynamicclasspath=yes])
  93 dnl force static classpath linking ??
  94 AC_MSG_CHECKING(Link classpath static)
  95 if test "xno" == "x$use_dynamicclasspath"; then
  96   STATIC_CLASSPATH="1"
  97 fi
  98
  99 if test "$STATIC_CLASSPATH" == "1"; then
 100         AC_MSG_RESULT(yes)
 101 else
 102         AC_MSG_RESULT(no)
 103 fi
 104 AC_SUBST(STATIC_CLASSPATH)
 105
 106 dnl Checks for programs.
 107 AC_PROG_CC
 108 AM_PROG_AS
 109 AC_PROG_RANLIB
 110 AC_DISABLE_SHARED
 111 AC_PROG_LIBTOOL
 112 AC_PROG_LN_S
 113 AC_PROG_MAKE_SET
 114
 115 dnl Checks for header files.
 116 AC_HEADER_DIRENT
 117 AC_HEADER_STDC
 118 AC_CHECK_HEADERS([fcntl.h])
 119 AC_CHECK_HEADERS([sys/time.h])
 120 AC_CHECK_HEADERS([unistd.h])
 121 AC_CHECK_HEADERS([sys/ioctl.h])
 122
 123 dnl Checks for typedefs, structures, and compiler characteristics.
 124 AC_C_CONST
 125 AC_C_INLINE
 126 AC_TYPE_OFF_T
 127 AC_TYPE_SIZE_T
 128 AC_HEADER_TIME
 129 AC_STRUCT_TM
 130
 131 dnl Checks for library functions.
 132 AC_PROG_GCC_TRADITIONAL
 133 AC_FUNC_MEMCMP
 134 AC_FUNC_MMAP
 135 AC_TYPE_SIGNAL
 136 AC_CHECK_FUNCS(getcwd gettimeofday mkdir mktime select socket)
 137
 138 dnl Checks for libraries.
 139 AC_CHECK_LIB(m, fmod)
 140
 141 dnl Check for mmap header anomalies (missing MAP_FAILED, etc.)
 142 if test $ac_cv_func_mmap_fixed_mapped = yes; then
 143         AC_CACHE_CHECK(whether MAP_FAILED is defined,
 144                        ac_cv_map_failed,
 145                        AC_EGREP_CPP(yes,
 146                                     [#include <sys/mman.h>
 147                                      #ifdef MAP_FAILED
 148                                         yes
 149                                      #endif],
 150                                     ac_cv_map_failed=yes,
 151                                     ac_cv_map_failed=no))
 152
 153         AC_CACHE_CHECK(whether MAP_ANONYMOUS is defined,
 154                        ac_cv_map_anonymous,
 155                        AC_EGREP_CPP(yes,
 156                                     [#include <sys/mman.h>
 157                                      #ifdef MAP_ANONYMOUS
 158                                         yes
 159                                      #endif],
 160                                     ac_cv_map_anonymous=yes,
 161                                     ac_cv_map_anonymous=no))
 162
 163         AC_CACHE_CHECK(whether MAP_ANON is defined,
 164                        ac_cv_map_anon,
 165                        AC_EGREP_CPP(yes,
 166                                     [#include <sys/mman.h>
 167                                      #ifdef MAP_ANON
 168                                         yes
 169                                      #endif],
 170                                     ac_cv_map_anon=yes,
 171                                     ac_cv_map_anon=no))
 172
 173         if test $ac_cv_map_failed = yes; then
 174                 AC_DEFINE([HAVE_MAP_FAILED], 1, [Define if <sys/mman.h> defines MAP_FAILED])
 175         fi
 176
 177         if test $ac_cv_map_anonymous = yes; then
 178                 AC_DEFINE([HAVE_MAP_ANONYMOUS], 1, [Define if <sys/mman.h> defines MAP_ANONYMOUS])
 179         fi
 180
 181         if test $ac_cv_map_anon = yes; then
 182                 AC_DEFINE([HAVE_MAP_ANON], 1, [Define if <sys/mman.h> defines MAP_ANON])
 183         fi
 184 fi
 185
 186
 187 dnl Features
 188
 189 dnl check arguments
 190 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 191 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 192
 193
 194 dnl threads
 195 AC_MSG_CHECKING(whether to include threads support)
 196 enable_threads=${enable_threads:-native}
 197 case "$enable_threads" in
 198 no | none | single)
 199         AC_MSG_RESULT(no)
 200         dnl no threads for boehm
 201         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 202         AM_CONDITIONAL([USE_THREADS], [false])
 203         AM_CONDITIONAL([NATIVE_THREADS], [false])
 204         ;;
 205
 206 green | native | posix | pthreads)
 207         AC_DEFINE([USE_THREADS], 1, [use threads])
 208         AC_DEFINE([EXTERNAL_OVERFLOW], 1, [external overflow])
 209         AC_DEFINE([DONT_FREE_FIRST], 1, [don't free first])
 210
 211         AM_CONDITIONAL([USE_THREADS], [true])
 212
 213         if test x"$enable_threads" != "xgreen"; then
 214                 AC_MSG_RESULT(yes, native)
 215                 AC_CHECK_LIB(pthread, main)
 216                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 217
 218                 CFLAGS="$CFLAGS -D_REENTRANT"
 219
 220                 dnl tell boehm to support threads as well and classpath to
 221                 dnl synchronize VM threads portably
 222                 ac_configure_args="$ac_configure_args --enable-boehm-threads=posix --enable-portable-native-sync"
 223                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 224
 225         else
 226                 AC_MSG_RESULT(yes, green)
 227
 228                 dnl no threads for boehm
 229                 ac_configure_args="$ac_configure_args --disable-boehm-threads"
 230                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 231         fi
 232     ;;
 233 *)
 234     AC_MSG_ERROR($enable_threads is an unknown thread package)
 235     ;;
 236 esac
 237
 238
 239 dnl Check whether the compiler supports the __thread keyword.
 240 if test "x$use__thread" != xno; then
 241   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 242   [cat > conftest.c <<\EOF
 243 __thread int a = 42;
 244 EOF
 245   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 246     ac_cv_gcc___thread=yes
 247   else
 248     ac_cv_gcc___thread=no
 249   fi
 250   rm -f conftest*])
 251   if test "$ac_cv_gcc___thread" = yes; then
 252     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 253   fi
 254 else
 255   ac_cv_gcc___thread=no
 256 fi
 257
 258
 259 dnl check if zlib should be used
 260 AC_ARG_ENABLE([zlib], [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])])
 261
 262 AC_MSG_CHECKING(whether zip archives should be supported)
 263 if test x"$enable_zlib" = "xno"; then
 264         AC_MSG_RESULT(no)
 265         AM_CONDITIONAL([USE_ZLIB], [false])
 266 else
 267         AC_MSG_RESULT(yes)
 268         AC_DEFINE([USE_ZLIB], 1, [use zlib])
 269         AC_CHECK_HEADERS([zlib.h])
 270         AC_CHECK_LIB(z, main)
 271         AM_CONDITIONAL([USE_ZLIB], [true])
 272 fi
 273
 274
 275 dnl check arguments
 276 AC_ARG_ENABLE([gtk-peer], [AS_HELP_STRING(--enable-gtk-peer,compile GTK native peers [[default=no]])])
 277
 278
 279 dnl enable gtk peer
 280 AC_MSG_CHECKING(whether to use gtk awt peers)
 281 if test x"$enable_gtk_peer" = "xyes"; then
 282         AC_MSG_RESULT(yes)
 283         AC_DEFINE([USE_GTK], 1, [use gtk])
 284         AM_CONDITIONAL([USE_GTK_PEER], [true])
 285
 286 else
 287         AC_MSG_RESULT(no)
 288         ac_configure_args="$ac_configure_args --disable-gtk-peer"
 289         AM_CONDITIONAL([USE_GTK_PEER], [false])
 290 fi
 291
 292
 293 if test "x1" == "x$STATIC_CLASSPATH"; then
 294         AC_DEFINE([STATIC_CLASSPATH], 1, [use classpath statically linked])
 295         AM_CONDITIONAL([STATIC_CLASSPATH], [true])
 296
 297 else
 298         AM_CONDITIONAL([STATIC_CLASSPATH], [false])
 299 fi
 300
 301
 302 dnl set some essential classpath options, even if their classpath default is
 303 dnl suitable for us
 304 ac_configure_args="$ac_configure_args --enable-jni --disable-cni --disable-regen-headers --enable-static --enable-shared --enable-load-library"
 305
 306
 307 dnl now configure boehm gc and gnu classpath
 308 dnl the export is not my favorite (is there another way?)
 309 export CFLAGS
 310 AC_CONFIG_SUBDIRS(src/boehm-gc src/classpath)
 311
 312
 313 AC_CONFIG_FILES([Makefile]
 314                 [doc/Makefile]
 315                 [doc/handbook/Makefile]
 316                 [man/Makefile]
 317                 [src/Makefile]
 318                 [src/cacao/Makefile]
 319                 [src/cacaoh/Makefile]
 320                 [src/mm/Makefile]
 321                 [src/native/Makefile]
 322                 [src/native/include/Makefile]
 323                 [src/native/tools/Makefile]
 324                 [src/native/vm/Makefile]
 325                 [src/scripts/Makefile]
 326                 [src/scripts/cacao]
 327                 [src/scripts/java]
 328                 [src/scripts/rmic]
 329                 [src/scripts/rmiregistry]
 330                 [src/threads/Makefile]
 331                 [src/threads/green/Makefile]
 332                 [src/threads/native/Makefile]
 333                 [src/toolbox/Makefile]
 334                 [src/vm/Makefile]
 335                 [src/vm/jit/Makefile]
 336                 [src/vm/jit/alpha/Makefile]
 337                 [src/vm/jit/i386/Makefile]
 338                 [src/vm/jit/inline/Makefile]
 339                 [src/vm/jit/loop/Makefile]
 340                 [src/vm/jit/mips/Makefile]
 341                 [src/vm/jit/powerpc/Makefile]
 342                 [src/vm/jit/tools/Makefile]
 343                 [src/vm/jit/verify/Makefile]
 344                 [src/vm/jit/x86_64/Makefile]
 345                 [tests/Makefile]
 346                 [tests/jvm98/Makefile]
 347                 [tests/kaffe/Makefile]
 348                 [tests/native/Makefile])
 349
 350 AC_OUTPUT
 351
 352
 353 ## Local variables:
 354 ## mode: m4
 355 ## indent-tabs-mode: t
 356 ## c-basic-offset: 4
 357 ## tab-width: 8
 358 ## compile-command: "automake --add-missing"
 359 ## End: