configure.in

   1
   2 AC_INIT(README)
   3 AC_CANONICAL_SYSTEM
   4 AM_CONFIG_HEADER(config.h)
   5 AM_INIT_AUTOMAKE(mono, 0.8)
   6 AM_MAINTAINER_MODE
   7
   8 AC_CHECK_TOOL(CC, gcc, gcc)
   9 AC_PROG_CC
  10 AM_PROG_CC_STDC
  11 AC_PROG_INSTALL
  12
  13 dnl may require a specific autoconf version
  14 dnl AC_PROG_CC_FOR_BUILD
  15 dnl CC_FOR_BUILD not automatically detected
  16 CC_FOR_BUILD=$CC
  17 BUILD_EXEEXT=
  18 if test "x$cross_compiling" = "xyes"; then
  19         CC_FOR_BUILD=cc
  20         BUILD_EXEEXT=""
  21 fi
  22 AC_SUBST(CC_FOR_BUILD)
  23 AC_SUBST(HOST_CC)
  24 AC_SUBST(BUILD_EXEEXT)
  25
  26 # Set STDC_HEADERS
  27 AC_HEADER_STDC
  28 AC_LIBTOOL_WIN32_DLL
  29 AM_PROG_LIBTOOL
  30
  31 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h)
  32
  33 # not 64 bit clean in cross-compile
  34 AC_CHECK_SIZEOF(void *, 4)
  35
  36 CFLAGS='-g -Wall -Wunused -Wmissing-prototypes -Wmissing-declarations'
  37
  38 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
  39 if test "x$PKG_CONFIG" = "xno"; then
  40         AC_MSG_ERROR([You need to install pkg-config])
  41 fi
  42
  43 dnl for use on the build system
  44 dnl pkg-config is stupid
  45 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
  46 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
  47 AC_SUBST(BUILD_GLIB_CFLAGS)
  48 AC_SUBST(BUILD_GLIB_LIBS)
  49
  50 PKG_PATH=
  51 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
  52         if test x$with_crosspkgdir = "x"; then
  53                 if test -s $PKG_CONFIG_PATH; then
  54                         PKG_PATH=$PKG_CONFIG_PATH
  55                 fi
  56         else
  57                 PKG_PATH=$with_crosspkgdir
  58                 PKG_CONFIG_PATH=$PKG_PATH
  59                 export PKG_CONFIG_PATH
  60         fi
  61 )
  62
  63 ## Versions of dependencies
  64 GLIB_REQUIRED_VERSION=1.3.11
  65
  66 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
  67
  68 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0`
  69 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0`
  70 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
  71 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
  72
  73 AC_SUBST(GLIB_CFLAGS)
  74 AC_SUBST(GLIB_LIBS)
  75 AC_SUBST(GMODULE_CFLAGS)
  76 AC_SUBST(GMODULE_LIBS)
  77
  78 dnl ****************************************
  79 dnl *** Check if we're building on win32 ***
  80 dnl ****************************************
  81 AC_MSG_CHECKING([if building for some Win32 platform])
  82 case "$host" in
  83         *-*-mingw*|*-*-cygwin*)
  84                 platform_win32=yes
  85                 AC_DEFINE(PLATFORM_WIN32)
  86                 ;;
  87         *)
  88                 platform_win32=no
  89                 ;;
  90 esac
  91 AC_MSG_RESULT($platform_win32)
  92 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
  93
  94 if test x$platform_win32 = xyes; then
  95         AC_MSG_CHECKING([if building for native Win32])
  96         case "$host" in
  97                 *-*-mingw*)
  98                         platform_win32_native=yes
  99                         AC_DEFINE(PLATFORM_WIN32_NATIVE)
 100                         ;;
 101                 *)
 102                         platform_win32_native=no
 103                         ;;
 104         esac
 105         AC_MSG_RESULT($platform_win32_native)
 106         AM_CONDITIONAL(PLATFORM_WIN32_NATIVE,
 107                        test x$platform_win32_native = xyes)
 108 fi
 109
 110
 111 if test x$platform_win32 = xno; then
 112         dnl ******************************************************************
 113         dnl *** Check for large file support                               ***
 114         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 115         dnl ******************************************************************
 116
 117         # Check that off_t can represent 2**63 - 1 correctly, working around
 118         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 119         # CFLAGS and sets $large_offt to yes if the test succeeds
 120         large_offt=no
 121         AC_DEFUN(LARGE_FILES, [
 122                 large_CPPFLAGS=$CPPFLAGS
 123                 CPPFLAGS="$CPPFLAGS $1"
 124                 AC_TRY_RUN([
 125                         #include <sys/types.h>
 126
 127                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 128
 129                         int main(void) {
 130                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 131                                                (BIG_OFF_T%2147483647==1));
 132                                 if(big_off_t) {
 133                                         exit(0);
 134                                 } else {
 135                                         exit(1);
 136                                 }
 137                         }
 138                 ], [
 139                         AC_MSG_RESULT(ok)
 140                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 141                         CFLAGS="$CFLAGS $1"
 142                         large_offt=yes
 143                 ], [
 144                         AC_MSG_RESULT(no)
 145                 ], "")
 146                 CPPFLAGS=$large_CPPFLAGS
 147         ])
 148
 149         AC_MSG_CHECKING(if off_t is 64 bits wide)
 150         LARGE_FILES("")
 151         if test $large_offt = no; then
 152                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 153                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 154         fi
 155         if test $large_offt = no; then
 156                 AC_MSG_WARN([No 64 bit file size support available])
 157         fi
 158
 159         dnl *****************************
 160         dnl *** Checks for libsocket  ***
 161         dnl *****************************
 162         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 163
 164         dnl *****************************
 165         dnl *** Checks for SOL_IP     ***
 166         dnl *****************************
 167         AC_MSG_CHECKING(for SOL_IP)
 168         AC_TRY_COMPILE([#include <netdb.h>], [
 169                 int level = SOL_IP;
 170         ], [
 171                 # Yes, we have it...
 172                 AC_MSG_RESULT(yes)
 173                 AC_DEFINE(HAVE_SOL_IP)
 174         ], [
 175                 # We'll have to use getprotobyname
 176                 AC_MSG_RESULT(no)
 177         ])
 178
 179         dnl *****************************
 180         dnl *** Checks for SOL_TCP    ***
 181         dnl *****************************
 182         AC_MSG_CHECKING(for SOL_TCP)
 183         AC_TRY_COMPILE([#include <netdb.h>], [
 184                 int level = SOL_TCP;
 185         ], [
 186                 # Yes, we have it...
 187                 AC_MSG_RESULT(yes)
 188                 AC_DEFINE(HAVE_SOL_TCP)
 189         ], [
 190                 # We'll have to use getprotobyname
 191                 AC_MSG_RESULT(no)
 192         ])
 193
 194         dnl *****************************
 195         dnl *** Checks for IP_PKTINFO ***
 196         dnl *****************************
 197         AC_MSG_CHECKING(for IP_PKTINFO)
 198         AC_TRY_COMPILE([#include <netdb.h>], [
 199                 int level = IP_PKTINFO;
 200         ], [
 201                 # Yes, we have it...
 202                 AC_MSG_RESULT(yes)
 203                 AC_DEFINE(HAVE_IP_PKTINFO)
 204         ], [
 205                 AC_MSG_RESULT(no)
 206         ])
 207
 208         dnl *********************************
 209         dnl *** Check for struct ip_mreqn ***
 210         dnl *********************************
 211         AC_MSG_CHECKING(for struct ip_mreqn)
 212         AC_TRY_COMPILE([#include <netinet/in.h>], [
 213                 struct ip_mreqn mreq;
 214                 mreq.imr_address.s_addr = 0;
 215         ], [
 216                 # Yes, we have it...
 217                 AC_MSG_RESULT(yes)
 218                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 219         ], [
 220                 # We'll just have to use struct ip_mreq
 221                 AC_MSG_RESULT(no)
 222         ])
 223
 224         dnl *****************************
 225         dnl *** Checks for libnsl     ***
 226         dnl *****************************
 227         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 228
 229         AC_CHECK_FUNCS(inet_pton inet_aton)
 230
 231         dnl *****************************
 232         dnl *** Checks for libpthread ***
 233         dnl *****************************
 234         AC_SEARCH_LIBS(pthread_create, pthread, [
 235                 AM_CONDITIONAL(THREADS_PTHREAD, true)
 236                 AC_DEFINE(HAVE_PTHREAD)
 237
 238                 # Need pthread_mutex_timedlock
 239                 pthread_CFLAGS=""
 240                 orig_CPPFLAGS=$CPPFLAGS
 241                 # This is a gcc-specific error, but we already set
 242                 # gcc-specific options in CFLAGS
 243                 CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
 244                 AC_MSG_CHECKING(for pthread_mutex_timedlock)
 245                 AC_TRY_COMPILE([ #include <pthread.h>], [
 246                         pthread_mutex_t mut=PTHREAD_MUTEX_INITIALIZER;
 247                         pthread_mutex_timedlock(&mut, NULL);
 248                 ], [
 249                         # Works!
 250                         AC_MSG_RESULT(yes)
 251                         AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 252                 ], [
 253                         AC_MSG_RESULT(no)
 254
 255                         # glibc requires -D_GNU_SOURCE before it will declare
 256                         # this function
 257                         AC_MSG_CHECKING(whether _GNU_SOURCE is needed for pthread_mutex_timedlock)
 258                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 259                         AC_TRY_COMPILE([ #include <pthread.h>], [
 260                                 pthread_mutex_t mut=PTHREAD_MUTEX_INITIALIZER;
 261                                 pthread_mutex_timedlock(&mut, NULL);
 262                         ], [
 263                                 AC_MSG_RESULT(yes)
 264                                 pthread_CFLAGS="-D_GNU_SOURCE"
 265                                 AC_DEFINE(HAVE_PTHREAD_MUTEX_TIMEDLOCK)
 266                         ], [
 267                                 AC_MSG_RESULT(no)
 268                                 dnl Add other variants here
 269                                 AC_MSG_WARN(Working around pthread_mutex_timedlock)
 270                         ])
 271                 ])
 272                 CPPFLAGS=$orig_CPPFLAGS
 273                 CFLAGS="$CFLAGS $pthread_CFLAGS"
 274
 275                 # Need PTHREAD_MUTEX_RECURSIVE
 276                 pthread_CFLAGS=""
 277                 orig_CPPFLAGS=$CPPFLAGS
 278                 # This is a gcc-specific error, but we already set
 279                 # gcc-specific options in CFLAGS
 280                 CPPFLAGS="$CPPFLAGS -Werror-implicit-function-declaration"
 281                 AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 282                 AC_TRY_COMPILE([ #include <pthread.h>], [
 283                         pthread_mutexattr_t attr;
 284                         pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 285                 ], [
 286                         # Works!
 287                         AC_MSG_RESULT(ok)
 288                 ], [
 289                         AC_MSG_RESULT(no)
 290
 291                         # glibc requires -D_GNU_SOURCE before it will declare
 292                         # this macro
 293                         AC_MSG_CHECKING(whether _GNU_SOURCE is needed for PTHREAD_MUTEX_RECURSIVE)
 294                         CPPFLAGS="$CPPFLAGS -D_GNU_SOURCE"
 295                         AC_TRY_COMPILE([ #include <pthread.h>], [
 296                                 pthread_mutexattr_t attr;
 297                                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 298                         ], [
 299                                 AC_MSG_RESULT(ok)
 300                                 pthread_CFLAGS="-D_GNU_SOURCE"
 301                         ], [
 302                                 AC_MSG_RESULT(no)
 303                                 dnl Add other variants here
 304                                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 305                                 AC_DEFINE(USE_MONO_MUTEX)
 306                         ])
 307                 ])
 308                 CPPFLAGS=$orig_CPPFLAGS
 309                 CFLAGS="$CFLAGS $pthread_CFLAGS"
 310         ], [
 311                 AC_MSG_ERROR([libpthread is required on non-win32 hosts])
 312         ])
 313
 314         dnl ********************************
 315         dnl *** Checks for semaphore lib ***
 316         dnl ********************************
 317         AC_CHECK_LIB(rt, sem_init, LIBS="$LIBS -lrt")
 318 fi
 319
 320 if test "x$cross_compiling" = "xno"; then
 321 # check for new iconv version
 322 AC_MSG_CHECKING(for new iconv)
 323 AC_CACHE_VAL(new_iconv,[
 324         AC_TRY_RUN([#include <stdio.h>
 325                 #include <iconv.h>
 326
 327                 int main()
 328                 {
 329                   exit (iconv_open ("UTF-16le", "UTF-8") == (iconv_t)-1);
 330                 }
 331                 ],
 332                 new_iconv=yes,new_iconv=)])
 333 if test -n "$new_iconv"; then
 334         AC_MSG_RESULT(yes)
 335         AC_DEFINE(HAVE_NEW_ICONV)
 336 else
 337         AC_MSG_RESULT(no)
 338 fi
 339 fi
 340
 341 TARGET="unknown"
 342 ACCESS_UNALIGNED="yes"
 343
 344 case "$host" in
 345 #mips-sgi-irix5.* | mips-sgi-irix6.*) TARGET=MIPS; ACCESS_UNALIGNED="no";;
 346 i*86-*-*) TARGET=X86; arch_target=x86;;
 347 sparc*-*-*) TARGET=SPARC; arch_target=sparc; ACCESS_UNALIGNED="no";;
 348 #alpha*-*-linux* | alpha*-*-osf*) TARGET=ALPHA; ACCESS_UNALIGNED="no";;
 349 #m68k-*-linux*) TARGET=M68K;;
 350 powerpc-*-linux* | powerpc-*-sysv*) TARGET=POWERPC; arch_target=ppc;;
 351 #arm-*-linux-*) TARGET=ARM; ACCESS_UNALIGNED="no";;
 352 esac
 353
 354 if test ${TARGET} = unknown; then
 355         CFLAGS="$CFLAGS -DNO_PORT"
 356         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
 357 fi
 358
 359 if test ${ACCESS_UNALIGNED} = no; then
 360         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
 361 fi
 362
 363 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
 364 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
 365 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
 366 AM_CONDITIONAL(X86, test x$TARGET = xX86)
 367 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
 368 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
 369 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
 370 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
 371
 372 AC_SUBST(arch_target)
 373 AC_SUBST(CFLAGS)
 374
 375 AC_OUTPUT([
 376 Makefile
 377 mono/Makefile
 378 mono/metadata/Makefile
 379 mono/dis/Makefile
 380 mono/cil/Makefile
 381 mono/arch/Makefile
 382 mono/arch/x86/Makefile
 383 mono/arch/ppc/Makefile
 384 mono/arch/sparc/Makefile
 385 mono/interpreter/Makefile
 386 mono/tests/Makefile
 387 mono/wrapper/Makefile
 388 mono/monoburg/Makefile
 389 mono/jit/Makefile
 390 mono/io-layer/Makefile
 391 runtime/Makefile
 392 scripts/Makefile
 393 man/Makefile
 394 doc/Makefile
 395 ])