configure.ac

   1 dnl configure.ac
   2 dnl
   3 dnl Copyright (C) 1996-2005, 2006, 2007 R. Grafl, A. Krall, C. Kruegel,
   4 dnl C. Oates, R. Obermaisser, M. Platter, M. Probst, S. Ring,
   5 dnl E. Steiner, C. Thalinger, D. Thuernbeck, P. Tomsich, C. Ullrich,
   6 dnl J. Wenninger, Institut f. Computersprachen - TU Wien
   7 dnl
   8 dnl This file is part of CACAO.
   9 dnl
  10 dnl This program is free software; you can redistribute it and/or
  11 dnl modify it under the terms of the GNU General Public License as
  12 dnl published by the Free Software Foundation; either version 2, or (at
  13 dnl your option) any later version.
  14 dnl
  15 dnl This program is distributed in the hope that it will be useful, but
  16 dnl WITHOUT ANY WARRANTY; without even the implied warranty of
  17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  18 dnl General Public License for more details.
  19 dnl
  20 dnl You should have received a copy of the GNU General Public License
  21 dnl along with this program; if not, write to the Free Software
  22 dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  23 dnl 02110-1301, USA.
  24 dnl
  25 dnl $Id: configure.ac 8126 2007-06-21 10:42:35Z twisti $
  26
  27 dnl Process this file with autoconf to produce a configure script.
  28
  29
  30 AC_INIT(cacao, 0.98+svn, cacao@cacaojvm.org)
  31 AC_CONFIG_SRCDIR(src/cacao/cacao.c)
  32 AC_CANONICAL_HOST
  33 AC_PREREQ(2.59)
  34 AM_INIT_AUTOMAKE([1.9.0 dist-bzip2])
  35 AM_MAINTAINER_MODE
  36
  37 AM_CONFIG_HEADER([config.h])
  38
  39 AC_PREFIX_DEFAULT(/usr/local/cacao)
  40
  41
  42 dnl set optimization and debugging for all architectures and systems
  43 if test x"$CFLAGS" = "x"; then
  44     OPT_CFLAGS="-O0 -g3"
  45 else
  46     OPT_CFLAGS=$CFLAGS
  47 fi
  48
  49 dnl system type
  50 case "$host_cpu" in
  51 alpha | alphaev56 | alphapca56 )
  52     ARCH_DIR="alpha"
  53     ARCH_CFLAGS="-mieee -D__ALPHA__"
  54     ;;
  55
  56 arm | armv4 | armv4tl | armv5b | armv5l )
  57     ARCH_DIR="arm"
  58     ARCH_CFLAGS="-D__ARM__"
  59     ;;
  60
  61 hppa2.0 )
  62     ARCH_DIR="parisc"
  63     ARCH_CFLAGS="-D__PARISC__"
  64     ;;
  65
  66 i386 | i486 | i586 | i686 )
  67     ARCH_DIR="i386"
  68     ARCH_CFLAGS="-D__I386__"
  69     ;;
  70
  71 m68k )
  72     ARCH_DIR="m68k"
  73     ARCH_CFLAGS="-D__M68K__"
  74     ;;
  75
  76 mips | mipsel )
  77     ARCH_DIR="mips"
  78     ARCH_CFLAGS="-D__MIPS__"
  79     ;;
  80
  81 powerpc )
  82     ARCH_DIR="powerpc"
  83     ARCH_CFLAGS="-D__POWERPC__"
  84     ;;
  85
  86 powerpc64 )
  87     ARCH_DIR="powerpc64"
  88     ARCH_CFLAGS="-D__POWERPC64__"
  89     ;;
  90
  91 s390 )
  92     ARCH_DIR="s390"
  93     ARCH_CFLAGS="-D__S390__"
  94     ;;
  95
  96 sparc | sparc64 )
  97     ARCH_DIR="sparc64"
  98     ARCH_CFLAGS="-mcpu=v9 -m64 -D__SPARC_64__"
  99     ;;
 100
 101 x86_64 )
 102     ARCH_DIR="x86_64"
 103     ARCH_CFLAGS="-D__X86_64__"
 104     ;;
 105
 106 xdspcore )
 107     ARCH_DIR="xdspcore"
 108     ENABLE_STATICVM="yes"
 109     ARCH_CFLAGS="-D__XDSPCORE__"
 110     USE_SCHEDULER="1"
 111     ;;
 112
 113 * )
 114     AC_MSG_ERROR($host_cpu systems are not supported at this time)
 115     ;;
 116 esac
 117
 118 dnl host type
 119 case "$host_os" in
 120 *cygwin* )
 121     OS_DIR="cygwin"
 122     INTRP_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -Wall -Wno-long-long"
 123     ARCH_CFLAGS="$ARCH_CFLAGS -D__WINDOWS__ -D__CYGWIN__ -ansi -pedantic -Wall -Wno-long-long"
 124     ;;
 125
 126 *darwin* )
 127     OS_DIR="darwin"
 128     INTRP_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -Wall -Wno-long-long"
 129     ARCH_CFLAGS="$ARCH_CFLAGS -D__DARWIN__ -ansi -pedantic -Wall -Wno-long-long"
 130     ;;
 131
 132 *freebsd* )
 133     OS_DIR="freebsd"
 134     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 135     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_XOPEN_SOURCE_EXTENDED"
 136     ;;
 137
 138 *irix* )
 139     OS_DIR="irix"
 140     INTRP_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 141     ARCH_CFLAGS="$ARCH_CFLAGS -D__IRIX__"
 142     ;;
 143
 144 *kfreebsd*-gnu)
 145     OS_DIR="freebsd"
 146     INTRP_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 147     ARCH_CFLAGS="$ARCH_CFLAGS -D__FREEBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 148     ;;
 149
 150 dnl must be before *linux*
 151 *uclinux | *elf )
 152     OS_DIR="uclinux"
 153     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 154     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 155     ;;
 156
 157 *linux* | *Linux* )
 158     OS_DIR="linux"
 159     INTRP_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 160     ARCH_CFLAGS="$ARCH_CFLAGS -D__LINUX__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 161     ;;
 162
 163 *netbsd* )
 164     OS_DIR="netbsd"
 165     INTRP_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 166     ARCH_CFLAGS="$ARCH_CFLAGS -D__NETBSD__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D_BSD_SOURCE"
 167     ;;
 168
 169 *solaris* )
 170     OS_DIR="solaris"
 171         dnl on solaris the architecture defines 'sparc','sun','unix' are not set when cpp is called with -ansi
 172         dnl therefore we add them here
 173     INTRP_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 174     ARCH_CFLAGS="$ARCH_CFLAGS -D__SOLARIS__ -ansi -pedantic -Wall -Wno-long-long -D_POSIX_C_SOURCE=199506L -D_XOPEN_SOURCE=500 -D__EXTENSIONS__ -D_BSD_SOURCE -Dsparc -Dsun -Dunix"
 175     ;;
 176
 177 * )
 178     ;;
 179 esac
 180
 181
 182 dnl temporary set the CFLAGS for configure tests (e.g. inline keyword)
 183 dnl we set it properly at the end of this file
 184 CFLAGS="$ARCH_CFLAGS $OPT_CFLAGS"
 185
 186 dnl set interpreter flags
 187 AC_SUBST(INTRP_CFLAGS)
 188
 189 dnl define some stuff required for --fullversion
 190 AC_DEFINE_UNQUOTED(VERSION_CONFIGURE_ARGS, "$ac_configure_args", [configure arguments])
 191 AC_DEFINE_UNQUOTED(VERSION_CC, "$CC", [CC used])
 192 AC_DEFINE_UNQUOTED(VERSION_CFLAGS, "$OPT_CFLAGS $ARCH_CFLAGS", [CFLAGS used])
 193
 194
 195 dnl define and substitute some architecture specific variables
 196 AC_DEFINE_UNQUOTED([ARCH_DIR], "${ARCH_DIR}", [architecture directory])
 197 AC_SUBST(ARCH_DIR)
 198 AC_SUBST(OS_DIR)
 199 AC_SUBST(USE_SCHEDULER)
 200
 201
 202 dnl Checks for programs.
 203 AC_PROG_CC
 204 AM_PROG_AS
 205 AC_PROG_LD
 206 AC_PROG_LD_GNU
 207 AC_PROG_RANLIB
 208 AC_PROG_LN_S
 209 AC_PROG_MAKE_SET
 210 AM_PROG_MKDIR_P
 211
 212 dnl Checks for header files.
 213 AC_HEADER_DIRENT
 214 AC_HEADER_STDC
 215
 216 dnl keep them alpha-sorted!
 217 AC_CHECK_HEADERS([fcntl.h])
 218 AC_CHECK_HEADERS([stdlib.h])
 219 AC_CHECK_HEADERS([string.h])
 220 AC_CHECK_HEADERS([time.h])
 221 AC_CHECK_HEADERS([unistd.h])
 222 AC_CHECK_HEADERS([sys/ioctl.h])
 223 AC_CHECK_HEADERS([sys/mman.h])
 224 AC_CHECK_HEADERS([sys/resource.h])
 225 AC_CHECK_HEADERS([sys/select.h])
 226 AC_CHECK_HEADERS([sys/socket.h])
 227 AC_CHECK_HEADERS([sys/stat.h])
 228 AC_CHECK_HEADERS([sys/time.h])
 229 AC_CHECK_HEADERS([sys/types.h])
 230
 231 dnl this is for fdlibm
 232 AC_CHECK_HEADERS([stdint.h])
 233 AC_CHECK_HEADERS([inttypes.h])
 234 AC_CHECK_HEADERS([sys/config.h])
 235 AC_CHECK_HEADERS([sys/types.h])
 236 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 237 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1, [Define to 1 if you have uint32_t]))
 238 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 239 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1, [Define to 1 if you have BSD u_int32_t]))
 240
 241 dnl Checks for typedefs, structures, and compiler characteristics.
 242 AC_C_CONST
 243 AC_C_INLINE
 244 AC_C_ATTRIBUTE
 245 AC_TYPE_OFF_T
 246 AC_TYPE_SIZE_T
 247 AC_HEADER_TIME
 248 AC_STRUCT_TM
 249
 250 dnl Checks for library functions.
 251 AC_PROG_GCC_TRADITIONAL
 252 AC_TYPE_SIGNAL
 253 AC_FUNC_MEMCMP
 254 AC_FUNC_MMAP
 255
 256 dnl keep them alpha-sorted!
 257 AC_CHECK_FUNCS([accept])
 258 AC_CHECK_FUNCS([atoi])
 259 AC_CHECK_FUNCS([atol])
 260 AC_CHECK_FUNCS([calloc])
 261 AC_CHECK_FUNCS([close])
 262 AC_CHECK_FUNCS([confstr])
 263 AC_CHECK_FUNCS([connect])
 264 AC_CHECK_FUNCS([fflush])
 265 AC_CHECK_FUNCS([fopen])
 266 AC_CHECK_FUNCS([fprintf])
 267 AC_CHECK_FUNCS([free])
 268 AC_CHECK_FUNCS([fstat])
 269 AC_CHECK_FUNCS([getcwd])
 270 AC_CHECK_FUNCS([gethostname])
 271 AC_CHECK_FUNCS([getpagesize])
 272 AC_CHECK_FUNCS([getrusage])
 273 AC_CHECK_FUNCS([getsockname])
 274 AC_CHECK_FUNCS([gettimeofday])
 275 AC_CHECK_FUNCS([ioctl])
 276 AC_CHECK_FUNCS([isnan])
 277 AC_CHECK_FUNCS([listen])
 278 AC_CHECK_FUNCS([localtime])
 279 AC_CHECK_FUNCS([localtime_r])
 280 AC_CHECK_FUNCS([lseek])
 281 AC_CHECK_FUNCS([mmap])
 282 AC_CHECK_FUNCS([mprotect])
 283 AC_CHECK_FUNCS([open])
 284 AC_CHECK_FUNCS([scandir])
 285 AC_CHECK_FUNCS([select])
 286 AC_CHECK_FUNCS([setsockopt])
 287 AC_CHECK_FUNCS([shutdown])
 288 AC_CHECK_FUNCS([socket])
 289 AC_CHECK_FUNCS([strchr])
 290 AC_CHECK_FUNCS([strdup])
 291 AC_CHECK_FUNCS([strerror])
 292 AC_CHECK_FUNCS([strncmp])
 293 AC_CHECK_FUNCS([strstr])
 294 AC_CHECK_FUNCS([time])
 295
 296
 297 dnl Checks for libraries.
 298
 299 dnl Checking sizeof void *
 300 AC_CHECK_SIZEOF(void *)
 301 AC_C_BIGENDIAN
 302
 303
 304 dnl define install prefix
 305 if test "x$prefix" = "xNONE"; then
 306     CACAO_PREFIX=$ac_default_prefix
 307 else
 308     CACAO_PREFIX=$prefix
 309 fi
 310 AC_DEFINE_UNQUOTED([CACAO_PREFIX], "${CACAO_PREFIX}", [installation prefix])
 311 AC_SUBST(CACAO_PREFIX)
 312
 313 dnl define libdir prefix
 314 if test "x$libdir" = "xNONE"; then
 315     CACAO_LIBDIR=$ac_default_libdir
 316 else
 317     CACAO_LIBDIR=$libdir
 318 fi
 319 dnl expand CACAO_LIBDIR to something that is usable in C code
 320 AS_AC_EXPAND([CACAO_LIBDIR], ${CACAO_LIBDIR})
 321 AC_DEFINE_UNQUOTED([CACAO_LIBDIR], "${CACAO_LIBDIR}", [library installation prefix])
 322 AC_SUBST(CACAO_LIBDIR)
 323
 324
 325 dnl Features
 326
 327 AC_CHECK_ENABLE_JAVA
 328 AC_CHECK_ENABLE_JIT
 329
 330 dnl with-options
 331 AC_CHECK_WITH_CACAOH
 332
 333 dnl check for stuff that should be done in software
 334 AC_CHECK_SOFTFLOAT
 335 AC_CHECK_SOFT_FLOAT_CMP
 336 AC_CHECK_SOFT_DOUBLE_CMP
 337
 338
 339 dnl check for interpreter
 340 AC_ARG_ENABLE([intrp], [AS_HELP_STRING(--enable-intrp,enable interpreter [[default=no]])])
 341
 342 AC_MSG_CHECKING(whether interpreter should be compiled)
 343 if test x"$enable_intrp" = "xyes"; then
 344     AC_MSG_RESULT(yes)
 345     AC_DEFINE([ENABLE_INTRP], 1, [enable interpreter])
 346     AM_CONDITIONAL([ENABLE_INTRP], [true])
 347     ENABLE_INTRP=yes
 348
 349     AC_ASM_SKIP16
 350
 351     dnl check for libffi
 352     AC_ARG_WITH([ffi],
 353                 [AS_HELP_STRING(--with-ffi,use libffi to call native functions)],
 354                 [WITH_FFI=yes
 355                  AC_CHECK_HEADERS([ffi.h],, [AC_MSG_ERROR(cannot find ffi.h)])
 356                  AC_CHECK_LIB(ffi, ffi_call,, [AC_MSG_ERROR(cannot find libffi)])
 357                  AC_DEFINE([WITH_FFI], 1, [use libffi])],
 358                 [WITH_FFI=no])
 359
 360     dnl check for libffcall
 361     AC_ARG_WITH([ffcall],
 362                 [AS_HELP_STRING(--with-ffcall,use libffcall to call native functions)],
 363                 [WITH_FFCALL=yes
 364                  AC_CHECK_HEADERS([avcall.h],, [AC_MSG_ERROR(cannot find avcall.h)])
 365                  AC_CHECK_LIB(avcall, __builtin_avcall,, [AC_MSG_ERROR(cannot find libavcall (from libffcall))])
 366                  AC_DEFINE([WITH_FFCALL], 1, [use libffcall])],
 367                 [WITH_FFCALL=no])
 368
 369     dnl check for libffi or libffcall
 370     if test x"${WITH_FFI}" = "xyes" -a x"${WITH_FFCALL}" = "xyes"; then
 371         AC_ERROR(Enable only libffi or libffcall.)
 372     fi
 373     if test x"${WITH_FFI}" = "xno" -a x"${WITH_FFCALL}" = "xno"; then
 374         AC_ERROR(Enable one of libffi or libffcall.)
 375     fi
 376
 377 else
 378     AC_MSG_RESULT(no)
 379     AM_CONDITIONAL([ENABLE_INTRP], [false])
 380     ENABLE_INTRP="no"
 381 fi
 382
 383 if test x"${ENABLE_JIT}" = "xno" -a x"${ENABLE_INTRP}" = "xno"; then
 384     AC_ERROR(You have to enable at least the JIT or the interpreter.)
 385 fi
 386
 387
 388 dnl check for garbage collector usage
 389 AC_ARG_ENABLE([gc], [AS_HELP_STRING(--enable-gc,enable garbage collector support (none,boehm,cacao) [[default=boehm]])])
 390 AC_MSG_CHECKING(whether GC should be enabled)
 391 enable_gc=${enable_gc:-boehm}
 392 case "$enable_gc" in
 393 no | none)
 394     AC_DEFINE([DISABLE_GC], 1, [disable garbage collector])
 395     ENABLE_GC=none
 396     AC_MSG_RESULT(no)
 397     ;;
 398
 399 boehm)
 400     AC_DEFINE([ENABLE_GC_BOEHM], 1, [enable conservative boehm-gc])
 401     ENABLE_GC=boehm
 402     AC_MSG_RESULT(yes, boehm-gc)
 403     ;;
 404
 405 cacao)
 406     AC_DEFINE([ENABLE_GC_CACAO], 1, [enable exact cacao-gc])
 407     ENABLE_GC=cacao
 408     AC_MSG_RESULT(yes, cacao-gc)
 409     ;;
 410
 411 *)
 412     AC_MSG_ERROR($enable_gc is an unknown garbage collector package)
 413     ;;
 414 esac
 415 AM_CONDITIONAL([DISABLE_GC], test x"${ENABLE_GC}" = "xnone")
 416 AM_CONDITIONAL([ENABLE_GC_BOEHM], test x"${ENABLE_GC}" = "xboehm")
 417 AM_CONDITIONAL([ENABLE_GC_CACAO], test x"${ENABLE_GC}" = "xcacao")
 418
 419
 420
 421 dnl check for dump memory usage
 422 AC_MSG_CHECKING(whether dump memory should be disabled)
 423 AC_ARG_ENABLE([dump],
 424               [AS_HELP_STRING(--disable-dump,disable dump memory (for debugging only!) [[default=yes]])],
 425               [case "${enableval}" in
 426                    no)
 427                        DISABLE_DUMP=yes
 428                        AC_DEFINE([DISABLE_DUMP], 1, [disable dump memory])
 429                        ;;
 430                    *) DISABLE_DUMP=no;;
 431                esac],
 432                [DISABLE_DUMP=no])
 433 AC_MSG_RESULT(${DISABLE_DUMP})
 434
 435
 436 dnl check for debug
 437 AC_MSG_CHECKING(whether debug code generation should be enabled)
 438 AC_ARG_ENABLE([debug],
 439               [AS_HELP_STRING(--disable-debug,disable debug code generation [[default=yes]])],
 440               [case "${enableval}" in
 441                    no) NDEBUG=yes
 442                        AC_DEFINE([NDEBUG], 1, [disable debug code])
 443                        ;;
 444                    *) NDEBUG=no;;
 445                esac],
 446               [NDEBUG=no])
 447
 448 if test x"${NDEBUG}" = "xno"; then
 449     AC_MSG_RESULT(yes)
 450 else
 451     AC_MSG_RESULT(no)
 452 fi
 453 AM_CONDITIONAL([NDEBUG], test x"${NDEBUG}" = "xyes")
 454
 455
 456 dnl check for memcheck support
 457 AC_MSG_CHECKING(whether debugging memory checks should be enabled)
 458 AC_ARG_ENABLE([memcheck],
 459               [AS_HELP_STRING(--enable-memcheck,enable debugging memory checks [[default=no]])],
 460               [case "${enableval}" in
 461                    yes) ENABLE_MEMCHECK=yes;;
 462                    *) ENABLE_MEMCHECK=no;;
 463                esac],
 464               [ENABLE_MEMCHECK=no])
 465 AC_MSG_RESULT(${ENABLE_MEMCHECK})
 466 AM_CONDITIONAL([ENABLE_MEMCHECK], test x"${ENABLE_MEMCHECK}" = "xyes")
 467
 468 if test x"${ENABLE_MEMCHECK}" = "xyes"; then
 469     AC_DEFINE([ENABLE_MEMCHECK], 1, [perform debugging memory checks])
 470 fi
 471
 472
 473 dnl check for vmlog support
 474 AC_MSG_CHECKING(whether vmlog tracing should be enabled)
 475 AC_ARG_ENABLE([vmlog],
 476               [AS_HELP_STRING(--enable-vmlog,enable vmlog tracing [[default=no]])],
 477               [case "${enableval}" in
 478                    yes) ENABLE_VMLOG=yes;;
 479                    *) ENABLE_VMLOG=no;;
 480                esac],
 481               [ENABLE_VMLOG=no])
 482 AC_MSG_RESULT(${ENABLE_VMLOG})
 483 AM_CONDITIONAL([ENABLE_VMLOG], test x"${ENABLE_VMLOG}" = "xyes")
 484
 485 if test x"${ENABLE_VMLOG}" = "xyes"; then
 486     AC_DEFINE([ENABLE_VMLOG], 1, [enable vmlog tracing code])
 487 fi
 488
 489
 490 dnl check for disassembler support
 491 AC_MSG_CHECKING(whether disassembler should be enabled)
 492 AC_ARG_ENABLE([disassembler],
 493               [AS_HELP_STRING(--enable-disassembler,enable disassembler [[default=no]])],
 494               [case "${enableval}" in
 495                    yes) ENABLE_DISASSEMBLER=yes;;
 496                    *) ENABLE_DISASSEMBLER=no;;
 497                esac],
 498               [ENABLE_DISASSEMBLER=no])
 499 AC_MSG_RESULT(${ENABLE_DISASSEMBLER})
 500 AM_CONDITIONAL([ENABLE_DISASSEMBLER], test x"${ENABLE_DISASSEMBLER}" = "xyes")
 501
 502 if test x"${ENABLE_DISASSEMBLER}" = "xyes"; then
 503     AC_DEFINE([ENABLE_DISASSEMBLER], 1, [enable disassembler])
 504
 505     dnl check for binutils headers and libraries on some architectures for the
 506     dnl disassembler
 507     case "${ARCH_DIR}" in
 508         arm | i386 | powerpc | x86_64 | sparc64 | powerpc64 | s390 | m68k)
 509             AC_CHECK_HEADER([ansidecl.h],, [AC_MSG_ERROR(cannot find ansidecl.h)])
 510             AC_CHECK_HEADER([symcat.h],, [AC_MSG_ERROR(cannot find symcat.h)])
 511             AC_CHECK_HEADER([bfd.h],, [AC_MSG_ERROR(cannot find bfd.h)])
 512             AC_CHECK_HEADER([dis-asm.h],, [AC_MSG_ERROR(cannot find dis-asm.h)])
 513
 514             case "${OS_DIR}" in
 515                 cygwin | darwin | netbsd | solaris)
 516                      AC_CHECK_LIB(intl, dcgettext,, [AC_MSG_ERROR(cannot find libintl (from binutils))])
 517                      ;;
 518             esac
 519
 520             AC_CHECK_LIB(iberty, xstrerror,, [AC_MSG_ERROR(cannot find libiberty (from binutils))])
 521             AC_CHECK_LIB(bfd, bfd_get_arch,, [AC_MSG_ERROR(cannot find libbfd (from binutils))])
 522             AC_CHECK_LIB(opcodes, disassembler,, [AC_MSG_ERROR(cannot find libopcodes (from binutils))])
 523             AC_DEFINE([WITH_BINUTILS_DISASSEMBLER], 1, [use binutils disassembler])
 524             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [true])
 525             ;;
 526         * )
 527             AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 528             ;;
 529     esac
 530 else
 531     AM_CONDITIONAL([WITH_BINUTILS_DISASSEMBLER], [false])
 532 fi
 533
 534
 535 dnl check for statistics
 536 AC_MSG_CHECKING(whether statistics generation should be enabled)
 537 AC_ARG_ENABLE([statistics],
 538               [AS_HELP_STRING(--enable-statistics,enable statistics generation [[default=no]])],
 539               [case "${enableval}" in
 540                    yes) ENABLE_STATISTICS=yes;;
 541                    *) ENABLE_STATISTICS=no;;
 542                esac],
 543               [ENABLE_STATISTICS=no])
 544 AC_MSG_RESULT(${ENABLE_STATISTICS})
 545 AM_CONDITIONAL([ENABLE_STATISTICS], test x"${ENABLE_STATISTICS}" = "xyes")
 546
 547 if test x"${ENABLE_STATISTICS}" = "xyes"; then
 548     AC_DEFINE([ENABLE_STATISTICS], 1, [enable statistics])
 549 fi
 550
 551
 552 dnl check for verifier
 553 AC_MSG_CHECKING(whether classfile verification should be enabled)
 554 AC_ARG_ENABLE([verifier],
 555               [AS_HELP_STRING(--disable-verifier,disable classfile verification [[default=yes]])],
 556               [case "${enableval}" in
 557                    no) ENABLE_VERIFIER=no;;
 558                    *) ENABLE_VERIFIER=yes;;
 559                esac],
 560               [ENABLE_VERIFIER=yes])
 561 AC_MSG_RESULT(${ENABLE_VERIFIER})
 562 AM_CONDITIONAL([ENABLE_VERIFIER], test x"${ENABLE_VERIFIER}" = "xyes")
 563
 564 if test x"${ENABLE_VERIFIER}" = "xyes"; then
 565     AC_DEFINE([ENABLE_VERIFIER], 1, [enable classfile verification])
 566 fi
 567
 568
 569 dnl check for compiler timing
 570 AC_MSG_CHECKING(whether real-time timing should be enabled)
 571 AC_ARG_ENABLE([rt-timing],
 572               [AS_HELP_STRING(--enable-rt-timing,enable real-time timing [[default=no]])],
 573               [case "${enableval}" in
 574                    yes) ENABLE_RT_TIMING=yes;;
 575                    *) ENABLE_RT_TIMING=no;;
 576                esac],
 577               [ENABLE_RT_TIMING=no])
 578 AC_MSG_RESULT(${ENABLE_RT_TIMING})
 579 AM_CONDITIONAL([ENABLE_RT_TIMING], test x"${ENABLE_RT_TIMING}" = "xyes")
 580
 581 if test x"${ENABLE_RT_TIMING}" = "xyes"; then
 582     AC_DEFINE([ENABLE_RT_TIMING], 1, [enable real-time timing])
 583 fi
 584
 585
 586 dnl check for cycle count statistics
 587 AC_MSG_CHECKING(whether cycle count statistics should be enabled)
 588 AC_ARG_ENABLE([cycles-stats],
 589               [AS_HELP_STRING(--enable-cycles-stats,enable cycle count statistics [[default=no]])],
 590               [case "${enableval}" in
 591                    yes) ENABLE_CYCLES_STATS=yes;;
 592                    *) ENABLE_CYCLES_STATS=no;;
 593                esac],
 594               [ENABLE_CYCLES_STATS=no])
 595 AC_MSG_RESULT(${ENABLE_CYCLES_STATS})
 596 AM_CONDITIONAL([ENABLE_CYCLES_STATS], test x"${ENABLE_CYCLES_STATS}" = "xyes")
 597
 598 if test x"${ENABLE_CYCLES_STATS}" = "xyes"; then
 599     AC_DEFINE([ENABLE_CYCLES_STATS], 1, [enable cycle count statistics])
 600 fi
 601
 602
 603 dnl check for JVMTI
 604 AC_MSG_CHECKING(whether to compile JVMTI support)
 605 AC_ARG_ENABLE([jvmti],
 606               [AS_HELP_STRING(--enable-jvmti,enable JVMTI [[default=no]])],
 607               [case "${enableval}" in
 608                    yes) ENABLE_JVMTI=yes;;
 609                    *) ENABLE_JVMTI=no;;
 610                esac],
 611               [ENABLE_JVMTI=no])
 612 AC_MSG_RESULT(${ENABLE_JVMTI})
 613 AM_CONDITIONAL([ENABLE_JVMTI], test x"${ENABLE_JVMTI}" = "xyes")
 614
 615 if test x"${ENABLE_JVMTI}" = "xyes"; then
 616     AC_DEFINE([ENABLE_JVMTI], 1, [use JVMTI])
 617 fi
 618
 619
 620 AC_CHECK_ENABLE_THREADS
 621
 622
 623 dnl check if if-conversion should be supported
 624 AC_MSG_CHECKING(whether if-conversion should be supported)
 625 AC_ARG_ENABLE([ifconv],
 626               [AS_HELP_STRING(--disable-ifconv,disable if-conversion [[default=yes]])],
 627               [case "${enableval}" in
 628                    no) ENABLE_IFCONV=no;;
 629                    *) ENABLE_IFCONV=yes;;
 630                esac],
 631               [ENABLE_IFCONV=yes])
 632 AC_MSG_RESULT(${ENABLE_IFCONV})
 633 AM_CONDITIONAL([ENABLE_IFCONV], test x"${ENABLE_IFCONV}" = "xyes")
 634
 635 if test x"${ENABLE_IFCONV}" = "xyes"; then
 636     AC_DEFINE([ENABLE_IFCONV], 1, [enable if-conversion])
 637 fi
 638
 639
 640 dnl check for inlining
 641 AC_MSG_CHECKING(whether method inlining should be supported)
 642 AC_ARG_ENABLE([inlining],
 643               [AS_HELP_STRING(--enable-inlining,enable method inlining [[default=no]])],
 644               [case "${enableval}" in
 645                    yes) ENABLE_INLINING=yes;;
 646                    *) ENABLE_INLINING=no;;
 647                esac],
 648               [ENABLE_INLINING=no])
 649 AC_MSG_RESULT(${ENABLE_INLINING})
 650 AM_CONDITIONAL([ENABLE_INLINING], test x"${ENABLE_INLINING}" = "xyes")
 651
 652 if test x"${ENABLE_INLINING}" = "xyes"; then
 653     AC_DEFINE([ENABLE_INLINING], 1, [use method inlining])
 654 fi
 655
 656
 657 dnl check for inlining debug options
 658 AC_MSG_CHECKING(whether method inlining debug options should be enabled)
 659 AC_ARG_ENABLE([inlining-debug],
 660               [AS_HELP_STRING(--enable-inlining-debug,enable method inlining debug options [[default=no]])],
 661               [case "${enableval}" in
 662                    yes) ENABLE_INLINING_DEBUG=yes;;
 663                    *) ENABLE_INLINING_DEBUG=no;;
 664                esac],
 665               [ENABLE_INLINING_DEBUG=no])
 666 AC_MSG_RESULT(${ENABLE_INLINING_DEBUG})
 667 AM_CONDITIONAL([ENABLE_INLINING_DEBUG], test x"${ENABLE_INLINING_DEBUG}" = "xyes")
 668
 669 if test x"${ENABLE_INLINING_DEBUG}" = "xyes"; then
 670     AC_DEFINE([ENABLE_INLINING_DEBUG], 1, [enable method inlining debug options])
 671 fi
 672
 673
 674 dnl check for replacement
 675 AC_MSG_CHECKING(whether on-stack replacement should be supported)
 676 AC_ARG_ENABLE([replacement],
 677               [AS_HELP_STRING(--enable-replacement,enable on-stack replacement [[default=no]])],
 678               [case "${enableval}" in
 679                    yes) ENABLE_REPLACEMENT=yes;;
 680                    *) ENABLE_REPLACEMENT=no;;
 681                esac],
 682               [ENABLE_REPLACEMENT=no])
 683 AC_MSG_RESULT(${ENABLE_REPLACEMENT})
 684 AM_CONDITIONAL([ENABLE_REPLACEMENT], test x"${ENABLE_REPLACEMENT}" = "xyes")
 685
 686 if test x"${ENABLE_REPLACEMENT}" = "xyes"; then
 687     AC_DEFINE([ENABLE_REPLACEMENT], 1, [use on-stack replacement])
 688 fi
 689
 690
 691 dnl check for loop optimization
 692 AC_MSG_CHECKING(whether loop optimization should be supported)
 693 AC_ARG_ENABLE([loop],
 694               [AS_HELP_STRING(--enable-loop,enable loop optimization [[default=no]])],
 695               [case "${enableval}" in
 696                    yes) ENABLE_LOOP=yes;;
 697                    *) ENABLE_LOOP=no;;
 698                esac],
 699               [ENABLE_LOOP=no])
 700 AC_MSG_RESULT(${ENABLE_LOOP})
 701 AM_CONDITIONAL([ENABLE_LOOP], test x"${ENABLE_LOOP}" = "xyes")
 702
 703 if test x"${ENABLE_LOOP}" = "xyes"; then
 704     AC_DEFINE([ENABLE_LOOP], 1, [use loop optimization])
 705 fi
 706
 707
 708 dnl check if linear scan register allocator(lsra) with SSA should be used
 709 AC_MSG_CHECKING(whether lsra with ssa should be supported)
 710 AC_ARG_ENABLE([ssa],
 711               [AS_HELP_STRING(--disable-ssa,disable ssa [[default=no]])],
 712               [case "${enableval}" in
 713                    no) ENABLE_SSA=no;;
 714                    *) ENABLE_SSA=yes;;
 715                esac],
 716               [ENABLE_SSA=no])
 717 AC_MSG_RESULT(${ENABLE_SSA})
 718 AM_CONDITIONAL([ENABLE_SSA], test x"${ENABLE_SSA}" = "xyes")
 719
 720 if test x"${ENABLE_SSA}" = "xyes"; then
 721     AC_DEFINE([ENABLE_SSA], 1, [enable lsra with ssa])
 722     ENABLE_LSRA="no"
 723 fi
 724
 725
 726 dnl check if linear scan register allocator(lsra) should be used
 727 AC_MSG_CHECKING(whether lsra should be supported)
 728 AC_ARG_ENABLE([lsra],
 729               [AS_HELP_STRING(--enable-lsra,enable linear scan register allocator [[default=no]])],
 730               [case "${enableval}" in
 731                    yes) ENABLE_LSRA=yes;;
 732                    *) ENABLE_LSRA=no;;
 733                esac],
 734               [ENABLE_LSRA=no])
 735
 736 if test x"${ENABLE_LSRA}" = "xyes"; then
 737     if test x"${ENABLE_SSA}" = "xyes"; then
 738         ENABLE_LSRA="no"
 739     fi
 740 fi
 741 AC_MSG_RESULT(${ENABLE_LSRA})
 742 AM_CONDITIONAL([ENABLE_LSRA], test x"${ENABLE_LSRA}" = "xyes")
 743
 744 if test x"${ENABLE_LSRA}" = "xyes"; then
 745     AC_DEFINE([ENABLE_LSRA], 1, [enable lsra])
 746 fi
 747
 748
 749 dnl check if profiling should be supported
 750 AC_MSG_CHECKING(whether profiling should be supported)
 751 AC_ARG_ENABLE([profiling],
 752               [AS_HELP_STRING(--enable-profiling,enable profiling [[default=no]])],
 753               [case "${enableval}" in
 754                    yes) ENABLE_PROFILING=yes;;
 755                    *) ENABLE_PROFILING=no;;
 756                esac],
 757               [ENABLE_PROFILING=no])
 758 AC_MSG_RESULT(${ENABLE_PROFILING})
 759 AM_CONDITIONAL([ENABLE_PROFILING], test x"${ENABLE_PROFILING}" = "xyes")
 760
 761 if test x"${ENABLE_PROFILING}" = "xyes"; then
 762     AC_DEFINE([ENABLE_PROFILING], 1, [enable profiling])
 763 fi
 764
 765
 766 dnl check for instruction scheduler
 767 AC_ARG_ENABLE([scheduler], [AS_HELP_STRING(--enable-scheduler,enable instruction scheduler [[default=no]])])
 768
 769 AC_MSG_CHECKING(whether instruction scheduler should be supported)
 770 if test x"${USE_SCHEDULER}" = "x1" -o x"$enable_scheduler" = "xyes"; then
 771         case "${ARCH_DIR}" in
 772                 xdspcore )
 773                         ;;
 774                 * )
 775                         AC_MSG_ERROR(instruction scheduler is not available for ${ARCH_DIR} code generator)
 776                         ;;
 777         esac
 778
 779         AC_MSG_RESULT(yes)
 780         AC_DEFINE([USE_SCHEDULER], 1, [use scheduler])
 781         AM_CONDITIONAL([USE_SCHEDULER], [true])
 782 else
 783         AC_MSG_RESULT(no)
 784         AM_CONDITIONAL([USE_SCHEDULER], [false])
 785 fi
 786
 787
 788 dnl check if zlib should be used
 789 AC_MSG_CHECKING(whether ZIP/JAR archives should be supported)
 790 AC_ARG_ENABLE([zlib],
 791               [AS_HELP_STRING(--disable-zlib,disable ZIP/JAR archive support (needs zlib) [[default=yes]])],
 792               [case "${enableval}" in
 793                   no) ENABLE_ZLIB=no;;
 794                   *) ENABLE_ZLIB=yes;;
 795                esac],
 796               [ENABLE_ZLIB=yes])
 797 AC_MSG_RESULT(${ENABLE_ZLIB})
 798
 799 if test x"${ENABLE_ZLIB}" = "xyes"; then
 800     AC_CHECK_HEADERS([zconf.h],, [AC_MSG_ERROR(cannot find zconf.h)])
 801     AC_CHECK_HEADERS([zlib.h],, [AC_MSG_ERROR(cannot find zlib.h)])
 802     AC_CHECK_LIB(z, inflate,, [AC_MSG_ERROR(cannot find libz)])
 803     AC_DEFINE([ENABLE_ZLIB], 1, [use zlib])
 804 fi
 805 AM_CONDITIONAL([ENABLE_ZLIB], test x"${ENABLE_ZLIB}" = "xyes")
 806
 807
 808 dnl check for stuff to be built
 809 AC_CHECK_ENABLE_JNI
 810
 811
 812 dnl check if a libjvm.so should be built
 813 AC_MSG_CHECKING(whether to build a libjvm.so)
 814 AC_ARG_ENABLE([libjvm],
 815               [AS_HELP_STRING(--disable-libjvm,build a libjvm.so [[default=yes]])],
 816               [case "${enableval}" in
 817                   no) ENABLE_LIBJVM=no;;
 818                   *) ENABLE_LIBJVM=yes;;
 819                esac],
 820               [ENABLE_LIBJVM=yes])
 821 AC_MSG_RESULT(${ENABLE_LIBJVM})
 822 AM_CONDITIONAL([ENABLE_LIBJVM], test x"${ENABLE_LIBJVM}" = "xyes")
 823 AC_SUBST(ENABLE_LIBJVM)
 824
 825 if test x"${ENABLE_LIBJVM}" = "xyes"; then
 826     AC_DEFINE([ENABLE_LIBJVM], 1, [enable libjvm.so])
 827
 828     dnl set AC_ENABLE_SHARED and AC_DISABLE_STATIC properly
 829     enable_shared=yes
 830     enable_static=no
 831 else
 832     enable_shared=no
 833     enable_static=yes
 834 fi
 835
 836 dnl libtool stuff
 837 AC_LIBTOOL_DLOPEN
 838 AC_PROG_LIBTOOL
 839
 840
 841 dnl check if CACAO should be linked statically
 842 AC_MSG_CHECKING(whether to link CACAO statically)
 843 AC_ARG_ENABLE([staticvm],
 844               [AS_HELP_STRING(--enable-staticvm,link CACAO statically [[default=no]])],
 845               [case "${enableval}" in
 846                   yes) ENABLE_STATICVM=yes
 847                        AC_DEFINE([ENABLE_STATICVM], 1, [link CACAO statically])
 848                        ;;
 849                   *) ENABLE_STATICVM=no;;
 850                esac],
 851               [ENABLE_STATICVM=no])
 852 AC_MSG_RESULT(${ENABLE_STATICVM})
 853 AM_CONDITIONAL([ENABLE_STATICVM], test x"${ENABLE_STATICVM}" = "xyes")
 854 AC_SUBST(ENABLE_STATICVM)
 855
 856
 857 dnl where is CACAO's vm.zip
 858 AC_MSG_CHECKING(where CACAO's vm.zip is installed)
 859 AC_ARG_WITH([vm-zip],
 860             [AS_HELP_STRING(--with-vm-zip=<path>,path to CACAO's vm.zip (includes the name of the file and may be flat) [[default=/usr/local/cacao/share/cacao/vm.zip]])],
 861             [CACAO_VM_ZIP=${withval}],
 862             [CACAO_VM_ZIP=${CACAO_PREFIX}/share/cacao/vm.zip])
 863 AC_MSG_RESULT(${CACAO_VM_ZIP})
 864 AC_DEFINE_UNQUOTED([CACAO_VM_ZIP], "${CACAO_VM_ZIP}", [CACAO's vm.zip])
 865 AC_SUBST(CACAO_VM_ZIP)
 866
 867
 868 AC_CHECK_WITH_CLASSPATH
 869 AC_CHECK_WITH_CLASSPATH_PREFIX
 870 AC_CHECK_WITH_CLASSPATH_CLASSES
 871 AC_CHECK_WITH_CLASSPATH_LIBDIR
 872 AC_CHECK_WITH_CLASSPATH_INCLUDEDIR
 873
 874
 875 dnl if we compile for a JRE-style directory layout
 876 AC_MSG_CHECKING(if we compile for a JRE-style directory layout)
 877 AC_ARG_WITH([jre-layout],
 878             [AS_HELP_STRING(--with-jre-layout,compile for JRE-style directory layout [[default=no]])],
 879             [case "${enableval}" in
 880                 yes) WITH_JRE_LAYOUT=yes
 881                      AC_DEFINE([WITH_JRE_LAYOUT], 1, [with JRE layout])
 882                      ;;
 883                 *) WITH_JRE_LAYOUT=no;;
 884              esac],
 885             [WITH_JRE_LAYOUT=no])
 886 AC_MSG_RESULT(${WITH_JRE_LAYOUT})
 887
 888
 889 dnl check if GNU Classpath should be linked statically into CACAO
 890 AC_MSG_CHECKING(whether to link GNU Classpath native libraries statically into CACAO)
 891 AC_ARG_WITH([static-classpath],
 892             [AS_HELP_STRING(--with-static-classpath,link GNU classpath native libraries statically into CACAO [[default=no]])],
 893             [case "${enableval}" in
 894                 yes) WITH_STATIC_CLASSPATH=yes;;
 895                 *) WITH_STATIC_CLASSPATH=no;;
 896              esac],
 897             [WITH_STATIC_CLASSPATH=no])
 898 AC_MSG_RESULT(${WITH_STATIC_CLASSPATH})
 899
 900 if test x"${WITH_STATIC_CLASSPATH}" = "xyes"; then
 901     AC_DEFINE([WITH_STATIC_CLASSPATH], 1, [link GNU classpath native libraries statically into CACAO])
 902
 903     dnl check for some classpath related stuff when we link statically
 904     AM_ICONV_LINK
 905 else
 906     dnl we need this check for --enable-staticvm, otherwise ltdl can't find dlopen
 907     if test x"${ENABLE_STATICVM}" = "xyes"; then
 908         AC_CHECK_LIB(dl, dlopen,, [AC_MSG_ERROR(cannot find libdl)])
 909     fi
 910
 911     AC_CHECK_HEADERS([ltdl.h],, [AC_MSG_ERROR(cannot find ltdl.h)])
 912     AC_CHECK_LIB(ltdl, lt_dlopen,, [AC_MSG_ERROR(cannot find libltdl)])
 913 fi
 914 AM_CONDITIONAL([WITH_STATIC_CLASSPATH], test x"${WITH_STATIC_CLASSPATH}" = "xyes")
 915 AC_SUBST(WITH_STATIC_CLASSPATH)
 916
 917
 918 dnl check for some programs we need
 919 AC_PROG_JAVAC
 920 AC_PROG_JAR
 921
 922 AC_CHECK_HEADERS(
 923         [regex.h],
 924         [
 925                 dnl If debug build and regex.h available, enable debug filter
 926                 if test x"${NDEBUG}" = "xno"; then
 927                         AC_DEFINE(ENABLE_DEBUG_FILTER, 1, [debug filter])
 928                 fi
 929                 dnl If vmlog enambled and regex.h available, enable vmlogfilter
 930                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [test x"${ENABLE_VMLOG}" = "xyes"])
 931         ],
 932         [
 933                 AM_CONDITIONAL([ENABLE_VMLOGFILTER], [false])
 934         ]
 935 )
 936
 937 dnl finally pass CFLAGS to Makefiles via AM_CFLAGS
 938 CFLAGS=$OPT_CFLAGS
 939 AM_CFLAGS=$ARCH_CFLAGS
 940 AC_SUBST(AM_CFLAGS)
 941
 942
 943 AC_CONFIG_FILES([Makefile]
 944                 [contrib/Makefile]
 945                 [contrib/setenvinstalled]
 946                 [contrib/setenvsource]
 947                 [contrib/vmlog/Makefile]
 948                 [contrib/vmlog/t/Makefile]
 949                 [doc/Makefile]
 950                 [doc/handbook/Makefile]
 951                 [man/Makefile]
 952                 [src/Makefile]
 953                 [src/cacao/Makefile]
 954                 [src/cacaoh/Makefile]
 955                 [src/fdlibm/Makefile]
 956                 [src/lib/Makefile]
 957                 [src/mm/Makefile]
 958                 [src/mm/cacao-gc/Makefile]
 959                 [src/native/Makefile]
 960                 [src/native/include/Makefile]
 961                 [src/native/jvmti/Makefile]
 962                 [src/native/tools/Makefile]
 963                 [src/native/vm/Makefile]
 964                 [src/native/vm/cldc1.1/Makefile]
 965                 [src/native/vm/gnu/Makefile]
 966                 [src/scripts/Makefile]
 967                 [src/scripts/java]
 968                 [src/threads/Makefile]
 969                 [src/threads/native/Makefile]
 970                 [src/threads/none/Makefile]
 971                 [src/toolbox/Makefile]
 972                 [src/vm/Makefile]
 973                 [src/vm/jit/Makefile]
 974                 [src/vm/jit/allocator/Makefile]
 975                 [src/vm/jit/alpha/Makefile]
 976                 [src/vm/jit/alpha/freebsd/Makefile]
 977                 [src/vm/jit/alpha/linux/Makefile]
 978                 [src/vm/jit/arm/Makefile]
 979                 [src/vm/jit/arm/linux/Makefile]
 980                 [src/vm/jit/i386/Makefile]
 981                 [src/vm/jit/i386/cygwin/Makefile]
 982                 [src/vm/jit/i386/darwin/Makefile]
 983                 [src/vm/jit/i386/freebsd/Makefile]
 984                 [src/vm/jit/i386/linux/Makefile]
 985                 [src/vm/jit/intrp/Makefile]
 986                 [src/vm/jit/inline/Makefile]
 987                 [src/vm/jit/loop/Makefile]
 988                 [src/vm/jit/m68k/Makefile]
 989                 [src/vm/jit/m68k/linux/Makefile]
 990                 [src/vm/jit/mips/Makefile]
 991                 [src/vm/jit/mips/irix/Makefile]
 992                 [src/vm/jit/mips/linux/Makefile]
 993                 [src/vm/jit/mips/uclinux/Makefile]
 994                 [src/vm/jit/optimizing/Makefile]
 995                 [src/vm/jit/parisc/Makefile]
 996                 [src/vm/jit/parisc/linux/Makefile]
 997                 [src/vm/jit/powerpc/Makefile]
 998                 [src/vm/jit/powerpc/darwin/Makefile]
 999                 [src/vm/jit/powerpc/linux/Makefile]
1000                 [src/vm/jit/powerpc/netbsd/Makefile]
1001                 [src/vm/jit/powerpc64/Makefile]
1002                 [src/vm/jit/powerpc64/linux/Makefile]
1003                 [src/vm/jit/s390/Makefile]
1004                 [src/vm/jit/schedule/Makefile]
1005                 [src/vm/jit/sparc64/Makefile]
1006                 [src/vm/jit/sparc64/linux/Makefile]
1007                 [src/vm/jit/sparc64/solaris/Makefile]
1008                 [src/vm/jit/tools/Makefile]
1009                 [src/vm/jit/verify/Makefile]
1010                 [src/vm/jit/x86_64/Makefile]
1011                 [src/vm/jit/x86_64/freebsd/Makefile]
1012                 [src/vm/jit/x86_64/linux/Makefile]
1013                 [src/vmcore/Makefile]
1014                 [tests/Makefile]
1015                 [tests/regression/Makefile]
1016                 [tests/regression/codepatching/Makefile]
1017                 [tests/regression/jasmin/Makefile]
1018                 [tests/regression/native/Makefile]
1019                 [tests/regression/resolving/Makefile]
1020                 [tests/regression/resolving/classes1/Makefile]
1021                 [tests/regression/resolving/classes2/Makefile]
1022                 [tests/regression/resolving/classes3/Makefile]
1023                 )
1024
1025
1026 dnl now configure subpackages with OPT_CFLAGS and ARCH_CFLAGS
1027 export OPT_CFLAGS
1028 export ARCH_CFLAGS
1029 AC_CONFIG_SUBDIRS(src/mm/boehm-gc)
1030
1031
1032 AC_OUTPUT
1033
1034
1035 ## Local variables:
1036 ## mode: m4
1037 ## indent-tabs-mode: t
1038 ## c-basic-offset: 4
1039 ## tab-width: 8
1040 ## compile-command: "automake --add-missing"
1041 ## End: