configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007, 2008
   4 dnl CACAOVM - Verein zur Foerderung der freien virtuellen Maschine CACAO
   5 dnl
   6 dnl This file is part of CACAO.
   7 dnl
   8 dnl This program is free software; you can redistribute it and/or
   9 dnl modify it under the terms of the GNU General Public License as
  10 dnl published by the Free Software Foundation; either version 2, or (at
  11 dnl your option) any later version.
  12 dnl
  13 dnl This program is distributed in the hope that it will be useful, but
  14 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 dnl General Public License for more details.
  17 dnl
  18 dnl You should have received a copy of the GNU General Public License
  19 dnl along with this program; if not, write to the Free Software
  20 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  21 dnl 02110-1301, USA.
  22
  23 dnl Process this file with autoconf to produce a configure script.
  24
  25
  26 AC_INIT(cacao, 0.98+svn, cacao@cacaojvm.org)
  27 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  28 AC_CANONICAL_HOST
  29 AC_PREREQ(2.59)
  30 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2])
  31 AM_MAINTAINER_MODE
  32
  33 AM_CONFIG_HEADER([config.h])
  34
  35 AC_PREFIX_DEFAULT(/usr/local/cacao)
  36
  37
  38 dnl set optimization and debugging for all architectures and systems
  39 if test x"$CFLAGS" = "x"; then
  40     OPT_CFLAGS="-O0 -g3"
  41 else
  42     OPT_CFLAGS=$CFLAGS
  43 fi
  44
  45 dnl system type
  46 case "$host_cpu" in
  47 alpha | alphaev56 | alphapca56 )
  48     ARCH_DIR="alpha"
  49     ARCH_CFLAGS="-mieee -D__ALPHA__"
  50     JAVA_ARCH="alpha"
  51     ;;
  52
  53 arm | armv4 | armv4tl | armv5b | armv5l )
  54     ARCH_DIR="arm"
  55     ARCH_CFLAGS="-D__ARM__"
  56     JAVA_ARCH="arm"
  57     ;;
  58
  59 hppa2.0 )
  60     ARCH_DIR="parisc"
  61     ARCH_CFLAGS="-D__PARISC__"
  62     JAVA_ARCH="hppa"
  63     ;;
  64
  65 i386 | i486 | i586 | i686 )
  66     ARCH_DIR="i386"
  67     ARCH_CFLAGS="-D__I386__"
  68     JAVA_ARCH="i386"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     JAVA_ARCH="m68k"
  75     ;;
  76
  77 mips | mipsel )
  78     ARCH_DIR="mips"
  79     ARCH_CFLAGS="-D__MIPS__"
  80     dnl Is this correct for mipsel?
  81     JAVA_ARCH="mips"
  82     ;;
  83
  84 powerpc )
  85     ARCH_DIR="powerpc"
  86     ARCH_CFLAGS="-D__POWERPC__"
  87     JAVA_ARCH="ppc"
  88     ;;
  89
  90 powerpc64 )
  91     ARCH_DIR="powerpc64"
  92     ARCH_CFLAGS="-D__POWERPC64__"
  93     JAVA_ARCH="ppc64"
  94     ;;
  95
  96 s390 )
  97     ARCH_DIR="s390"
  98     ARCH_CFLAGS="-D__S390__"
  99     JAVA_ARCH="s390"
 100     ;;
 101
 102 sparc | sparc64 )
 103     ARCH_DIR="sparc64"
 104     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
 105     dnl Is this correct for 64-bits?
 106     JAVA_ARCH="sparc"
 107     ;;
 108
 109 x86_64 )
 110     ARCH_DIR="x86_64"
 111     ARCH_CFLAGS="-D__X86_64__"
 112     JAVA_ARCH="amd64"
 113     ;;
 114
 115 xdspcore )
 116     ARCH_DIR="xdspcore"
 117     ENABLE_STATICVM="yes"
 118     ARCH_CFLAGS="-D__XDSPCORE__"
 119     USE_SCHEDULER="1"
 120     ;;
 121
 122 * )
 123     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 124     ;;
 125 esac
 126
 127 dnl host type
 128 case "$host_os" in
 129 *cygwin* )
 130     OS_DIR="cygwin"
 131     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 132     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -ansi -pedantic -Wall -Wno-long-long"
 133     ;;
 134
 135 *darwin* )
 136     OS_DIR="darwin"
 137     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 138     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
 139     ;;
 140
 141 *freebsd* )
 142     OS_DIR="freebsd"
 143     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 144     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 145     ;;
 146
 147 *irix* )
 148     OS_DIR="irix"
 149     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 150     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 151     ;;
 152
 153 *kfreebsd*-gnu)
 154     OS_DIR="freebsd"
 155     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 156     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 157     ;;
 158
 159 dnl must be before *linux*
 160 *uclinux | *elf )
 161     OS_DIR="uclinux"
 162     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 163     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 164     ;;
 165
 166 *linux* | *Linux* )
 167     OS_DIR="linux"
 168     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 169     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 170     ;;
 171
 172 *netbsd* )
 173     OS_DIR="netbsd"
 174     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 175     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 176     ;;
 177
 178 *solaris* )
 179     OS_DIR="solaris"
 180         dnl on solaris the architecture defines 'sparc','sun','unix' are not set when cpp is called with -ansi
 181         dnl therefore we add them here
 182     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 183     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 184     ;;
 185
 186 * )
 187     ;;
 188 esac
 189
 190
 191 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 192 dnl we set it properly at the end of this file
 193 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 194
 195 dnl set interpreter flags
 196 AC_SUBST(INTRP_CFLAGS)
 197
 198 dnl define some stuff required for --fullversion
 199 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 200 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 201 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS", [CFLAGS used])
 202
 203
 204 dnl define and substitute some architecture specific variables
 205 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 206 AC_DEFINE_UNQUOTED([JAVA_ARCH], "${JAVA_ARCH}", [Java architecture name])
 207 AC_SUBST(ARCH_DIR)
 208 AC_SUBST(OS_DIR)
 209 AC_SUBST(USE_SCHEDULER)
 210
 211
 212 dnl Checks for programs.
 213 AC_PROG_CC
 214 AM_PROG_AS
 215 AC_PROG_LD
 216 AC_PROG_LD_GNU
 217 AC_PROG_RANLIB
 218 AC_PROG_LN_S
 219 AC_PROG_MAKE_SET
 220 AM_PROG_MKDIR_P
 221
 222 dnl Checks for header files.
 223 AC_HEADER_DIRENT
 224 AC_HEADER_STDC
 225
 226 dnl keep them alpha-sorted!
 227 AC_CHECK_HEADERS([assert.h])
 228 AC_CHECK_HEADERS([errno.h])
 229 AC_CHECK_HEADERS([fcntl.h])
 230 AC_CHECK_HEADERS([libgen.h])
 231 AC_CHECK_HEADERS([netdb.h])
 232 AC_CHECK_HEADERS([stdlib.h])
 233 AC_CHECK_HEADERS([string.h])
 234 AC_CHECK_HEADERS([time.h])
 235 AC_CHECK_HEADERS([ucontext.h])
 236 AC_CHECK_HEADERS([unistd.h])
 237 AC_CHECK_HEADERS([sys/ioctl.h])
 238 AC_CHECK_HEADERS([sys/mman.h])
 239 AC_CHECK_HEADERS([sys/resource.h])
 240 AC_CHECK_HEADERS([sys/select.h])
 241 AC_CHECK_HEADERS([sys/socket.h])
 242 AC_CHECK_HEADERS([sys/stat.h])
 243 AC_CHECK_HEADERS([sys/time.h])
 244 AC_CHECK_HEADERS([sys/types.h])
 245
 246 dnl this is for fdlibm
 247 AC_CHECK_HEADERS([stdint.h])
 248 AC_CHECK_HEADERS([inttypes.h])
 249 AC_CHECK_HEADERS([sys/config.h])
 250 AC_CHECK_HEADERS([sys/types.h])
 251 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 252 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 253 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 254 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 255
 256 dnl Checks for typedefs, structures, and compiler characteristics.
 257 AC_C_CONST
 258 AC_C_INLINE
 259 AC_C_ATTRIBUTE
 260 AC_TYPE_OFF_T
 261 AC_TYPE_SIZE_T
 262 AC_HEADER_TIME
 263 AC_STRUCT_TM
 264
 265 dnl Checks for libraries (NOTE: Should be done before function checks,
 266 dnl as some functions may be in libraries we check for).
 267 AC_CHECK_LIB(dl, dlopen,,)
 268
 269 dnl Checks for library functions.
 270 AC_PROG_GCC_TRADITIONAL
 271 AC_TYPE_SIGNAL
 272 AC_FUNC_MEMCMP
 273 AC_FUNC_MMAP
 274
 275 dnl keep them alpha-sorted!
 276 AC_CHECK_FUNCS([accept])
 277 AC_CHECK_FUNCS([access])
 278 AC_CHECK_FUNCS([atoi])
 279 AC_CHECK_FUNCS([atol])
 280 AC_CHECK_FUNCS([calloc])
 281 AC_CHECK_FUNCS([close])
 282 AC_CHECK_FUNCS([confstr])
 283 AC_CHECK_FUNCS([connect])
 284 AC_CHECK_FUNCS([dirname])
 285 AC_CHECK_FUNCS([fclose])
 286 AC_CHECK_FUNCS([fflush])
 287 AC_CHECK_FUNCS([fopen])
 288 AC_CHECK_FUNCS([fprintf])
 289 AC_CHECK_FUNCS([fread])
 290 AC_CHECK_FUNCS([free])
 291 AC_CHECK_FUNCS([fstat])
 292 AC_CHECK_FUNCS([fsync])
 293 AC_CHECK_FUNCS([ftruncate])
 294 AC_CHECK_FUNCS([getcwd])
 295 AC_CHECK_FUNCS([gethostbyname])
 296 AC_CHECK_FUNCS([gethostname])
 297 AC_CHECK_FUNCS([getpagesize])
 298 AC_CHECK_FUNCS([getrusage])
 299 AC_CHECK_FUNCS([getsockname])
 300 AC_CHECK_FUNCS([getsockopt])
 301 AC_CHECK_FUNCS([gettimeofday])
 302 AC_CHECK_FUNCS([htons])
 303 AC_CHECK_FUNCS([ioctl])
 304 AC_CHECK_FUNCS([isnan])
 305 AC_CHECK_FUNCS([listen])
 306 AC_CHECK_FUNCS([localtime])
 307 AC_CHECK_FUNCS([localtime_r])
 308 AC_CHECK_FUNCS([lseek])
 309 AC_CHECK_FUNCS([malloc])
 310 AC_CHECK_FUNCS([memcpy])
 311 AC_CHECK_FUNCS([memset])
 312 AC_CHECK_FUNCS([mmap])
 313 AC_CHECK_FUNCS([mprotect])
 314 AC_CHECK_FUNCS([open])
 315 AC_CHECK_FUNCS([read])
 316 AC_CHECK_FUNCS([readlink])
 317 AC_CHECK_FUNCS([realloc])
 318 AC_CHECK_FUNCS([recv])
 319 AC_CHECK_FUNCS([scandir])
 320 AC_CHECK_FUNCS([select])
 321 AC_CHECK_FUNCS([send])
 322 AC_CHECK_FUNCS([setsockopt])
 323 AC_CHECK_FUNCS([shutdown])
 324 AC_CHECK_FUNCS([socket])
 325 AC_CHECK_FUNCS([stat])
 326 AC_CHECK_FUNCS([strchr])
 327 AC_CHECK_FUNCS([strdup])
 328 AC_CHECK_FUNCS([strerror])
 329 AC_CHECK_FUNCS([strncmp])
 330 AC_CHECK_FUNCS([strstr])
 331 AC_CHECK_FUNCS([time])
 332 AC_CHECK_FUNCS([write])
 333
 334
 335 dnl Checks for libraries.
 336
 337 dnl Checking sizeof void *
 338 AC_CHECK_SIZEOF(void *)
 339 AC_C_BIGENDIAN
 340
 341
 342 dnl define install prefix
 343 if test "x$prefix" = "xNONE"; then
 344     CACAO_PREFIX=$ac_default_prefix
 345 else
 346     CACAO_PREFIX=$prefix
 347 fi
 348 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 349 AC_SUBST(CACAO_PREFIX)
 350
 351 dnl define libdir prefix
 352 if test "x$libdir" = "xNONE"; then
 353     CACAO_LIBDIR=$ac_default_libdir
 354 else
 355     CACAO_LIBDIR=$libdir
 356 fi
 357 dnl expand CACAO_LIBDIR to something that is usable in C code
 358 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 359 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 360 AC_SUBST(CACAO_LIBDIR)
 361
 362
 363 AC_CHECK_ENABLE_LTDL
 364
 365 AC_CHECK_ENABLE_JAVA
 366
 367 AC_CHECK_ENABLE_JIT
 368 AC_CHECK_ENABLE_INTRP
 369
 370 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 371     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 372 fi
 373
 374 AC_CHECK_SOFTFLOAT
 375 AC_CHECK_SOFT_FLOAT_CMP
 376 AC_CHECK_SOFT_DOUBLE_CMP
 377
 378 AC_CHECK_ENABLE_GC
 379 AC_CHECK_ENABLE_DEBUG
 380 AC_CHECK_ENABLE_DUMP
 381
 382
 383 dnl check for memcheck support
 384 AC_MSG_CHECKING(whether debugging memory checks should be enabled)
 385 AC_ARG_ENABLE([memcheck],
 386               [AS_HELP_STRING(--enable-memcheck,enable debugging memory checks [[default=no]])],
 387               [case "${enableval}" in
 388                    yes) ENABLE_MEMCHECK=yes;;
 389                    *) ENABLE_MEMCHECK=no;;
 390                esac],
 391               [ENABLE_MEMCHECK=no])
 392 AC_MSG_RESULT(${ENABLE_MEMCHECK})
 393 AM_CONDITIONAL([ENABLE_MEMCHECK], test x"${ENABLE_MEMCHECK}" = "xyes")
 394
 395 if test x"${ENABLE_MEMCHECK}" = "xyes"; then
 396     AC_DEFINE([ENABLE_MEMCHECK], 1, [perform debugging memory checks])
 397 fi
 398
 399
 400 dnl check for handles (indirection cells) support
 401 AC_MSG_CHECKING(whether handles (indirection cells) should be enabled)
 402 AC_ARG_ENABLE([handles],
 403               [AS_HELP_STRING(--enable-handles,enable handles (indirection cells) [[default=no]])],
 404               [case "${enableval}" in
 405                    yes) ENABLE_HANDLES=yes;;
 406                    *) ENABLE_HANDLES=no;;
 407                esac],
 408               [ENABLE_HANDLES=no])
 409 AC_MSG_RESULT(${ENABLE_HANDLES})
 410 AM_CONDITIONAL([ENABLE_HANDLES], test x"${ENABLE_HANDLES}" = "xyes")
 411
 412 if test x"${ENABLE_HANDLES}" = "xyes"; then
 413     AC_DEFINE([ENABLE_HANDLES], 1, [enable handles (indirection cells)])
 414 fi
 415
 416
 417 dnl check for vmlog support
 418 AC_MSG_CHECKING(whether vmlog tracing should be enabled)
 419 AC_ARG_ENABLE([vmlog],
 420               [AS_HELP_STRING(--enable-vmlog,enable vmlog tracing [[default=no]])],
 421               [case "${enableval}" in
 422                    yes) ENABLE_VMLOG=yes;;
 423                    *) ENABLE_VMLOG=no;;
 424                esac],
 425               [ENABLE_VMLOG=no])
 426 AC_MSG_RESULT(${ENABLE_VMLOG})
 427 AM_CONDITIONAL([ENABLE_VMLOG], test x"${ENABLE_VMLOG}" = "xyes")
 428
 429 if test x"${ENABLE_VMLOG}" = "xyes"; then
 430     AC_DEFINE([ENABLE_VMLOG], 1, [enable vmlog tracing code])
 431 fi
 432
 433
 434 dnl check for disassembler support
 435 AC_MSG_CHECKING(whether disassembler should be enabled)
 436 AC_ARG_ENABLE([disassembler],
 437               [AS_HELP_STRING(--enable-disassembler,enable disassembler [[default=no]])],
 438               [case "${enableval}" in
 439                    yes) ENABLE_DISASSEMBLER=yes;;
 440                    *) ENABLE_DISASSEMBLER=no;;
 441                esac],
 442               [ENABLE_DISASSEMBLER=no])
 443 AC_MSG_RESULT(${ENABLE_DISASSEMBLER})
 444 AM_CONDITIONAL([ENABLE_DISASSEMBLER], test x"${ENABLE_DISASSEMBLER}" = "xyes")
 445
 446 if test x"${ENABLE_DISASSEMBLER}" = "xyes"; then
 447     AC_DEFINE([ENABLE_DISASSEMBLER], 1, [enable disassembler])
 448
 449     dnl check for binutils headers and libraries on some architectures for the
 450     dnl disassembler
 451     case "${ARCH_DIR}" in
 452         arm | i386 | powerpc | x86_64 | sparc64 | powerpc64 | s390 | m68k)
 453             AC_CHECK_HEADER([ansidecl.h],, [AC_MSG_ERROR(cannot find ansidecl.h)])
 454             AC_CHECK_HEADER([symcat.h],, [AC_MSG_ERROR(cannot find symcat.h)])
 455             AC_CHECK_HEADER([bfd.h],, [AC_MSG_ERROR(cannot find bfd.h)])
 456             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 457
 458             case "${OS_DIR}" in
 459                 cygwin | darwin | netbsd | solaris)
 460                      AC_CHECK_LIB(intl, dcgettext,, [AC_MSG_ERROR(cannot find libintl (from binutils))])
 461                      ;;
 462             esac
 463
 464             case "${OS_DIR}" in
 465                 solaris)
 466                                          AC_CHECK_LIB(rt, sem_init,, [AC_MSG_ERROR(cannot find librt)])
 467                      ;;
 468             esac
 469
 470
 471             AC_CHECK_LIB(iberty, xstrerror,, [AC_MSG_ERROR(cannot find libiberty (from binutils))])
 472             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from binutils))])
 473             AC_CHECK_LIB(opcodes, disassembler,, [AC_MSG_ERROR(cannot find libopcodes (from binutils))])
 474             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 475             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 476             ;;
 477         * )
 478             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 479             ;;
 480     esac
 481 else
 482     AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 483 fi
 484
 485
 486 dnl check for statistics
 487 AC_MSG_CHECKING(whether statistics generation should be enabled)
 488 AC_ARG_ENABLE([statistics],
 489               [AS_HELP_STRING(--enable-statistics,enable statistics generation [[default=no]])],
 490               [case "${enableval}" in
 491                    yes) ENABLE_STATISTICS=yes;;
 492                    *) ENABLE_STATISTICS=no;;
 493                esac],
 494               [ENABLE_STATISTICS=no])
 495 AC_MSG_RESULT(${ENABLE_STATISTICS})
 496 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 497
 498 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 499     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 500 fi
 501
 502
 503 dnl check for verifier
 504 AC_MSG_CHECKING(whether classfile verification should be enabled)
 505 AC_ARG_ENABLE([verifier],
 506               [AS_HELP_STRING(--disable-verifier,disable classfile verification [[default=enabled]])],
 507               [case "${enableval}" in
 508                    no) ENABLE_VERIFIER=no;;
 509                    *) ENABLE_VERIFIER=yes;;
 510                esac],
 511               [ENABLE_VERIFIER=yes])
 512 AC_MSG_RESULT(${ENABLE_VERIFIER})
 513 AM_CONDITIONAL([ENABLE_VERIFIER], test x"${ENABLE_VERIFIER}" = "xyes")
 514
 515 if test x"${ENABLE_VERIFIER}" = "xyes"; then
 516     AC_DEFINE([ENABLE_VERIFIER], 1, [enable classfile verification])
 517 fi
 518
 519
 520 dnl check for compiler timing
 521 AC_MSG_CHECKING(whether real-time timing should be enabled)
 522 AC_ARG_ENABLE([rt-timing],
 523               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 524               [case "${enableval}" in
 525                    yes) ENABLE_RT_TIMING=yes;;
 526                    *) ENABLE_RT_TIMING=no;;
 527                esac],
 528               [ENABLE_RT_TIMING=no])
 529 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 530 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 531
 532 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 533     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 534 fi
 535
 536
 537 dnl check for cycle count statistics
 538 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 539 AC_ARG_ENABLE([cycles-stats],
 540               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 541               [case "${enableval}" in
 542                    yes) ENABLE_CYCLES_STATS=yes;;
 543                    *) ENABLE_CYCLES_STATS=no;;
 544                esac],
 545               [ENABLE_CYCLES_STATS=no])
 546 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 547 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 548
 549 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 550     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 551 fi
 552
 553
 554 dnl check for JVMTI
 555 AC_MSG_CHECKING(whether to compile JVMTI support)
 556 AC_ARG_ENABLE([jvmti],
 557               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 558               [case "${enableval}" in
 559                    yes) ENABLE_JVMTI=yes;;
 560                    *) ENABLE_JVMTI=no;;
 561                esac],
 562               [ENABLE_JVMTI=no])
 563 AC_MSG_RESULT(${ENABLE_JVMTI})
 564 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 565
 566 if test x"${ENABLE_JVMTI}" = "xyes"; then
 567     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 568 fi
 569
 570
 571 AC_CHECK_ENABLE_THREADS
 572
 573
 574 dnl check if if-conversion should be supported
 575 AC_MSG_CHECKING(whether if-conversion should be supported)
 576 AC_ARG_ENABLE([ifconv],
 577               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=enabled]])],
 578               [case "${enableval}" in
 579                    no) ENABLE_IFCONV=no;;
 580                    *) ENABLE_IFCONV=yes;;
 581                esac],
 582               [ENABLE_IFCONV=yes])
 583 AC_MSG_RESULT(${ENABLE_IFCONV})
 584 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 585
 586 if test x"${ENABLE_IFCONV}" = "xyes"; then
 587     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 588 fi
 589
 590
 591 dnl check for inlining
 592 AC_MSG_CHECKING(whether method inlining should be supported)
 593 AC_ARG_ENABLE([inlining],
 594               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 595               [case "${enableval}" in
 596                    yes) ENABLE_INLINING=yes;;
 597                    *) ENABLE_INLINING=no;;
 598                esac],
 599               [ENABLE_INLINING=no])
 600 AC_MSG_RESULT(${ENABLE_INLINING})
 601 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 602
 603 if test x"${ENABLE_INLINING}" = "xyes"; then
 604     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 605 fi
 606
 607
 608 dnl check for inlining debug options
 609 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 610 AC_ARG_ENABLE([inlining-debug],
 611               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 612               [case "${enableval}" in
 613                    yes) ENABLE_INLINING_DEBUG=yes;;
 614                    *) ENABLE_INLINING_DEBUG=no;;
 615                esac],
 616               [ENABLE_INLINING_DEBUG=no])
 617 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 618 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 619
 620 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 621     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 622 fi
 623
 624
 625 dnl check for replacement
 626 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 627 AC_ARG_ENABLE([replacement],
 628               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 629               [case "${enableval}" in
 630                    yes) ENABLE_REPLACEMENT=yes;;
 631                    *) ENABLE_REPLACEMENT=no;;
 632                esac],
 633               [ENABLE_REPLACEMENT=no])
 634 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 635 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 636
 637 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 638     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 639 fi
 640
 641
 642 dnl check for loop optimization
 643 AC_MSG_CHECKING(whether loop optimization should be supported)
 644 AC_ARG_ENABLE([loop],
 645               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 646               [case "${enableval}" in
 647                    yes) ENABLE_LOOP=yes;;
 648                    *) ENABLE_LOOP=no;;
 649                esac],
 650               [ENABLE_LOOP=no])
 651 AC_MSG_RESULT(${ENABLE_LOOP})
 652 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 653
 654 if test x"${ENABLE_LOOP}" = "xyes"; then
 655     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 656 fi
 657
 658
 659 dnl check if linear scan register allocator(lsra) with SSA should be used
 660 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 661 AC_ARG_ENABLE([ssa],
 662               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=disabled]])],
 663               [case "${enableval}" in
 664                    no) ENABLE_SSA=no;;
 665                    *) ENABLE_SSA=yes;;
 666                esac],
 667               [ENABLE_SSA=no])
 668 AC_MSG_RESULT(${ENABLE_SSA})
 669 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 670
 671 if test x"${ENABLE_SSA}" = "xyes"; then
 672     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 673     ENABLE_LSRA="no"
 674 fi
 675
 676
 677 dnl check if linear scan register allocator(lsra) should be used
 678 AC_MSG_CHECKING(whether lsra should be supported)
 679 AC_ARG_ENABLE([lsra],
 680               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 681               [case "${enableval}" in
 682                    yes) ENABLE_LSRA=yes;;
 683                    *) ENABLE_LSRA=no;;
 684                esac],
 685               [ENABLE_LSRA=no])
 686
 687 if test x"${ENABLE_LSRA}" = "xyes"; then
 688     if test x"${ENABLE_SSA}" = "xyes"; then
 689         ENABLE_LSRA="no"
 690     fi
 691 fi
 692 AC_MSG_RESULT(${ENABLE_LSRA})
 693 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 694
 695 if test x"${ENABLE_LSRA}" = "xyes"; then
 696     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 697 fi
 698
 699
 700 dnl check if profiling should be supported
 701 AC_MSG_CHECKING(whether profiling should be supported)
 702 AC_ARG_ENABLE([profiling],
 703               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 704               [case "${enableval}" in
 705                    yes) ENABLE_PROFILING=yes;;
 706                    *) ENABLE_PROFILING=no;;
 707                esac],
 708               [ENABLE_PROFILING=no])
 709 AC_MSG_RESULT(${ENABLE_PROFILING})
 710 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 711
 712 if test x"${ENABLE_PROFILING}" = "xyes"; then
 713     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 714 fi
 715
 716
 717 dnl check for instruction scheduler
 718 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 719
 720 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 721 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 722         case "${ARCH_DIR}" in
 723                 xdspcore )
 724                         ;;
 725                 * )
 726                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 727                         ;;
 728         esac
 729
 730         AC_MSG_RESULT(yes)
 731         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 732         AM_CONDITIONAL([USE_SCHEDULER], [true])
 733 else
 734         AC_MSG_RESULT(no)
 735         AM_CONDITIONAL([USE_SCHEDULER], [false])
 736 fi
 737
 738
 739 AC_CHECK_ENABLE_ZLIB
 740
 741 dnl check for stuff to be built
 742 AC_CHECK_ENABLE_JNI
 743 AC_CHECK_ENABLE_LIBJVM
 744
 745 dnl ATTENTION: These check must be after setting
 746 dnl enable_shared/enable_static (happens in AC_CHECK_ENABLE_LIBJVM),
 747 dnl because libtool uses them to build the correct libraries.
 748 AC_LIBTOOL_DLOPEN
 749 AC_PROG_LIBTOOL
 750
 751 AC_CHECK_ENABLE_STATICVM
 752 AC_CHECK_ENABLE_ANNOTATIONS
 753 AC_CHECK_ENABLE_ASSERTION
 754
 755
 756 dnl where is CACAO's vm.zip
 757 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 758 AC_ARG_WITH([vm-zip],
 759             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 760             [CACAO_VM_ZIP=${withval}],
 761             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 762 AC_MSG_RESULT(${CACAO_VM_ZIP})
 763 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 764 AC_SUBST(CACAO_VM_ZIP)
 765
 766
 767 AC_CHECK_WITH_CACAOH
 768 AC_CHECK_WITH_CLASSPATH
 769 AC_CHECK_WITH_CLASSPATH_PREFIX
 770 AC_CHECK_WITH_CLASSPATH_CLASSES
 771 AC_CHECK_WITH_CLASSPATH_LIBDIR
 772 AC_CHECK_WITH_CLASSPATH_INCLUDEDIR
 773 AC_CHECK_WITH_JRE_LAYOUT
 774
 775
 776 dnl check for some programs we need
 777
 778 case "${WITH_CLASSPATH}" in
 779     cldc1.1 | gnu)
 780         AC_PROG_JAVAC
 781         AC_PROG_JAR
 782         ;;
 783     sun)
 784         ;;
 785     *)
 786         AC_MSG_ERROR(unknown classpath configuration ${WITH_CLASSPATH})
 787         ;;
 788 esac
 789
 790
 791 AC_CHECK_HEADERS(
 792         [regex.h],
 793         [
 794                 dnl If debug build and regex.h available, enable debug filter
 795                 if test x"${NDEBUG}" = "xno"; then
 796                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 797                 fi
 798                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 799                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 800         ],
 801         [
 802                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 803         ]
 804 )
 805
 806 dnl python
 807
 808 AZ_PYTHON_DEFAULT
 809 AZ_PYTHON_ENABLE
 810 AZ_PYTHON_WITH
 811 AZ_PYTHON_VERSION_ENSURE( [2.4] )
 812 AZ_PYTHON_CSPEC
 813 AZ_PYTHON_LSPEC
 814
 815
 816 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 817 CFLAGS=$OPT_CFLAGS
 818 AM_CFLAGS=$ARCH_CFLAGS
 819 AC_SUBST(AM_CFLAGS)
 820
 821
 822 AC_CONFIG_FILES([Makefile]
 823                 [contrib/Makefile]
 824                 [contrib/setenvinstalled]
 825                 [contrib/setenvsource]
 826                 [contrib/vmlog/Makefile]
 827                 [contrib/vmlog/t/Makefile]
 828                 [doc/Makefile]
 829                 [doc/handbook/Makefile]
 830                 [man/Makefile]
 831                 [src/Makefile]
 832                 [src/cacao/Makefile]
 833                 [src/cacaoh/Makefile]
 834                 [src/fdlibm/Makefile]
 835                 [src/lib/Makefile]
 836                 [src/mm/Makefile]
 837                 [src/mm/cacao-gc/Makefile]
 838                 [src/native/Makefile]
 839                 [src/native/include/Makefile]
 840                 [src/native/jvmti/Makefile]
 841                 [src/native/vm/Makefile]
 842                 [src/native/vm/cldc1.1/Makefile]
 843                 [src/native/vm/gnu/Makefile]
 844                 [src/native/vm/sun/Makefile]
 845                 [src/scripts/Makefile]
 846                 [src/scripts/java]
 847                 [src/threads/Makefile]
 848                 [src/threads/native/Makefile]
 849                 [src/threads/none/Makefile]
 850                 [src/toolbox/Makefile]
 851                 [src/vm/Makefile]
 852                 [src/vm/jit/Makefile]
 853                 [src/vm/jit/allocator/Makefile]
 854                 [src/vm/jit/alpha/Makefile]
 855                 [src/vm/jit/alpha/freebsd/Makefile]
 856                 [src/vm/jit/alpha/linux/Makefile]
 857                 [src/vm/jit/arm/Makefile]
 858                 [src/vm/jit/arm/linux/Makefile]
 859                 [src/vm/jit/i386/Makefile]
 860                 [src/vm/jit/i386/cygwin/Makefile]
 861                 [src/vm/jit/i386/darwin/Makefile]
 862                 [src/vm/jit/i386/freebsd/Makefile]
 863                 [src/vm/jit/i386/linux/Makefile]
 864                 [src/vm/jit/intrp/Makefile]
 865                 [src/vm/jit/inline/Makefile]
 866                 [src/vm/jit/ir/Makefile]
 867                 [src/vm/jit/loop/Makefile]
 868                 [src/vm/jit/m68k/Makefile]
 869                 [src/vm/jit/m68k/linux/Makefile]
 870                 [src/vm/jit/mips/Makefile]
 871                 [src/vm/jit/mips/irix/Makefile]
 872                 [src/vm/jit/mips/linux/Makefile]
 873                 [src/vm/jit/mips/uclinux/Makefile]
 874                 [src/vm/jit/optimizing/Makefile]
 875                 [src/vm/jit/parisc/Makefile]
 876                 [src/vm/jit/parisc/linux/Makefile]
 877                 [src/vm/jit/powerpc/Makefile]
 878                 [src/vm/jit/powerpc/darwin/Makefile]
 879                 [src/vm/jit/powerpc/linux/Makefile]
 880                 [src/vm/jit/powerpc/netbsd/Makefile]
 881                 [src/vm/jit/powerpc64/Makefile]
 882                 [src/vm/jit/powerpc64/linux/Makefile]
 883                 [src/vm/jit/s390/Makefile]
 884                 [src/vm/jit/schedule/Makefile]
 885                 [src/vm/jit/sparc64/Makefile]
 886                 [src/vm/jit/sparc64/linux/Makefile]
 887                 [src/vm/jit/sparc64/solaris/Makefile]
 888                 [src/vm/jit/verify/Makefile]
 889                 [src/vm/jit/x86_64/Makefile]
 890                 [src/vm/jit/x86_64/freebsd/Makefile]
 891                 [src/vm/jit/x86_64/linux/Makefile]
 892                 [src/vmcore/Makefile]
 893                 [tests/Makefile]
 894                 [tests/regression/Makefile]
 895                 [tests/regression/codepatching/Makefile]
 896                 [tests/regression/jasmin/Makefile]
 897                 [tests/regression/native/Makefile]
 898                 [tests/regression/resolving/Makefile]
 899                 [tests/regression/resolving/classes1/Makefile]
 900                 [tests/regression/resolving/classes2/Makefile]
 901                 [tests/regression/resolving/classes3/Makefile]
 902 )
 903
 904
 905 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
 906 export OPT_CFLAGS
 907 export ARCH_CFLAGS
 908 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
 909
 910
 911 AC_OUTPUT
 912
 913
 914 ## Local variables:
 915 ## mode: m4
 916 ## indent-tabs-mode: t
 917 ## c-basic-offset: 4
 918 ## tab-width: 8
 919 ## compile-command: "automake --add-missing"
 920 ## End: