configure.in

   1 AC_INIT(README)
   2 AC_CANONICAL_SYSTEM
   3
   4 # Gross hack to enable 'make dist' on automake 1.9+tar 1.14.
   5 # The extra brackets are to foil regex-based scans.
   6 m4_ifdef([_A][M_PROG_TAR],[_A][M_SET_OPTION([tar-ustar])])
   7
   8 AM_CONFIG_HEADER(config.h)
   9 AM_INIT_AUTOMAKE(mono,1.1.16)
  10 AM_MAINTAINER_MODE
  11
  12 AC_PROG_LN_S
  13
  14 # In case of cygwin, override LN_S, irrespective of what it determines.
  15 # The build uses cygwin, but the actual runtime doesn't.
  16 case $host_os in
  17 *cygwin* ) LN_S='cp -p';;
  18 esac
  19
  20
  21 dnl
  22 dnl libgc checks
  23 dnl
  24
  25 gc_headers=no
  26 gc=included
  27 use_included_gc=no
  28 libgc_configure_args=
  29
  30 if test -d $srcdir/libgc ; then
  31   gc_default=included
  32 else
  33   gc_default=boehm
  34 fi
  35
  36 #
  37 # These are the flags that need to be stored in the mono.pc file for
  38 # compiling code that will embed Mono
  39 #
  40 libmono_cflags=""
  41 libmono_ldflags=""
  42 AC_SUBST(libmono_cflags)
  43 AC_SUBST(libmono_ldflags)
  44
  45 # Variable to have relocatable .pc files (lib, or lib64)
  46 reloc_libdir=`basename ${libdir}`
  47 AC_SUBST(reloc_libdir)
  48
  49
  50 dnl if linker handles the version script
  51 no_version_script=no
  52
  53 # Set to yes if Unix sockets cannot be created in an anonymous namespace
  54 need_link_unlink=no
  55
  56 # Thread configuration inspired by sleepycat's db
  57 AC_MSG_CHECKING([host platform characteristics])
  58 libgc_threads=no
  59 case "$host" in
  60         *-*-mingw*|*-*-cygwin*)
  61                 platform_win32=yes
  62                 AC_DEFINE(PLATFORM_WIN32,1,[Platform is Win32])
  63                 if test "x$cross_compiling" = "xno"; then
  64                         CC="gcc -mno-cygwin -g"
  65                         # So libgc configure gets -mno-cygwin
  66                         export CC
  67                 fi
  68                 HOST_CC="gcc"
  69                 CPPFLAGS="$CPPFLAGS -DWIN32_THREADS -DFD_SETSIZE=1024"
  70                 libdl=
  71                 libgc_threads=win32
  72                 gc_default=included
  73                 with_nptl=default
  74                 with_sigaltstack=no
  75                 LN_S=cp
  76                 # This forces libgc to use the DllMain based thread registration code on win32
  77                 libgc_configure_args="$libgc_configure_args --enable-win32-dllmain=yes"
  78                 ;;
  79         *-*-*netbsd*)
  80                 platform_win32=no
  81                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
  82                 libmono_cflags="-D_REENTRANT"
  83                 LDFLAGS="$LDFLAGS -pthread"
  84                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD"
  85                 libmono_ldflags="-pthread"
  86                 need_link_unlink=yes
  87                 libdl=
  88                 libgc_threads=no
  89                 ;;
  90 # these flags will work for all versions of -STABLE
  91 #
  92         *-*-*freebsd4*)
  93                 platform_win32=no
  94                 if test "x$PTHREAD_CFLAGS" = "x"; then
  95                         CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
  96                         libmono_cflags="-D_THREAD_SAFE"
  97                 else
  98                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
  99                         libmono_cflags="$PTHREAD_CFLAGS"
 100                 fi
 101                 if test "x$PTHREAD_LIBS" = "x"; then
 102                         LDFLAGS="$LDFLAGS -pthread"
 103                         libmono_ldflags="-pthread"
 104                 else
 105                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 106                         libmono_ldflags="$PTHREAD_LIBS"
 107                 fi
 108                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD -DPLATFORM_BSD4"
 109                 need_link_unlink=yes
 110                 AC_DEFINE(PTHREAD_POINTER_ID)
 111                 libdl=
 112                 libgc_threads=pthreads
 113 # TLS isn't implemented at all on 4-STABLE
 114                 with_nptl=no
 115                 with_tls=pthread
 116                 ;;
 117         *-*-*freebsd5*)
 118                 platform_win32=no
 119                 if test "x$PTHREAD_CFLAGS" = "x"; then
 120                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 121                         libmono_cflags=
 122                 else
 123                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 124                         libmono_cflags="$PTHREAD_CFLAGS"
 125                 fi
 126                 if test "x$PTHREAD_LIBS" = "x"; then
 127                         LDFLAGS="$LDFLAGS -pthread"
 128                         libmono_ldflags="-pthread"
 129                 else
 130                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 131                         libmono_ldflags="$PTHREAD_LIBS"
 132                 fi
 133                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD -DPLATFORM_BSD5"
 134                 need_link_unlink=yes
 135                 AC_DEFINE(PTHREAD_POINTER_ID)
 136                 libdl=
 137                 with_sigaltstack=yes
 138                 libgc_threads=pthreads
 139 # TLS is only partially implemented on 5-STABLE (compiler support
 140 # but NOT library support)
 141 #
 142                 with_tls=pthread
 143                 ;;
 144         *-*-*freebsd6*)
 145                 platform_win32=no
 146                 if test "x$PTHREAD_CFLAGS" = "x"; then
 147                         CPPFLAGS="$CPPFLAGS -DGC_FREEBSD_THREADS"
 148                         libmono_cflags=
 149                 else
 150                         CPPFLAGS="$CPPFLAGS $PTHREAD_CFLAGS -DGC_FREEBSD_THREADS"
 151                         libmono_cflags="$PTHREAD_CFLAGS"
 152                 fi
 153                 if test "x$PTHREAD_LIBS" = "x"; then
 154                         LDFLAGS="$LDFLAGS -pthread"
 155                         libmono_ldflags="-pthread"
 156                 else
 157                         LDFLAGS="$LDFLAGS $PTHREAD_LIBS"
 158                         libmono_ldflags="$PTHREAD_LIBS"
 159                 fi
 160                 CPPFLAGS="$CPPFLAGS -DPLATFORM_BSD -DPLATFORM_BSD6"
 161                 need_link_unlink=yes
 162                 AC_DEFINE(PTHREAD_POINTER_ID)
 163                 libdl=
 164                 libgc_threads=pthreads
 165                 with_sigaltstack=yes
 166 # TLS is only partially implemented on -CURRENT (compiler support
 167 # but NOT library support)
 168 #
 169                 with_tls=pthread
 170                 ;;
 171         *-*-*openbsd*)
 172                 platform_win32=no
 173                 CPPFLAGS="$CPPFLAGS -D_THREAD_SAFE -DGC_FREEBSD_THREADS"
 174                 libmono_cflags="-D_THREAD_SAFE"
 175                 LDFLAGS="$LDFLAGS -pthread"
 176                 libmono_ldflags="-pthread"
 177                 need_link_unlink=yes
 178                 AC_DEFINE(PTHREAD_POINTER_ID)
 179                 libdl=
 180                 libgc_threads=pthreads
 181                 ;;
 182         *-*-linux*)
 183                 platform_win32=no
 184                 CPPFLAGS="$CPPFLAGS -DGC_LINUX_THREADS -D_GNU_SOURCE -D_REENTRANT -DUSE_MMAP -DUSE_MUNMAP"
 185                 libmono_cflags="-D_REENTRANT"
 186                 libmono_ldflags="-lpthread"
 187                 libdl="-ldl"
 188                 libgc_threads=pthreads
 189                 ;;
 190         *-*-hpux*)
 191         platform_win32=no
 192                 CPPFLAGS="$CPPFLAGS -DGC_HPUX_THREADS -D_HPUX_SOURCE -D_XOPEN_SOURCE_EXTENDED -D_REENTRANT"
 193                 CFLAGS="$CFLAGS +ESdbgasm"
 194                 LDFLAGS="$LDFLAGS -z"
 195                 libmono_cflags="-D_REENTRANT"
 196                 libmono_ldflags="-lpthread"
 197                 libgc_threads=pthreads
 198                 need_link_unlink=yes
 199                 ;;
 200         *-*-solaris*)
 201                 platform_win32=no
 202                 CPPFLAGS="$CPPFLAGS -DGC_SOLARIS_THREADS -DGC_SOLARIS_PTHREADS -D_REENTRANT -D_POSIX_PTHREAD_SEMANTICS -DUSE_MMAP -DUSE_MUNMAP"
 203                 need_link_unlink=yes
 204                 libmono_cflags="-D_REENTRANT"
 205                 libgc_threads=pthreads
 206                 # This doesn't seem to work on solaris/x86, but the configure test runs
 207                 with_nptl=no
 208                 ;;
 209         *-*-darwin*)
 210                 platform_win32=no
 211                 CPPFLAGS="$CPPFLAGS -no-cpp-precomp -D_THREAD_SAFE -DGC_MACOSX_THREADS -DPLATFORM_MACOSX"
 212                 libmono_cflags="-D_THREAD_SAFE"
 213                 LDFLAGS="$LDFLAGS -pthread"
 214                 libmono_ldflags="-pthread"
 215                 need_link_unlink=yes
 216                 AC_DEFINE(PTHREAD_POINTER_ID)
 217                 AC_DEFINE(USE_MACH_SEMA)
 218                 no_version_script=yes
 219                 libdl=
 220                 libgc_threads=pthreads
 221                 ;;
 222         *)
 223                 AC_MSG_WARN([*** Please add $host to configure.in checks!])
 224                 platform_win32=no
 225                 libdl="-ldl"
 226                 ;;
 227 esac
 228 AC_MSG_RESULT(ok)
 229
 230 if test x$need_link_unlink = xyes; then
 231    AC_DEFINE(NEED_LINK_UNLINK, 1, [Define if Unix sockets cannot be created in an anonymous namespace])
 232 fi
 233
 234 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
 235
 236 AC_CHECK_TOOL(CC, gcc, gcc)
 237 AC_PROG_CC
 238 AM_PROG_CC_STDC
 239 AC_PROG_INSTALL
 240 AC_PROG_AWK
 241 dnl We should use AM_PROG_AS, but it's not available on automake/aclocal 1.4
 242 : ${CCAS='$(CC)'}
 243 # Set ASFLAGS if not already set.
 244 : ${CCASFLAGS='$(CFLAGS)'}
 245 AC_SUBST(CCAS)
 246 AC_SUBST(CCASFLAGS)
 247
 248 AC_CHECK_PROG(BISON, bison,yes,no)
 249 if test "x$BISON" = "xno";
 250 then
 251         AC_MSG_ERROR([You need to install bison])
 252 fi
 253
 254 dnl may require a specific autoconf version
 255 dnl AC_PROG_CC_FOR_BUILD
 256 dnl CC_FOR_BUILD not automatically detected
 257 CC_FOR_BUILD=$CC
 258 CFLAGS_FOR_BUILD=$CFLAGS
 259 BUILD_EXEEXT=
 260 if test "x$cross_compiling" = "xyes"; then
 261         CC_FOR_BUILD=cc
 262         CFLAGS_FOR_BUILD=
 263         BUILD_EXEEXT=""
 264 fi
 265 AC_SUBST(CC_FOR_BUILD)
 266 AC_SUBST(CFLAGS_FOR_BUILD)
 267 AC_SUBST(HOST_CC)
 268 AC_SUBST(BUILD_EXEEXT)
 269
 270 AM_CONDITIONAL(CROSS_COMPILING, [test x$cross_compiling = xyes])
 271
 272 # Set STDC_HEADERS
 273 AC_HEADER_STDC
 274 AC_LIBTOOL_WIN32_DLL
 275 # This causes monodis to not link correctly
 276 #AC_DISABLE_FAST_INSTALL
 277 AM_PROG_LIBTOOL
 278
 279 # Test whenever ld supports -version-script
 280 AC_PROG_LD
 281 AC_PROG_LD_GNU
 282 if test "x$lt_cv_prog_gnu_ld" = "xno"; then
 283    no_version_script=yes
 284 fi
 285
 286 AM_CONDITIONAL(NO_VERSION_SCRIPT, test x$no_version_script = xyes)
 287
 288 AC_CHECK_HEADERS(sys/filio.h sys/sockio.h netdb.h utime.h semaphore.h sys/un.h linux/rtc.h sys/syscall.h)
 289
 290 AC_CHECK_HEADER(zlib.h, [have_zlib=yes], [have_zlib=no])
 291
 292 AM_CONDITIONAL(HAVE_ZLIB, test x$have_zlib = xyes)
 293
 294 # for mono/metadata/debug-symfile.c
 295 AC_CHECK_HEADERS(elf.h)
 296
 297 # for support
 298 AC_CHECK_HEADERS(poll.h)
 299 AC_CHECK_HEADERS(sys/poll.h)
 300 AC_CHECK_HEADERS(sys/wait.h)
 301 AC_CHECK_HEADERS(grp.h)
 302 AC_CHECK_HEADERS(syslog.h)
 303
 304 # for mono/dis
 305 AC_CHECK_HEADERS(wchar.h)
 306 case "$host" in
 307         *-*-*freebsd6*)
 308                 AC_CHECK_HEADERS(ieeefp.h)
 309         ;;
 310         *-*-*freebsd*)
 311                 /* Only freebsd6 has a working ieeefp.h */
 312         ;;
 313         *)
 314                 AC_CHECK_HEADERS(ieeefp.h)
 315         ;;
 316 esac
 317 AC_MSG_CHECKING(for isinf)
 318 AC_TRY_LINK([#include <math.h>], [
 319         int f = isinf (1);
 320 ], [
 321         AC_MSG_RESULT(yes)
 322         AC_DEFINE(HAVE_ISINF, 1, [isinf available])
 323 ], [
 324         # We'll have to use signals
 325         AC_MSG_RESULT(no)
 326 ])
 327
 328
 329 # not 64 bit clean in cross-compile
 330 AC_CHECK_SIZEOF(void *, 4)
 331
 332 WARN=''
 333 if test x"$GCC" = xyes; then
 334         WARN='-Wall -Wunused -Wmissing-prototypes -Wmissing-declarations -Wstrict-prototypes  -Wmissing-prototypes -Wnested-externs -Wpointer-arith -Wno-cast-qual -Wcast-align -Wwrite-strings'
 335                 # The runtime code does not respect ANSI C strict aliasing rules
 336                 CFLAGS="$CFLAGS -fno-strict-aliasing"
 337
 338                 ORIG_CFLAGS=$CFLAGS
 339                 CFLAGS="$CFLAGS -Wdeclaration-after-statement"
 340                 AC_MSG_CHECKING(for -Wdeclaration-after-statement option to gcc)
 341                 AC_TRY_COMPILE([], [
 342                                                    void main () { }
 343                 ], [
 344                    AC_MSG_RESULT(yes)
 345                 ], [
 346                    AC_MSG_RESULT(no)
 347                    CFLAGS=$ORIG_CFLAGS
 348                 ])
 349 else
 350         # The Sun Forte compiler complains about inline functions that access static variables
 351         # so disable all inlining.
 352         case "$host" in
 353         *-*-solaris*)
 354                 CFLAGS="$CFLAGS -Dinline="
 355                 ;;
 356         esac
 357 fi
 358 CFLAGS="$CFLAGS -g $WARN"
 359
 360 # Where's the 'mcs' source tree?
 361 if test -d $srcdir/mcs; then
 362   mcsdir=mcs
 363 else
 364   mcsdir=../mcs
 365 fi
 366
 367 mcs_topdir='$(top_srcdir)/'$mcsdir
 368 mcs_topdir_from_srcdir='$(top_builddir)/'$mcsdir
 369
 370 ## Maybe should also disable if mcsdir is invalid.  Let's punt the issue for now.
 371 AM_CONDITIONAL(BUILD_MCS, [test x$cross_compiling = xno])
 372
 373 AC_SUBST([mcs_topdir])
 374 AC_SUBST([mcs_topdir_from_srcdir])
 375
 376 AC_ARG_WITH([libgdiplus],
 377         [  --with-libgdiplus=installed|sibling|<path>   Override the libgdiplus used for System.Drawing tests (defaults to NO)],
 378         [], [with_libgdiplus=installed])
 379
 380 case $with_libgdiplus in
 381 no|installed) libgdiplus_loc= ;;
 382 yes|sibling) libgdiplus_loc=`cd ../libgdiplus && pwd`/src/libgdiplus.la ;;
 383 /*) libgdiplus_loc=$with_libgdiplus ;;
 384 *) libgdiplus_loc=`pwd`/$with_libgdiplus ;;
 385 esac
 386 AC_SUBST([libgdiplus_loc])
 387
 388 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
 389 if test "x$PKG_CONFIG" = "xno"; then
 390         AC_MSG_ERROR([You need to install pkg-config])
 391 fi
 392
 393 pkg_config_path=
 394 AC_ARG_WITH(crosspkgdir, [  --with-crosspkgdir=/path/to/pkg-config/dir],
 395         if test x$with_crosspkgdir = "x"; then
 396                 if test -s $PKG_CONFIG_PATH; then
 397                         pkg_config_path=$PKG_CONFIG_PATH
 398                 fi
 399         else
 400                 pkg_config_path=$with_crosspkgdir
 401                 PKG_CONFIG_PATH=$pkg_config_path
 402                 export PKG_CONFIG_PATH
 403         fi
 404 )
 405
 406 AC_ARG_WITH([glib],
 407         [  --with-glib=embedded|system       Choose glib API: system or embedded (default to system)],
 408         [], [with_glib=system])
 409
 410 case $with_glib in
 411 embedded)
 412   GLIB_CFLAGS='-I$(top_srcdir)/eglib/src'
 413   GLIB_LIBS='-L$(top_builddir)/eglib/src -leglib'
 414   AC_CONFIG_SUBDIRS(eglib)
 415   ;;
 416 system)
 417   BUILD_GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 418   BUILD_GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 419   AC_SUBST(BUILD_GLIB_CFLAGS)
 420   AC_SUBST(BUILD_GLIB_LIBS)
 421
 422   ## Versions of dependencies
 423   GLIB_REQUIRED_VERSION=1.3.11
 424
 425   PKG_CHECK_MODULES(BASE_DEPENDENCIES, glib-2.0 >= $GLIB_REQUIRED_VERSION)
 426
 427   GLIB_CFLAGS=`$PKG_CONFIG --cflags glib-2.0 gthread-2.0`
 428   GLIB_LIBS=`$PKG_CONFIG --libs glib-2.0 gthread-2.0`
 429   GMODULE_CFLAGS=`$PKG_CONFIG --cflags gmodule-2.0`
 430   GMODULE_LIBS=`$PKG_CONFIG --libs gmodule-2.0`
 431   ;;
 432 *)
 433   AC_MSG_ERROR([Invalid argument to --with-glib.])
 434 esac
 435
 436 AC_SUBST(GLIB_CFLAGS)
 437 AC_SUBST(GLIB_LIBS)
 438 AC_SUBST(GMODULE_CFLAGS)
 439 AC_SUBST(GMODULE_LIBS)
 440
 441 if test x$cross_compiling$platform_win32 = xnoyes; then
 442    AC_MSG_CHECKING(for cygwin glib2-dev package)
 443    if [ cygcheck --f /usr/lib/libglib-2.0.dll.a | grep -q glib2-devel ]; then
 444       AC_MSG_RESULT(found)
 445           AC_MSG_ERROR([Mono cannot be built with the cygwin glib2-devel package installed, because that package doesn't work with -mno-cygwin. Please uninstall it then re-run configure.])
 446    else
 447       AC_MSG_RESULT(not found, ok)
 448    fi
 449
 450    AC_MSG_CHECKING(for broken gwin32.h)
 451    glib_include=`$PKG_CONFIG --cflags-only-I glib-2.0 | sed -e 's/ -I.*//g' | sed -e 's/-I//g'`
 452    if test -f $glib_include/glib/gwin32.h; then
 453           if [ grep ftruncate $glib_include/glib/gwin32.h | grep -q define ]; then
 454                  AC_MSG_RESULT(failed)
 455                  hashmark='#'
 456                  AC_MSG_ERROR([Your version of gwin32.h is broken and will cause compilation errors when building mono. Please fix it by deleting the line: '$hashmark   define ftruncate...' from '$glib_include/glib/gwin32.h' then re-run configure.])
 457           fi
 458    fi
 459    AC_MSG_RESULT(ok)
 460 fi
 461
 462 AC_ARG_WITH(gc, [  --with-gc=boehm,included,none],[gc=$with_gc],[gc=$gc_default])
 463
 464 # Enable support for fast thread-local storage
 465 # Some systems have broken support, so we allow to disable it.
 466 AC_ARG_WITH(tls, [  --with-tls=__thread,pthread       select Thread Local Storage implementation],[],[with_tls=__thread])
 467
 468 # Kept for compatibility
 469 AC_ARG_WITH(nptl, [  --with-nptl=yes,no      deprecated, use --with-tls instead],[],[with_nptl=default])
 470
 471 if test "x$with_nptl" != "xdefault"; then
 472    if test "x$with_nptl" = "xyes"; then
 473       AC_MSG_WARN([--with-nptl=yes is deprecated, use --with-tls=__thread option instead.])
 474           with_tls=__thread
 475    fi
 476    if test "x$with_nptl" = "xno"; then
 477       AC_MSG_WARN([--with-nptl=no is deprecated, use --with-tls=pthread option instead.])
 478           with_tls=pthread
 479    fi
 480 fi
 481
 482 # Enable support for using sigaltstack for SIGSEGV and stack overflow handling
 483 # This does not work on some platforms (bug #55253)
 484 AC_ARG_WITH(sigaltstack, [  --with-sigaltstack=yes,no      enable/disable support for sigaltstack],[],[with_sigaltstack=no])
 485
 486 AC_ARG_WITH(static_mono, [  --with-static_mono=yes,no      link mono statically to libmono (faster)],[],[with_static_mono=yes])
 487
 488 if test "x$enable_static" = "xno"; then
 489    with_static_mono=no
 490 fi
 491
 492 if test "x$platform_win32" = "xyes"; then
 493    # Boehm GC requires the runtime to be in its own dll
 494    with_static_mono=no
 495 fi
 496
 497 AM_CONDITIONAL(STATIC_MONO, test x$with_static_mono != xno)
 498
 499 AC_ARG_WITH(xen_opt,   [  --with-xen_opt=yes,no      Enable Xen-specific behaviour],[],[with_xen_opt=yes])
 500 if test "x$with_xen_opt" = "xyes"; then
 501         AC_DEFINE(MONO_XEN_OPT, 1, [Xen-specific behaviour])
 502         ORIG_CFLAGS=$CFLAGS
 503         CFLAGS="$CFLAGS -mno-tls-direct-seg-refs"
 504         AC_MSG_CHECKING(for -mno-tls-direct-seg-refs option to gcc)
 505         AC_TRY_COMPILE([], [
 506                                            void main () { }
 507         ], [
 508            AC_MSG_RESULT(yes)
 509         ], [
 510            AC_MSG_RESULT(no)
 511            CFLAGS=$ORIG_CFLAGS
 512         ])
 513 fi
 514
 515 DISABLED_FEATURES=none
 516
 517 AC_ARG_ENABLE(minimal, [  --enable-minimal=LIST      drop support for LIST subsystems.
 518   LIST is a comma-separated list from: aot, profiler, decimal, pinvoke, debug,
 519   reflection_emit, large_code, logging, com, ssa, generics.],
 520 [
 521         for feature in `echo "$enable_minimal" | sed -e "s/,/ /g"`; do
 522                 eval "mono_feature_disable_$feature='yes'"
 523                 AC_MSG_NOTICE([Disabled support for feature: $feature])
 524         done
 525         DISABLED_FEATURES=$enable_minimal
 526         disabled="Disabled:    $enable_minimal"
 527 ],[])
 528
 529 AC_DEFINE_UNQUOTED(DISABLED_FEATURES, "$DISABLED_FEATURES", [String of disabled features])
 530
 531 if test "x$mono_feature_disable_aot" = "xyes"; then
 532         AC_DEFINE(DISABLE_AOT, 1, [Disable AOT support])
 533 fi
 534
 535 if test "x$mono_feature_disable_profiler" = "xyes"; then
 536         AC_DEFINE(DISABLE_PROFILER, 1, [Disable default profiler support])
 537 fi
 538
 539 if test "x$mono_feature_disable_decimal" = "xyes"; then
 540         AC_DEFINE(DISABLE_DECIMAL, 1, [Disable System.Decimal support])
 541 fi
 542
 543 if test "x$mono_feature_disable_pinvoke" = "xyes"; then
 544         AC_DEFINE(DISABLE_PINVOKE, 1, [Disable P/Invoke support])
 545 fi
 546
 547 if test "x$mono_feature_disable_debug" = "xyes"; then
 548         AC_DEFINE(DISABLE_DEBUG, 1, [Disable runtime debugging support])
 549 fi
 550
 551 if test "x$mono_feature_disable_reflection_emit" = "xyes"; then
 552         AC_DEFINE(DISABLE_REFLECTION_EMIT, 1, [Disable reflection emit support])
 553 fi
 554
 555 if test "x$mono_feature_disable_large_code" = "xyes"; then
 556         AC_DEFINE(DISABLE_LARGE_CODE, 1, [Disable support for huge assemblies])
 557 fi
 558
 559 if test "x$mono_feature_disable_logging" = "xyes"; then
 560         AC_DEFINE(DISABLE_LOGGING, 1, [Disable support debug logging])
 561 fi
 562
 563 if test "x$mono_feature_disable_com" = "xyes"; then
 564         AC_DEFINE(DISABLE_COM, 1, [Disable COM support])
 565 fi
 566
 567 if test "x$mono_feature_disable_ssa" = "xyes"; then
 568         AC_DEFINE(DISABLE_SSA, 1, [Disable advanced SSA JIT optimizations])
 569 fi
 570
 571 if test "x$mono_feature_disable_generics" = "xyes"; then
 572         AC_DEFINE(DISABLE_GENERICS, 1, [Disable generics support])
 573 fi
 574
 575 AC_MSG_CHECKING(for visibility __attribute__)
 576 AC_TRY_COMPILE([], [
 577    void __attribute__ ((visibility ("hidden"))) doit (void) {}
 578    void main () { doit (); }
 579 ], [
 580    have_visibility_hidden=yes
 581    AC_MSG_RESULT(yes)
 582 ], [
 583    have_visibility_hidden=no
 584    AC_MSG_RESULT(no)
 585 ])
 586
 587 LIBGC_CFLAGS=
 588 LIBGC_LIBS=
 589 LIBGC_STATIC_LIBS=
 590 libgc_dir=
 591 case "x$gc" in
 592         xboehm|xbohem|xyes)
 593                 AC_CHECK_HEADERS(gc.h gc/gc.h, gc_headers=yes)
 594                 AC_CHECK_LIB(gc, GC_malloc, found_boehm="yes",,$libdl)
 595
 596                 if test "x$found_boehm" != "xyes"; then
 597                         AC_MSG_ERROR("GC requested but libgc not found! Install libgc or run configure with --with-gc=none.")
 598                 fi
 599                 if test "x$gc_headers" != "xyes"; then
 600                         AC_MSG_ERROR("GC requested but header files not found! You may need to install them by hand.")
 601                 fi
 602
 603                 AC_DEFINE(HAVE_BOEHM_GC)
 604                 AC_SUBST(HAVE_BOEHM_GC)
 605                 LIBGC_LIBS="-lgc $libdl"
 606                 LIBGC_STATIC_LIBS="$LIBGC_LIBS"
 607
 608                 # AC_CHECK_FUNCS does not work for some reason...
 609                 AC_CHECK_LIB(gc, GC_gcj_malloc, found_gcj_malloc="yes",,$libdl)
 610                 if test "x$found_gcj_malloc" = "xyes"; then
 611                         AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 612                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (with typed GC)", [GC description])
 613                 else
 614                         AC_DEFINE_UNQUOTED(USED_GC_NAME, "System Boehm (no typed GC)", [GC description])
 615                 fi
 616                 AC_CHECK_LIB(gc, GC_enable, found_gc_enable="yes",,$libdl)
 617                 if test "x$found_gc_enable" = "xyes"; then
 618                         AC_DEFINE(HAVE_GC_ENABLE)
 619                 fi
 620                 ;;
 621
 622         xincluded)
 623                 AC_CONFIG_SUBDIRS(libgc)
 624
 625                 # Pass CPPFLAGS to libgc configure
 626                 # Maybe we should use a separate variable for this to avoid passing useless and
 627                 # potentially problematic defines to libgc (like -D_FILE_OFFSET_BITS=64)
 628                 export CPPFLAGS
 629
 630                 found_boehm=yes
 631                 gc_headers=yes
 632                 use_included_gc=yes
 633                 libgc_dir=libgc
 634
 635                 LIBGC_CFLAGS='-I$(top_srcdir)/libgc/include'
 636                 LIBGC_LIBS='$(top_builddir)/libgc/libmonogc.la'
 637                 LIBGC_STATIC_LIBS='$(top_builddir)/libgc/libmonogc-static.la'
 638
 639                 AC_DEFINE(HAVE_BOEHM_GC)
 640                 AC_SUBST(HAVE_BOEHM_GC)
 641
 642                 AC_DEFINE(HAVE_GC_H)
 643                 AC_DEFINE(USE_INCLUDED_LIBGC)
 644
 645                 # The included libgc contains GCJ support
 646                 AC_DEFINE(HAVE_GC_GCJ_MALLOC)
 647                 AC_DEFINE(HAVE_GC_ENABLE)
 648                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Included Boehm (with typed GC)", [GC description])
 649                 ;;
 650
 651         xsgen)
 652                 found_boehm=no
 653                 gc_headers=no
 654                 use_included_gc=no
 655                 AC_DEFINE(HAVE_SGEN_GC,1,[Using the simple generational GC.])
 656                 AC_DEFINE(HAVE_MOVING_COLLECTOR,1,[The GC can move objects.])
 657                 AC_DEFINE(HAVE_WRITE_BARRIERS,1,[The GC needs write barriers.])
 658                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "Simple generational", [GC description])
 659                 ;;
 660
 661         xnone)
 662                 AC_MSG_WARN("Compiling mono without GC.")
 663                 AC_DEFINE_UNQUOTED(USED_GC_NAME, "none", [GC description])
 664                 AC_DEFINE(HAVE_NULL_GC,1,[No GC support.])
 665                 ;;
 666         *)
 667                 AC_MSG_ERROR([Invalid argument to --with-gc.])
 668                 ;;
 669 esac
 670
 671 AC_ARG_WITH(large-heap, [  --with-large-heap=yes,no    Enable support for GC heaps larger than 3GB], [large_heap=$withval], [large_heap=no])
 672 if test "x$large_heap" = "xyes"; then
 673    echo "FOO"
 674    CPPFLAGS="$CPPFLAGS -DLARGE_CONFIG"
 675 fi
 676
 677 # tell libgc/configure about what we want
 678 ac_configure_args="$ac_configure_args --disable-embed-check --with-libgc-threads=$libgc_threads $libgc_configure_args"
 679
 680 AM_CONDITIONAL(INCLUDED_LIBGC, test x$use_included_gc = xyes)
 681 AC_SUBST(LIBGC_CFLAGS)
 682 AC_SUBST(LIBGC_LIBS)
 683 AC_SUBST(LIBGC_STATIC_LIBS)
 684 AC_SUBST(libgc_dir)
 685
 686 dnl
 687 dnl End of libgc checks
 688 dnl
 689
 690 if test x$platform_win32 = xno; then
 691
 692         dnl ******************************************************************
 693         dnl *** Checks for the IKVM JNI interface library                  ***
 694         dnl ******************************************************************
 695         AC_ARG_WITH(ikvm-native, [  --with-ikvm-native=yes,no  build the IKVM JNI interface library],[with_ikvm_native=$withval],[with_ikvm_native=yes])
 696
 697         ikvm_native_dir=
 698         if test x$with_ikvm_native = xyes; then
 699                 ikvm_native_dir=ikvm-native
 700                 jdk_headers_found="IKVM Native"
 701         fi
 702
 703         AC_SUBST(ikvm_native_dir)
 704
 705         AC_CHECK_HEADERS(execinfo.h)
 706
 707         AC_CHECK_FUNCS(getgrgid_r)
 708         AC_CHECK_FUNCS(getgrnam_r)
 709         AC_CHECK_FUNCS(getpwnam_r)
 710         AC_CHECK_FUNCS(getpwuid_r)
 711         AC_CHECK_FUNCS(getresuid)
 712         AC_CHECK_FUNCS(setresuid)
 713         AC_CHECK_FUNCS(kqueue)
 714         AC_CHECK_FUNCS(backtrace_symbols)
 715
 716         dnl ******************************************************************
 717         dnl *** Check for large file support                               ***
 718         dnl *** (If we were using autoconf 2.50 we'd use AC_SYS_LARGEFILE) ***
 719         dnl ******************************************************************
 720
 721         # Check that off_t can represent 2**63 - 1 correctly, working around
 722         # potential compiler bugs.  Defines LARGE_FILE_SUPPORT, adds $1 to
 723         # CPPFLAGS and sets $large_offt to yes if the test succeeds
 724         large_offt=no
 725         AC_DEFUN([LARGE_FILES], [
 726                 large_CPPFLAGS=$CPPFLAGS
 727                 CPPFLAGS="$CPPFLAGS $1"
 728                 AC_TRY_RUN([
 729                         #include <sys/types.h>
 730
 731                         #define BIG_OFF_T (((off_t)1<<62)-1+((off_t)1<<62))
 732
 733                         int main(void) {
 734                                 int big_off_t=((BIG_OFF_T%2147483629==721) &&
 735                                                (BIG_OFF_T%2147483647==1));
 736                                 if(big_off_t) {
 737                                         exit(0);
 738                                 } else {
 739                                         exit(1);
 740                                 }
 741                         }
 742                 ], [
 743                         AC_MSG_RESULT(ok)
 744                         AC_DEFINE(HAVE_LARGE_FILE_SUPPORT)
 745                         large_CPPFLAGS="$large_CPPFLAGS $1"
 746                         large_offt=yes
 747                 ], [
 748                         AC_MSG_RESULT(no)
 749                 ], "")
 750                 CPPFLAGS=$large_CPPFLAGS
 751         ])
 752
 753         AC_MSG_CHECKING(if off_t is 64 bits wide)
 754         LARGE_FILES("")
 755         if test $large_offt = no; then
 756                 AC_MSG_CHECKING(if _FILE_OFFSET_BITS=64 gives 64 bit off_t)
 757                 LARGE_FILES("-D_FILE_OFFSET_BITS=64")
 758         fi
 759         if test $large_offt = no; then
 760                 AC_MSG_WARN([No 64 bit file size support available])
 761         fi
 762
 763         dnl *****************************
 764         dnl *** Checks for libsocket  ***
 765         dnl *****************************
 766         AC_CHECK_LIB(socket, socket, LIBS="$LIBS -lsocket")
 767
 768         dnl *******************************
 769         dnl *** Checks for MSG_NOSIGNAL ***
 770         dnl *******************************
 771         AC_MSG_CHECKING(for MSG_NOSIGNAL)
 772         AC_TRY_COMPILE([#include <sys/socket.h>], [
 773                 int f = MSG_NOSIGNAL;
 774         ], [
 775                 # Yes, we have it...
 776                 AC_MSG_RESULT(yes)
 777                 AC_DEFINE(HAVE_MSG_NOSIGNAL)
 778         ], [
 779                 # We'll have to use signals
 780                 AC_MSG_RESULT(no)
 781         ])
 782
 783         dnl *****************************
 784         dnl *** Checks for SOL_IP     ***
 785         dnl *****************************
 786         AC_MSG_CHECKING(for SOL_IP)
 787         AC_TRY_COMPILE([#include <netdb.h>], [
 788                 int level = SOL_IP;
 789         ], [
 790                 # Yes, we have it...
 791                 AC_MSG_RESULT(yes)
 792                 AC_DEFINE(HAVE_SOL_IP)
 793         ], [
 794                 # We'll have to use getprotobyname
 795                 AC_MSG_RESULT(no)
 796         ])
 797
 798         dnl *****************************
 799         dnl *** Checks for SOL_IPV6     ***
 800         dnl *****************************
 801         AC_MSG_CHECKING(for SOL_IPV6)
 802         AC_TRY_COMPILE([#include <netdb.h>], [
 803                 int level = SOL_IPV6;
 804         ], [
 805                 # Yes, we have it...
 806                 AC_MSG_RESULT(yes)
 807                 AC_DEFINE(HAVE_SOL_IPV6)
 808         ], [
 809                 # We'll have to use getprotobyname
 810                 AC_MSG_RESULT(no)
 811         ])
 812
 813         dnl *****************************
 814         dnl *** Checks for SOL_TCP    ***
 815         dnl *****************************
 816         AC_MSG_CHECKING(for SOL_TCP)
 817         AC_TRY_COMPILE([#include <netdb.h>], [
 818                 int level = SOL_TCP;
 819         ], [
 820                 # Yes, we have it...
 821                 AC_MSG_RESULT(yes)
 822                 AC_DEFINE(HAVE_SOL_TCP)
 823         ], [
 824                 # We'll have to use getprotobyname
 825                 AC_MSG_RESULT(no)
 826         ])
 827
 828         dnl *****************************
 829         dnl *** Checks for IP_PKTINFO ***
 830         dnl *****************************
 831         AC_MSG_CHECKING(for IP_PKTINFO)
 832         AC_TRY_COMPILE([#include <netdb.h>], [
 833                 int level = IP_PKTINFO;
 834         ], [
 835                 # Yes, we have it...
 836                 AC_MSG_RESULT(yes)
 837                 AC_DEFINE(HAVE_IP_PKTINFO)
 838         ], [
 839                 AC_MSG_RESULT(no)
 840         ])
 841
 842         dnl *****************************
 843     dnl *** Checks for IPV6_PKTINFO ***
 844     dnl *****************************
 845     AC_MSG_CHECKING(for IPV6_PKTINFO)
 846     AC_TRY_COMPILE([#include <netdb.h>], [
 847         int level = IPV6_PKTINFO;
 848     ], [
 849         # Yes, we have it...
 850         AC_MSG_RESULT(yes)
 851         AC_DEFINE(HAVE_IPV6_PKTINFO)
 852     ], [
 853         AC_MSG_RESULT(no)
 854     ])
 855
 856         dnl *********************************
 857         dnl *** Check for struct ip_mreqn ***
 858         dnl *********************************
 859         AC_MSG_CHECKING(for struct ip_mreqn)
 860         AC_TRY_COMPILE([#include <netinet/in.h>], [
 861                 struct ip_mreqn mreq;
 862                 mreq.imr_address.s_addr = 0;
 863         ], [
 864                 # Yes, we have it...
 865                 AC_MSG_RESULT(yes)
 866                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
 867         ], [
 868                 # We'll just have to try and use struct ip_mreq
 869                 AC_MSG_RESULT(no)
 870                 AC_MSG_CHECKING(for struct ip_mreq)
 871                 AC_TRY_COMPILE([#include <netinet/in.h>], [
 872                         struct ip_mreq mreq;
 873                         mreq.imr_interface.s_addr = 0;
 874                 ], [
 875                         # Yes, we have it...
 876                         AC_MSG_RESULT(yes)
 877                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 878                 ], [
 879                         # No multicast support
 880                         AC_MSG_RESULT(no)
 881                 ])
 882         ])
 883
 884         dnl **********************************
 885         dnl *** Check for gethostbyname2_r ***
 886         dnl **********************************
 887         AC_MSG_CHECKING(for gethostbyname2_r)
 888                 AC_TRY_LINK([#include <netdb.h>], [
 889                 gethostbyname2_r(NULL,0,NULL,NULL,0,NULL,NULL);
 890         ], [
 891                 # Yes, we have it...
 892                 AC_MSG_RESULT(yes)
 893                 AC_DEFINE(HAVE_GETHOSTBYNAME2_R)
 894         ], [
 895                 AC_MSG_RESULT(no)
 896         ])
 897
 898         dnl *****************************
 899         dnl *** Checks for libnsl     ***
 900         dnl *****************************
 901         AC_CHECK_LIB(nsl, gethostbyaddr, LIBS="$LIBS -lnsl")
 902
 903         AC_CHECK_FUNCS(inet_pton inet_aton)
 904
 905         dnl ***********************************************
 906         dnl *** Checks for size of sockaddr_un.sun_path ***
 907         dnl ***********************************************
 908         # AC_CHECK_SIZEOF can't cope with struct members :-(
 909         AC_MSG_CHECKING(size of sockaddr_un.sun_path)
 910         AC_CACHE_VAL(cv_mono_sizeof_sunpath,
 911                 [AC_TRY_RUN([
 912                         #include <sys/types.h>
 913                         #include <stdio.h>
 914                         #include <sys/un.h>
 915
 916                         int main(void) {
 917                                 struct sockaddr_un sock_un;
 918                                 FILE *f=fopen("conftestval", "w");
 919                                 if(!f) exit(1);
 920                                 fprintf(f, "%d\n", sizeof(sock_un.sun_path));
 921                                 exit(0);
 922                         }
 923                 ], cv_mono_sizeof_sunpath=`cat conftestval`,
 924                    cv_mono_sizeof_sunpath=0,
 925                    cv_mono_sizeof_sunpath=0)])dnl
 926         AC_MSG_RESULT($cv_mono_sizeof_sunpath)
 927         AC_DEFINE_UNQUOTED(MONO_SIZEOF_SUNPATH, $cv_mono_sizeof_sunpath)
 928
 929         dnl *************************************
 930         dnl *** Checks for zero length arrays ***
 931         dnl *************************************
 932         AC_MSG_CHECKING(whether $CC supports zero length arrays)
 933         AC_TRY_COMPILE([
 934                 struct s {
 935                         int  length;
 936                         char data [0];
 937                 };
 938         ], [], [
 939                 AC_MSG_RESULT(yes)
 940                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 0)
 941         ], [
 942                 AC_MSG_RESULT(no)
 943                 AC_DEFINE_UNQUOTED(MONO_ZERO_ARRAY_LENGTH, 1)
 944         ])
 945
 946         dnl *****************************
 947         dnl *** Checks for libxnet    ***
 948         dnl *****************************
 949         case "${host}" in
 950                 *solaris* )
 951                         AC_MSG_CHECKING(for Solaris XPG4 support)
 952                         if test -f /usr/lib/libxnet.so; then
 953                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=500"
 954                                 CPPFLAGS="$CPPFLAGS -D__EXTENSIONS__"
 955                                 CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE_EXTENDED=1"
 956                                 LIBS="$LIBS -lxnet"
 957                                 AC_MSG_RESULT(yes)
 958                         else
 959                                 AC_MSG_RESULT(no)
 960                         fi
 961
 962                         if test "$GCC" = "yes"; then
 963                                 CFLAGS="$CFLAGS -Wno-char-subscripts"
 964                         fi
 965                 ;;
 966         esac
 967
 968         dnl *****************************
 969         dnl *** Checks for libpthread ***
 970         dnl *****************************
 971 # on FreeBSD -STABLE, the pthreads functions all reside in libc_r
 972 # and libpthread does not exist
 973 #
 974         case "${host}" in
 975                 *-*-*freebsd4*)
 976                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 977                 ;;
 978                 *-*-*freebsd5*)
 979                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 980                 ;;
 981                 *-*-*freebsd6*)
 982                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -pthread")
 983                 ;;
 984                 *)
 985                         AC_CHECK_LIB(pthread, main, LIBS="$LIBS -lpthread")
 986                 ;;
 987         esac
 988         AC_CHECK_HEADERS(pthread.h)
 989         AC_CHECK_FUNCS(pthread_mutex_timedlock)
 990         AC_CHECK_FUNCS(pthread_getattr_np pthread_attr_get_np)
 991         AC_MSG_CHECKING(for PTHREAD_MUTEX_RECURSIVE)
 992         AC_TRY_COMPILE([ #include <pthread.h>], [
 993                 pthread_mutexattr_t attr;
 994                 pthread_mutexattr_settype(&attr, PTHREAD_MUTEX_RECURSIVE);
 995         ], [
 996                 AC_MSG_RESULT(ok)
 997         ], [
 998                 AC_MSG_RESULT(no)
 999                 AC_MSG_WARN(Using mono_mutex_t for recursive mutexes)
1000                 AC_DEFINE(USE_MONO_MUTEX)
1001         ])
1002         AC_CHECK_FUNCS(pthread_attr_setstacksize)
1003         AC_CHECK_FUNCS(pthread_attr_getstack)
1004         AC_CHECK_FUNCS(pthread_get_stacksize_np pthread_get_stackaddr_np)
1005
1006         dnl ***********************************
1007         dnl *** Checks for working __thread ***
1008         dnl ***********************************
1009         AC_MSG_CHECKING(for working __thread)
1010         if test "x$with_tls" != "x__thread"; then
1011                 AC_MSG_RESULT(disabled)
1012         else
1013                 AC_TRY_RUN([
1014                         #include <pthread.h>
1015                         __thread int i;
1016                         static int res1, res2;
1017
1018                         void thread_main (void *arg)
1019                         {
1020                                 i = arg;
1021                                 sleep (1);
1022                                 if (arg == 1)
1023                                         res1 = (i == arg);
1024                                 else
1025                                         res2 = (i == arg);
1026                         }
1027
1028                         int main () {
1029                                 pthread_t t1, t2;
1030
1031                                 i = 5;
1032
1033                                 pthread_create (&t1, NULL, thread_main, 1);
1034                                 pthread_create (&t2, NULL, thread_main, 2);
1035
1036                                 pthread_join (t1, NULL);
1037                                 pthread_join (t2, NULL);
1038
1039                                 return !(res1 + res2 == 2);
1040                         }
1041                 ], [
1042                                 AC_MSG_RESULT(yes)
1043                 ], [
1044                                 AC_MSG_RESULT(no)
1045                                 with_tls=pthread
1046                 ])
1047         fi
1048
1049         dnl **************************************
1050         dnl *** Checks for working sigaltstack ***
1051         dnl **************************************
1052         AC_MSG_CHECKING(for working sigaltstack)
1053         if test "x$with_sigaltstack" != "xyes"; then
1054                 AC_MSG_RESULT(disabled)
1055         else
1056                 AC_TRY_RUN([
1057                         #include <stdio.h>
1058                         #include <stdlib.h>
1059                         #include <unistd.h>
1060                         #include <signal.h>
1061                         #include <pthread.h>
1062                         #include <sys/wait.h>
1063                         #if defined(__FreeBSD__) || defined(__NetBSD__)
1064                         #define SA_STACK SA_ONSTACK
1065                         #endif
1066                         static void
1067                         sigsegv_signal_handler (int _dummy, siginfo_t *info, void *context)
1068                         {
1069                                 exit (0);
1070                         }
1071
1072                         static void *
1073                         loop (void *ignored)
1074                         {
1075                                 char *ptr = NULL;
1076
1077                                 *ptr = 0;
1078                                 return NULL;
1079                         }
1080
1081                         static void
1082                         child ()
1083                         {
1084                                 struct sigaction sa;
1085                                 struct sigaltstack sas;
1086                                 pthread_t id;
1087                                 pthread_attr_t attr;
1088
1089                                 sa.sa_sigaction = sigsegv_signal_handler;
1090                                 sigemptyset (&sa.sa_mask);
1091                                 sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
1092                                 if (sigaction (SIGSEGV, &sa, NULL) == -1) {
1093                                         perror ("sigaction");
1094                                         return;
1095                                 }
1096
1097                                 sas.ss_sp = malloc (SIGSTKSZ);
1098                                 sas.ss_size = SIGSTKSZ;
1099                                 sas.ss_flags = 0;
1100                                 if (sigaltstack (&sas, NULL) == -1) {
1101                                         perror ("sigaltstack");
1102                                         return;
1103                                 }
1104
1105                                 pthread_attr_init (&attr);
1106                                 if (pthread_create(&id, &attr, loop, &attr) != 0) {
1107                                         printf ("pthread_create\n");
1108                                         return;
1109                                 }
1110
1111                                 sleep (100);
1112                         }
1113
1114                         int
1115                         main ()
1116                         {
1117                                 pid_t son;
1118                                 int status;
1119                                 int i;
1120
1121                                 son = fork ();
1122                                 if (son == -1) {
1123                                         return 1;
1124                                 }
1125
1126                                 if (son == 0) {
1127                                         child ();
1128                                         return 0;
1129                                 }
1130
1131                                 for (i = 0; i < 3; ++i) {
1132                                         sleep (1);
1133                                         waitpid (son, &status, WNOHANG);
1134                                         if (WIFEXITED (status) && WEXITSTATUS (status) == 0)
1135                                                 return 0;
1136                                 }
1137
1138                                 kill (son, SIGKILL);
1139                                 return 1;
1140                         }
1141
1142                 ], [
1143                                 AC_MSG_RESULT(yes)
1144                                 AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
1145                 ], [
1146                                 with_sigaltstack=no
1147                                 AC_MSG_RESULT(no)
1148                 ])
1149         fi
1150
1151         dnl ********************************
1152         dnl *** Checks for semaphore lib ***
1153         dnl ********************************
1154         # 'Real Time' functions on Solaris
1155         # posix4 on Solaris 2.6
1156         # pthread (first!) on Linux
1157         AC_SEARCH_LIBS(sem_init, pthread rt posix4)
1158
1159         dnl ********************************
1160         dnl *** Checks for timezone stuff **
1161         dnl ********************************
1162         AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,
1163                 AC_TRY_COMPILE([
1164                         #include <time.h>
1165                         ], [
1166                         struct tm tm;
1167                         tm.tm_gmtoff = 1;
1168                         ], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
1169         if test $ac_cv_struct_tm_gmtoff = yes; then
1170                 AC_DEFINE(HAVE_TM_GMTOFF)
1171         else
1172                 AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
1173                         AC_TRY_COMPILE([
1174                                 #include <time.h>
1175                         ], [
1176                                 timezone = 1;
1177                         ], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
1178                 if test $ac_cv_var_timezone = yes; then
1179                         AC_DEFINE(HAVE_TIMEZONE)
1180                 else
1181                         AC_ERROR(unable to find a way to determine timezone)
1182                 fi
1183         fi
1184
1185         dnl *********************************
1186         dnl *** Checks for math functions ***
1187         dnl *********************************
1188         LIBS="$LIBS -lm";
1189         AC_CHECK_FUNCS(finite, , AC_MSG_CHECKING(for finite in math.h)
1190                 AC_TRY_LINK([#include <math.h>],
1191                 [ finite(0.0); ],
1192                 AC_DEFINE(HAVE_FINITE) AC_MSG_RESULT(yes),
1193                 AC_MSG_RESULT(no)))
1194         AC_CHECK_FUNCS(isfinite, , AC_MSG_CHECKING(for isfinite in math.h)
1195                 AC_TRY_LINK([#include <math.h>],
1196                 [ isfinite(0.0); ],
1197                 AC_DEFINE(HAVE_ISFINITE) AC_MSG_RESULT(yes),
1198                 AC_MSG_RESULT(no)))
1199
1200         dnl ****************************************************************
1201         dnl *** Checks for working poll() (macosx defines it but doesn't ***
1202         dnl *** have it in the library (duh))                            ***
1203         dnl ****************************************************************
1204         AC_CHECK_FUNCS(poll)
1205
1206         dnl *************************
1207         dnl *** Check for signbit ***
1208         dnl *************************
1209         AC_MSG_CHECKING(for signbit)
1210         AC_TRY_LINK([#include <math.h>], [
1211                 int s = signbit(1.0);
1212         ], [
1213                 AC_MSG_RESULT(yes)
1214                 AC_DEFINE(HAVE_SIGNBIT)
1215         ], [
1216                 AC_MSG_RESULT(no)
1217         ])
1218
1219         dnl **********************************
1220         dnl *** epoll                      ***
1221         dnl **********************************
1222         AC_CHECK_HEADERS(sys/epoll.h)
1223         haveepoll=no
1224         AC_CHECK_FUNCS(epoll_ctl, [haveepoll=yes], )
1225         if test "x$haveepoll" = "xyes" -a "x$ac_cv_header_sys_epoll_h" = "xyes" ; then
1226                 AC_DEFINE(HAVE_EPOLL, 1, [epoll supported])
1227         fi
1228
1229         dnl ******************************
1230         dnl *** Checks for SIOCGIFCONF ***
1231         dnl ******************************
1232         AC_CHECK_HEADERS(sys/ioctl.h)
1233         AC_CHECK_HEADERS(net/if.h)
1234         AC_MSG_CHECKING(for ifreq)
1235         AC_TRY_COMPILE([
1236                 #include <sys/ioctl.h>
1237                 #include <net/if.h>
1238                 ], [
1239                 struct ifconf ifc;
1240                 struct ifreq *ifr;
1241                 void *x;
1242                 ifc.ifc_len = 0;
1243                 ifc.ifc_buf = NULL;
1244                 x = (void *) &ifr->ifr_addr;
1245                 ],[
1246                         AC_MSG_RESULT(yes)
1247                         AC_DEFINE(HAVE_SIOCGIFCONF, 1, [Can get interface list])
1248                 ], [
1249                         AC_MSG_RESULT(no)
1250                 ])
1251         dnl **********************************
1252         dnl *** Checks for MonoPosixHelper ***
1253         dnl **********************************
1254         AC_CHECK_FUNC(setkey, ,
1255                 AC_CHECK_LIB(crypt, setkey, [
1256                         AC_DEFINE(HAVE_SETKEY, 1, [Define if setkey(3) is available])
1257                         CRYPT_LIBS="-lcrypt"
1258                 ])
1259         )
1260         AC_SUBST(CRYPT_LIBS)
1261         AC_CHECK_HEADERS(checklist.h)
1262         AC_CHECK_HEADERS(fstab.h)
1263         AC_CHECK_HEADERS(attr/xattr.h)
1264         AC_CHECK_HEADERS(sys/extattr.h)
1265         AC_CHECK_HEADERS(sys/sendfile.h)
1266         AC_CHECK_HEADERS(sys/statvfs.h)
1267         AC_CHECK_HEADERS(sys/vfstab.h)
1268         AC_CHECK_HEADERS(sys/xattr.h)
1269         AC_CHECK_HEADERS(sys/mman.h)
1270         AC_CHECK_FUNCS(getdomainname)
1271         AC_CHECK_FUNCS(setdomainname)
1272         AC_CHECK_FUNCS(fgetgrent)
1273         AC_CHECK_FUNCS(fgetpwent)
1274         AC_CHECK_FUNCS(fgetpwent)
1275         AC_CHECK_FUNCS(getfsstat)
1276         AC_CHECK_FUNCS(lutimes)
1277         AC_CHECK_FUNCS(mremap)
1278         AC_CHECK_FUNCS(remap_file_pages)
1279         AC_CHECK_FUNCS(posix_fadvise)
1280         AC_CHECK_FUNCS(posix_fallocate)
1281         AC_CHECK_FUNCS(posix_madvise)
1282         AC_CHECK_FUNCS(vsnprintf)
1283         AC_CHECK_FUNCS(sendfile)
1284         AC_CHECK_FUNCS(sethostid)
1285         AC_CHECK_FUNCS(statfs)
1286         AC_CHECK_FUNCS(fstatfs)
1287         AC_CHECK_FUNCS(statvfs)
1288         AC_CHECK_FUNCS(fstatvfs)
1289         AC_CHECK_FUNCS(stime)
1290         AC_CHECK_FUNCS(strerror_r)
1291         AC_CHECK_FUNCS(ttyname_r)
1292         AC_CHECK_SIZEOF(size_t)
1293         AC_CHECK_MEMBERS(
1294                 [struct dirent.d_off, struct dirent.d_reclen, struct dirent.d_type],,,
1295                 [#include <sys/types.h>
1296                  #include <dirent.h>])
1297
1298         dnl Favour xattr through glibc, but use libattr if we have to
1299         AC_CHECK_FUNC(lsetxattr, ,
1300                 AC_CHECK_LIB(attr, lsetxattr, XATTR_LIB="-lattr",)
1301         )
1302         AC_SUBST(XATTR_LIB)
1303
1304         dnl *********************************
1305         dnl *** Check for Console 2.0 I/O ***
1306         dnl *********************************
1307         AC_CHECK_HEADERS([curses.h])
1308         AC_CHECK_HEADERS([term.h], [], [],
1309         [#if HAVE_CURSES_H
1310          #include <curses.h>
1311          #endif
1312         ])
1313         AC_CHECK_HEADERS([termios.h])
1314
1315         dnl * This is provided in io-layer, but on windows it's only available
1316         dnl * on xp+
1317         AC_DEFINE(HAVE_GETPROCESSID, 1, [Define if GetProcessId is available])
1318 else
1319         jdk_headers_found=no
1320         AC_CHECK_LIB(ws2_32, main, LIBS="$LIBS -lws2_32", AC_ERROR(bad mingw install?))
1321         AC_CHECK_LIB(psapi, main, LIBS="$LIBS -lpsapi", AC_ERROR(bad mingw install?))
1322         AC_CHECK_LIB(ole32, main, LIBS="$LIBS -lole32", AC_ERROR(bad mingw install?))
1323         AC_CHECK_LIB(oleaut32, main, LIBS="$LIBS -loleaut32", AC_ERROR(bad mingw install?))
1324
1325         dnl *********************************
1326         dnl *** Check for struct ip_mreqn ***
1327         dnl *********************************
1328         AC_MSG_CHECKING(for struct ip_mreqn)
1329         AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1330                 struct ip_mreqn mreq;
1331                 mreq.imr_address.s_addr = 0;
1332         ], [
1333                 # Yes, we have it...
1334                 AC_MSG_RESULT(yes)
1335                 AC_DEFINE(HAVE_STRUCT_IP_MREQN)
1336         ], [
1337                 # We'll just have to try and use struct ip_mreq
1338                 AC_MSG_RESULT(no)
1339                 AC_MSG_CHECKING(for struct ip_mreq)
1340                 AC_TRY_COMPILE([#include <ws2tcpip.h>], [
1341                         struct ip_mreq mreq;
1342                         mreq.imr_interface.s_addr = 0;
1343                 ], [
1344                         # Yes, we have it...
1345                         AC_MSG_RESULT(yes)
1346                         AC_DEFINE(HAVE_STRUCT_IP_MREQ)
1347                 ], [
1348                         # No multicast support
1349                         AC_MSG_RESULT(no)
1350                 ])
1351         ])
1352         AC_CHECK_FUNCS(GetProcessId)
1353 fi
1354
1355 dnl socklen_t check
1356 AC_MSG_CHECKING(for socklen_t)
1357 AC_TRY_COMPILE([
1358 #include <sys/types.h>
1359 #include <sys/socket.h>
1360 ],[
1361   socklen_t foo;
1362 ],[
1363 ac_cv_c_socklen_t=yes
1364         AC_DEFINE(HAVE_SOCKLEN_T)
1365         AC_MSG_RESULT(yes)
1366 ],[
1367         AC_MSG_RESULT(no)
1368 ])
1369
1370 AC_MSG_CHECKING(for array element initalizer support)
1371 AC_TRY_COMPILE([#include <sys/socket.h>], [
1372         const int array[] = {[1] = 2,};
1373 ], [
1374         # Yes, we have it...
1375         AC_MSG_RESULT(yes)
1376         AC_DEFINE(HAVE_ARRAY_ELEM_INIT,1,[Supports C99 array initialization])
1377 ], [
1378         # We'll have to use signals
1379         AC_MSG_RESULT(no)
1380 ])
1381
1382 AC_CHECK_FUNCS(trunc, , AC_MSG_CHECKING(for trunc in math.h)
1383         # Simply calling trunc (0.0) is no good since gcc will optimize the call away
1384         AC_TRY_LINK([#include <math.h>],
1385         [ static void *p = &trunc; ],
1386         [
1387                 AC_DEFINE(HAVE_TRUNC)
1388                 AC_MSG_RESULT(yes)
1389                 ac_cv_trunc=yes
1390         ],
1391         AC_MSG_RESULT(no)))
1392
1393 if test "x$ac_cv_truncl" != "xyes"; then
1394    AC_CHECK_LIB(sunmath, aintl, [ AC_DEFINE(HAVE_AINTL) LIBS="$LIBS -lsunmath"])
1395 fi
1396
1397 dnl ****************************
1398 dnl *** Look for /dev/random ***
1399 dnl ****************************
1400
1401 AC_MSG_CHECKING([if usage of random device is requested])
1402 AC_ARG_ENABLE(dev-random,
1403 [  --disable-dev-random    disable the use of the random device],
1404 try_dev_random=$enableval, try_dev_random=yes)
1405 AC_MSG_RESULT($try_dev_random)
1406
1407 case "{$target}" in
1408     *-openbsd*)
1409     NAME_DEV_RANDOM="/dev/srandom"
1410     ;;
1411
1412 dnl Win32 does not have /dev/random, they have their own method...
1413
1414     *-*-mingw*|*-*-cygwin*)
1415     ac_cv_have_dev_random=no
1416     ;;
1417
1418 dnl Everywhere else, it's /dev/random
1419
1420     *)
1421     NAME_DEV_RANDOM="/dev/random"
1422     ;;
1423 esac
1424
1425 AC_DEFINE_UNQUOTED(NAME_DEV_RANDOM, "$NAME_DEV_RANDOM")
1426
1427 dnl Now check if the device actually exists
1428
1429 if test "x$try_dev_random" = "xyes"; then
1430     AC_CACHE_CHECK(for random device, ac_cv_have_dev_random,
1431     [if test -r "$NAME_DEV_RANDOM" ; then
1432         ac_cv_have_dev_random=yes; else ac_cv_have_dev_random=no; fi])
1433     if test "x$ac_cv_have_dev_random" = "xyes"; then
1434         AC_DEFINE(HAVE_CRYPT_RNG)
1435     fi
1436 else
1437     AC_MSG_CHECKING(for random device)
1438     ac_cv_have_dev_random=no
1439     AC_MSG_RESULT(has been disabled)
1440 fi
1441
1442 if test "x$platform_win32" = "xyes"; then
1443     AC_DEFINE(HAVE_CRYPT_RNG)
1444 fi
1445
1446 if test "x$ac_cv_have_dev_random" = "xno" \
1447     && test "x$platform_win32" = "xno"; then
1448     AC_MSG_WARN([[
1449 ***
1450 *** A system-provided entropy source was not found on this system.
1451 *** Because of this, the System.Security.Cryptography random number generator
1452 *** will throw a NotImplemented exception.
1453 ***
1454 *** If you are seeing this message, and you know your system DOES have an
1455 *** entropy collection in place, please contact <crichton@gimp.org> and
1456 *** provide information about the system and how to access the random device.
1457 ***
1458 *** Otherwise you can install either egd or prngd and set the environment
1459 *** variable MONO_EGD_SOCKET to point to the daemon's socket to use that.
1460 ***]])
1461 fi
1462
1463 AC_MSG_CHECKING([if inter-process shared handles are requested])
1464 AC_ARG_ENABLE(shared-handles, [  --disable-shared-handles disable inter-process shared handles], try_shared_handles=$enableval, try_shared_handles=yes)
1465 AC_MSG_RESULT($try_shared_handles)
1466 if test "x$try_shared_handles" != "xyes"; then
1467         AC_DEFINE(DISABLE_SHARED_HANDLES)
1468         AC_SUBST(DISABLE_SHARED_HANDLES)
1469 fi
1470
1471 AC_ARG_ENABLE(nunit-tests, [ --enable-nunit-tests       Run the nunit tests of the class library on 'make check'])
1472 AM_CONDITIONAL(ENABLE_NUNIT_TESTS, [test x$enable_nunit_tests = xyes])
1473
1474 TARGET="unknown"
1475 ACCESS_UNALIGNED="yes"
1476
1477 JIT_SUPPORTED=no
1478 INTERP_SUPPORTED=no
1479 LIBC="libc.so.6"
1480 INTL="libc.so.6"
1481 SQLITE="libsqlite.so.0"
1482 SQLITE3="libsqlite3.so.0"
1483 X11="libX11.so"
1484
1485 jit_wanted=false
1486 interp_wanted=false
1487 case "$host" in
1488 #       mips-sgi-irix5.* | mips-sgi-irix6.*)
1489 #               TARGET=MIPS;
1490 #               ACCESS_UNALIGNED="no"
1491 #               ;;
1492         i*86-*-*)
1493                 TARGET=X86;
1494                 arch_target=x86;
1495                 JIT_SUPPORTED=yes
1496                 jit_wanted=true
1497                 case $host_os in
1498                   solaris*)
1499                         LIBC="libc.so"
1500                         INTL="libintl.so"
1501
1502                         # On solaris 10 x86, gcc prints a warning saying 'visibility attribute not supported on this configuration; ignored', but linking fails. A test case:
1503                         # int astruct __attribute__ ((visibility ("hidden")));
1504                         # void foo ()
1505                         # {
1506                         #       void *p = &astruct;
1507                         # }
1508                         # gcc -fPIC --shared -o libfoo.so foo.c
1509                         # yields:
1510                         # foo.c:6: warning: visibility attribute not supported in this configuration; ignored
1511                         # ld: fatal: relocation error: R_386_GOTOFF: file /var/tmp//ccxYR96k.o: symbol astruct: relocation must bind locally
1512                         have_visibility_hidden=no
1513
1514                         libmono_ldflags="$libmono_ldflags $LIBS"
1515                 esac
1516                 ;;
1517         x86_64-*-* | amd64-*-*)
1518                 TARGET=AMD64;
1519                 arch_target=amd64;
1520                 JIT_SUPPORTED=yes
1521                 jit_wanted=true
1522                 ;;
1523         ia64-*-*)
1524                 TARGET=IA64
1525                 arch_target=ia64
1526                 ACCESS_UNALIGNED="no"
1527                 JIT_SUPPORTED=yes
1528                 jit_wanted=true
1529                 LIBC="libc.so.6.1"
1530                 INTL="libc.so.6.1"
1531                 AC_CHECK_LIB(unwind, _U_dyn_register, [], [AC_MSG_ERROR(library libunwind not found)])
1532                 libmono_ldflags="-lunwind"
1533                 ;;
1534         sparc*-*-*)
1535                 if test "x$ac_cv_sizeof_void_p" = "x8"; then
1536                    TARGET=SPARC64
1537                 else
1538                         TARGET=SPARC
1539                 fi
1540                 arch_target=sparc;
1541                 JIT_SUPPORTED=yes
1542                 ACCESS_UNALIGNED="no"
1543                 case $host_os in
1544                   linux*) ;;
1545                   *)
1546                         LIBC="libc.so"
1547                         INTL="libintl.so"
1548                         libmono_ldflags="$libmono_ldflags $LIBS"
1549                 esac
1550                 jit_wanted=true
1551                 if test x"$GCC" = xyes; then
1552                         # We don't support v8 cpus
1553                         CFLAGS="$CFLAGS -Wno-cast-align -mcpu=v9"
1554                 fi
1555                 if test x"$AR" = xfalse; then
1556                         AC_MSG_ERROR([The required utility 'ar' is not found in your PATH. Usually it can be found in /usr/ccs/bin.])
1557                 fi
1558                 ;;
1559        alpha*-*-linux* | alpha*-*-osf*)
1560                 TARGET=ALPHA;
1561                 ACCESS_UNALIGNED="no"
1562                 JIT_SUPPORTED=yes
1563                 jit_wanted=true
1564                 arch_target=alpha;
1565                 case $host_os in
1566                   linux*)
1567                         LIBC="libc.so.6.1"
1568                         INTL="libc.so.6.1"
1569                 esac
1570                ;;
1571         *-*-mingw*|*-*-cygwin*)
1572                 INTL="intl"
1573                 ;;
1574         hppa2.0w-hp-hpux11.00 | hppa64-hp-hpux11.00)
1575                 TARGET=HPPA;
1576                 arch_target=hppa;
1577                 LIBC="libc.sl"
1578                 ACCESS_UNALIGNED="no"
1579                 INTERP_SUPPORTED=yes
1580                 interp_wanted=true
1581                 ;;
1582         hppa*linux*)
1583                 TARGET=HPPA;
1584                 arch_target=hppa;
1585                 ACCESS_UNALIGNED="no"
1586                 INTERP_SUPPORTED=yes
1587                 interp_wanted=true
1588                 ;;
1589         macppc-*-openbsd* | powerpc-*-linux* | powerpc-*-openbsd* | \
1590         powerpc-*-sysv* | powerpc-*-darwin*)
1591                 TARGET=POWERPC;
1592                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1593                 arch_target=ppc;
1594                 JIT_SUPPORTED=yes
1595                 jit_wanted=true
1596                 ;;
1597         arm*-linux*)
1598                 TARGET=ARM;
1599                 arch_target=arm;
1600                 ACCESS_UNALIGNED="no"
1601                 JIT_SUPPORTED=yes
1602                 jit_wanted=true
1603                 ;;
1604         s390-*-linux*)
1605                 TARGET=S390;
1606                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1607                 arch_target=s390;
1608                 ACCESS_UNALIGNED="no"
1609                 JIT_SUPPORTED=yes
1610                 jit_wanted=true
1611                 ;;
1612         s390x-*-linux*)
1613                 TARGET=S390x;
1614                 AC_DEFINE(MONO_ARCH_REGPARMS,1,[Architecture uses registers for Parameters])
1615                 arch_target=s390x;
1616                 ACCESS_UNALIGNED="no"
1617                 JIT_SUPPORTED=yes
1618                 jit_wanted=true
1619                 ;;
1620 esac
1621
1622 if test "x$have_visibility_hidden" = "xyes"; then
1623    AC_DEFINE(HAVE_VISIBILITY_HIDDEN, 1, [Support for the visibility ("hidden") attribute])
1624 fi
1625
1626 AC_ARG_WITH(jit, [  --with-jit=yes,no       If you want to build scripts that default to the JIT],[
1627         if test x$withval = xyes; then
1628            jit_wanted=true
1629         else
1630            jit_wanted=false
1631         fi
1632 ])
1633
1634 AC_ARG_WITH(interp, [  --with-interp=yes,no    If you want to build scripts that default to the interpreter],[
1635         if test x$withval = xyes; then
1636            interp_wanted=true
1637         else
1638            interp_wanted=false
1639         fi
1640 ])
1641
1642 USEJIT=false
1643 if test x$JIT_SUPPORTED = xyes; then
1644    if $jit_wanted; then
1645       USEJIT=true
1646       jit_status="Building and using the JIT"
1647    else
1648       if $interp_wanted; then
1649          jit_status="Building the JIT, defaulting to the interpreter"
1650       else
1651          AC_ERROR(No JIT or interpreter support available or selected.)
1652       fi
1653    fi
1654 else
1655    if test x$interp_wanted = xtrue; then
1656       jit_status="interpreter"
1657    else
1658       AC_ERROR(No JIT or interpreter support available or selected.)
1659    fi
1660 fi
1661
1662 AM_CONDITIONAL(USE_JIT, test x$USEJIT = xtrue)
1663
1664 libsuffix=".so"
1665
1666 case "$host" in
1667      *-*-darwin*)
1668         libsuffix=".dylib"
1669         LIBC="libc.dylib"
1670         INTL="libintl.dylib"
1671         SQLITE="libsqlite.0.dylib"
1672         SQLITE3="libsqlite3.0.dylib"
1673         X11="libX11.dylib"
1674         ;;
1675      *-*-*netbsd*)
1676         LIBC="libc.so.12"
1677         INTL="libintl.so.0"
1678         ;;
1679     *-*-*freebsd*)
1680         LIBC="libc.so"
1681         INTL="libintl.so"
1682         ;;
1683     *-*-*openbsd*)
1684         LIBC="libc.so"
1685         INTL="libintl.so"
1686         ;;
1687     *-*-*linux*)
1688         AC_PATH_X
1689         AC_MSG_CHECKING(for the soname of libX11.so)
1690         for i in $x_libraries /usr/lib /usr/lib64; do
1691                 for r in 4 5 6; do
1692                         if test -f $i/libX11.so.$r; then
1693                                 X11=libX11.so.$r
1694                                 AC_MSG_RESULT($X11)
1695                         fi
1696                 done
1697         done
1698
1699         if test "x$X11" = "xlibX11.so"; then
1700                 AC_MSG_WARN([Could not find X development libs. Do you have the -devel package installed? WinForms may not work...]);
1701         fi
1702         ;;
1703 esac
1704
1705
1706 AC_SUBST(libsuffix)
1707
1708 if test "x$TARGET" != "xAMD64"; then
1709    # valgrind headers don't compile under x86-64
1710    AC_CHECK_HEADERS(valgrind/memcheck.h)
1711 fi
1712
1713 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1714         if test "x$with_tls" = "x__thread"; then
1715                 #
1716                 # On some linux distributions, TLS works in executables, but linking
1717                 # against a shared library containing TLS fails with:
1718                 # undefined reference to `__tls_get_addr'
1719                 #
1720                 rm -f conftest.c conftest.so conftest
1721                 echo "static __thread int foo; void main () { foo = 5; }" > conftest.c
1722                 $CC -fPIC --shared -o conftest.so conftest.c > /dev/null 2>&1
1723                 $CC -o conftest conftest.so > /dev/null 2>&1
1724                 if test ! -f conftest; then
1725                    AC_MSG_WARN([Disabling usage of __thread.]);
1726                    with_tls=pthread
1727                 fi
1728                 rm -f conftest.c conftest.so conftest
1729         fi
1730 fi
1731
1732 mono_debugger_supported=no
1733 if test "x$TARGET" = "xAMD64" -o "x$TARGET" = "xX86"; then
1734         if test x$use_included_gc = xyes; then
1735                 case "$host" in
1736                 *-*-*linux*)
1737                         mono_debugger_supported=yes
1738                         ;;
1739                 esac
1740         fi
1741 fi
1742
1743 AC_MSG_CHECKING(if the Mono Debugger is supported on this platform)
1744 if test "x$mono_debugger_supported" = "xyes"; then
1745         AC_DEFINE(MONO_DEBUGGER_SUPPORTED,1,[The Mono Debugger is supported on this platform])
1746 fi
1747 AC_MSG_RESULT($mono_debugger_supported)
1748 AM_CONDITIONAL(MONO_DEBUGGER_SUPPORTED, test x$mono_debugger_supported = xyes)
1749
1750 if test "x$with_tls" = "x__thread"; then
1751         AC_DEFINE(HAVE_KW_THREAD)
1752         # Pass the information to libgc
1753         CPPFLAGS="$CPPFLAGS -DUSE_COMPILER_TLS"
1754         AC_MSG_CHECKING(if the tls_model attribute is supported)
1755         AC_TRY_COMPILE([static __thread int foo __attribute__((tls_model("initial-exec")));], [
1756                 ], [
1757                         AC_MSG_RESULT(yes)
1758                         AC_DEFINE(HAVE_TLS_MODEL_ATTR, 1, [tld_model available])
1759                 ], [
1760                         AC_MSG_RESULT(no)
1761         ])
1762 fi
1763
1764 if test ${TARGET} = ARM; then
1765         dnl ******************************************
1766         dnl *** Check to see what FPU is available ***
1767         dnl ******************************************
1768         AC_MSG_CHECKING(which FPU to use)
1769
1770         AC_TRY_COMPILE([], [
1771                 __asm__ ("ldfd f0, [r0]");
1772                 ], fpu=FPA, [
1773                         AC_TRY_COMPILE([], [
1774                                 __asm__ ("fldd d0, [r0]");
1775                         ], fpu=VFP, fpu=NONE)
1776                 ])
1777
1778         AC_MSG_RESULT($fpu)
1779         CPPFLAGS="$CPPFLAGS -DARM_FPU_$fpu"
1780         unset fpu
1781 fi
1782
1783 if test ${TARGET} = unknown; then
1784         CPPFLAGS="$CPPFLAGS -DNO_PORT"
1785         AC_MSG_WARN("mono has not been ported to $host: some things may not work.")
1786 fi
1787
1788 if test ${ACCESS_UNALIGNED} = no; then
1789         CPPFLAGS="$CPPFLAGS -DNO_UNALIGNED_ACCESS"
1790 fi
1791
1792 PREVIEW=yes
1793 AC_ARG_WITH(preview, [ --with-preview=yes,no     If you want to install the 2.0 FX preview],[
1794         if test x$with_preview = xno; then
1795               PREVIEW=no
1796         fi
1797 ])
1798
1799 AM_CONDITIONAL(INSTALL_2_0, test x$PREVIEW = xyes)
1800
1801 AM_CONDITIONAL(MIPS_GCC, test ${TARGET}${ac_cv_prog_gcc} = MIPSyes)
1802 AM_CONDITIONAL(MIPS_SGI, test ${TARGET}${ac_cv_prog_gcc} = MIPSno)
1803 AM_CONDITIONAL(SPARC, test x$TARGET = xSPARC)
1804 AM_CONDITIONAL(SPARC64, test x$TARGET = xSPARC64)
1805 AM_CONDITIONAL(X86, test x$TARGET = xX86)
1806 AM_CONDITIONAL(AMD64, test x$TARGET = xAMD64)
1807 AM_CONDITIONAL(ALPHA, test x$TARGET = xALPHA)
1808 AM_CONDITIONAL(IA64, test x$TARGET = xIA64)
1809 AM_CONDITIONAL(M68K, test x$TARGET = xM68K)
1810 AM_CONDITIONAL(POWERPC, test x$TARGET = xPOWERPC)
1811 AM_CONDITIONAL(ARM, test x$TARGET = xARM)
1812 AM_CONDITIONAL(S390, test x$TARGET = xS390)
1813 AM_CONDITIONAL(S390x, test x$TARGET = xS390x)
1814 AM_CONDITIONAL(HPPA, test x$TARGET = xHPPA)
1815
1816 AM_CONDITIONAL(JIT_SUPPORTED, test x$JIT_SUPPORTED = xyes)
1817 AM_CONDITIONAL(INTERP_SUPPORTED, test x$interp_wanted = xtrue)
1818 AM_CONDITIONAL(INCLUDED_LIBGC, test x$gc = xincluded)
1819
1820 AC_SUBST(LIBC)
1821 AC_SUBST(INTL)
1822 AC_SUBST(SQLITE)
1823 AC_SUBST(SQLITE3)
1824 AC_SUBST(X11)
1825
1826 AC_SUBST(arch_target)
1827 AC_SUBST(CFLAGS)
1828 AC_SUBST(CPPFLAGS)
1829 AC_SUBST(LDFLAGS)
1830
1831 mono_build_root=`pwd`
1832 AC_SUBST(mono_build_root)
1833
1834 if test x$USEJIT = xtrue; then
1835   mono_runtime=mono/mini/mono
1836 else
1837   mono_runtime=mono/interpreter/mint
1838 fi
1839 AC_SUBST(mono_runtime)
1840
1841 mono_cfg_root=$mono_build_root/runtime
1842 if test x$platform_win32 = xyes; then
1843   mono_cfg_dir=`cygpath -w -a $mono_cfg_root`\\etc
1844 else
1845   mono_cfg_dir=$mono_cfg_root/etc
1846 fi
1847 AC_SUBST(mono_cfg_dir)
1848
1849 AC_CONFIG_FILES([runtime/mono-wrapper],[chmod +x runtime/mono-wrapper])
1850 AC_CONFIG_FILES([runtime/monodis-wrapper],[chmod +x runtime/monodis-wrapper])
1851 AC_CONFIG_FILES([runtime/semdel-wrapper],[chmod +x runtime/semdel-wrapper])
1852
1853 AC_CONFIG_COMMANDS([runtime/etc/mono/1.0/machine.config],
1854 [   depth=../../../..
1855     case $srcdir in
1856     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
1857     .) reldir=$depth ;;
1858     *) reldir=$depth/$srcdir ;;
1859     esac
1860     $ac_aux_dir/install-sh -d runtime/etc/mono/1.0
1861     cd runtime/etc/mono/1.0
1862     rm -f machine.config
1863     $LN_S $reldir/data/net_1_1/machine.config machine.config
1864     cd $depth
1865 ],[LN_S='$LN_S'])
1866
1867 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/machine.config],
1868 [   depth=../../../..
1869     case $srcdir in
1870     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
1871     .) reldir=$depth ;;
1872     *) reldir=$depth/$srcdir ;;
1873     esac
1874     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1875     cd runtime/etc/mono/2.0
1876     rm -f machine.config
1877     $LN_S $reldir/data/net_2_0/machine.config machine.config
1878     cd $depth
1879 ],[LN_S='$LN_S'])
1880
1881 AC_CONFIG_COMMANDS([runtime/etc/mono/2.0/web.config],
1882 [   depth=../../../..
1883     case $srcdir in
1884     [[\\/$]]* | ?:[[\\/]]* ) reldir=$srcdir ;;
1885     .) reldir=$depth ;;
1886     *) reldir=$depth/$srcdir ;;
1887     esac
1888     $ac_aux_dir/install-sh -d runtime/etc/mono/2.0
1889     cd runtime/etc/mono/2.0
1890     rm -f web.config
1891     $LN_S $reldir/data/net_2_0/web.config web.config
1892     cd $depth
1893 ],[LN_S='$LN_S'])
1894
1895 AC_OUTPUT([
1896 Makefile
1897 mint.pc
1898 mono.pc
1899 mono-cairo.pc
1900 dotnet.pc
1901 mono-uninstalled.pc
1902 scripts/mono-nunit.pc
1903 scripts/mono-find-provides
1904 scripts/mono-find-requires
1905 mono/Makefile
1906 mono/utils/Makefile
1907 mono/metadata/Makefile
1908 mono/dis/Makefile
1909 mono/cil/Makefile
1910 mono/arch/Makefile
1911 mono/os/Makefile
1912 mono/arch/x86/Makefile
1913 mono/arch/amd64/Makefile
1914 mono/arch/hppa/Makefile
1915 mono/arch/ppc/Makefile
1916 mono/arch/sparc/Makefile
1917 mono/arch/s390/Makefile
1918 mono/arch/s390x/Makefile
1919 mono/arch/arm/Makefile
1920 mono/arch/alpha/Makefile
1921 mono/arch/ia64/Makefile
1922 mono/interpreter/Makefile
1923 mono/tests/Makefile
1924 mono/tests/tests-config
1925 mono/tests/cas/Makefile
1926 mono/tests/cas/assembly/Makefile
1927 mono/tests/cas/demand/Makefile
1928 mono/tests/cas/inheritance/Makefile
1929 mono/tests/cas/linkdemand/Makefile
1930 mono/tests/cas/threads/Makefile
1931 mono/benchmark/Makefile
1932 mono/monoburg/Makefile
1933 mono/monograph/Makefile
1934 mono/io-layer/Makefile
1935 mono/mini/Makefile
1936 mono/profiler/Makefile
1937 ikvm-native/Makefile
1938 scripts/Makefile
1939 man/Makefile
1940 web/Makefile
1941 docs/Makefile
1942 data/Makefile
1943 data/net_1_1/Makefile
1944 data/net_2_0/Makefile
1945 samples/Makefile
1946 support/Makefile
1947 data/config
1948 tools/Makefile
1949 tools/locale-builder/Makefile
1950 runtime/Makefile
1951 ])
1952
1953 if test x$platform_win32 = xyes; then
1954    # Get rid of 'cyg' prefixes in library names
1955    sed -e "s/\/cyg\//\/\//" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
1956    # libtool seems to inherit -mno-cygwin from our CFLAGS, and uses it to compile its executable
1957    # wrapper scripts which use exec(). gcc has no problem compiling+linking this, but the resulting
1958    # executable doesn't work...
1959    sed -e "s,-mno-cygwin,,g" libtool > libtool.new; mv libtool.new libtool; chmod 755 libtool
1960 fi
1961
1962 (
1963   case $prefix in
1964   NONE) prefix=$ac_default_prefix ;;
1965   esac
1966   case $exec_prefix in
1967   NONE) exec_prefix='${prefix}' ;;
1968   esac
1969
1970   test -w $srcdir/$mcsdir/build || chmod +w $srcdir/$mcsdir/build
1971
1972   #
1973   # If we are cross compiling, we don't build in the mcs/ tree.  Let us not clobber
1974   # any existing config.make.  This allows people to share the same source tree
1975   # with different build directories, one native and one cross
1976   #
1977   if test x$cross_compiling = xno; then
1978     echo "prefix=$prefix" > $srcdir/$mcsdir/build/config.make
1979     echo "exec_prefix=$exec_prefix" >> $srcdir/$mcsdir/build/config.make
1980     echo 'mono_libdir=${exec_prefix}/lib' >> $srcdir/$mcsdir/build/config.make
1981     echo 'MCS_FLAGS = $(PLATFORM_DEBUG_FLAGS)' >> $srcdir/$mcsdir/build/config.make
1982     echo 'IL_FLAGS = /debug' >> $srcdir/$mcsdir/build/config.make
1983     echo "RUNTIME = $mono_build_root/runtime/mono-wrapper" >> $srcdir/$mcsdir/build/config.make
1984     echo "ILDISASM = $mono_build_root/runtime/monodis-wrapper" >> $srcdir/$mcsdir/build/config.make
1985
1986     case $INSTALL in
1987     [[\\/$]]* | ?:[[\\/]]* ) mcs_INSTALL=$INSTALL ;;
1988     *) mcs_INSTALL=$mono_build_root/$INSTALL ;;
1989     esac
1990
1991     echo "INSTALL = $mcs_INSTALL" >> $srcdir/$mcsdir/build/config.make
1992
1993     export VERSION
1994     [myver=$($AWK 'BEGIN {
1995       split (ENVIRON["VERSION"] ".0.0.0", vsplit, ".")
1996       print vsplit [1] "." vsplit [2] "." vsplit [3] "." vsplit [4]
1997     }')]
1998
1999     echo "MONO_VERSION = $myver" >> $srcdir/$mcsdir/build/config.make
2000   fi
2001 )
2002
2003 libgdiplus_msg=${libgdiplus_loc:-assumed to be installed}
2004
2005 echo "
2006         mcs source:  $mcs_topdir
2007         GC:          $gc
2008         TLS:         $with_tls
2009         SIGALTSTACK: $with_sigaltstack
2010         Engine:      $jit_status
2011         2.0 Alpha:   $PREVIEW
2012         JNI support: $jdk_headers_found
2013         libgdiplus:  $libgdiplus_msg
2014         $disabled
2015
2016 "
2017 if test x$gc = xsgen; then
2018         echo IMPORTANT:
2019         echo IMPORTANT: You have selected an experimental, work-in-progress
2020         echo IMPORTANT: GC engine.  This GC engine is currently not supported
2021         echo IMPORTANT: and is not yet ready for use.
2022         echo IMPORTANT:
2023         echo IMPORTANT: There are known problems with it, use at your own risk.
2024 fi