configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT(cacao, 0.93+cvs, cacao@cacaojvm.org)
   4 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
   5 AC_CANONICAL_HOST
   6 AC_PREREQ(2.59)
   7 AM_INIT_AUTOMAKE([1.9.0])
   8 AM_MAINTAINER_MODE
   9
  10 AM_CONFIG_HEADER([config.h])
  11
  12 AC_PREFIX_DEFAULT(/usr/local/cacao)
  13
  14
  15 dnl set optimization and debugging for all architectures and systems
  16 if test x"$CFLAGS" = "x"; then
  17         CFLAGS="-O0 -g3"
  18 fi
  19
  20 dnl system type
  21 case "$host_cpu" in
  22 alpha | alphaev56 | alphapca56 )
  23         ARCH_DIR="alpha"
  24         CFLAGS="$CFLAGS -mieee -D__ALPHA__"
  25         ;;
  26
  27 arm | armv4tl | armv5b )
  28         ARCH_DIR="arm"
  29         CFLAGS="$CFLAGS -D__ARM__"
  30         ;;
  31
  32 i386 | i486 | i586 | i686 )
  33         ARCH_DIR="i386"
  34         CFLAGS="$CFLAGS -D__I386__"
  35         ;;
  36
  37 mips )
  38         ARCH_DIR="mips"
  39         CFLAGS="$CFLAGS -D__MIPS__"
  40         ;;
  41
  42 powerpc )
  43         ARCH_DIR="powerpc"
  44         CFLAGS="$CFLAGS -D__POWERPC__"
  45         ;;
  46
  47 x86_64 )
  48         ARCH_DIR="x86_64"
  49         CFLAGS="$CFLAGS -D__X86_64__"
  50         ;;
  51
  52 xdspcore )
  53         ARCH_DIR="xdspcore"
  54         ENABLE_STATICVM="yes"
  55         CFLAGS="$CFLAGS -D__XDSPCORE__"
  56         USE_SCHEDULER="1"
  57         ;;
  58 * )
  59         AC_MSG_ERROR($host_cpu systems are not supported at this time)
  60         ;;
  61 esac
  62
  63 dnl host type
  64 case "$host_os" in
  65 *linux* | *Linux* )
  66         OS_DIR="linux"
  67         CFLAGS="$CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
  68         ;;
  69 *darwin* )
  70         OS_DIR="darwin"
  71         CFLAGS="$CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
  72         ;;
  73 *freebsd* )
  74         OS_DIR="freebsd"
  75         CFLAGS="$CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
  76         ;;
  77 *irix* )
  78         OS_DIR="irix"
  79         CFLAGS="$CFLAGS -D__IRIX__"
  80         ;;
  81 * )
  82         ;;
  83 esac
  84
  85
  86 dnl define and substitute some architecture specific variables
  87 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
  88 AC_SUBST(ARCH_DIR)
  89 AC_SUBST(OS_DIR)
  90 AC_SUBST(USE_SCHEDULER)
  91
  92
  93 dnl Checks for programs.
  94 AC_PROG_CC
  95 AM_PROG_AS
  96 AC_PROG_LD
  97 AC_PROG_LD_GNU
  98 AC_PROG_RANLIB
  99 AC_DISABLE_SHARED
 100 AC_PROG_LN_S
 101 AC_PROG_MAKE_SET
 102
 103 dnl libtool stuff
 104 AC_LIBTOOL_DLOPEN
 105 AC_LIBLTDL_CONVENIENCE
 106 AC_PROG_LIBTOOL
 107 AC_SUBST(LIBLTDL)
 108
 109 dnl Checks for header files.
 110 AC_HEADER_DIRENT
 111 AC_HEADER_STDC
 112 AC_CHECK_HEADERS([fcntl.h])
 113 AC_CHECK_HEADERS([sys/time.h])
 114 AC_CHECK_HEADERS([unistd.h])
 115 AC_CHECK_HEADERS([sys/ioctl.h])
 116
 117 dnl this is for fdlibm
 118 AC_CHECK_HEADERS([stdint.h])
 119 AC_CHECK_HEADERS([inttypes.h])
 120 AC_CHECK_HEADERS([sys/config.h])
 121 AC_CHECK_HEADERS([sys/types.h])
 122 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 123 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 124 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 125 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 126
 127 dnl Checks for typedefs, structures, and compiler characteristics.
 128 AC_C_CONST
 129 AC_C_INLINE
 130 AC_C_ATTRIBUTE
 131 AC_TYPE_OFF_T
 132 AC_TYPE_SIZE_T
 133 AC_HEADER_TIME
 134 AC_STRUCT_TM
 135
 136 dnl Checks for library functions.
 137 AC_PROG_GCC_TRADITIONAL
 138 AC_TYPE_SIGNAL
 139 AC_FUNC_MEMCMP
 140 AC_CHECK_FUNCS(calloc mprotect getpagesize free)
 141 AC_CHECK_FUNCS(getcwd gettimeofday)
 142 AC_CHECK_FUNCS(scandir)
 143 AC_CHECK_FUNCS(mmap)
 144
 145 dnl Checks for libraries.
 146
 147 dnl Checking sizeof void *
 148 AC_COMPILE_CHECK_SIZEOF(void *)
 149 AC_C_BIGENDIAN
 150
 151
 152 dnl check which ld flags are required to export symbols
 153 if test x"$with_gnu_ld" = "xyes"; then
 154     EXPORT_SYMBOLS_FLAGS="-Wl,--export-dynamic"
 155 else
 156     EXPORT_SYMBOLS_FLAGS=""
 157 fi
 158 AC_SUBST(EXPORT_SYMBOLS_FLAGS)
 159
 160
 161 dnl define install prefix
 162 if test "x$prefix" = "xNONE"; then
 163     CACAO_INSTALL_PREFIX=$ac_default_prefix
 164 else
 165     CACAO_INSTALL_PREFIX=$prefix
 166 fi
 167 AC_DEFINE_UNQUOTED([CACAO_INSTALL_PREFIX], "${CACAO_INSTALL_PREFIX}", [installation prefix])
 168 AC_SUBST(CACAO_INSTALL_PREFIX)
 169
 170
 171 dnl Features
 172
 173 dnl check arguments
 174
 175 dnl check for JIT compiler
 176 AC_MSG_CHECKING(whether JIT compiled should be compiled)
 177 AC_ARG_ENABLE([jit],
 178               [AS_HELP_STRING(--disable-jit,disable JIT compiler [[default=yes]])],
 179               [case "${enableval}" in
 180                    no) ENABLE_JIT=no;;
 181                    *) ENABLE_JIT=yes;;
 182                esac],
 183               [ENABLE_JIT=yes])
 184 AC_MSG_RESULT(${ENABLE_JIT})
 185 AM_CONDITIONAL([ENABLE_JIT], test x"${ENABLE_JIT}" = "xyes")
 186
 187 if test x"${ENABLE_JIT}" = "xyes"; then
 188     AC_DEFINE([ENABLE_JIT], 1, [enable JIT compiler])
 189 fi
 190
 191
 192 dnl check for interpreter
 193 AC_ARG_ENABLE([intrp], [AS_HELP_STRING(--enable-intrp,enable interpreter [[default=no]])])
 194
 195 AC_MSG_CHECKING(whether interpreter should be compiled)
 196 if test x"$enable_intrp" = "xyes"; then
 197     AC_MSG_RESULT(yes)
 198     AC_DEFINE([ENABLE_INTRP], 1, [enable interpreter])
 199     AM_CONDITIONAL([ENABLE_INTRP], [true])
 200     ENABLE_INTRP=yes
 201
 202     AC_ASM_SKIP16
 203
 204     dnl check for libffi
 205     AC_ARG_WITH([ffi],
 206                 [AS_HELP_STRING(--with-ffi,use libffi to call native functions)],
 207                 [WITH_FFI=yes
 208                  AC_CHECK_HEADERS([ffi.h],, [AC_MSG_ERROR(cannot find ffi.h)])
 209                  AC_CHECK_LIB(ffi, ffi_call,, [AC_MSG_ERROR(cannot find libffi)])
 210                  AC_DEFINE([WITH_FFI], 1, [use libffi])],
 211                 [WITH_FFI=no])
 212
 213     dnl check for libffcall (avcall)
 214     AC_ARG_WITH([avcall],
 215                 [AS_HELP_STRING(--with-avcall,use libffcall to call native functions)],
 216                 [WITH_FFCALL=yes
 217                  AC_CHECK_HEADERS([avcall.h],, [AC_MSG_ERROR(cannot find avcall.h)])
 218                  AC_CHECK_LIB(avcall, av_call,, [AC_MSG_ERROR(cannot find libffcall)])
 219                  AC_DEFINE([WITH_FFCALL], 1, [use libffcall])],
 220                 [WITH_FFCALL=no])
 221
 222     dnl check for libffi or libffcall
 223     if test x"${WITH_FFI}" = "xyes" -a x"${WITH_FFCALL}" = "xyes"; then
 224         AC_ERROR(Enable only libffi or libffcall.)
 225     fi
 226     if test x"${WITH_FFI}" = "xno" -a x"${WITH_FFCALL}" = "xno"; then
 227         AC_ERROR(Enable one of libffi or libffcall.)
 228     fi
 229
 230 else
 231     AC_MSG_RESULT(no)
 232     AM_CONDITIONAL([ENABLE_INTRP], [false])
 233     ENABLE_INTRP="no"
 234 fi
 235
 236 if test x"${ENABLE_JIT}" = "xyes" -a x"${ENABLE_INTRP}" = "xyes"; then
 237     AC_ERROR(This is currently not supported. Please disable the JIT or the interpreter.)
 238 fi
 239 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 240     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 241 fi
 242
 243
 244 dnl check for garbage collector usage
 245 AC_MSG_CHECKING(whether GC should be disabled)
 246 AC_ARG_ENABLE([gc],
 247               [AS_HELP_STRING(--disable-gc,disable garbage collector (for debugging only!) [[default=yes]])],
 248               [case "${enableval}" in
 249                    no) DISABLE_GC=yes
 250                        AC_DEFINE([DISABLE_GC], 1, [disable garbage collector])
 251                        ;;
 252                    *) DISABLE_GC=no;;
 253                esac],
 254               [DISABLE_GC=no])
 255 AC_MSG_RESULT(${DISABLE_GC})
 256 AM_CONDITIONAL([DISABLE_GC], test x"${DISABLE_GC}" = "xyes")
 257
 258
 259 dnl check for dump memory usage
 260 AC_MSG_CHECKING(whether dump memory should be disabled)
 261 AC_ARG_ENABLE([dump],
 262               [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])],
 263               [case "${enableval}" in
 264                    no)
 265                        DISABLE_DUMP=yes
 266                        AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 267                        ;;
 268                    *) DISABLE_DUMP=no;;
 269                esac],
 270                [DISABLE_DUMP=no])
 271 AC_MSG_RESULT(${DISABLE_DUMP})
 272
 273
 274 dnl check for debug
 275 AC_MSG_CHECKING(whether debug code generation should be enabled)
 276 AC_ARG_ENABLE([debug],
 277               [AS_HELP_STRING(--disable-debug,disable debug code generation [[default=yes]])],
 278               [case "${enableval}" in
 279                    no) NDEBUG=yes
 280                        AC_DEFINE([NDEBUG], 1, [disable debug code])
 281                        ;;
 282                    *) NDEBUG=no;;
 283                esac],
 284               [NDEBUG=no])
 285 AC_MSG_RESULT(${NDEBUG})
 286
 287
 288 dnl check for statistics
 289 AC_MSG_CHECKING(whether statistics generation should be enabled)
 290 AC_ARG_ENABLE([statistics],
 291               [AS_HELP_STRING(--disable-statistics,disable statistics generation [[default=yes]])],
 292               [case "${enableval}" in
 293                    no) ENABLE_STATISTICS=no;;
 294                    *) ENABLE_STATISTICS=yes;;
 295                esac],
 296               [ENABLE_STATISTICS=yes])
 297 AC_MSG_RESULT(${ENABLE_STATISTICS})
 298 AM_CONDITIONAL([STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 299
 300 if test x"$enable_statistics" = "xno"; then
 301     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 302 fi
 303
 304
 305 dnl check for JVMTI
 306 AC_MSG_CHECKING(whether to compile JVMTI support)
 307 AC_ARG_ENABLE([jvmti],
 308               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 309               [case "${enableval}" in
 310                    yes) ENABLE_JVMTI=yes;;
 311                    *) ENABLE_JVMTI=no;;
 312                esac],
 313               [ENABLE_JVMTI=no])
 314 AC_MSG_RESULT(${ENABLE_JVMTI})
 315 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 316
 317 if test x"${ENABLE_JVMTI}" = "xyes"; then
 318     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 319 fi
 320
 321
 322 dnl threads
 323 AC_ARG_ENABLE([threads], [AS_HELP_STRING(--enable-threads,enable threads support (none,green,native) [[default=native]])])
 324 AC_ARG_ENABLE([__thread], [AS_HELP_STRING(--enable-__thread,use TLS features)], [use__thread=$enableval], [use__thread=no])
 325
 326 AC_MSG_CHECKING(whether to include threads support)
 327 enable_threads=${enable_threads:-native}
 328 case "$enable_threads" in
 329 no | none | single)
 330         AC_MSG_RESULT(no)
 331         dnl no threads for boehm
 332         ac_configure_args="$ac_configure_args --disable-boehm-threads"
 333         AM_CONDITIONAL([USE_THREADS], [false])
 334         AM_CONDITIONAL([NATIVE_THREADS], [false])
 335         ;;
 336
 337 green | native | posix | pthreads)
 338         AC_DEFINE([USE_THREADS], 1, [use threads])
 339
 340         AM_CONDITIONAL([USE_THREADS], [true])
 341
 342         if test x"$enable_threads" != "xgreen"; then
 343                 AC_MSG_RESULT(yes, native)
 344                 AC_CHECK_LIB(pthread, main)
 345                 AC_DEFINE([NATIVE_THREADS], 1, [use pthreads])
 346
 347                 CFLAGS="$CFLAGS -D_REENTRANT"
 348
 349                 dnl tell boehm to support threads as well
 350                 ac_configure_args="$ac_configure_args --enable-boehm-threads=posix"
 351                 AM_CONDITIONAL([NATIVE_THREADS], [true])
 352
 353         else
 354                 AC_MSG_RESULT(yes, green)
 355
 356                 dnl no threads for boehm
 357                 ac_configure_args="$ac_configure_args --disable-boehm-threads"
 358                 AM_CONDITIONAL([NATIVE_THREADS], [false])
 359         fi
 360     ;;
 361 *)
 362     AC_MSG_ERROR($enable_threads is an unknown thread package)
 363     ;;
 364 esac
 365
 366
 367 dnl Check whether the compiler supports the __thread keyword.
 368 if test "x$use__thread" != xno; then
 369   AC_CACHE_CHECK([for __thread], ac_cv_gcc___thread,
 370   [cat > conftest.c <<\EOF
 371 __thread int a = 42;
 372 EOF
 373   if AC_TRY_COMMAND([${CC-cc} $CFLAGS -c conftest.c >&AS_MESSAGE_LOG_FD]); then
 374     ac_cv_gcc___thread=yes
 375   else
 376     ac_cv_gcc___thread=no
 377   fi
 378   rm -f conftest*])
 379   if test "$ac_cv_gcc___thread" = yes; then
 380     AC_DEFINE([HAVE___THREAD], 1, [have __thread])
 381   fi
 382 else
 383   ac_cv_gcc___thread=no
 384 fi
 385
 386
 387 dnl check if linear scan register allocator(lsra) should be used
 388 AC_MSG_CHECKING(whether lsra should be supported)
 389 AC_ARG_ENABLE([lsra],
 390               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=yes]])],
 391               [case "${enableval}" in
 392                    no) ENABLE_LSRA=no;;
 393                    *) ENABLE_LSRA=yes;;
 394                esac],
 395               [ENABLE_LSRA=yes])
 396 AC_MSG_RESULT(${ENABLE_LSRA})
 397
 398 if test x"${ENABLE_LSRA}" = "xyes"; then
 399     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 400 fi
 401
 402
 403 dnl check for inlining
 404 dnl AC_ARG_ENABLE([inlining], [AS_HELP_STRING(--disable-inlining,disable method inlining [[default=yes]])])
 405
 406 dnl AC_MSG_CHECKING(whether method inlining should be disabled)
 407 dnl if test x"$enable_inlining" = "xno"; then
 408 dnl     AC_MSG_RESULT(yes)
 409 dnl     AM_CONDITIONAL([USE_INLINING], [false])
 410 dnl else
 411 dnl     AC_MSG_RESULT(no)
 412         AC_DEFINE([USE_INLINING], 1, [use method inlining])
 413         AM_CONDITIONAL([USE_INLINING], [true])
 414 dnl fi
 415
 416
 417 dnl check for instruction scheduler
 418 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 419
 420 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 421 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 422         case "${ARCH_DIR}" in
 423                 xdspcore )
 424                         ;;
 425                 * )
 426                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 427                         ;;
 428         esac
 429
 430         AC_MSG_RESULT(yes)
 431         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 432         AM_CONDITIONAL([USE_SCHEDULER], [true])
 433 else
 434         AC_MSG_RESULT(no)
 435         AM_CONDITIONAL([USE_SCHEDULER], [false])
 436 fi
 437
 438
 439 dnl check if zlib should be used
 440 AC_MSG_CHECKING(whether zip archives should be supported)
 441 AC_ARG_ENABLE([zlib],
 442               [AS_HELP_STRING(--enable-zlib,enable zip archive class storage (needs zlib) [[default=yes]])],
 443               [case "${enableval}" in
 444                   no) ENABLE_ZLIB=yes;;
 445                   *) ENABLE_ZLIB=no;;
 446                esac],
 447               [ENABLE_ZLIB=yes])
 448 AC_MSG_RESULT(${ENABLE_ZLIB})
 449
 450 if test x"${ENABLE_ZLIB}" = "xyes"; then
 451     AC_CHECK_HEADERS([zlib.h],, [AC_MSG_ERROR(cannot find zlib.h)])
 452     AC_CHECK_LIB(z, inflate,, [AC_MSG_ERROR(cannot find libz)])
 453     AC_DEFINE([ENABLE_ZLIB], 1, [use zlib])
 454 fi
 455 AM_CONDITIONAL([ENABLE_ZLIB], test x"${ENABLE_ZLIB}" = "xyes")
 456
 457
 458 dnl check if CACAO should be linked statically
 459 AC_MSG_CHECKING(whether to link GNU classpath native libraries statically into CACAO)
 460 AC_ARG_ENABLE([staticvm],
 461               [AS_HELP_STRING(--enable-staticvm, link GNU classpath native libraries statically into CACAO [[default=no]])],
 462               [case "${enableval}" in
 463                   yes) ENABLE_STATICVM=yes;;
 464                   *) ENABLE_STATICVM=no;;
 465                esac],
 466               [ENABLE_STATICVM=no])
 467 AC_MSG_RESULT(${ENABLE_STATICVM})
 468
 469 if test x"${ENABLE_STATICVM}" = "xyes"; then
 470     AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 471
 472     dnl check for some classpath related stuff when we link statically
 473     AM_ICONV_LINK
 474 fi
 475 AM_CONDITIONAL([ENABLE_STATICVM], test x"${ENABLE_STATICVM}" = "xyes")
 476 AC_SUBST(ENABLE_STATICVM)
 477
 478
 479 dnl is GNU classpath installed somewhere different
 480 AC_MSG_CHECKING(where GNU classpath is installed)
 481 AC_ARG_WITH([classpath-install-dir],
 482             [AS_HELP_STRING(--with-classpath-install-dir=<dir>,installation directory of GNU classpath [[default=/usr/local/classpath]])],
 483             [CLASSPATH_INSTALL_DIR=${withval}],
 484             [CLASSPATH_INSTALL_DIR=/usr/local/classpath])
 485 AC_MSG_RESULT(${CLASSPATH_INSTALL_DIR})
 486 AC_DEFINE_UNQUOTED([CLASSPATH_INSTALL_DIR], "${CLASSPATH_INSTALL_DIR}", [GNU classpath installation directory])
 487 AC_SUBST(CLASSPATH_INSTALL_DIR)
 488
 489
 490 dnl Maybe the user has Classpath installed 'flat'.
 491 AC_ARG_WITH([flat-classpath], [AS_HELP_STRING(--with-flat-classpath, GNU Classpath is not zipped in the install directory)])
 492 if test x"$with_flat_classpath" = "x"; then
 493         GLIBJZ=glibj.zip
 494 else
 495         GLIBJZ=
 496 fi
 497 AC_SUBST(GLIBJZ)
 498 AC_DEFINE_UNQUOTED(GLIBJZ_STRING, "$GLIBJZ", [define to the string base name of the classpath zip file])
 499
 500
 501 dnl now configure subpackages
 502 dnl the export is not my favorite (is there another way?)
 503 export CFLAGS
 504 AC_CONFIG_SUBDIRS(src/boehm-gc src/libltdl)
 505
 506 AC_CONFIG_FILES([Makefile]
 507                 [contrib/Makefile]
 508                 [contrib/setenvinstalled]
 509                 [contrib/setenvsource]
 510                 [doc/Makefile]
 511                 [doc/handbook/Makefile]
 512                 [man/Makefile]
 513                 [src/Makefile]
 514                 [src/cacao/Makefile]
 515                 [src/cacaoh/Makefile]
 516                 [src/fdlibm/Makefile]
 517                 [src/lib/Makefile]
 518                 [src/mm/Makefile]
 519                 [src/native/Makefile]
 520                 [src/native/include/Makefile]
 521                 [src/native/jvmti/Makefile]
 522                 [src/native/tools/Makefile]
 523                 [src/native/vm/Makefile]
 524                 [src/scripts/Makefile]
 525                 [src/scripts/java]
 526                 [src/scripts/rmiregistry]
 527                 [src/threads/Makefile]
 528                 [src/threads/green/Makefile]
 529                 [src/threads/native/Makefile]
 530                 [src/toolbox/Makefile]
 531                 [src/vm/Makefile]
 532                 [src/vm/jit/Makefile]
 533                 [src/vm/jit/alpha/Makefile]
 534                 [src/vm/jit/alpha/freebsd/Makefile]
 535                 [src/vm/jit/alpha/linux/Makefile]
 536                 [src/vm/jit/i386/Makefile]
 537                 [src/vm/jit/i386/freebsd/Makefile]
 538                 [src/vm/jit/i386/linux/Makefile]
 539                 [src/vm/jit/intrp/Makefile]
 540                 [src/vm/jit/inline/Makefile]
 541                 [src/vm/jit/loop/Makefile]
 542                 [src/vm/jit/mips/Makefile]
 543                 [src/vm/jit/mips/irix/Makefile]
 544                 [src/vm/jit/mips/linux/Makefile]
 545                 [src/vm/jit/powerpc/Makefile]
 546                 [src/vm/jit/powerpc/darwin/Makefile]
 547                 [src/vm/jit/powerpc/linux/Makefile]
 548                 [src/vm/jit/schedule/Makefile]
 549                 [src/vm/jit/tools/Makefile]
 550                 [src/vm/jit/verify/Makefile]
 551                 [src/vm/jit/x86_64/Makefile]
 552                 [tests/Makefile]
 553                 [tests/codepatching/Makefile]
 554                 [tests/native/Makefile]
 555                 [tests/regression/Makefile])
 556
 557 AC_OUTPUT
 558
 559
 560 ## Local variables:
 561 ## mode: m4
 562 ## indent-tabs-mode: t
 563 ## c-basic-offset: 4
 564 ## tab-width: 8
 565 ## compile-command: "automake --add-missing"
 566 ## End: