configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,1.1.3)
  10 AM_MAINTAINER_MODE
  11
  12 AC_PROG_LN_S
  13
  14 # In case of cygwin, override LN_S, irrespective of what it determines.
  15 # The build uses cygwin, but the actual runtime doesn't.
  16 case $host_os in
  17 *cygwin* ) LN_S='cp -p';;
  18 esac
  19
  20
  21 dnl
  22 dnl libgc checks
  23 dnl
  24
  25 gc_headers=no
  26 gc=included
  27 use_included_gc=no
  28
  29 if test -d $srcdir/libgc ; then
  30   gc_default=included
  31 else
  32   gc_default=boehm
  33 fi
  34
  35 #
  36 # These are the flags that need to be stored in the mono.pc file for
  37 # compiling code that will embed Mono
  38 #
  39 libmono_cflags=""
  40 libmono_ldflags=""
  41 AC_SUBST(libmono_cflags)
  42 AC_SUBST(libmono_ldflags)
  43
  44 dnl if linker handles the version script
  45 no_version_script=no
  46
  47 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  48 need_link_unlink=no
  49
  50 # Thread configuration inspired by sleepycat's db
  51 AC_MSG_CHECKING([host platform characteristics])
  52 libgc_threads=no
  53 case "$host" in
  54         *-*-mingw*|*-*-cygwin*)
  55                 platform_win32=yes
  56                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  57                 CC="gcc -mno-cygwin -g"
  58                 HOST_CC="gcc"
  59                 # So libgc configure gets -mno-cygwin
  60                 export CC
  61 # latest libgc already defines GC_WIN32_THREADS
  62 #               CPPFLAGS="$CPPFLAGS -DGC_WIN32_THREADS -DWIN32_THREADS"
  63                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS"
  64                 libdl=
  65                 libgc_threads=win32
  66                 gc_default=included
  67                 with_nptl=default
  68                 with_sigaltstack=no
  69                 LN_S=cp
  70                 ;;
  71         *-*-*netbsd*)
  72                 platform_win32=no
  73                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  74                 libmono_cflags="-D_REENTRANT"
  75                 LDFLAGS="$LDFLAGS -pthread"
  76                 libmono_ldflags="-pthread"
  77                 need_link_unlink=yes
  78                 libdl=
  79                 libgc_threads=no
  80                 ;;
  81 # these flags will work for all versions of -STABLE
  82 #
  83         *-*-*freebsd4*)
  84                 platform_win32=no
  85                 if test "x$PTHREAD_CFLAGS" = "x"; then
  86                         CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  87                         libmono_cflags="-D_THREAD_SAFE"
  88                 else
  89                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
  90                         libmono_cflags="$PTHREAD_CFLAGS"
  91                 fi
  92                 if test "x$PTHREAD_LIBS" = "x"; then
  93                         LDFLAGS="$LDFLAGS -pthread"
  94                         libmono_ldflags="-pthread"
  95                 else
  96                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
  97                         libmono_ldflags="$PTHREAD_LIBS"
  98                 fi
  99                 need_link_unlink=yes
 100                 AC_DEFINE(PTHREAD_POINTER_ID)
 101                 libdl=
 102                 libgc_threads=pthreads
 103 # TLS isn't implemented at all on -STABLE
 104                 with_nptl=no
 105                 with_tls=pthread
 106                 ;;
 107 # older versions of -CURRENT will break with these flags but testing
 108 # indicates these older versions won't run Mono anyway
 109 #
 110         *-*-*freebsd5*)
 111                 platform_win32=no
 112                 if test "x$PTHREAD_CFLAGS" = "x"; then
 113                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 114                         libmono_cflags=
 115                 else
 116                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 117                         libmono_cflags="$PTHREAD_CFLAGS"
 118                 fi
 119                 if test "x$PTHREAD_LIBS" = "x"; then
 120                         LDFLAGS="$LDFLAGS -lpthread"
 121                         libmono_ldflags="-lpthread"
 122                 else
 123                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 124                         libmono_ldflags="$PTHREAD_LIBS"
 125                 fi
 126                 need_link_unlink=yes
 127                 AC_DEFINE(PTHREAD_POINTER_ID)
 128                 libdl=
 129                 libgc_threads=pthreads
 130 # TLS is only partially implemented on -CURRENT (compiler support
 131 # but NOT library support)
 132 #
 133                 with_nptl=no
 134                 with_tls=pthread
 135                 ;;
 136         *-*-*openbsd*)
 137                 platform_win32=no
 138                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 139                 libmono_cflags="-D_THREAD_SAFE"
 140                 LDFLAGS="$LDFLAGS -pthread"
 141                 libmono_ldflags="-pthread"
 142                 need_link_unlink=yes
 143                 AC_DEFINE(PTHREAD_POINTER_ID)
 144                 libdl=
 145                 libgc_threads=pthreads
 146                 ;;
 147         *-*-linux*)
 148                 platform_win32=no
 149                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT"
 150                 libmono_cflags="-D_REENTRANT"
 151                 libmono_ldflags="-lpthread"
 152                 libdl="-ldl"
 153                 libgc_threads=pthreads
 154                 ;;
 155         *-*-hpux*)
 156                 platform_win32=no
 157                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 158                 CFLAGS="$CFLAGS +ESdbgasm"
 159                 LDFLAGS="$LDFLAGS -z"
 160                 libmono_cflags="-D_REENTRANT"
 161                 libmono_ldflags="-lpthread"
 162                 libgc_threads=pthreads
 163                 need_link_unlink=yes
 164                 ;;
 165         *-*-solaris*)
 166                 platform_win32=no
 167                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT"
 168                 need_link_unlink=yes
 169                 libmono_cflags="-D_REENTRANT"
 170                 libgc_threads=pthreads
 171                 ;;
 172         *-*-darwin*)
 173                 platform_win32=no
 174                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS"
 175                 libmono_cflags="-D_THREAD_SAFE"
 176                 LDFLAGS="$LDFLAGS -pthread"
 177                 libmono_ldflags="-pthread"
 178                 need_link_unlink=yes
 179                 AC_DEFINE(PTHREAD_POINTER_ID)
 180                 AC_DEFINE(USE_MACH_SEMA)
 181                 no_version_script=yes
 182                 libdl=
 183                 libgc_threads=pthreads
 184                 ;;
 185         *)
 186                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 187                 platform_win32=no
 188                 libdl="-ldl"
 189                 ;;
 190 esac
 191 AC_MSG_RESULT(ok)
 192
 193 if test x$need_link_unlink = xyes; then
 194    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 195 fi
 196
 197 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 198
 199 AC_CHECK_TOOL(CC, gcc, gcc)
 200 AC_PROG_CC
 201 AM_PROG_CC_STDC
 202 AC_PROG_INSTALL
 203 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 204 : ${CCAS='$(CC)'}
 205 # Set ASFLAGS if not already set.
 206 : ${CCASFLAGS='$(CFLAGS)'}
 207 AC_SUBST(CCAS)
 208 AC_SUBST(CCASFLAGS)
 209
 210 AC_CHECK_PROG(BISON, bison,yes,no)
 211 if test "x$BISON" = "xno";
 212 then
 213         AC_MSG_ERROR([You need to install bison])
 214 fi
 215
 216 dnl may require a specific autoconf version
 217 dnl AC_PROG_CC_FOR_BUILD
 218 dnl CC_FOR_BUILD not automatically detected
 219 CC_FOR_BUILD=$CC
 220 BUILD_EXEEXT=
 221 if test "x$cross_compiling" = "xyes"; then
 222         CC_FOR_BUILD=cc
 223         BUILD_EXEEXT=""
 224 fi
 225 AC_SUBST(CC_FOR_BUILD)
 226 AC_SUBST(HOST_CC)
 227 AC_SUBST(BUILD_EXEEXT)
 228
 229 # Set STDC_HEADERS
 230 AC_HEADER_STDC
 231 AC_LIBTOOL_WIN32_DLL
 232 AM_PROG_LIBTOOL
 233
 234 # Test whenever ld supports -version-script
 235 AC_PROG_LD
 236 AC_PROG_LD_GNU
 237 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 238    no_version_script=yes
 239 fi
 240
 241 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 242
 243 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h linux/rtc.h)
 244
 245 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 246
 247 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 248
 249 # for mono/metadata/debug-symfile.c
 250 AC_CHECK_HEADERS(elf.h)
 251
 252 # for mono/dis
 253 AC_CHECK_HEADERS(wchar.h)
 254 AC_CHECK_HEADERS(ieeefp.h)
 255 AC_MSG_CHECKING(for isinf)
 256 AC_TRY_COMPILE([#include <math.h>], [
 257         int f = isinf (1);
 258 ], [
 259         AC_MSG_RESULT(yes)
 260         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 261 ], [
 262         # We'll have to use signals
 263         AC_MSG_RESULT(no)
 264 ])
 265
 266
 267 # not 64 bit clean in cross-compile
 268 AC_CHECK_SIZEOF(void *, 4)
 269
 270 WARN=''
 271 if test x"$GCC" = xyes; then
 272         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 273                 # The runtime code does not respect ANSI C strict aliasing rules
 274                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 275 else
 276         # The Sun Forte compiler complains about inline functions that access static variables
 277         # so disable all inlining.
 278         case "$host" in
 279         *-*-solaris*)
 280                 CFLAGS="$CFLAGS -Dinline="
 281                 ;;
 282         esac
 283 fi
 284 CFLAGS="$CFLAGS -g $WARN"
 285
 286 # Where's the 'mcs' source tree?
 287 if test -d $srcdir/mcs; then
 288   mcsdir=mcs
 289 else
 290   mcsdir=../mcs
 291 fi
 292
 293 mcs_topdir='$(top_srcdir)/'$mcsdir
 294 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 295
 296 AC_SUBST([mcs_topdir])
 297 AC_SUBST([mcs_topdir_from_srcdir])
 298
 299 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 300 if test "x$PKG_CONFIG" = "xno"; then
 301         AC_MSG_ERROR([You need to install pkg-config])
 302 fi
 303
 304 dnl for use on the build system
 305 dnl pkg-config is stupid
 306 BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 307 BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 308 AC_SUBST(BUILD_GLIB_CFLAGS)
 309 AC_SUBST(BUILD_GLIB_LIBS)
 310
 311 PKG_PATH=
 312 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 313         if test x$with_crosspkgdir = "x"; then
 314                 if test -s $PKG_CONFIG_PATH; then
 315                         PKG_PATH=$PKG_CONFIG_PATH
 316                 fi
 317         else
 318                 PKG_PATH=$with_crosspkgdir
 319                 PKG_CONFIG_PATH=$PKG_PATH
 320                 export PKG_CONFIG_PATH
 321         fi
 322 )
 323
 324 ## Versions of dependencies
 325 GLIB_REQUIRED_VERSION=1.3.11
 326
 327 PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 328
 329 GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 330 GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 331 GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 332 GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 333
 334 AC_SUBST(GLIB_CFLAGS)
 335 AC_SUBST(GLIB_LIBS)
 336 AC_SUBST(GMODULE_CFLAGS)
 337 AC_SUBST(GMODULE_LIBS)
 338
 339 if test x$platform_win32 = xyes; then
 340    AC_MSG_CHECKING(for cygwin glib2-dev package)
 341    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 342       AC_MSG_RESULT(found)
 343           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 344    else
 345       AC_MSG_RESULT(not found, ok)
 346    fi
 347
 348    AC_MSG_CHECKING(for broken gwin32.h)
 349    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 350    if test -f $glib_include/glib/gwin32.h; then
 351           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 352                  AC_MSG_RESULT(failed)
 353                  hashmark='#'
 354                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 355           fi
 356    fi
 357    AC_MSG_RESULT(ok)
 358 fi
 359
 360 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 361
 362 # Enable support for fast thread-local storage
 363 # Some systems have broken support, so we allow to disable it.
 364 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 365
 366 # Kept for compatibility
 367 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      deprecated, use --with-tls instead],[],[with_nptl=default])
 368
 369 if test "x$with_nptl" != "xdefault"; then
 370    if test "x$with_nptl" = "xyes"; then
 371       AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
 372           with_tls=__thread
 373    fi
 374    if test "x$with_nptl" = "xno"; then
 375       AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
 376           with_tls=pthread
 377    fi
 378 fi
 379
 380 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 381 # This does not work on some platforms (bug #55253)
 382 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=no])
 383
 384 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 385
 386 if test "x$enable_static" = "xno"; then
 387    with_static_mono=no
 388 fi
 389
 390 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 391
 392 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 393   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug, reflection_emit.],
 394 [
 395         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 396                 eval "mono_feature_disable_$feature='yes'"
 397                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 398         done
 399         disabled="Disabled:    $enable_minimal"
 400 ],[])
 401
 402 if test "x$mono_feature_disable_aot" = "xyes"; then
 403         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 404 fi
 405
 406 if test "x$mono_feature_disable_profiler" = "xyes"; then
 407         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 408 fi
 409
 410 if test "x$mono_feature_disable_decimal" = "xyes"; then
 411         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 412 fi
 413
 414 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 415         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 416 fi
 417
 418 if test "x$mono_feature_disable_debug" = "xyes"; then
 419         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 420 fi
 421
 422 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 423         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 424 fi
 425
 426 LIBGC_CFLAGS=
 427 LIBGC_LIBS=
 428 LIBGC_STATIC_LIBS=
 429 libgc_dir=
 430 case "x$gc" in
 431         xboehm|xbohem|xyes)
 432                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 433                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 434
 435                 if test "x$found_boehm" != "xyes"; then
 436                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 437                 fi
 438                 if test "x$gc_headers" != "xyes"; then
 439                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 440                 fi
 441
 442                 AC_DEFINE(HAVE_BOEHM_GC)
 443                 AC_SUBST(HAVE_BOEHM_GC)
 444                 LIBGC_LIBS="-lgc $libdl"
 445                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 446
 447                 # AC_CHECK_FUNCS does not work for some reason...
 448                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 449                 if test "x$found_gcj_malloc" = "xyes"; then
 450                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 451                 fi
 452                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 453                 if test "x$found_gc_enable" = "xyes"; then
 454                         AC_DEFINE(HAVE_GC_ENABLE)
 455                 fi
 456                 ;;
 457
 458         xincluded)
 459                 AC_CONFIG_SUBDIRS(libgc)
 460
 461                 found_boehm=yes
 462                 gc_headers=yes
 463                 use_included_gc=yes
 464                 libgc_dir=libgc
 465
 466                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 467                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 468                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 469
 470                 AC_DEFINE(HAVE_BOEHM_GC)
 471                 AC_SUBST(HAVE_BOEHM_GC)
 472
 473                 AC_DEFINE(HAVE_GC_H)
 474                 AC_DEFINE(USE_INCLUDED_LIBGC)
 475
 476                 # The included libgc contains GCJ support
 477                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 478                 AC_DEFINE(HAVE_GC_ENABLE)
 479                 ;;
 480
 481         xnone)
 482                 AC_MSG_WARN("Compiling mono without GC.")
 483                 ;;
 484         *)
 485                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 486                 ;;
 487 esac
 488
 489
 490 # tell libgc/configure about what we want
 491 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads"
 492
 493 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 494 AC_SUBST(LIBGC_CFLAGS)
 495 AC_SUBST(LIBGC_LIBS)
 496 AC_SUBST(LIBGC_STATIC_LIBS)
 497 AC_SUBST(libgc_dir)
 498
 499 dnl
 500 dnl End of libgc checks
 501 dnl
 502
 503 if test x$platform_win32 = xno; then
 504
 505         dnl ******************************************************************
 506         dnl *** Checks for the IKVM JNI interface library                  ***
 507         dnl ******************************************************************
 508         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 509
 510         ikvm_native_dir=
 511         if test x$with_ikvm_native = xyes; then
 512                 ikvm_native_dir=ikvm-native
 513         fi
 514
 515         AC_SUBST(ikvm_native_dir)
 516
 517         AC_CHECK_FUNCS(getgrgid_r)
 518         AC_CHECK_FUNCS(getgrnam_r)
 519         AC_CHECK_FUNCS(getpwnam_r)
 520         AC_CHECK_FUNCS(getpwuid_r)
 521         AC_CHECK_FUNCS(getresuid)
 522         AC_CHECK_FUNCS(setresuid)
 523         AC_CHECK_FUNCS(kqueue)
 524         AC_CHECK_FUNCS(backtrace_symbols)
 525
 526         dnl ******************************************************************
 527         dnl *** Check for large file support                               ***
 528         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 529         dnl ******************************************************************
 530
 531         # Check that off_t can represent 2**63 - 1 correctly, working around
 532         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 533         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 534         large_offt=no
 535         AC_DEFUN(LARGE_FILES, [
 536                 large_CPPFLAGS=$CPPFLAGS
 537                 CPPFLAGS="$CPPFLAGS $1"
 538                 AC_TRY_RUN([
 539                         #include <sys/types.h>
 540
 541                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 542
 543                         int main(void) {
 544                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 545                                                (BIG_OFF_T%2147483647==1));
 546                                 if(big_off_t) {
 547                                         exit(0);
 548                                 } else {
 549                                         exit(1);
 550                                 }
 551                         }
 552                 ], [
 553                         AC_MSG_RESULT(ok)
 554                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 555                         large_CPPFLAGS="$large_CPPFLAGS $1"
 556                         large_offt=yes
 557                 ], [
 558                         AC_MSG_RESULT(no)
 559                 ], "")
 560                 CPPFLAGS=$large_CPPFLAGS
 561         ])
 562
 563         AC_MSG_CHECKING(if off_t is 64 bits wide)
 564         LARGE_FILES("")
 565         if test $large_offt = no; then
 566                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 567                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 568         fi
 569         if test $large_offt = no; then
 570                 AC_MSG_WARN([No 64 bit file size support available])
 571         fi
 572
 573         dnl *****************************
 574         dnl *** Checks for libsocket  ***
 575         dnl *****************************
 576         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 577
 578         dnl *******************************
 579         dnl *** Checks for MSG_NOSIGNAL ***
 580         dnl *******************************
 581         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 582         AC_TRY_COMPILE([#include <sys/socket.h>], [
 583                 int f = MSG_NOSIGNAL;
 584         ], [
 585                 # Yes, we have it...
 586                 AC_MSG_RESULT(yes)
 587                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 588         ], [
 589                 # We'll have to use signals
 590                 AC_MSG_RESULT(no)
 591         ])
 592
 593         dnl *****************************
 594         dnl *** Checks for SOL_IP     ***
 595         dnl *****************************
 596         AC_MSG_CHECKING(for SOL_IP)
 597         AC_TRY_COMPILE([#include <netdb.h>], [
 598                 int level = SOL_IP;
 599         ], [
 600                 # Yes, we have it...
 601                 AC_MSG_RESULT(yes)
 602                 AC_DEFINE(HAVE_SOL_IP)
 603         ], [
 604                 # We'll have to use getprotobyname
 605                 AC_MSG_RESULT(no)
 606         ])
 607
 608         dnl *****************************
 609         dnl *** Checks for SOL_IPV6     ***
 610         dnl *****************************
 611         AC_MSG_CHECKING(for SOL_IPV6)
 612         AC_TRY_COMPILE([#include <netdb.h>], [
 613                 int level = SOL_IPV6;
 614         ], [
 615                 # Yes, we have it...
 616                 AC_MSG_RESULT(yes)
 617                 AC_DEFINE(HAVE_SOL_IPV6)
 618         ], [
 619                 # We'll have to use getprotobyname
 620                 AC_MSG_RESULT(no)
 621         ])
 622
 623         dnl *****************************
 624         dnl *** Checks for SOL_TCP    ***
 625         dnl *****************************
 626         AC_MSG_CHECKING(for SOL_TCP)
 627         AC_TRY_COMPILE([#include <netdb.h>], [
 628                 int level = SOL_TCP;
 629         ], [
 630                 # Yes, we have it...
 631                 AC_MSG_RESULT(yes)
 632                 AC_DEFINE(HAVE_SOL_TCP)
 633         ], [
 634                 # We'll have to use getprotobyname
 635                 AC_MSG_RESULT(no)
 636         ])
 637
 638         dnl *****************************
 639         dnl *** Checks for IP_PKTINFO ***
 640         dnl *****************************
 641         AC_MSG_CHECKING(for IP_PKTINFO)
 642         AC_TRY_COMPILE([#include <netdb.h>], [
 643                 int level = IP_PKTINFO;
 644         ], [
 645                 # Yes, we have it...
 646                 AC_MSG_RESULT(yes)
 647                 AC_DEFINE(HAVE_IP_PKTINFO)
 648         ], [
 649                 AC_MSG_RESULT(no)
 650         ])
 651
 652         dnl *********************************
 653         dnl *** Check for struct ip_mreqn ***
 654         dnl *********************************
 655         AC_MSG_CHECKING(for struct ip_mreqn)
 656         AC_TRY_COMPILE([#include <netinet/in.h>], [
 657                 struct ip_mreqn mreq;
 658                 mreq.imr_address.s_addr = 0;
 659         ], [
 660                 # Yes, we have it...
 661                 AC_MSG_RESULT(yes)
 662                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 663         ], [
 664                 # We'll just have to try and use struct ip_mreq
 665                 AC_MSG_RESULT(no)
 666                 AC_MSG_CHECKING(for struct ip_mreq)
 667                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 668                         struct ip_mreq mreq;
 669                         mreq.imr_interface.s_addr = 0;
 670                 ], [
 671                         # Yes, we have it...
 672                         AC_MSG_RESULT(yes)
 673                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 674                 ], [
 675                         # No multicast support
 676                         AC_MSG_RESULT(no)
 677                 ])
 678         ])
 679
 680         dnl **********************************
 681         dnl *** Check for gethostbyname2_r ***
 682         dnl **********************************
 683         AC_MSG_CHECKING(for gethostbyname2_r)
 684                 AC_TRY_LINK([#include <netdb.h>], [
 685                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 686         ], [
 687                 # Yes, we have it...
 688                 AC_MSG_RESULT(yes)
 689                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 690         ], [
 691                 AC_MSG_RESULT(no)
 692         ])
 693
 694         dnl *****************************
 695         dnl *** Checks for libnsl     ***
 696         dnl *****************************
 697         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 698
 699         AC_CHECK_FUNCS(inet_pton inet_aton)
 700
 701         dnl ***********************************************
 702         dnl *** Checks for size of sockaddr_un.sun_path ***
 703         dnl ***********************************************
 704         # AC_CHECK_SIZEOF can't cope with struct members :-(
 705         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 706         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 707                 [AC_TRY_RUN([
 708                         #include <sys/types.h>
 709                         #include <stdio.h>
 710                         #include <sys/un.h>
 711
 712                         int main(void) {
 713                                 struct sockaddr_un sock_un;
 714                                 FILE *f=fopen("conftestval", "w");
 715                                 if(!f) exit(1);
 716                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 717                                 exit(0);
 718                         }
 719                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 720                    cv_mono_sizeof_sunpath=0,
 721                    cv_mono_sizeof_sunpath=0)])dnl
 722         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 723         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 724
 725         dnl *************************************
 726         dnl *** Checks for zero length arrays ***
 727         dnl *************************************
 728         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 729         AC_TRY_COMPILE([
 730                 struct s {
 731                         int  length;
 732                         char data [0];
 733                 };
 734         ], [], [
 735                 AC_MSG_RESULT(yes)
 736                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 737         ], [
 738                 AC_MSG_RESULT(no)
 739                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 740         ])
 741
 742         dnl *****************************
 743         dnl *** Checks for libxnet    ***
 744         dnl *****************************
 745         case "${host}" in
 746                 *solaris* )
 747                         AC_MSG_CHECKING(for Solaris XPG4 support)
 748                         if test -f /usr/lib/libxnet.so; then
 749                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 750                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 751                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 752                                 LIBS="$LIBS -lxnet"
 753                                 AC_MSG_RESULT(yes)
 754                         else
 755                                 AC_MSG_RESULT(no)
 756                         fi
 757
 758                         if test "$GCC" = "yes"; then
 759                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 760                         fi
 761                 ;;
 762         esac
 763
 764         dnl *****************************
 765         dnl *** Checks for libpthread ***
 766         dnl *****************************
 767 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
 768 # and libpthread does not exist
 769 #
 770         case "${host}" in
 771                 *-*-*freebsd4*)
 772                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 773                 ;;
 774                 *)
 775                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 776                 ;;
 777         esac
 778         AC_CHECK_HEADERS(pthread.h)
 779         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 780         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 781         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 782         AC_TRY_COMPILE([ #include <pthread.h>], [
 783                 pthread_mutexattr_t attr;
 784                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 785         ], [
 786                 AC_MSG_RESULT(ok)
 787         ], [
 788                 AC_MSG_RESULT(no)
 789                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
 790                 AC_DEFINE(USE_MONO_MUTEX)
 791         ])
 792         AC_CHECK_FUNCS(pthread_attr_setstacksize)
 793
 794         dnl ***********************************
 795         dnl *** Checks for working __thread ***
 796         dnl ***********************************
 797         AC_MSG_CHECKING(for working __thread)
 798         if test "x$with_tls" != "x__thread"; then
 799                 AC_MSG_RESULT(disabled)
 800         else
 801                 AC_TRY_RUN([
 802                         #include <pthread.h>
 803
 804                         __thread int i;
 805                         static int res1, res2;
 806
 807                         void thread_main (void *arg)
 808                         {
 809                                 i = arg;
 810                                 sleep (1);
 811                                 if (arg == 1)
 812                                         res1 = (i == arg);
 813                                 else
 814                                         res2 = (i == arg);
 815                         }
 816
 817                         int main () {
 818                                 pthread_t t1, t2;
 819
 820                                 i = 5;
 821
 822                                 pthread_create (&t1, NULL, thread_main, 1);
 823                                 pthread_create (&t2, NULL, thread_main, 2);
 824
 825                                 pthread_join (t1, NULL);
 826                                 pthread_join (t2, NULL);
 827
 828                                 return !(res1 + res2 == 2);
 829                         }
 830                 ], [
 831                                 AC_MSG_RESULT(yes)
 832                 ], [
 833                                 AC_MSG_RESULT(no)
 834                                 with_tls=pthread
 835                 ])
 836         fi
 837
 838         dnl **************************************
 839         dnl *** Checks for working sigaltstack ***
 840         dnl **************************************
 841         AC_MSG_CHECKING(for working sigaltstack)
 842         if test "x$with_sigaltstack" != "xyes"; then
 843                 AC_MSG_RESULT(disabled)
 844         else
 845                 AC_TRY_RUN([
 846                         #include <stdio.h>
 847                         #include <stdlib.h>
 848                         #include <unistd.h>
 849                         #include <signal.h>
 850                         #include <pthread.h>
 851                         #include <sys/wait.h>
 852
 853                         static void
 854                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
 855                         {
 856                                 exit (0);
 857                         }
 858
 859                         static void *
 860                         loop (void *ignored)
 861                         {
 862                                 char *ptr = NULL;
 863
 864                                 *ptr = 0;
 865                                 return NULL;
 866                         }
 867
 868                         static void
 869                         child ()
 870                         {
 871                                 struct sigaction sa;
 872                                 struct sigaltstack sas;
 873                                 pthread_t id;
 874                                 pthread_attr_t attr;
 875
 876                                 sa.sa_sigaction = sigsegv_signal_handler;
 877                                 sigemptyset (&sa.sa_mask);
 878                                 sa.sa_flags = SA_SIGINFO | SA_STACK;
 879                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
 880                                         perror ("lala");
 881                                         return;
 882                                 }
 883
 884                                 sas.ss_sp = malloc (SIGSTKSZ);
 885                                 sas.ss_size = SIGSTKSZ;
 886                                 sas.ss_flags = SS_ONSTACK;
 887                                 if (sigaltstack (&sas, NULL) == -1) {
 888                                         perror ("lala");
 889                                         return;
 890                                 }
 891
 892                                 pthread_attr_init (&attr);
 893                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
 894                                         printf ("failed\n");
 895                                         return;
 896                                 }
 897
 898                                 sleep (100);
 899                         }
 900
 901                         int
 902                         main ()
 903                         {
 904                                 pid_t son;
 905                                 int status;
 906                                 int i;
 907
 908                                 son = fork ();
 909                                 if (son == -1) {
 910                                         return 1;
 911                                 }
 912
 913                                 if (son == 0) {
 914                                         child ();
 915                                         return 0;
 916                                 }
 917
 918                                 for (i = 0; i < 3; ++i) {
 919                                         sleep (1);
 920                                         waitpid (son, &status, WNOHANG);
 921                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
 922                                                 return 0;
 923                                 }
 924
 925                                 kill (son, SIGKILL);
 926                                 return 1;
 927                         }
 928
 929                 ], [
 930                                 AC_MSG_RESULT(yes)
 931                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 932                 ], [
 933                                 with_sigaltstack=no
 934                                 AC_MSG_RESULT(no)
 935                 ])
 936         fi
 937
 938         dnl ********************************
 939         dnl *** Checks for semaphore lib ***
 940         dnl ********************************
 941         # 'Real Time' functions on Solaris
 942         # posix4 on Solaris 2.6
 943         # pthread (first!) on Linux
 944         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
 945
 946         dnl ********************************
 947         dnl *** Checks for timezone stuff **
 948         dnl ********************************
 949         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
 950                 AC_TRY_COMPILE([
 951                         #include <time.h>
 952                         ], [
 953                         struct tm tm;
 954                         tm.tm_gmtoff = 1;
 955                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
 956         if test $ac_cv_struct_tm_gmtoff = yes; then
 957                 AC_DEFINE(HAVE_TM_GMTOFF)
 958         else
 959                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
 960                         AC_TRY_COMPILE([
 961                                 #include <time.h>
 962                         ], [
 963                                 timezone = 1;
 964                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
 965                 if test $ac_cv_var_timezone = yes; then
 966                         AC_DEFINE(HAVE_TIMEZONE)
 967                 else
 968                         AC_ERROR(unable to find a way to determine timezone)
 969                 fi
 970         fi
 971
 972         dnl *********************************
 973         dnl *** Checks for math functions ***
 974         dnl *********************************
 975         LIBS="$LIBS -lm";
 976         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
 977                 AC_TRY_LINK([#include <math.h>],
 978                 [ finite(0.0); ],
 979                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
 980                 AC_MSG_RESULT(no)))
 981         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
 982                 AC_TRY_LINK([#include <math.h>],
 983                 [ isfinite(0.0); ],
 984                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
 985                 AC_MSG_RESULT(no)))
 986
 987         dnl ****************************************************************
 988         dnl *** Checks for working poll() (macosx defines it but doesn't ***
 989         dnl *** have it in the library (duh))                            ***
 990         dnl ****************************************************************
 991         AC_CHECK_FUNCS(poll)
 992
 993         dnl *************************
 994         dnl *** Check for signbit ***
 995         dnl *************************
 996         AC_MSG_CHECKING(for signbit)
 997         AC_TRY_LINK([#include <math.h>], [
 998                 int s = signbit(1.0);
 999         ], [
1000                 AC_MSG_RESULT(yes)
1001                 AC_DEFINE(HAVE_SIGNBIT)
1002         ], [
1003                 AC_MSG_RESULT(no)
1004         ])
1005
1006         dnl *********************
1007         dnl *** Check for AIO ***
1008         dnl *********************
1009         AC_MSG_CHECKING([for SIGEV_THREAD definition])
1010         dnl Some systems (FreeBSD at least) may have aio_read
1011         dnl but don't support/define SIGEV_THREAD.
1012         AC_TRY_COMPILE([
1013         #include <sys/signal.h>
1014         ],[
1015         int x = SIGEV_THREAD;
1016         ],[
1017                 ac_cv_c_sigev_thread=yes
1018                 AC_MSG_RESULT(yes)
1019         ],[
1020                 AC_MSG_RESULT(no)
1021         ])
1022
1023         if test "$ac_cv_c_sigev_thread" = "yes" ; then
1024                 AC_CHECK_HEADERS(aio.h sys/aio.h)
1025                 AC_CHECK_LIB(rt, aio_read, [ LIBS="$LIBS -lrt" ],)
1026                 SIGVAL_PTR="undefined"
1027                 if test "$ac_cv_header_aio_h" = "yes" -o "$ac_cv_header_sys_aio_h" = "yes" ; then
1028                         AC_CHECK_MEMBER(union sigval.sigval_ptr,SIGVAL_PTR="sigval_ptr",, [
1029                                         #include <sys/signal.h>
1030                                         ])
1031                         AC_CHECK_MEMBER(union sigval.sival_ptr,SIGVAL_PTR="sival_ptr",, [
1032                                         #include <sys/signal.h>
1033                                         ])
1034                         if test "$SIGVAL_PTR" = "undefined" ; then
1035                                 AC_MSG_ERROR([Unable to detect field name in 'union sigval'])
1036                         fi
1037                 fi
1038                 AC_DEFINE_UNQUOTED(SIGVAL_PTR,$SIGVAL_PTR,[Pointer field name in 'union sigval'])
1039         fi
1040
1041         dnl **********************************
1042         dnl *** Checks for MonoPosixHelper ***
1043         dnl **********************************
1044         AC_CHECK_HEADERS(checklist.h)
1045         AC_CHECK_HEADERS(fstab.h)
1046         AC_CHECK_HEADERS(sys/sendfile.h)
1047         AC_CHECK_HEADERS(sys/statvfs.h)
1048         AC_CHECK_HEADERS(sys/vfstab.h)
1049         AC_CHECK_FUNCS(getdomainname)
1050         AC_CHECK_FUNCS(setdomainname)
1051         AC_CHECK_FUNCS(fgetgrent)
1052         AC_CHECK_FUNCS(fgetpwent)
1053         AC_CHECK_FUNCS(fgetpwent)
1054         AC_CHECK_FUNCS(getfsstat)
1055         AC_CHECK_FUNCS(posix_fadvise)
1056         AC_CHECK_FUNCS(posix_fallocate)
1057         AC_CHECK_FUNCS(posix_madvise)
1058         AC_CHECK_FUNCS(vsnprintf)
1059         AC_CHECK_FUNCS(sendfile)
1060         AC_CHECK_FUNCS(sethostid)
1061         AC_CHECK_FUNCS(statfs)
1062         AC_CHECK_FUNCS(fstatfs)
1063         AC_CHECK_FUNCS(statvfs)
1064         AC_CHECK_FUNCS(fstatvfs)
1065         AC_CHECK_FUNCS(stime)
1066         AC_CHECK_FUNCS(strerror_r)
1067         AC_CHECK_FUNCS(ttyname_r)
1068         AC_CHECK_SIZEOF(size_t)
1069         AC_CHECK_MEMBERS(
1070                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1071                 [#include <sys/types.h>
1072                  #include <dirent.h>])
1073 else
1074         jdk_headers_found=no
1075         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1076         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1077         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1078
1079         dnl *********************************
1080         dnl *** Check for struct ip_mreqn ***
1081         dnl *********************************
1082         AC_MSG_CHECKING(for struct ip_mreqn)
1083         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1084                 struct ip_mreqn mreq;
1085                 mreq.imr_address.s_addr = 0;
1086         ], [
1087                 # Yes, we have it...
1088                 AC_MSG_RESULT(yes)
1089                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1090         ], [
1091                 # We'll just have to try and use struct ip_mreq
1092                 AC_MSG_RESULT(no)
1093                 AC_MSG_CHECKING(for struct ip_mreq)
1094                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1095                         struct ip_mreq mreq;
1096                         mreq.imr_interface.s_addr = 0;
1097                 ], [
1098                         # Yes, we have it...
1099                         AC_MSG_RESULT(yes)
1100                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1101                 ], [
1102                         # No multicast support
1103                         AC_MSG_RESULT(no)
1104                 ])
1105         ])
1106 fi
1107
1108 dnl socklen_t check
1109 AC_MSG_CHECKING(for socklen_t)
1110 AC_TRY_COMPILE([
1111 #include <sys/types.h>
1112 #include <sys/socket.h>
1113 ],[
1114   socklen_t foo;
1115 ],[
1116 ac_cv_c_socklen_t=yes
1117         AC_DEFINE(HAVE_SOCKLEN_T)
1118         AC_MSG_RESULT(yes)
1119 ],[
1120         AC_MSG_RESULT(no)
1121 ])
1122
1123 AC_MSG_CHECKING(for array element initalizer support)
1124 AC_TRY_COMPILE([#include <sys/socket.h>], [
1125         const int array[] = {[1] = 2,};
1126 ], [
1127         # Yes, we have it...
1128         AC_MSG_RESULT(yes)
1129         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1130 ], [
1131         # We'll have to use signals
1132         AC_MSG_RESULT(no)
1133 ])
1134
1135 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1136         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1137         AC_TRY_LINK([#include <math.h>],
1138         [ static void *p = &trunc; ],
1139         [
1140                 AC_DEFINE(HAVE_TRUNC)
1141                 AC_MSG_RESULT(yes)
1142                 ac_cv_trunc=yes
1143         ],
1144         AC_MSG_RESULT(no)))
1145
1146 if test "x$ac_cv_truncl" != "xyes"; then
1147    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1148 fi
1149
1150 dnl ****************************
1151 dnl *** Look for /dev/random ***
1152 dnl ****************************
1153
1154 AC_MSG_CHECKING([if usage of random device is requested])
1155 AC_ARG_ENABLE(dev-random,
1156 [  --disable-dev-random    disable the use of the random device],
1157 try_dev_random=$enableval, try_dev_random=yes)
1158 AC_MSG_RESULT($try_dev_random)
1159
1160 case "{$target}" in
1161     *-openbsd*)
1162     NAME_DEV_RANDOM="/dev/srandom"
1163     ;;
1164
1165 dnl Win32 does not have /dev/random, they have their own method...
1166
1167     *-*-mingw*|*-*-cygwin*)
1168     ac_cv_have_dev_random=no
1169     ;;
1170
1171 dnl Everywhere else, it's /dev/random
1172
1173     *)
1174     NAME_DEV_RANDOM="/dev/random"
1175     ;;
1176 esac
1177
1178 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1179
1180 dnl Now check if the device actually exists
1181
1182 if test "x$try_dev_random" = "xyes"; then
1183     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1184     [if test -r "$NAME_DEV_RANDOM" ; then
1185         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1186     if test "x$ac_cv_have_dev_random" = "xyes"; then
1187         AC_DEFINE(HAVE_CRYPT_RNG)
1188     fi
1189 else
1190     AC_MSG_CHECKING(for random device)
1191     ac_cv_have_dev_random=no
1192     AC_MSG_RESULT(has been disabled)
1193 fi
1194
1195 if test "x$platform_win32" = "xyes"; then
1196     AC_DEFINE(HAVE_CRYPT_RNG)
1197 fi
1198
1199 if test "x$ac_cv_have_dev_random" = "xno" \
1200     && test "x$platform_win32" = "xno"; then
1201     AC_MSG_WARN([[
1202 ***
1203 *** A system-provided entropy source was not found on this system.
1204 *** Because of this, the System.Security.Cryptography random number generator
1205 *** will throw a NotImplemented exception.
1206 ***
1207 *** If you are seeing this message, and you know your system DOES have an
1208 *** entropy collection in place, please contact <crichton@gimp.org> and
1209 *** provide information about the system and how to access the random device.
1210 ***
1211 *** Otherwise you can install either egd or prngd and set the environment
1212 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1213 ***]])
1214 fi
1215
1216 AC_MSG_CHECKING([if inter-process shared handles are requested])
1217 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1218 AC_MSG_RESULT($try_shared_handles)
1219 if test "x$try_shared_handles" != "xyes"; then
1220         AC_DEFINE(DISABLE_SHARED_HANDLES)
1221         AC_SUBST(DISABLE_SHARED_HANDLES)
1222 fi
1223
1224 #
1225 # ICU
1226 #
1227 ICU_CFLAGS=""
1228 ICU_LIBS=""
1229 enable_icu="no;  default"
1230
1231 probe_icu=false
1232 AC_ARG_WITH(icu, [  --with-icu=yes/no],
1233         if test x$with_icu = xno; then
1234            probe_icu=false;
1235            AC_MSG_RESULT(Will not probe for ICU)
1236         fi
1237         if test x$with_icu = xyes; then
1238            probe_icu=true;
1239         fi
1240 )
1241
1242 if $probe_icu; then
1243         AC_PATH_PROG(ICU_CONFIG, icu-config, no)
1244         if test "x$ICU_CONFIG" = "xno" -o ! -x "$ICU_CONFIG"; then
1245                 AC_MSG_WARN([Only invariant locale available; install ICU for I18N support])
1246                 enable_icu="no, if you want full i18n support download it from: http://oss.software.ibm.com/icu/index.html"
1247         else
1248                 enable_icu="yes. Version: `$ICU_CONFIG --version`"
1249                 AC_DEFINE(HAVE_ICU)
1250                 ICU_CFLAGS=`$ICU_CONFIG --cppflags`
1251                 ICU_LIBS=`$ICU_CONFIG --ldflags`
1252         fi
1253 fi
1254 AC_SUBST(ICU_CFLAGS)
1255 AC_SUBST(ICU_LIBS)
1256
1257 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1258 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1259
1260 TARGET="unknown"
1261 ACCESS_UNALIGNED="yes"
1262
1263 JIT_SUPPORTED=no
1264 INTERP_SUPPORTED=no
1265 LIBC="libc.so.6"
1266 INTL="libc.so.6"
1267
1268 jit_wanted=false
1269 interp_wanted=false
1270 case "$host" in
1271 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1272 #               TARGET=MIPS;
1273 #               ACCESS_UNALIGNED="no"
1274 #               ;;
1275         i*86-*-*)
1276                 TARGET=X86;
1277                 arch_target=x86;
1278                 JIT_SUPPORTED=yes
1279                 jit_wanted=true
1280                 ;;
1281         x86_64-*-* | amd64-*-*)
1282                 TARGET=AMD64;
1283                 arch_target=amd64;
1284                 JIT_SUPPORTED=yes
1285                 jit_wanted=true
1286                 ;;
1287         sparc*-*-*)
1288                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1289                    TARGET=SPARC64
1290                 else
1291                         TARGET=SPARC
1292                 fi
1293                 arch_target=sparc;
1294                 JIT_SUPPORTED=yes
1295                 ACCESS_UNALIGNED="no"
1296                 LIBC="libc.so"
1297                 INTL="libintl.so"
1298                 jit_wanted=true
1299                 if test x"$GCC" = xyes; then
1300                         CFLAGS="$CFLAGS -Wno-cast-align"
1301                 fi
1302                 ;;
1303        alpha*-*-linux* | alpha*-*-osf*)
1304                 TARGET=ALPHA;
1305                 ACCESS_UNALIGNED="no"
1306                 JIT_SUPPORTED=no
1307                 INTERP_SUPPORTED=yes
1308                 interp_wanted=true
1309                 arch_target=alpha;
1310                ;;
1311 #       ia64-*-linux* | ia64-*-hpux*)
1312 #               TARGET=IA64;
1313 #               arch_target=ia64;
1314 #               JIT_SUPPORTED=no;
1315 #               ACCESS_UNALIGNED="no";
1316 #               case "$host_os" in
1317 #                       linux*) LIBC="libc.so.6.1";;
1318 #                       hpux*)  LIBC="libc.so.1";;
1319 #               esac
1320 #               ;;
1321 #       m68k-*-linux*)
1322 #               TARGET=M68K
1323 #               ;;
1324         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1325                 TARGET=HPPA;
1326                 arch_target=hppa;
1327                 LIBC="libc.sl"
1328                 ACCESS_UNALIGNED="no"
1329                 INTERP_SUPPORTED=yes
1330                 interp_wanted=true
1331                 ;;
1332         hppa*linux*)
1333                 TARGET=HPPA;
1334                 arch_target=hppa;
1335                 ACCESS_UNALIGNED="no"
1336                 INTERP_SUPPORTED=yes
1337                 interp_wanted=true
1338                 ;;
1339         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1340         powerpc-*-sysv* | powerpc-*-darwin*)
1341                 TARGET=POWERPC;
1342                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1343                 arch_target=ppc;
1344                 JIT_SUPPORTED=yes
1345                 jit_wanted=true
1346                 ;;
1347         arm-*-linux-* | armv4l-*-linux-*)
1348                 TARGET=ARM;
1349                 arch_target=arm;
1350                 ACCESS_UNALIGNED="no"
1351                 INTERP_SUPPORTED=yes
1352                 interp_wanted=true
1353                 ;;
1354         s390-*-linux*)
1355                 TARGET=S390;
1356                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1357                 arch_target=s390;
1358                 ACCESS_UNALIGNED="no"
1359                 JIT_SUPPORTED=yes
1360                 ;;
1361         s390x-*-linux*)
1362                 TARGET=S390x;
1363                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1364                 arch_target=s390x;
1365                 ACCESS_UNALIGNED="no"
1366                 JIT_SUPPORTED=yes
1367                 ;;
1368 esac
1369
1370 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1371         if test x$withval = xyes; then
1372            jit_wanted=true
1373         else
1374            jit_wanted=false
1375         fi
1376 ])
1377
1378 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1379         if test x$withval = xyes; then
1380            interp_wanted=true
1381         else
1382            interp_wanted=false
1383         fi
1384 ])
1385
1386 USEJIT=false
1387 if test x$JIT_SUPPORTED = xyes; then
1388    if $jit_wanted; then
1389       USEJIT=true
1390       jit_status="Building and using the JIT"
1391    else
1392       if $interp_wanted; then
1393          jit_status="Building the JIT, defaulting to the interpreter"
1394       else
1395          AC_ERROR(No JIT or interpreter support available or selected.)
1396       fi
1397    fi
1398 else
1399    if $interp_wanted; then
1400       jit_status="interpreter"
1401    else
1402       AC_ERROR(No JIT or interpreter support available or selected.)
1403    fi
1404 fi
1405
1406 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1407
1408 libsuffix=".so"
1409
1410 case "$host" in
1411      powerpc-*-darwin*)
1412         libsuffix=".dylib"
1413         LIBC="libc.dylib"
1414         INTL="libintl.dylib"
1415         ;;
1416      *-*-*netbsd*)
1417         LIBC="libc.so.12"
1418         INTL="libintl.so.0"
1419         ;;
1420     *-*-*freebsd*)
1421         LIBC="libc.so"
1422         INTL="libintl.so"
1423         ;;
1424     *-*-*openbsd*)
1425         LIBC="libc.so"
1426         INTL="libintl.so"
1427         ;;
1428 esac
1429 AC_SUBST(libsuffix)
1430
1431 if test "x$TARGET" != "xAMD64"; then
1432    # valgrind headers don't compile under x86-64
1433    AC_CHECK_HEADERS(valgrind/memcheck.h)
1434 fi
1435
1436 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1437         if test "x$with_tls" = "x__thread"; then
1438                 #
1439                 # On some linux distributions, TLS works in executables, but linking
1440                 # against a shared library containing TLS fails with:
1441                 # undefined reference to `__tls_get_addr'
1442                 #
1443                 rm -f conftest.c conftest.so conftest
1444                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1445                 gcc -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1446                 gcc -o conftest conftest.so > /dev/null 2>&1
1447                 if test ! -f conftest; then
1448                    AC_MSG_WARN([Disabling usage of __thread.]);
1449                    with_tls=pthread
1450                 fi
1451                 rm -f conftest.c conftest.so conftest
1452         fi
1453 fi
1454
1455 if test "x$with_tls" = "x__thread"; then
1456         AC_DEFINE(HAVE_KW_THREAD)
1457    # Pass the information to libgc
1458         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1459         export CPPFLAGS
1460 fi
1461
1462 if test ${TARGET} = ARM; then
1463         dnl ******************************************
1464         dnl *** Check to see what FPU is available ***
1465         dnl ******************************************
1466         AC_MSG_CHECKING(which FPU to use)
1467
1468         AC_TRY_COMPILE([], [
1469                 __asm__ ("ldfd f0, [r0]");
1470                 ], fpu=FPA, [
1471                         AC_TRY_COMPILE([], [
1472                                 __asm__ ("fldd d0, [r0]");
1473                         ], fpu=VFP, fpu=NONE)
1474                 ])
1475
1476         AC_MSG_RESULT($fpu)
1477         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1478         unset fpu
1479 fi
1480
1481 if test ${TARGET} = unknown; then
1482         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1483         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1484 fi
1485
1486 if test ${ACCESS_UNALIGNED} = no; then
1487         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1488 fi
1489
1490 PREVIEW=no
1491 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1492         if test x$with_preview = xyes; then
1493               PREVIEW=yes
1494         fi
1495 ])
1496
1497 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1498
1499 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1500 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1501 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1502 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1503 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1504 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1505 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1506 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1507 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1508 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1509 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1510 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1511 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1512 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1513
1514 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1515 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
1516 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
1517
1518 AC_SUBST(LIBC)
1519 AC_SUBST(INTL)
1520
1521 AC_SUBST(arch_target)
1522 AC_SUBST(CFLAGS)
1523 AC_SUBST(CPPFLAGS)
1524 AC_SUBST(LDFLAGS)
1525
1526 mono_build_root=`pwd`
1527 AC_SUBST(mono_build_root)
1528
1529 if test x$USEJIT = xtrue; then
1530   mono_runtime=mono/mini/mono
1531 else
1532   mono_runtime=mono/interpreter/mint
1533 fi
1534 AC_SUBST(mono_runtime)
1535
1536 mono_cfg_root=$mono_build_root/runtime
1537 if test x$platform_win32 = xyes; then
1538   mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
1539 else
1540   mono_cfg_dir=$mono_cfg_root/etc
1541 fi
1542 AC_SUBST(mono_cfg_dir)
1543
1544 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
1545
1546 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
1547 [   depth=../../../..
1548     case $srcdir in
1549     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1550     .) reldir=$depth ;;
1551     *) reldir=$depth/$srcdir ;;
1552     esac
1553     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
1554     cd runtime/etc/mono/1.0
1555     rm -f machine.config
1556     $LN_S $reldir/data/net_1_1/machine.config machine.config
1557     cd $depth
1558 ],[LN_S='$LN_S'])
1559
1560 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
1561 [   depth=../../../..
1562     case $srcdir in
1563     [\\/$]* | ?:[\\/]* ) reldir=$srcdir ;;
1564     .) reldir=$depth ;;
1565     *) reldir=$depth/$srcdir ;;
1566     esac
1567     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1568     cd runtime/etc/mono/2.0
1569     rm -f machine.config
1570     $LN_S $reldir/data/net_2_0/machine.config machine.config
1571     cd $depth
1572 ],[LN_S='$LN_S'])
1573
1574 AC_OUTPUT([
1575 Makefile
1576 mint.pc
1577 mono.pc
1578 scripts/mono-nunit.pc
1579 mono/Makefile
1580 mono/utils/Makefile
1581 mono/metadata/Makefile
1582 mono/dis/Makefile
1583 mono/cil/Makefile
1584 mono/arch/Makefile
1585 mono/os/Makefile
1586 mono/os/win32/Makefile
1587 mono/os/unix/Makefile
1588 mono/arch/x86/Makefile
1589 mono/arch/amd64/Makefile
1590 mono/arch/hppa/Makefile
1591 mono/arch/ppc/Makefile
1592 mono/arch/sparc/Makefile
1593 mono/arch/s390/Makefile
1594 mono/arch/s390x/Makefile
1595 mono/arch/arm/Makefile
1596 mono/arch/alpha/Makefile
1597 mono/interpreter/Makefile
1598 mono/tests/Makefile
1599 mono/tests/tests-config
1600 mono/benchmark/Makefile
1601 mono/monoburg/Makefile
1602 mono/monograph/Makefile
1603 mono/io-layer/Makefile
1604 mono/handles/Makefile
1605 mono/mini/Makefile
1606 mono/profiler/Makefile
1607 ikvm-native/Makefile
1608 scripts/Makefile
1609 man/Makefile
1610 web/Makefile
1611 docs/Makefile
1612 data/Makefile
1613 data/net_1_1/Makefile
1614 data/net_2_0/Makefile
1615 samples/Makefile
1616 support/Makefile
1617 data/config
1618 mono.spec
1619 tools/Makefile
1620 tools/locale-builder/Makefile
1621 runtime/Makefile
1622 ])
1623
1624 (
1625   case $prefix in
1626   NONE) prefix=/usr/local ;;
1627   esac
1628   case $exec_prefix in
1629   NONE | '${prefix}') exec_prefix=$prefix ;;
1630   esac
1631
1632   echo "prefix=$exec_prefix" > $srcdir/$mcsdir/build/config.make
1633   echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
1634 )
1635
1636 echo "
1637         mcs source:  $mcs_topdir
1638         GC:          $gc
1639         ICU:         $enable_icu
1640         TLS:         $with_tls
1641         SIGALTSTACK: $with_sigaltstack
1642         Engine:      $jit_status
1643         2.0 Alpha:   $PREVIEW
1644         JNI support: $jdk_headers_found
1645         $disabled
1646
1647 "